{{htmlmetatags>metatag-description:(ICL George 3 and George 4 GIN macro: FILEWAIT)}}
====== FILEWAIT ======
(GIN Macro)

**Defined in:** [[george:source:MACROS|MACROS]]

**Used in:** [[george:source:COPYFILE867|COPYFILE867]]

<code - FILEWAIT.mac.txt>
 3LFN ...[??? FILEWAIT SECT FILE FGN 9 DOC   
 3LPG    #   
 3M96    #MAC  FILEWAIT  
 3MNQ    M13FILEWAIT 
 3N8B          HUNTW    2,BSTB,FULLB 
 3NN2          BNG   2  M1FILEWAIT          [ERROR IF NOT THERE  
 3P7L          LDX   0  A1(2)               [RECORD HEADER   
 3PM=          SBN   0  2
 3Q6W          STO   0  BATEMAN3            [NO. OF BLOCK NOS
 3QBN ...      BZE   0  M91FILEWAIT         [EXIT IF FILE EMPTY  
 3QLG          LDX   0  A1+1(2)             [LFN 
 3R66          ADX   0  0                   [DOUBLE TO USE AS MOD TO LF TABLE
 3RKQ          LDX   1  ALFTP
 3S5B          SMO      0
 3SK2          LDX   0  A1(1)               [BSUN IN BITS 0-11   
 3T4L          BPZ   0  M2FILEWAIT          [J IF LF EXISTS  
 3TJ=    M1FILEWAIT  
 3W3W          GEOERR   1,FILEWAIT          [OTHER WISE ERROR
 3WHG    M5FILEWAIT  
 3X36                   +BSCHANAD
 3XGQ                   +BSSCHAD 
 3Y2B                   +BSQWCHAN
 3YG2    M2FILEWAIT  
 3Y^L          SRL   0  12   
 3^F=          MPY   0  ASBSAB   
 3^YW          NGX   1  1
 42DG          ADX   1  BBAC 
 42Y6          ADX   1  ASBSAB              [X1 CONTAINS BSA ADDRESS 
 43CQ          LDN   3  3
 43XB          STO   3  BATEMAN1            [NO OF BS QUEUES 
 44C2    M15FILEWAIT 
 44WL          ADX   3  FX1  
 45B=          SMO      M5FILEWAIT-1(3)  
 45TW          LDN   0  0(1)                [BASE OF QUEUE   
 46*G          SMO      M5FILEWAIT-1(3)  
 46T6    M17FILEWAIT 
 47#Q          LDX   1  0(1)                [NEXT ON QUEUE   
 47SB          TXU   1  0
 48#2          BCC      M3FILEWAIT          [J IF END OF QUEUE   
 48RL          SBN   1  CHAINADD            [START OF QUEUE BLOCK
 49?=          LDN   3  BA1(1)   
 49QW          LDX   4  ATYPE(1) 
 4==G          TXL   4  CACT 
 4=Q6          BCC      M10FILEWAIT         [J IF ACTIVITY   
 4?9Q          SBX   4  BSP10
 4?PB          BNZ   4  M1FILEWAIT          [ERROR IF NOT BSTB/BQBLK 
 4#92          LDN   3  ATRAN(1) 
 4#NL    M10FILEWAIT 
 4*8=          LDX   5  0(3) 
 4*MW          LDX   4  2(3)                [BLOCK NO
 4B7G          LDX   3  1(3)                [LENGTH/LFN  
 4BM6          ADN   1  CHAINADD 
 4C6Q          ANDN  5  BONL 
 4CLB          BNZ   5  M17FILEWAIT         [GET NEXT QUEUE BLK IF ONLINE
 4D62          ANDN  3  #377                [LFN 
 4DKL          TXU   3  A1+1(2)  
 4F5=          BCS      M17FILEWAIT         [NOT SAME LF 
 4FJW          LDX   5  BATEMAN3            [NO OF BLOCK NOS IN FULLB
 4G4G    M12FILEWAIT 
 4GJ6          SMO      5
 4H3Q          TXU   4  A1+1(2)  
 4HHB          BCS      M11FILEWAIT         [J IF UNEQUAL
 4J32 ...      COOR3    #41                 [WAIT FOR A CLEANCT  
 4JGL          BRN      M13FILEWAIT         [TRY AGAIN   
 4K2=    M11FILEWAIT 
 4KFW          BCT   5  M12FILEWAIT         [REDUCE MOD  
 4K^G          BRN      M17FILEWAIT         [GET NEXT ON BS QUEUE
 4LF6    M3FILEWAIT  
 4LYQ          LDX   3  BATEMAN1 
 4MDB          SMO      FX1  
 4MY2          SBX   1  M5FILEWAIT-1(3)     [X1 POINTS TO START OF BSA   
 4NCL          SBN   3  1                   [DECREASE COUNT OF QUEUES
 4NX=          STO   3  BATEMAN1 
 4PBW          BNZ   3  M15FILEWAIT  
 4PLN ...M91FILEWAIT 
 4PWG    #NOR
</code>