22FL    #OPT  K0DSCNCT=0
22^=    #LIS  K0DSCNCT>K0COMMAND>K0ALLGEO>K0GREATGEO
23DW    #SEG  DSCNCT                      [RICHARD GRIMWADE 
23JR ...[   
23NN ...[ (C)  COPYRIGHT INTERNATIONAL COMPUTERS LIMITED  1982  
23SK ...[   
23YG    #OPT  WELLTEST=0
24D6                   8HDSCNCT 
24XQ    #   
25CB    #     THIS SEGMENT IMPLEMENTS THE DISCONNECT COMMAND,WHICH RESTARTS THE 
25X2    #     JOB JUST BROKEN IN ON AS AN OFFLINE JOB,ALSO LOGGING IN AS A NEW O
26BL    #     JOB IF REQUESTED,USING ROUTINES IN SEGMENT LOGIN TO DO THIS . 
26W=    #   
27*W    #     ENTRY POINTS  
27TG    #   
28*6          SEGENTRY K1DSCNCT,XK1        [ DC COMMAND DIRECT  
28SQ          SEGENTRY K2DSCNCT,XK2        [ ENTRY FROM ENWELL  
29#B          SEGENTRY K3DSCNCT,XK3        [ UPDATE JWELL FOR CN/DC 
29D? ...      FSHENTRY K4DSCNCT,XK4,,XK4
29J8 ...      FSHENTRY K5DSCNCT,XK5,,XK5
29N5 ...      FSHENTRY K7DSCNCT,XK7,,XK7
29S2          SEGENTRY K99DSCNCT
29XX ...[   
2=3S ...[     SEGENTRY K25DSCNCT USED BY RESTORE TIME MACROS PRESETRP   
2=7P ...[     SEGENTRY K70DSCNCT IS USED BY RESTORE TIME MACRO REPORTNEST   
2=?L    #   
2=R=    PLINKLOGIN  
2?=W          PAIR     ENWELL,2 
2?QG    PLINKCOMPRO 
2#=6 ...      PAIR     COMPROA,1
2#PQ    PCONTEXT       #22012              [CONTEXT-NOT BRK-IN,TENT.ST. ,MOP
2*9B                                       [AND NO-USER.
2*F8 ...RCONTEXT       #20012   
2*K5 ...      SEGENTRY K25DSCNCT
2*P2    PRAMXMSK       +AMXMSKPR
2B8L    XONE           +1   
2BN=    TWO            +2   
2BY4 ...THREE          +3   
2C7W    #   
2CMG    #   
2D76    #   
2DLQ    #   
2F6B    XK1 
2FL2          PARUNACC                     [GET JOB NAME
2G5L          HUNT     3,CPB,CUNI   
2GK=          LDX   7  ANUM(3)  
2H4W          BNG   7  NOJOBNAME
2HJG          BZE   7  NOJOBNAME           [J NO JOB NAME SPECIFIED 
2J46          ACROSS   INITJOB,1
2LG=    XK2                                [RE-ENTRY FROM INITJOB   
2L^W          GETACT   CPAT 
2MFG          LDX   3  BPTR(2)             [GET AND LOCK A NEW CPA  
2M^6 ...      LDX   0  ACTNUM(3)
2NDQ ...      STO   0  EXT+1(2) 
2PD2          LDX   0  AWORK2(2)
2PXL    [   
2QC=    [     -3 FOR DC ENDING IN NO-USER CONTECT   
2QWW    [   
2RBG          SBN   0  1
2RW6          STO   0  AWORK2(3)
2S*Q          FJOCA    2
2STB          LDN   5  CPREFIX(3)   
2T*2          LDN   4  JUSER(2) 
2TSL          MOVE  4  3
2W#=          LINKSET  3,PLINKLOGIN(1)     [SET LINK TO ENTER AT K3LOGIN
2WRW          LDX   5  PCONTEXT(1)         [SET INITIAL CONTEXT=NOT BREAKIN,
2X?G          STO   5  CONTEXT(3)          [MOP,NO USER 
2XR6          LDX   2  FX2  
2Y=Q          HUNT     1,ADATA,CSTORE   
2YQB          BNG   1  NOCH 
2^=2          CHAIN 1,3 
2^PL    NOCH  HUNT     3,CPB,CUNI   
329=          CHAIN    3,BPTR(2)           [GIVE BLK CONTAINING JOB NAME
3GSG          LDX   3  BPTR(2)  
3H#6          HUNT     1,JWELL,COPYSYS     [ RECHAIN IF NECESSARY   
3HRQ          BNG   1  XCHAN               [ J IF NOT   
3J?B          CHAIN    1,3                 [ ELSE RECHAIN   
3JR2    XCHAN CHAINJWELL                   [ RECHAIN ANY OTHER JWELL BLOCKS 
3JRD ...#                          MAKE AND GIVE COPY OF PARAMETER BLK  
3JRW ...     MHUNTW    3,CPB,CALAS  
3JS# ...      LDX   4  ALOGLEN(3)   
3JSQ ...      GETCORE  4,1                 [GET BLK SAME SIZE   
3JT8 ...      FINDCORE 3
3JTL ...      NAME     3,CPB,CALAS  
3JW4 ...      CHAIN    3,BPTR(2)           [CHAIN AT END OF NEW ACTIVITY
3JWG ...     MHUNTW    3,CPB,CALAS  
3JWY ...      LDN   4  A1(3)
3JXB ...      SMO      BPTR(2)             [ADDR OF NEW CPB 
3JXS ...      LDN   5  A1   
3JY= ...      LDX   1  ALOGLEN(3)          [COPY CONTENTS OF OLD CPB TO NEW CPB 
3JYN ...      MOVE  4  0(1) 
3J^6 ...      SMO      BPTR(2)  
3J^J ...      STOZ     CPBCPLEV 
3K22 ...      LDX   0  GSIGN
3K2D ...      SMO   BPTR(2) 
3K2W ...      STO   0  CPBFSD   
3K3# ...      SMO      BPTR(2)  
3K3Q ...      STOZ     CMFMSK   
3K48 ...#                          MAKE AND GIVE COPY OF LINE BUFFER
3K4L ...     MHUNTW    3,CLB
3K54 ...      LDX   4  ALOGLEN(3)   
3K5G ...      GETCORE  4,1                 [GET BLK SAME SIZE   
3K5Y ...      FINDCORE 3
3K6B ...      NAME     3,CLB
3K6S ...      CHAIN    3,BPTR(2)           [CHAIN AT END OF NEW ACTIVITY
3K7= ...     MHUNTW    3,CLB
3K7N ...      LDN   4  A1(3)
3K86 ...      SMO      BPTR(2)             [ADDR OF NEW CLB 
3K8J ...      LDN   5  A1   
3K92 ...      LDX   1  ALOGLEN(3)          [COPY CONTENTS OF ORIGINAL CLB INTO  
3K9D ...      MOVE  4  0(1)                [NEW CLB 
3K=L    [   
3KQ=          LDX   6  JOBNO(2)            [ NOW UPDATE JWELL ETC...
3L9W          CALL  7  WELLAMMEND   
3LPG    [   
3S5B    #                          COMPLETE SETTING UP OF NEW CPA AND ADJUST
3SK2    #                          CURRENT CPA(I.E. MAKE OFF-LINE)  
3SR= ...      LDX   3  2
3S^G ...XFIND FINDACTFB 3,,CPAT,,,BPTR  
3T7Q ...      LDX   0  ACTNUM(3)
3TB2 ...      BXU   0  EXT+1(2),XFIND   
3TJ=          LDX   5  AMXMSK(2)
3W3W          STO   5  AMXMSK(3)           [IF STILL LOGGED IN, PASS ON REPORT S
3W4R ...#UNS CMXMSK 
3W5N ...(   
3W6K ...      HUNT2J   1,CPB,CALAS,3,NOCPB        [FIND NEW CPB/CALAS   
3W7G ...[   
3W8C ...      SEGENTRY K70DSCNCT
3W9# ...      BRN      XK71                 [THIS IS MENDED BY REPORTNEST   
3W=9 ...      STO    5 CMXMSK(1)
3W?6 ...      BRN      XK72 
3W#3 ...[   
3W#Y ...NOCPB GEOERR   1,CPBCALAS           [BREAK IF BLOCK NOT FOUND   
3W*T ...[   
3WBQ ...XK71
3WC8 ...      SEGENTRY K71DSCNCT
3WCM ...      STOZ     CMXMSK(1)            [ZERO IF REPORTNEST NOT ON  
3WDJ ...XK72
3WGB ...)   
3WHG    #     J IF HLS ON   
3X36          BSOFF    HLSBIT,SETCPAS   
3XGQ          LDN   5  #4000
3Y2B          ANDX  5  CONTEXT(2)   
3YG2          BZE   5  SETCPAS             [J IF MOP JOB NOT FULLY STARTED  
3Y^L          LDN   5  #6000
3^F=          ERS   5  CONTEXT(3)          [MAKE NEW MOP ACT FULLY STARTED  
3^YW    #     DISCONNECT WITH NO JOBNAME JOINS MAIN PATH HERE   
42DG    #     THE NEW ACTIVITY HAS NO JOBLOCK   
42Y6    TBCT
43CQ          LDX   5  HLSCOUNT+1          [LOAD BACKGROUND COUNT   
43XB          TXL   5  BACKGROUND   
44C2          BCC      NOMORE              [J IF NO. OFFLINE JOBS NOT<LIMIT 
44WL          ADN   5  1                   [INCREASE COUNT BY 1 
45B=          STO   5  HLSCOUNT+1          [STORE NEW VALUE OF COUNT
45G7 ...#   
45TW          BRN      SETCPAS  
46*G    NOMORE  
46T6          LDN   5  #6000
47#Q          ERS   5  CONTEXT(2)          [MAKE BACKGROUND JOB TENT. STARTED   
47CW ...      FJOCA    2
47H2 ...      NGNC  0  1
47L6 ...      ANDS  0  JURGE(2)            [CLEAR JOBBLOCK FS BIT   
47P= ...      LDX   2  FX2  
47SB    SETCPAS 
48RL          CNSOURCE 3,4  
49?=          LDX   4  AWORK1(2)
49QW          STO   4  AWORK1(3)           [MOVE ACROSS CONTEXT PRIVILEGES  
4==G          STOZ     AMXMSK(2)
4=#4 ...#UNS CMXMSK 
4=*L ...(   
4=C8 ...      SEGENTRY K72DSCNCT
4=DQ ...      BRN      XK73 
4=G# ...      SETCMXSK 2
4=HW ...      LDX   2  FX2  
4=KD ...XK73
4=M2 ...      SEGENTRY K73DSCNCT
4=NJ ...)   
4=Q6          LDX   5  JOBEVENTS(2) 
4?9Q          STOZ     JOBEVENTS(2) 
4?PB          STO   5  JOBEVENTS(3) 
4#92          LDN   5  #14                 [CHANGE CONTEXT OF CURRENT JOB FROM  
4#NL          ERS   5  CONTEXT(2)          [MOP TO OFFLINE  
4*8=          FJOCA    2
4*MW ...      LDCT  5  #500 
4J32          ORS   5  JMISC(2) 
4J88 ...      LDCT  5  #100 
4J*B ...      ERS   5  JMISC(2)            [SET OFFLINE AND CLEAR B-IN  
4JGL ...      LDX   2  3
4K^G          FPUT                         [ENTER AT K1COMPRO OR K3LOGIN)   
4LF6          BSON     HLSBIT,XNOTFS       [J IF PRE-HLS
4LYQ    #     INFORM THE JOB STARTER PROGRAM OF THE CHANGE OF   
4MDB    #     STATUS OF THE CONNECTED JOB   
4QK2 ...      HLSINFORM XHLSB,CONNECT,JOBNO(2)  
4QLP ...XHLSB LDX   0  CONTEXT(2)   
4QND ...      ANDN  0  #4000
4QQ7 ...      BZE   0  XNOTFS   
4QTQ          LDX   4  HLSCOUNT 
4R*B          SBN   4  1
4RT2          BPZ   4  XOK  
4S#L          GEOERR   1,HLSCOUNT   
4SS=    XOK   STO   4  HLSCOUNT 
4T?W          LDN   4  1
4TRG          ADS   4  HLSCOUNT+1   
4TXC ...#   
4W?6    XNOTFS  
4WQQ          OUTPAR TIMENOW
4X=B          OUTMILL   
4XQ2          LDN   4  1
4Y9L          LDN   5  JPDJOBTYPE   
4YP=          LDX   7  JSOURCE3(2)  
4^8W          BZE   7  XCENTRAL 
4^NG ...      LDN   3  THREE(1) 
5286          CALL  7  XOUTPACK 
52MQ          LDN   3  JSOURCE3(2)  
537B          LDN   5  JPDPROPS 
53M2          CALL  7  XOUTPACK 
546L          BRN      PARAMOUT 
54L=    XCENTRAL
555W          LDN   3  XONE(1)  
55KG          CALL  7  XOUTPACK 
5656          OUTPAR   SKIP 
56JQ    PARAMOUT
574B          LDN   0  #400 
57J2          ANDX  0  CONTEXT(2)   
583L          BNZ   0  XSK  
58H=          FJOCA 3,2 
592W          LDX   0  HCLOCKTIME(3)
59GG          LDX   1  HCLOCKTIME+1(3)  
5=26          BNZ   0  NSK1 
5=FQ          SRA   1  5
5=^B          SBN   1  1875 
5?F2          BNG   1  XSK  
5?YL    NSK1
5#D=          OUTPAR   PROGMILL 
5#XW          BRN      NSK  
5*CG    XSK 
5*X6          OUTPAR   SKIP 
5BBQ    NSK 
5BWB          MONOUT JTYPE  
5CB2          PERCOUNT  
5CNB ...      VFREEW   APERI,ASSOCS0
5D2S ...      ACROSS   CONTINUE,3          [TERMINATE BREAKIN IN CURRENT JOB
5D*=    #   
5DSW    #   
5F#G    NOJOBNAME   
5FS6          FREECORE 3
5G?Q    #SKI  WELLTEST  
5GRB          RGTRACE  9,XBRK   
5H?2          ADDJOBJ  XDEAD,XBRK   
5HQL          SUBJOB
5J==          LDX   6  JOBNO(2) 
5JPW          CALL  7  WELLAMMEND   
5K9G          GETACT   CPAT                [GET CPA BLK 
5KP6          LDX   3  BPTR(2)  
5L8Q ...      LDX   5  RCONTEXT(1)  
5N7=          STO   5  CONTEXT(3)   
5NLW          LINKSET  3,PLINKCOMPRO(1)    [SET LINK TO ENTER AT K1COMPRO   
5P6G          LDX   5  PRAMXMSK(1)  
5PL6          STO   5  AMXMSK(3)           [SET REPORT STYLES TO ALLBUT,COMMANDS
5PTY ...[   
5Q5Q          BSOFF    HLSBIT,SETCPAS      [J IF HLS
5QKB          LDN   5  #4000
5R52          ANDX  5  CONTEXT(2)   
5RJL          BZE   5  SETCPAS             [J IF MOP ACT. NOT FULLY STARTED 
5S4=          LDN   5  1                   [ REDUCE MOP COUNT   
5SHW          SBS   5  HLSCOUNT            [ BY 1   
5T3G          LDX   5  HLSCOUNT            [ GET NEW COUNT  
5TH6          TXL   5  IMOPLIMIT
5W2Q          BCC      TBCT                [J IF COUNT NOT < LIMIT SET  
5WGB          FON      #31                 [WAKE UP WAITING MOP ACTIVITIES  
5WL? ...#   
5X22          BRN      TBCT 
5XFL    #   
5YDW    XDEAD ENDCOM
5YYG    XBRK  COMBRKIN  
5^D6    XOUTPACK
5^XQ          SBX   7  FX1  
62CB          OUTPACKX 3,4,5
62X2          ADX   7  FX1  
63BL          EXIT  7  0
63W=    [   
64*W    [   
64TG    [   
65*6    [   
65SQ    [     CHANGE STATE OF JOB BEING CONNECTED OR DISCONNECTED   
66#B    [     X6 = JOBNO
66S2    [   
67?L    WELLAMMEND  
67R=          SBX   7  FX1  
68=W          TRACE    6,AMMEND 
68QG ...OFF   POP      OFF,,JWACCESS       [ SET SEMAPHORE  
69=6 ...      OPENSYS  ,JOBLIST,GENERAL 
69PQ          GETJOB   6,SYSTEM 
6=9B          TESTREP2 OK,RD               [ J IF JOB FOUND 
6=P2          GEOERR   1,NO JOB?
6?8L    RD    READAGAIN                    [ READ JOBLIST RECORD
6?N=          MHUNTW   3,FILE,FRB   
6#7W          NAME     3,FILE,FWB          [ FOR REWRITE
6#MG          JLADJUST 3
6*76          LDN   0  1                   [ CHANGE MOP TO BACK OR....  
6*LQ          ERS   0  JLSTAT(3)           [ VICE VERSA 
6B6B          REWRITE                      [ REWRITE RECORD 
6BL2          MHUNT    3,FILE,FWB          [ REFIND RECORD  
6C5L          NAME     3,JWELL,COPYSYS     [ FOR UPDATE OF JWELL BLOCK  
6CK=          JWELLADD LIVE                [ ADD NEW JOB
6D4W          MHUNT    3,JWELL,COPYSYS  
6DJG          JLADJUST 3
6F46          LDN   0  1
6FHQ          ERS   0  JLSTAT(3)
6G3B          JWELLSUB LIVE                [ REMOVE OLD JOB 
6GH2    [   
6H2L    [     NB... JWELLSUB GOES DOWN TO JWUPDATE WHICH DOES A JSASCAN 
6HG=    [     CLOSES JOBLIST AND RELEASES THE SEMAPHORE..... AS WELL AS 
6H^W    [     UPDATING THE JWELL BLOCK. 
6JFG    [   
6J^6          MFREE    JWELL,COPYSYS       [ FREE JWELL BLOCK   
6K53 ...#   
6KDQ          ADX   7  FX1  
6KYB          EXIT  7  0                   [ RETURN 
6LD2    [   
6LXL    [   
6MC=    XK3   CALL  7  WELLAMMEND          [ PERFORM UPDATE 
6MWW          UP
6NBG    [   
6NW6    [   
6P*Q    #END
^^^^ ...55521025000200000000