{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: ABANDONA867)}}
====== ABANDONA867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BC|BC]], [[george:macro:BITDEFS|BITDEFS]], [[george:macro:BS|BS]], [[george:macro:CHEKLFN2|CHEKLFN2]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:COMERRX|COMERRX]], [[george:macro:DOWN|DOWN]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHTEST|FSHTEST]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETJOB|GETJOB]], [[george:macro:HUNT2|HUNT2]], [[george:macro:HUNT2J|HUNT2J]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:LOSEPARS|LOSEPARS]], [[george:macro:MBS|MBS]], [[george:macro:MEND|MEND]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:MONOUTX|MONOUTX]], [[george:macro:NAME|NAME]], [[george:macro:OUTMESS|OUTMESS]], [[george:macro:OUTNULL|OUTNULL]], [[george:macro:OUTPARAM|OUTPARAM]], [[george:macro:PARAFREE|PARAFREE]], [[george:macro:PARALYSE|PARALYSE]], [[george:macro:READ|READ]], [[george:macro:READAGAIN|READAGAIN]], [[george:macro:RESTART|RESTART]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SKIP|SKIP]], [[george:macro:SPARABEG|SPARABEG]], [[george:macro:SPARANOX|SPARANOX]], [[george:macro:SPARUNAC|SPARUNAC]], [[george:macro:STEP|STEP]], [[george:macro:STEPAGAIN|STEPAGAIN]], [[george:macro:SUICIDE|SUICIDE]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:TESTRPN2|TESTRPN2]], [[george:macro:UP|UP]], [[george:macro:VFREEW|VFREEW]], [[george:macro:VOP|VOP]]
229S ...#OPT K0ABANDONA=0
22FL ...#LIS K0ABANDONA>K0COMMAND>K0ALLGEO
22^= ...#SEG ABANDONA [ BILL IZATT : CENT
2357 ...[
2394 ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1983
23#^ ...[
23DW ... 8HABANDONA
23YG [ ENTRY POINT. THIS LOCATION MUST REMAIN FIXED
248# ... SEGENTRY K1ABANDONA,START
24D6 ... SEGENTRY K2ABANDONA,MONY
24MY ... SEGENTRY K3ABANDONA,XCONFREE
24XQ ... SEGENTRY K4ABANDONA,NOSTOP
257J ...#
25CB ...XABANDON +ABANDON
25X2 ...XABANDWELL +ABANDWELL
27*W SPACE #20
27TG SCOMMA #34
27TW ...SCOLON #12
27WL ...XCOLON +1
27XB ... 4H:
27Y6 ...STEMP +4
27YW ... 4HTEMP
27^L ...STE +2
282B ... 2HTE
2836 ...MESSAGE +7
283W ... 7HMESSAGE
284L ...ME +2
285B ... 2HME
285D ... SEGENTRY K60ABANDONA
285G ...#UNS FSHTEST
285J ...#SKI
2866 ... BITDEFS AWORK4,0,SWELL,SMOP,,USER,TEMP,SMESS
286Y ... BITDEFS AWORK4,8,XFROZEN,XAUTO
287S ...#SKI JSKI31
288N ...(
289J ... BITDEFS AWORK4,7,POSTM
28=D ...XPM +2
28?# ... 2HPM
28#8 ...)
28*6 XCOUT
28SQ ...#HAL +CONBUFF+COUT,0
29#B XIREM
29L^ ...#HAL +CONBUFF+IREMTW,0
29^J ...#
2=#7 ...# SUBROUTINES
2=LQ ...#
2=^F ...READNAME
2=^P ... SBX 7 FX1
2=^^ ... READAGAIN
2?29 ... MHUNTW 3,FILE,FRB
2?2F ... NAME 3,JWELL,COPYSYS
2?2P ...X7XIT
2?2^ ... ADX 7 FX1
2?39 ... EXIT 7 0
2?3F ...[
2?4Y ...#UNS FSHTEST
2?6C ...#SKI
2?=W SRDISPLAY
2?BR ... SMO FX1
2?GN ... LDX 6 XABANDON
2?LK ...SRDISPLAY1
2?QG SBX 5 FX1
2#2# ... CALL 7 NAMEMOVE
2#=6 ... LDX 4 ACOMMUNE7(2)
2#FY ... LDX 3 ACOMMUNE8(2)
2*F8 ... OUTPARAM 4,ACOMMUNE1
2*P2 ... OUTPARAM 3,ACOMMUNE4
2*YS ... MONOUTX 6
2B4P ...X5XIT
2B8L ADX 5 FX1
2BN= EXIT 5 0
2C7W [
2CMS ...NAMEMOVE
2CNW ... LDX 0 ACES
2CPY ... STO 0 ACOMMUNE1(2)
2CR2 ... LDN 0 ACOMMUNE1(2)
2CS4 ... LDN 1 ACOMMUNE2(2)
2CT6 ... MOVE 0 5 [ CLEAR TO SPACES
2CW8 ... MHUNT 1,CPB,CUNI
2CWP ... LDX 3 1
2CX= ... LDEX 4 ANUM(1)
2CY# ... STO 4 ACOMMUNE7(2) [ CHARS IN JOBNAME
2C^B ... LDN 0 APARA(1)
2D2D ... LDN 1 ACOMMUNE1(2)
2D3G ... SMO 4
2D4J ... MVCH 0 0 [ JOBNAME
2D5L ... HUNT2 3,CPB,CUNI
2D6N ... LDEX 4 ANUM(3)
2D7Q ... STO 4 ACOMMUNE8(2) [ CHARS IN USERNAME
2D8S ... LDN 0 APARA(3)
2D9W ... LDN 1 ACOMMUNE4(2)
2D=Y ... SMO 4
2D#2 ... MVCH 0 0 [ USERNAME
2D*4 ... LDX 1 FX1
2DB6 ... EXIT 7 0
2DBJ ...[
2DC2 ...PARGET
2DCD ... SBX 7 FX1
2DCW ... SPARABEG 1,0(3),,,0
2DD# ... MHUNT 3,CPB,CUNI
2DDQ ... LDX 0 ANUM(3)
2DF8 ... BPZ 0 PGT1
2DFL ... FREECORE 3
2DG4 ... SBN 7 1
2DGG ...PGT1 ADX 7 FX1
2DGY ... EXIT 7 1
2DHB ...[
2DHS ...[
2DJ= ...VOP STO 0 GEN0
2DJN ... VOP ,JWACCESS
2DK6 ... BRN (GEN0)
2DKJ ...[
2DL2 ...[
2DLD ...SPARA SBX 7 FX1
2DLW ... SPARANOX 4
2DM# ... BRN X7XIT
2DMQ ...[
2DN8 ...XFACT1
2DNL ... LDX 3 FX2
2DP4 ...XFACT FINDACTF 3,3,CPAT,,(4),FPTR
2DPG ... HUNT2J 1,JWELL,COPYSYS,3,XFACT
2DPY ... TXU 6 A1+FRH+JLJOBNO(1)
2DQB ... BCS XFACT
2DQS ... LDX 3 ACTNUM(3)
2DR= ... STO 3 AWORK1(2)
2DSK ... EXIT 4 1
2DSL ...#
2DW^ ...#
2D^# ...#
2F3M ...[
2F62 ...[ INITIALISE MARKER WORD
2F8* ...[
2F=N ...START STOZ AWORK4(2)
2F*3 ...[
2FCB ...[ CONTEXT BITS
2FFP ...[
2FJ4 ... LDX 0 CONTEXT(2)
2FLC ... ANDN 0 #21 [ OPERATOR AND USER
2FNQ ... BZE 0 NOCONTEXT
2FR5 ... ANDN 0 1
2FTD ... BZE 0 PUSER [ J IF NOT USER
2FXR ... JBS PUSER,2,EXOPCOM [ J IF OP COMMAND
2G26 ... BS 2,USER [ USER CONTEXT ABANDON
2G4F ...[
2G6S ...PUSER LDN 3 XCOLON(1)
2G97 ... CALL 7 PARGET [ USERNAME
2G?G ... BRN USEAB [ NO USERNAME -SEE IF USER AB
2G*T ... CHEKLFN2 NOUSER,WRONGF,3 [ NONE : WRONG FORMAT
2GD8 ... JBS USERCTXT,2,USER [ USERNAME IN USER CONTEXT : ERROR
2GPJ ... BRN PJOB [ OK : SO DO JOBNAME
2GRX ...[
2GW= ...USEAB JBC NOUSER,2,USER [ ERROR:NO USERNAME IN OPERATOR CNTXT
2GYK ... SETNCORE APARA+3,2,CPB,CUNI [ CREATE CPB/CUNI HOLDING USERNAME
2H2Y ... FJOCA 3,FX2 [ FROM JOB BLOCK
2H5? ... LDN 4 JUSER(3)
2H7L ... LDN 5 12
2H9^ ... LDN 3 0
2H## ...X SMO 4
2HBM ... LDCH 7 0(3)
2HF2 ... TXU 7 SPACE(1)
2HH* ... BCC XX
2HKN ... LDX 0 5 [ NON-SPACE CHAR
2HN3 ...XX BCHX 3 £
2HQB ... BCT 5 X
2HSP ... NGX 0 0
2HX4 ... ADN 0 13 [ SIG CHARS
2H^C ... LDN 5 APARA(2)
2J3Q ... SMO 0
2J65 ... MVCH 4 0
2J8D ... STO 0 ANUM(2) [ USERNAME CPB/CUNI
2J=R ... LDX 2 FX2
2J*6 ...[
2JBN ...PJOB
2JD= ... SPARUNAC [JOBNAME
2JFS ... CHEKLFN2 NOJOBNAME,WRONGF [NONE : WRONG FORMAT
2JJ7 ...[
2JLG ...[ CHECK OUT TEMP AND MESSAGE PARAMS
2JNT ...[
2JR8 ...#SKI JSKI31
2JTH ...(
2JXW ... SEGENTRY K80ABANDONA
2K29 ... BRN XPLUSN
2K4J ... LDN 3 XPM(1)
2K6X ... CALL 7 PARGET
2K9= ... BRN XPLUSN
2K?K ... BS 2,POSTM
2K*Y ... FREECORE 3
2KD? ...XPLUSN
2KGL ...)
2KJ^ ... LDN 3 STEMP(1)
2KM# ... CALL 7 PARGET [ TEMP
2KPM ... BRN XP1
2KS2 ... BRN XTE
2KW* ...XP1 LDN 3 STE(1)
2KYN ... CALL 7 PARGET [ TE
2L33 ... BRN XP2
2L5B ...XTE BS 2,TEMP [ TEMP PARAM GIVEN
2L7P ... FREECORE 3 [ BLOCK NOT WANTED
2L=4 ... JBS XUTE,2,USER
2L#C ... LDX 0 CONTEXT(2)
2LBQ ... ANDN 0 #200
2LF5 ... BNZ 0 XUTE
2LHD ...XP2 LDN 3 MESSAGE(1)
2LKR ... CALL 7 PARGET [ MESSAGE( )
2LN6 ... BRN XP3
2LQF ... BRN XME
2LSS ...XP3 LDN 3 ME(1)
2LX7 ... CALL 7 PARGET [ ME( )
2L^G ... BRN SEARCHJOBQ
2M3T ...XME LDX 0 ANUM(3)
2M68 ... SRL 0 12
2M8H ... SBN 0 2
2M=W ... LDX 4 JPARNUM(3)
2M*9 ... BNZ 0 WRNGMESS [ NOT TYPE 2
2MCJ ... FREECORE 3 [ CPB/CUNI
2MFX ...RPT
2MJ= ... PARALYSE ,,4 [ SPLIT
2MK3 ...#UNS ANSTOOMANY
2MKS ... TESTREP2 UNPAIR,UNPAIR,TOOMANY,TOOMANY
2MLK ... BZE 3 SCND
2MNY ... LDN 4 2
2MR? ... LDN 3 0
2MTL ... BRN RPT
2MX^ ...SCND
2N2# ... LDN 4 1
2N4M ... CALL 7 SPARA
2N72 ... PARAFREE [ CPB/CMULTIS
2N9* ... MHUNT 3,CPB,CUNI
2N?N ... LDX 0 ANUM(3)
2NB3 ... BZE 0 XFREE
2NDB ... BNG 0 XFREE
2NGP ... NAME 3,GMON,JABAND [ FOR AB MESSAGES
2NK4 ... BS 2,SMESS [ REMEMBER MESSAGE GIVEN
2NMC ... BRN SEARCHJOBQ
2NPQ ...XFREE FREECORE 3 [ EMPTY CPB/CUNI
2NS5 ...SEARCHJOBQ
2NWD ... STOZ AWORK3(2) [ JOBNO OF JOB BEING ABANDONED
2NYR ... STOZ AWORK2(2) [ AB MESSAGE TIMER
2P36 ... STOZ AWORK1(2) [ ACT NO OF WELL CPAT
2P5F ... ACROSS ABANDON,3
2P5L ...XFSHNBTRAN
2P7S ...#
2P=7 ...#
2P#G ...XCONFREE
2PFJ ...[ THIS SECTION REMOVES CONBUFF-COUT AND CONBUFF-IREMTW
2PH6 ...[ BLOCKS RELATING TO THIS JOB FROM THE CONSOLE OUTPUT CHAIN.
2PJN ...[ IT IGNORES THE FIRST BLOCK ON THE CHAIN SINCE THAT ONE MAY BE
2PL= ...[ BEING USED BY THE CONSOLE ACTIVITY. IN DME, WHERE THERE
2PMS ...[ ARE POSSIBLY OTHER BLOCKS ON THE CHAIN, THIS ACTION STILL
2PPB ...[ HOLDS VALID AS LONG AS THE CONSOLE ACTIVITY CLEARS ALL OTHER
2PQY ...[ BLOCKS OUT OF THE CHAIN FIRST. IT CURRENTLY DOES, BUT
2PSG ...[ THIS ASSUMPTION SHOULD NOT BE MADE IN ANY SUBSEQUENT TIDY-UP
2PW4 ...[ OF THIS CHAPTER. STIG TOWNSEND 1AUG77
2PXL LDX 3 BCONSOUT
2QC= TXU 3 CXCO
2QWW BCC NODISP [J IF CHAIN EMPTY
2RBG BRN RESTART
2RW6 NEXT LDX 3 6
2S*Q LDX 2 FX2
2STB RESTART
2T*2 LDX 3 FPTR(3)
2TSL TXU 3 CXCO
2W#= BCC NODISP [J IF END OF CHAIN REACHED
2WRW LDX 0 ATYPE(3)
2X?G TXU 0 XCOUT(1)
2XR6 BCC XC
2Y=Q TXU 0 XIREM(1)
2YQB BCC XI
2YTG ...#UNS ENHOPER
2YYL ... BRN RESTART [IGNORE OTHER BLOCKTYPES
2^3Q ...#UNS ENHOPER
2^6W ...#SKI
2^=2 GEOERR 1,CONBUFF [UNKNOWN BLOCKS IN CONSOUT CHAIN
2^PL XC LDX 4 AREC(3)
329= SBN 4 1 [NO.OF WORDS IN MESSAGE
32NW STO 3 6
338G LDN 3 ATEXT(3) [POINTER TO MESSAGE
33N6 BRN XCHCH
347Q XI LDX 4 A1(3)
34MB ANDN 4 #7777 [NO OF WORDS
3572 STO 3 6
35LL LDN 3 ICBUFF(3) [POINTER
366= XCHCH
36KW BZE 4 NEXT
375G SLL 4 2 [CHAR.COUNT
37K6 LDCH 0 0(3) [GET FIRST CHARACTER
384Q ... TXU 0 SCOLON(1)
38JB BCS NEXT [J - NOT REQUIRED BLOCK
3942 BCHX 3 £ [UPDATE CHAR MOD. FOR BLK
39HL ... LDX 7 ACOMMUNE8(2) [COPY COUNT OF CHARS IN US:NAME TO X7
3=3= LDN 2 ACOMMUNE4(2) [PTR TO START OF USERNAME
3=GW WLOOP BCT 4 WLOOP1
3?2G BRN NEXT
3?G6 WLOOP1
3?^Q LDCH 5 0(2)
3#FB LDCH 0 0(3)
3#^2 TXU 0 5
3*DL BCS NEXT [J IF NO MATCH
3*Y= BCHX 2 £ [ UPDATE BOTH
3BCW BCHX 3 £ [ POINTERS
3BXG BCT 7 WLOOP
3CC6 NEXTNAME
3CWQ SBN 4 1
3DBB BZE 4 NEXT
3DW2 LDCH 0 0(3)
3F*L TXU 0 SCOMMA(1)
3FT= BCS NEXT [J IF NO MATCH
3G#W BCHX 3 £
3GSG SMO FX2
3H#6 LDN 2 ACOMMUNE1
3HRQ SMO FX2
3J?B ... LDX 7 ACOMMUNE7 [GET COUNT OF JOBNAME CHARS
3JR2 WLOOP2
3K=L BCT 4 WLOOP3
3KQ= BRN NEXT
3L9W WLOOP3
3LPG LDCH 5 0(2)
3M96 LDCH 0 0(3)
3MNQ TXU 0 5
3N8B BCS NEXT [J IF NO MATCH
3NN2 BCHX 2 £
3P7L BCHX 3 £ [UPDATE PTRS
3PM= BCT 7 WLOOP2
3Q6W BCT 4 WEND
3QLG BRN WEND1
3R66 ...WEND LDCH 0 0(3)
3RKQ TXU 0 SPACE(1)
3S5B BCS NEXT [J IF NOT SPACE CHAR - BLK NOT REQ.
3SK2 WEND1 SMO 6
3T4L ... LDX 3 BPTR [POINTER TO PRECEDING BLOCK
3TJ= FREECORE 6
3W3W BRN RESTART
3WHG NODISP
3WNN ... LDX 2 FX2
3WTW ... JBS SUICIDE,2,XAUTO
3X36 CALL 5 SRDISPLAY [O/P ABANDON MESSAGE TO OP'S CONSOLE
3X5D ...XFSHNBCONS
3X=4 ...XDEAD
3XF2 ... ENDCOM
3XMY ...SUICIDE
3XT6 ... SUICIDE
3Y2B ...[
3YG2 ...[
3Y^L ...NOSTOP
3^F= ... JBC PERMAB,2,TEMP
3^YW ... MFREE JWELL,COPYSYS
42DG ...[
42Y6 ...[ TEMPORARY ABANDON OF A JOB IN THE WELL
43CQ ...[
43JY ... CLOSETOP
43Q7 ... LDN 5 0 [INDICATES AB COMMAND
43XB ... DOWN JOBLIST,6
4444 ... OUTMESS ATEMPAB
448Q ... LDX 6 XABANDWELL(1)
44?W ... CALL 5 SRDISPLAY1
44C2 ... BRN XDEAD
46T6 ...[
47#Q ...PERMAB [ PERMANENT AB OF WELL BACK
47P= ... OUTNULL
47XG ... LDX 6 XABANDWELL(1)
485Q ... CALL 5 SRDISPLAY1
48#2 ... SKIP ,1
48RL ... READ
49?= ... MHUNT 3,FILE,FRB
49QW ... NAME 3,JWELL,AJDF
4==G ... CLOSETOP [USER JOBLIST FILE
4=Q6 ... ACROSS ENWELLB,2
4?9Q ...[
4?9W ...XFSHNBSTOP
4?=7 ...[
4?=J ...[ THIS ENTRY POINT ABANDONS ALL A HARD UP USER'S WELL JOBS
4?=^ ...[
4??B ...MONY
4??R ... LDX 0 AWORK4(2)
4?#8 ... STO 0 AWORK2(2) [BREAKIN BITS
4?#K ... STOZ AWORK4(2)
4?#T ... MBS 2,SWELL,TEMP,USER [TEMP+USER => HARDUP AB
4?*5 ... LDX 0 AWORK1(2)
4?*6 ... BNG 0 NFRZ
4?*7 ... BS 2,XFROZEN
4?*8 ... BC 2,USER [TEMP+NO-USER MOP =>FROZEN AB
4?*9 ...NFRZ
4?*C ... LDN 5 0
4?*S ...MNXT STEP 1
4?B9 ... BZE 3 MEND
4?BL ... LDX 6 JLJOBNO(3)
4?BP ... GETJOB 6,SYSTEM
4?BS ... TESTRPN2 OK,MSKP
4?BX ... STEPAGAIN
4?C3 ... ADX 3 JOBDATASIZE
4?CD ... JBS MSKP,3,JLBRUNNING
4?CH ... JBC NFZC,2,XFROZEN
4?CJ ... JBS MSKP,3,JLBFROZEN
4?CK ...NFZC
4?CT ... JBC NMOP,3,JLBMOP
4?D= ... BS 2,SMOP
4?DB ... CALL 4 XFACT1
4?DG ... BRN MSKP
4?DR ... DOWN PROCONTX,14 [ABANDON MOP JOB
4?F4 ... NULL
4?FF ... NULL
4?FM ... NULL
4?FW ...MSKP SKIP 1,3
4?G? ... BRN MNXT
4?GN ...NMOP BC 2,SMOP
4?HG ... CALL 7 READNAME [SET UP COPYSYS
4?J# ... LDN 5 1 [INDICATES HARD UP ABANDON
4?JC ... JBC NFRZ1,2,XFROZEN
4?JD ... NGN 5 1
4?JF ...NFRZ1
4?JP ... DOWN JOBLIST,6
4?J^ ... VFREEW JWELL,COPYSYS
4?K9 ... BRN MSKP
4?KH ...MEND CLOSETOP
4?KY ... CLOSETOP
4?L6 ... CALL 0 VOP
4?L# ... LDCH 0 ATYPE(2)
4?LG ... SBN 0 CPAT/64
4?LN ... BNZ 0 NCPAT
4?LW ... LDX 0 AWORK2(2)
4?M7 ... STO 0 JOBEVENTS(2)
4?MJ ...NCPAT BZE 5 NMESS
4?MS ... JBS NMESS,2,XFROZEN
4?M^ ... MONOUT JHARDUP
4?NB ...NMESS LOSEPARS
4?NR ... UP
4?PB ...[
4#92 ...#
4#NL ...# ERROR CODE
4*8= ...#
4*MW ...XUTE
4B7G ... LDX 6 Y14(1)
4BM6 ... BRN RERR1
4C6Q ...NOCONTEXT
4CLB ... LDX 6 Y12(1)
4D62 ... BRN RERR1
4DKL ...WRNGMESS
4F5= ... CALL 7 SPARA
4FJW ... LDX 6 Y7(1) [ MESS PARAM ERROR
4G4G ... BRN RERR1
4GJ6 ...WRONGF
4H3Q ... NGN 7 1 [JOBNAME OR USERNAME WRONG
4HHB ... LDX 6 Y7(1) [PARAMETER FORMAT ERROR
4J32 ... BRN RERR3
4JGL ...USERCTXT
4K2= ... NGN 7 1
4KFW ... LDX 6 Y13(1) [NOT IN USER CONTEXT
4K^G ... BRN RERR3
4L39 ...TOOMANY
4L4Y ... NGN 7 1
4L6M ... LDX 6 Y15(1)
4L8B ... BRN RERR3
4L=5 ...UNPAIR
4L?S ... NGN 7 1
4L*H ... LDX 6 Y16(1)
4LC= ... BRN RERR3
4LF6 ...NOUSER
4LYQ ... LDX 7 Y2(1) [ USERNAME
4MDB ... BRN RERR2
4MY2 ...#
4NCL ...NOJOBNAME
4NX= ... LDX 7 Y3(1) [JOBNAME MISSING
4PBW ...RERR2
4PWG ... LDX 6 Y4(1) [ PARAM MISSING
4QB6 ...RERR3
4QTQ ... COMERRX 6,7
4R*B ...#
4RT2 ...RERR1
4S#L ... NGN 7 1
4SS= ... BRN RERR3
4T?W ...#
4TRG ...Y2 +JUSNA
4W?6 ...Y3 +JJOBNA
4WQQ ...Y4 +JPARMIS
4X=B ...Y7 +APFERR
4XQ2 ...Y12 +JXABCNTXT
4Y9L ...Y13 +JXUSERAB
4YP= ...Y14 +JXUSERTEM
4YP^ ...Y15 +JMAXPAR
4YQN ...Y16 +ERUNPAIR
4^8W ...#
5R52 #END
^^^^ ...36007113000200000000