{{htmlmetatags>metatag-description:(ICL George 3 and George 4 GIN macro: MOPSTATE)}}
====== MOPSTATE ======
(GIN Macro)

**Defined in:** [[george:source:MACS_MISW|MACS MISW]]

**Used in:** [[george:source:DUMMYB867|DUMMYB867]], [[george:source:RIGHT867|RIGHT867]], [[george:source:WHATPERB867|WHATPERB867]], [[george:source:WHATPERX867|WHATPERX867]]

<code - MOPSTATE.mac.txt>
 9B#G    [???  MOPSTATE   SECT  COMM  FGN 40 DOC 
 9BS6    [   
 9C?Q    [   
 9CRB    [     MACRO TO FIND THE STATE OF A REMOTE UNIT  
 9D?2    [     IE WHETHER IT IS MOPPED ON OR OFF OR WHETHER IT IS BEING  
 9DQL    [     MOPPED ON OR OFF  
 9F==    [   
 9FPW    [   
 9G9G    #MAC  MOPSTATE  
 9GP6          JALLOC   %A,MMOPSTATE1       [J. IF ALLOCATED TO AN ACTIVITY  
 9H8Q          BRN      MMOPSTATE2   
 9HNB    MMOPSTATE1  
 9J82          JONL     %A,MMOPSTATE14      [J. ONLINE TO OBJECT PROG.   
 9JML          LDX   1  %A   
 9K7=    #STR  %C
 9KLW    (   
 9L6G    [   
 9LL6    [     IPB   
 9M5Q    [   
 9MKB          LAMOP    1,2  
 9N52          LDCT  %B #030 
 9NJL          ANDX  %B IPBSW(2)            [MASK IPB SWITCH WORD
 9P4=          BNZ   %B MMOPSTATE4          [J. IF EITHER BIT SET
 9PHW          HUNT2J   1,AMXOR,ADEVS,2,MMOPSTATE3  [J IF ADEVS MISSING  
 9Q3G          STOZ     %B   
 9QH6          BRN      MMOPSTATE8          [%B = ZERO MOPPED ON 
 9R2Q    MMOPSTATE3  
 9RGB          LDX   %B GSIGN               [%B = NEG MOPPED OFF 
 9S22          BRN      MMOPSTATE8   
 9SFL    MMOPSTATE4  
 9S^=          SLC   %B 6
 9TDW          BRN      MMOPSTATE8        [%B = 1,2, OR 3
 9TYG    )   
 9WD6    #STR  %C
 9WXQ    #SKI
 9XCB    (   
 9XX2    [   
 9YBL    [     CHARACTER BUFFERING   
 9YW=    [   
 9^*W          LAMOP   1,2                  [FIND AMOP   
 9^TG          HUNT2J   1,AMXOR,ALINES,2,MMOPSTATE13 [J IF ALINES MISSING MOP OFF
 =2*6          LDX   0  ALOGLEN(1)   
 =2SQ          SBN   0  4
 =3#B          BZE   0  MMOPSTATE10         [J UNIPLEXOR 
 =3S2          ADN   1  4                   [STEP FIRST ENTRY IN ALINES  
 =4?L    MMOPSTATE10 
 =4R=          LDX   2  FX2  
 =5=W          STOZ     %B                   [%B = ZERO MOPPED ON
 =5QG          LDCT  0  #140 
 =6=6          ANDS  0  A1+FOURTHWD(1)      [MASK FOURTHWD B2 AND B3 
 =6PQ          SLL   0  2
 =79B          BPZ   0  MMOPSTATE11          [J MOPPED ON OR BEING MOPPED ON 
 =7P2          LDN   %B 2                    [%B =2 BEING MOPPED OFF 
 =88L    MMOPSTATE11 
 =8N=          SLL   0  1
 =97W          BZE   0  MMOPSTATE8         [J. IF B3 NOT SET 
 =9MG          ADN   %B 1                   [%B = 1 BEING MOPPED ON  
 ==76                                         [%B = 3 BEING MOPPED ON & OFF  
 ==LQ          BRN      MMOPSTATE8   
 =?6B    MMOPSTATE13 
 =?L2          LDX   %B GSIGN
 =#5L          BRN      MMOPSTATE8               [%B = NEG MOPPED OFF
 =#K=    )   
 =*4W    MMOPSTATE2  
 =*JG          LDN   %B 5
 =B46          BRN      MMOPSTATE8   
 =BHQ    MMOPSTATE14 
 =C3B          LDN   %B 4                     [UNIT ONLINED  
 =CH2    MMOPSTATE8  
 =D2L    #STR  %D
 =DG=    #SKI
 =D^W    (   
 =FFG          LDX   2  FX2  
 =F^6    )   
 =GDQ          LDX   1  FX1  
 =GYB    #NOR
</code>