82L4 ...[??? IPBACKJA SECT FILE FGN 65 DOC  
 84SB    #     THIS MACRO IS USED TO CALCULATE AND INSERT INTO ANY BSTB-BSLIST   
 85#2    #     BLOCK NOT USED AS A SWAP FILE, THE MINIMUM FREE BLOCKS VALUE  
 85RL    #     NECESSARY TO PREVENT THE UNJAMMER SYARTING
 86?=    #     FOR MK7 IT ALSO CALCULATES THE THRESHOLD VALUE
 86QW    #     NB. SPECIAL RESIDENCES HAVE BSJAML=BSTHRESH=0 (IE. 100%)  
 87=G    #   
 87Q6    #MAC  IPBACKJAM 
 889Q          LDX   2  BMISC               [FPTR TO FIRST BLOCK IN MISC CKALN   
 88PB          LDN   0  100  
 8992          LDX   1  BSAB 
 89NL    M1TJ
 8=8=          BXU   1  ATYPE(2),M2TJ       [J IF NOT BSLIST BLOCK   
 8=MW          LDX   6  BSLETH(2)
 8?7G          BNG   6  M2TJ                [J IF SWAP FILE  
 8?M6          STOZ     BSJAML(2)           [CLEAR BACKJAM LIMIT 
 8#6Q          STOZ     BSTHRESH(2)         [CLEAR BACKTHRESH LIMIT  
 8#LB          LDN   6  47                  [BSJAML AND BSTHRESH ZERO
 8*62          BXL   6  BACK1(2),M2TJ       [  FOR SPECIAL RESIDENCES
 8*KL ...      NGX   6  BSRESERVE(2)        [TOTAL BLOCK SIZE - SIZE RESERVE TANK
 8B5=          ADX   6  BSTOT(2)            [  TEMPORARILY HELD  
 8BJW          STO   6  BSTHRESH(2)         [  IN BSTHRESH   
 8C4G          LDX   6  0                   [100 
 8CJ6          SBX   6  BSJAM               [100- (BACKJAM)  
 8D3Q          MPY   6  BSTHRESH(2)         [MPY BY (SIZE OF BSUNIT-AWELL)   
 8DHB ...      DVD   6  0                   [FIND PERCENTAGE 
 8F32          STO   7  BSJAML(2)           [STORE JAM LIMIT VALUE   
 8FGL          LDN   7  0                   [NEEDED FOR CASE WHEN BACKTHRESH VALU
 8G2=          LDX   6  0                   [100 
 8GFW          SBX   6  BSJAM               [100- (BACKJAM)  
 8G^G          ADX   6  BACKTHRESH          [INCLUDE BACKTHRESH  
 8HF6          BNG   6  M3TJ                [ZERPIZE IF NEGATIVE 
 8HYQ          MPY   6  BSTHRESH(2)         [X BY (SIZE OF BSUNIT -AWELL)
 8JDB ...      DVD   6  0                   [FIND PERCENTAGE 
 8JY2    M3TJ  STO   7  BSTHRESH(2)         [STORE THRESHOLD VALUE   
 8KCL    M2TJ  LDX   2  0(2)                [UPDATE BLOCK POINTER
 8KX=          BXU   2  CXMI,M1TJ           [J IF MORE BLOCKS IN CHAIN   
 8LBW          LDX   1  FX1  
 8LWG          LDX   2  FX2  
 8MB6    #NOR