{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: ABANDON867)}}
====== ABANDON867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BC|BC]], [[george:macro:BITDEFS|BITDEFS]], [[george:macro:BS|BS]], [[george:macro:BSON|BSON]], [[george:macro:BXE|BXE]], [[george:macro:BXU|BXU]], [[george:macro:CHAIN|CHAIN]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:COMBRKIN|COMBRKIN]], [[george:macro:COMERRX|COMERRX]], [[george:macro:COOR4|COOR4]], [[george:macro:DOWN|DOWN]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FCAJO|FCAJO]], [[george:macro:FPUT|FPUT]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETACT|GETACT]], [[george:macro:GETJOB|GETJOB]], [[george:macro:HLSAV|HLSAV]], [[george:macro:HUNT|HUNT]], [[george:macro:HUNT2|HUNT2]], [[george:macro:HUNT2J|HUNT2J]], [[george:macro:HUNTMISB|HUNTMISB]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:JLADJUST|JLADJUST]], [[george:macro:JOBLOCK|JOBLOCK]], [[george:macro:LINK|LINK]], [[george:macro:LINKSET|LINKSET]], [[george:macro:LONGWAIT|LONGWAIT]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUTX|MONOUTX]], [[george:macro:NAME|NAME]], [[george:macro:OPEN|OPEN]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:OUTPARAM|OUTPARAM]], [[george:macro:PICKREP2|PICKREP2]], [[george:macro:POP|POP]], [[george:macro:READAGAIN|READAGAIN]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SHLSQ|SHLSQ]], [[george:macro:STEPAGAIN|STEPAGAIN]], [[george:macro:SUICIDE|SUICIDE]], [[george:macro:TERROR|TERROR]], [[george:macro:TESTREP|TESTREP]], [[george:macro:TESTRPN2|TESTRPN2]], [[george:macro:UNSAVE|UNSAVE]], [[george:macro:USEROPEN|USEROPEN]], [[george:macro:VOP|VOP]]
22FL #LIS K0ABANDON>K0COMMAND>K0ALLGEO
22^= #SEG ABANDON [ BILL IZATT : CENT
2357 ...[
2394 ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1983
23#^ ...[
23DW 8HABANDON
23YG [ ENTRY POINT. THIS LOCATION MUST REMAIN FIXED
24D6 SEGENTRY K1ABANDON,(GEOERR)
24XQ SEGENTRY K2ABANDON,(GEOERR)
25CB SEGENTRY K3ABANDON,XAUTOENT
25X2 FSHENTRY K4ABANDON,,XMESSBLOCK,XMESSBLOCK
266S ... FSHENTRY K5ABANDON,XCDOWNENT,,XCDOWNENT
26BL #
27TG #
28*6 XABANDON +ABANDON
28SQ XABANDWT +ABANDWT
29#B BITDEFS AWORK4,0,SWELL,SMOP,OPENJL,USER,TEMP,SMESS,SAVED
29S2 BITDEFS AWORK4,9,XAUTO
2=?L XAUTOLNK
2=R= LINK ABANDON,3
2?=W #SKI JSKI31
2?QG (
2#=6 BITDEFS AWORK4,7,POSTM
2#PQ SEGENTRY K79ABANDON
2*9B XABPM +0
2*P2 )
2B8L #
2BN= #DEF SIZELIST=10
2C7W XJOBLIST +SIZELIST
2CMG 12H
2D76 12HJOBLIST
2DLQ 1
2F6B 1
2FL2 4H****
2G5L [
2GK= [
2H4W [
2J46 [
2JHQ XJOBL
2K3B JOBLOCK 6,3
2KH2 EXIT 7 0
2L2L [
2MFG [
2M^6 XHLSQ
2NDQ SHLSQ 6,3,(7)
2NYB EXIT 7 1
2PD2 [
2PXL XCAJO
2QC= FCAJO 2,3,N
2QWW LDCH 0 ATYPE(2)
2RBG SBN 0 CPAT/64
2RW6 BNZ 0 TELL
2S*Q EXIT 7 0
2STB [
2T*2 READNAME
2TSL SBX 7 FX1
2W#= READAGAIN
2WRW MHUNTW 3,FILE,FRB
2X?G NAME 3,JWELL,COPYSYS
2XR6 X7XIT
2Y=Q ADX 7 FX1
2YQB EXIT 7 0
2^=2 [
2^PL OPENGET
329= SBX 5 FX1
32?8 ...[ B5156 CORRECTION
32*6 ...[ USE QUERY MODE TO PREVENT GEOERR IF
32C4 ...[ FILE ALREADY OPEN TO JOB
32F2 ...[ 02.06.82
32GY ... OPENSYS X5XIT,JOBLIST,GENERAL,QUERY
32JW ...[ TEST REPLY AND EXIT +1 IF FILE ALREADY OPEN
32LS ... ADN 5 1
32NQ ... TESTREP OK,OPENOK
32QN ... TESTREP CLUDGE,X5XIT
32SL ...[ THE FOLLOWING 'TESTREP' CAN BE REMOVED WHEN
32WJ ...[ 'OPENSYS' IS CORRECTED TO REPLY WITH 'CLUDGE'
32YG ...[ INSTEAD OF 'NAME' WHEN DIRECTORY IS OPEN TO JOB
332D ... TESTREP NAME,X5XIT
334B ... GEOERR 1,ABNOJL [UNEXPECTED REPLY
336# ...OPENOK
338G GETJOB 6,SYSTEM
33N6 PICKREP2 6
347Q STEPAGAIN
34MB ADX 3 JOBDATASIZE
3572 LDX 3 JLSTAT(3)
35LL CLOSETOP
366= ADN 5 1
36KW BNZ 6 X5XIT [J IF NOT OK FROM GETJOB
375G BUX 5 X5XIT [=EXIT 5 2
37K6 [
384Q SQUEUE
38JB LDX 3 4 [ADDRESS OF CHAIN BASE
3942 SQ1 LDX 3 FPTR(3)
39HL LDN 6 0
3=3= BXE 3 4,(7) [EXIT +0 IF NOT FOUND
3=GW LDN 6 6
3?2G SQ2 ADX 3 5
3?G6 SMO 6
3?^Q LDX 0 0(3)
3#FB SBX 3 5
3#^2 SMO 6
3*DL BXU 0 ACOMMUNE1-1(2),SQ1 [J IF NO MATCH
3*Y= BCT 6 SQ2 [COMPARE ALL 6 WORDS
3BCW EXIT 7 1
3BXG [
3CC6 SRDISPLAY
3CWQ SMO FX1
3DBB LDX 6 XABANDON
3DW2 SRDISPLAY1
3F*L SBX 5 FX1
3FT= CALL 7 NAMEMOVE
3G#W LDX 4 ACOMMUNE7(2)
3GSG LDX 3 ACOMMUNE8(2)
3H#6 OUTPARAM 4,ACOMMUNE1
3HRQ OUTPARAM 3,ACOMMUNE4
3J?B MONOUTX 6
3JR2 X5XIT
3K=L ADX 5 FX1
3KQ= EXIT 5 0
3L9W [
3LPG SOURCEHW
3M96 ANDX 7 BITS22LS
3MNQ LDX 5 1 [ PRESERVE APERI/CONSOLE BLOCK
3N8B SHW LDX 6 A1+1(1)
3NN2 BZE 6 SEXIT [ FINISH
3P7L ANDX 6 BITS22LS
3PM= TXU 6 7
3Q6W BCC SHWF [ COMPARE PROPERY
3QLG BDX 1 SHW [ LOOP
3R66 SHWF LDX 6 A1+2(1) [ CONSOLE IDENTIFIER
3RKQ SEXIT LDX 1 5 [ RESTORE POINTER
3S5B EXIT 0 0
3SK2 [
3T4L [
3TJ= NAMEMOVE
3W3W LDX 0 ACES
3WHG STO 0 ACOMMUNE1(2)
3X36 LDN 0 ACOMMUNE1(2)
3XGQ LDN 1 ACOMMUNE2(2)
3Y2B MOVE 0 5 [ CLEAR TO SPACES
3YG2 MHUNT 1,CPB,CUNI
3Y^L LDX 3 1
3^F= LDEX 4 ANUM(1)
3^YW STO 4 ACOMMUNE7(2) [ CHARS IN JOBNAME
42DG LDN 0 APARA(1)
42Y6 LDN 1 ACOMMUNE1(2)
43CQ SMO 4
43XB MVCH 0 0 [ JOBNAME
44C2 HUNT2 3,CPB,CUNI
44WL LDEX 4 ANUM(3)
45B= STO 4 ACOMMUNE8(2) [ CHARS IN USERNAME
45TW LDN 0 APARA(3)
46*G LDN 1 ACOMMUNE4(2)
46T6 SMO 4
47#Q MVCH 0 0 [ USERNAME
47SB LDX 1 FX1
48#2 EXIT 7 0
48RL [
49?= [
49QW VOP STO 0 GEN0
4==G VOP ,JWACCESS
4=Q6 BRN (GEN0)
4?9Q [
4?PB XFACT1
4#92 LDX 3 FX2
4#NL XFACT FINDACTF 3,3,CPAT,,(4),FPTR
4*8= HUNT2J 1,JWELL,COPYSYS,3,XFACT
4*MW TXU 6 A1+FRH+JLJOBNO(1)
4B7G BCS XFACT
4BM6 LDX 3 ACTNUM(3)
4C6Q STO 3 AWORK1(2)
4CLB EXIT 4 1
4DKL #
4F5= #
4FJW #
4G4G # MAIN ENTRY POINT FOR ABANDONING JOBS
4GJ6 XAUTOENT
4LF6 SEARCHAGAIN
4LYQ LDX 6 AWORK3(2)
4MDB BZE 6 SNAME [ J IF FIRST TIME THROUGH
4MY2 CALL 7 XJOBL [LOCATE JOBLOCK
4NCL BNG 3 SEARCHHLSQ [ J IF NOT FOUND
4NX= BRN SFND [ FOUND
4PBW SNAME CALL 7 NAMEMOVE [ SET UP ACOMMUNE WORDS
4PWG LDN 4 BJOBQ
4QB6 LDN 5 JNAME-1
4QTQ CALL 7 SQUEUE [SEARCH JOBQ FOR JOB
4R*B BRN SEARCHHLSQ [J IF NOT FOUND
4RT2 LDX 6 JOBNUM(3)
4S#L STO 6 AWORK3(2) [ JOBNO
4SS= SFND CALL 7 XCAJO [FIND JOB'S CPA
4T?W LDCT 0 1
4TRG ANDX 0 JMISC(3)
4W?6 BZE 0 SCPAT [ J IF NOT BEING SAVED
4WQQ CALL 7 XHLSQ [LOCATE HLSQ BLOCK
4X=B BRN NOTHLS [J IF NONE FOUND
4XQ2 HLSAV 3,CLEAR,SAVING,HLSQ,SAVEDJ
4Y9L WAIT BRN TELL
4YP= [
4^8W SEARCHHLSQ
4^NG BSON HLSBIT,TRYJOBLIST [ J IF NO HLS - HLSQ EMPTY
5286 BZE 6 S0 [ J IF SEARCH BY NAME
52MQ CALL 7 XHLSQ [LOCATE HLSQ BLOCK
537B BRN TRYJOBLIST [J IF NONE FOUND
53M2 BRN S4 [ FOUND
546L S0 LDN 4 BHLSQ
54L= LDN 5 HLSJNAM-1
555W CALL 7 SQUEUE [SEARCH HLSQ FOR JOB
55KG BRN TRYJOBLIST [J IF NOT FOUND
5656 S4 LDX 6 HLSJONO(3) [ JOBNO
56JQ STO 6 AWORK3(2)
574B HLSAV 3,CLEAR,SAVED,HLSQ,TRYJOBLIST
57J2 SAVEDJ
583L BS 2,SAVED
58H= LDX 7 HLSPCT(3)
592W BRN TESTREST
59GG [
5=26 SEARCHCPAT
5=FQ CALL 7 XJOBL [LOCATE JOBLOCK
5=^B BPZ 3 SCPAFND [ J IF JOBBLOCK FOUND
5?F2 TELL LDN 5 1
5?YL LONGWAIT XBIN,#62,,,5 [ CAN'T FIND CPA SO WAIT
5#D= JBS SEARCHAGAIN,2,XAUTO [J IF AUTO AB
5#XW LDX 0 AWORK2(2)
5*CG SBN 0 FONINTP
5*X6 STO 0 AWORK2(2) [ DECREMENT MESSAGE TIMER
5BBQ BNG 0 TELLAGAIN
5BWB BNZ 0 SEARCHAGAIN [ TRY AGAIN
5CB2 TELLAGAIN
5CTL LDX 6 XABANDWT(1)
5D*= CALL 5 SRDISPLAY1
5DSW LDX 0 ASYSTEMMESS
5F#G STO 0 AWORK2(2) [ RESET MESSAGE TIMER
5FS6 CALL 7 NAMEMOVE
5G?Q BRN SEARCHAGAIN
5GRB SETAUTO
5H?2 JBS TELL,2,XAUTO [J IF ALREADY IN AUTO AB
5LNB GETACT GENERAL,ACTSAVE
5M82 LDX 3 BPTR(2) [PTR TO AUTONOMOUS ACTIVITY
5MML LDN 0 AWORK3(2) [SET UP AWORK3, AWORK4 AND
5N7= LDN 1 AWORK3(3) [ ACOMMUNE1 - ACOMMUNE8 IN
5NLW MOVE 0 10 [ AUTONOMOUS ACTIVITY BLOCK
5T3G LDX 1 FX1 [RESET X1
5TH6 BS 3,XAUTO [SET AUTONOMOUS ACTIVITY BIT
5W2Q LINKSET 3,XAUTOLNK(1) [SET LINK FOR ENTRY TO ABANDON
5WGB LDX 2 3
5X22 FPUT
5X^= (
5YDW LDX 6 XABANDWT(1)
5YYG CALL 5 SRDISPLAY1
5^D6 )
5^XQ XEND
65*6 ENDCOM
65SQ [
66#B SUICIDE
69PQ SUICIDE
6=9B [
6=P2 SCPAT
6?8L [
6?N= SCPAFND
6#7W CALL 7 XCAJO [FIND JOB'S CPA
6#MG [
6*76 LDX 0 ACTNUM(2)
6*LQ SMO FX2
6B6B STO 0 AWORK1
6BL2 LDXC 0 CONTEXT(2)
6C5L BCS SYSAB [ CAN'T AB SYSTEM ISSUED JOB
6CK= ANDN 0 8 [ MOP CONTEXT BIT
6D4W LDX 7 JSOURCE3(2) [ JOBS CONSOLE PROPERTY
6DJG LDX 2 FX2 [ RESTORE FX2
6F46 BZE 0 SNAM [ J IF JOB NOT MOP
6FHQ BS 2,SMOP [ MOPJOB AB
6G3B SNAM
6GH2 JBC TESTREST,2,USER [ J IF OPERATOR
6H2L [
6HG= [ LOCATE OWN JOBNAME FOR COMPARISON
6H^W [
6JFG LDX 4 JOBNO(2)
6J^6 BXE 4 AWORK3(2),SELFAB
6KDQ [
6KYB TESTREST
6LD2 JBS SENTRAL,2,XAUTO
6LXL JBC NOTTE,2,TEMP
6MC= JBC NOTWE,2,SWELL
6MWW JBS TEMPMPAB,2,SMOP
6NBG BRN NOTTE
6NW6 NOTWE
6P*Q LDX 6 AWORK3(2)
6PTB CALL 5 OPENGET
6Q*2 BRN XBIN [J IF B-IN DURING OPEN
6QJS ... BRN XNOJL [JIF FILE ALREADY OPEN TO JOB
6QSL BRN NOJOB [J IF GETJOB NOT OK
6R#= ANDN 3 #14
6RFD ...[ B9211 CORRECTION 21.06.82
6RLL ...[ OUTPUT NEW MESSAGE 'JXABDCTEMP' FOR DISCONNECTED JOBS
6RRS ... BZE 3 NOTTE
6R^2 ... JBS TEMPMPAB,2,SMOP
6S68 ... BRN TEMPDCAB
6S?G NOTTE
6SR6 JBS SENTRAL,2,USER
6T=Q LDX 0 JSOURCE3(2)
6TQB BZE 0 SENTRAL [ CENTRAL OPS CONSOLE
6W=2 HUNTMISB 1,APERI,CONSOLE
6WPL BNG 1 WRONGCLUS
6X9= CALL 0 SOURCEHW [ CONSOLE PROP OF AB JOB
6XNW LDX 4 6
6Y8G LDX 7 JSOURCE3(2)
6YN6 CALL 0 SOURCEHW [ AB ACTIVITY CONSOLE PROP
6^7Q TXU 4 6
6^MB BCS WRONGCLUS [ ERROR IF DIFFERENT
7272 SENTRAL
72LL LDX 6 AWORK3(2)
736= JBC UNSAVED,2,SAVED
73KW BC 2,SAVED
745G ... UNSAVE 6,A
74K6 BRN SVFAIL
754Q BRN SEARCHCPAT
75JB TRYJOBLIST
7642
76HL JBS SUICIDE,2,XAUTO
773= POP SEARCHAGAIN,,JWACCESS
77GW SETNCORE SIZELIST,3,FILE,FABSNB
782G LDN 5 A1(3)
78G6 LDN 4 XJOBLIST(1)
78^Q MOVE 4 SIZELIST [ BASIC JOBLIST(****) FABSNB
79FB ADN 5 1
79^2 LDN 4 ACOMMUNE4(2)
7=DL MOVE 4 3 [ USERNAME
7=Y= OPEN USEROPEN XBROKE,GENERAL,NOERREP,UNTRAP,FROZEN
7?6G ... TESTREP OK,OPENUSEROK
7?#Q ... TESTREP CLUDGE,XNOUSERJL
7?H2 ... BRN NOJBV
7?P= ...OPENUSEROK
7?XG CALL 7 NAMEMOVE
7#C6 LDN 4 ACOMMUNE1(2)
7#WQ GETJOB 4,USER [ GET ENTRY
7*BB TESTRPN2 OK,NOJOBC
7*W2 BS 2,SWELL [ WELLJOB EXISTS
7B*L CALL 7 READNAME [SET UP COPYSYS
7BT= LDX 6 A1+JLJOBNO(3)
7C#W LDX 0 AWORK3(2)
7CSG BZE 0 NOCOMP
7D#6 BXU 0 6,NOJOBC
7DRQ NOCOMP
7F?B CALL 5 OPENGET
7FR2 BRN XBRK [J IF B-IN DURING OPEN
7G2S ... BRN XNOJLC [JIF FILE ALREADY OPEN TO JOB
7G=L BRN NOJOBC [J IF GETJOB NOT OK
7GQ= MHUNT 3,JWELL,COPYSYS
7H9W JLADJUST 3
7HPG JBC SNOTE,2,TEMP
7J96 JBS TERROR,3,JLBABAND
7JNQ SNOTE JBC RPROP,3,JLBMOP
7K8B BS 2,SMOP
7KN2 CLOSETOP
7L7L CALL 0 VOP
7LM= BRN PROP
7M6W RPROP BS 2,OPENJL [ JOBLIST LEFT OPEN
7MLG PROP MHUNT 3,JWELL,COPYSYS
7N66 ADN 3 A1
7NKQ LDX 6 JLJOBNO(3)
7P5B STO 6 AWORK3(2) [ JOBNO
7PK2 LDX 7 JLPROPNO(3)
7Q4L JBC TESTREST,2,SMOP
7QJ= CALL 4 XFACT1
7R3W BRN NOJOB
7RHG BRN TESTREST
7S36 UNSAVED
7SGQ JBC STOP,2,SWELL [ J IF NOT WELL
7T2B JBC NOSTOP,2,SMOP [ CAN'T STOP WELL BACK
7TG2 STOP JBC STOPAB,2,SMESS [ J IF NO MESSAGE
7T^L HUNT 1,GMON,JABAND
7WF= BNG 1 STOPAB
7WYW LDX 4 AWORK1(2)
7XDG FINDACTN 3,4,S6
8QRG LDX 3 ACTRING(3)
8R?6 SBN 3 ACTRING
8RQQ LDX 3 BPTR(3)
8S=B CHAIN 1,3 [ RECHAIN MESSAGE
8YM2 STOPAB
8^6L #SKI JSKI31
8^L= (
925W JBC NSTORE,2,POSTM
92KG JBS NSTORE,2,SMOP
9356 LDN 4 15
93JQ LDX 1 FX1
944B WATE SMO XABPM(1)
94J2 LDX 0 0
953L BZE 0 STORE
95H= COOR4 #62
962W BCT 4 WATE
96GG STORE SMO XABPM(1)
9726 STO 6 0
97FQ NSTORE
97^B )
98F2 DOWN PROCONTX,14
98YL NULL
99D= BRN SETAUTO [J TO SET UP AUTO AB
99XW BRN XALREADY [JOB ALREADY BEING AB'ED
9=CG #
9=X6 S6
9?BQ ACROSS ABANDONA,3 [REMOVE CONSOLE BLOCKS
9?WB #
9#B2 NOSTOP
9#TL ACROSS ABANDONA,4 [TEMP ABANDON JOB IN WELL
9**= #
9*SW # ERROR CODE
9B#G #
9BS6 TERROR
9C?Q LDX 6 Y11(1)
9CRB CLOSETOP
9D?2 CALL 0 VOP
9DQL BRN RERR1
9F== TEMPMPAB
9FPW LDX 1 FX1
9G9G LDX 6 Y10(1) [ TEMP MOP AB
9GP6 BRN RERR1
9GS= ...TEMPDCAB
9GXB ... LDX 1 FX1
9H2G ... LDX 6 Y19(1)
9H5L ... BRN RERR1
9H8Q SELFAB
9HNB LDX 1 FX1
9J82 LDX 6 Y9(1) [ SELF AB
9JML BRN RERR1
9K7= SYSAB
9KLW LDX 6 Y1(1) [JOB NOT ABANDONABLE
9L6G BRN RERR1
9LL6 XALREADY
9M5Q JBS SUICIDE,2,XAUTO
9MKB LDX 6 Y15(1)
9N52 BRN RERR1
9NJL #
9P4= WRONGCLUS
9PHW JBC WCL,2,OPENJL
9Q3G CLOSETOP
9QH6 CALL 0 VOP
9R2Q WCL
9RGB LDX 1 FX1
9S22 LDX 6 Y6(1) [NOT ABANDONABLE:WRONG CLUSTER
9SFL BRN RERR1
9S^= #
9TDW NOJOBC
9TYG CLOSETOP
9WD6 NOJBV CALL 0 VOP
9WXQ NOJOB
9XCB LDX 6 Y5(1) [JOB DOES NOT EXIST
9XX2 RERR1
9YBL NGN 7 1
9YW= COMERRX 6,7
9YX? ...XNOJLC
9YY# ... CLOSETOP
9Y^B ...XNOUSERJL
9^4G ... CALL 0 VOP
9^64 ...XNOJL
9^7L ... LDX 6 Y18(1)
9^=Q ... BRN RERR1
9^*W #
9^TG Y1 +JXABANDON
=2*6 Y5 +JXEXIST
=2SQ Y6 +JXCLUS
=3#B Y9 +JXSELFAB
=3S2 Y10 +JXABMOPTEMP
=4?L Y11 +JXTEMPABTE
=4R= Y15 +JXABALREADY
=534 ...Y18 +JSYSFILE
=56^ ...Y19 +JXABDCTEMP
=5=W #
=5QG #
=6=6 XBRK CLOSETOP
=6PQ XBROKE
=79B CALL 0 VOP
=7P2 XBIN
=?6B COMBRKIN
=?L2 #
=#5L #
=#K= SVFAIL
=*4W GEOERR 1,ABUNSAVE
=*JG NOTHLS
=B46 GEOERR 1,HLS JOB!
=C3B #END
^^^^ ...031643250002