{{htmlmetatags>metatag-description:(ICL George 3 and George 4 GIN macro: MELADJUST)}}
====== MELADJUST ======
(GIN Macro)

**Defined in:** [[george:source:LLSMACROS|LLSMACROS]]

**Used in:** [[george:source:SCHDJOBA867|SCHDJOBA867]], [[george:source:SCHEDJOB867|SCHEDJOB867]]

<code - MELADJUST.mac.txt>
 96*K ...#MAC  MELADJUST 
 96*M ...[   
 96*P ...[     MACRO TO ALTER THE MILL PRIORITIES IN THE PCA TO THE VALUES IN THE
 96*R ...[     JOB BLOCK,RE-RINGING THE PROGRAM MEMBERS ON THE PROGRAM RING IF TH
 96*T ...[     PROGRAM IS PLUGGED IN 
 96*X ...[     %A - -> TO JOB BLOCK.MAY NOT BE X0
 96*^ ...[     %B - -> TO PCA.IF ABSENT,PCA WILL BE FOUND FROM %A.   
 96B3 ...[   
 96B5 ...#STR  1,%B                         [INCLUDE IF %B=1 
 96B7 ...#SKI
 96B9 ...(   
 96B? ...      LDX   0  %B   
 96B* ...      LDX   1  %A   
 96BC ...      LDX   2  0                   [X2 -> PCA   
 96BF ...)   
 96BH ...#STR  1,%B                         [INCLUDE IF %B NOT = 1   
 96BK ...(   
 96BM ...#STR  1,%A  
 96BP ...      LDX   1  %A                  [X1 -> JOB BLOCK 
 96BR ...#STR  %B,2                         [INCLUDE IF %B NOT=2 OR ABSENT   
 96BT ...      LDX   2  %B   
 96BX ...#STR  %B
 96B^ ...#SKI
 96C3 ...      FPCAJO 2,1                   [AS %B ABSENT,FIND PCA   
 96C5 ...)   
 96C7 ...      PCATEST 2,MNORM,,MPUC 
 96C9 ...      FINDPUC 2,2                  [IF TP CURRENT,FIND PUC  
 96C? ...MPUC  ORX   2  GSIGN               [AND SET MILL PRIORITY IN PUC'S PCA  
 96C* ...      LDCH  0  AMILLP(1)           [(ONLY MEMBER 0 OF A PUC USED)   
 96CC ...      BNZ   0  MOTD1
 96CF ...      LDN   0  30   
 96CH ...MOTD1   
 96CK ...      DCH   0  AMR1(2)  
 96CM ...      FINDTP 2,2                   [GET TP TO SET ITS MILL PRIORITIES   
 96CP ...MNORM   
 96CR ...      STO   3  GEN3 
 96CT ...      LDN   3  4                   [4 PROGRAM MEMBERS   
 96CX ...      ORX   2  GSIGN               [MILL PRI. CHARACTER 2 IN PCA
 96C^ ...MEXTMP  
 96D3 ...      LDCH  0  AMILLP(1)           [LOAD MILL PRI. FOR THIS MEMBER  
 96D5 ...      BNZ   0  MOTD                [0 INDICATES DEFAULT WHICH IS
 96D7 ...      LDN   0  30                  [  A MILL PRI. OF 30 
 96D9 ...MOTD
 96D? ...      DCH   0  AMR1(2)             [STORE MILL PRI. IN PCA  
 96D* ...      BCHX  1  £
 96DC ...      ADN   2  1
 96DF ...      BCT   3  MEXTMP              [J IF MORE MEMBERS   
 96DH ...      LDX   3  GEN3                [RESTORE X3  
 96DK ...      SBN   1  1                   [RESET JOB BLOCK PTR 
 96DM ...      JBC MEND,1,JBPLUG            [ONLY RERING IF PLUGGED IN   
 96DP ...      FPCAJO 2,1                   [REFIND CURRENT PCA  
 96DR ...      MELRERING 2                  [RERING MEMBERS IF MILL PRI. CHANGED 
 96DT ...MEND
 96DX ...      LDX   1  FX1  
 96D^ ...      LDX   2  FX2  
 96F3 ...#NOR
</code>