{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: ANTIC867)}}
====== ANTIC867 ======
(George Source)
**Macros used:** [[george:macro:BACKSPACE|BACKSPACE]], [[george:macro:BBUS|BBUS]], [[george:macro:BS|BS]], [[george:macro:CHECKEXT|CHECKEXT]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FADDRESS|FADDRESS]], [[george:macro:FINDSU|FINDSU]], [[george:macro:FINMOVE|FINMOVE]], [[george:macro:FOUTMOVE|FOUTMOVE]], [[george:macro:FPCACA|FPCACA]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETACTX|GETACTX]], [[george:macro:GETWORD|GETWORD]], [[george:macro:ILLEGAL|ILLEGAL]], [[george:macro:KEEPREP|KEEPREP]], [[george:macro:LGEOG|LGEOG]], [[george:macro:LINKSET|LINKSET]], [[george:macro:LOGACCESS|LOGACCESS]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFINDEXOF|MFINDEXOF]], [[george:macro:MFINDSU|MFINDSU]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:NAME|NAME]], [[george:macro:OLPFIN1|OLPFIN1]], [[george:macro:OPENDIR|OPENDIR]], [[george:macro:OPTMESS|OPTMESS]], [[george:macro:PAIR|PAIR]], [[george:macro:PUTPERENT|PUTPERENT]], [[george:macro:PUTREP2|PUTREP2]], [[george:macro:RELST|RELST]], [[george:macro:REWRITE|REWRITE]], [[george:macro:ROLPA|ROLPA]], [[george:macro:RUNPROG|RUNPROG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETREP|SETREP]], [[george:macro:TESTREP|TESTREP]], [[george:macro:TESTREPNOT|TESTREPNOT]], [[george:macro:TOPCA1|TOPCA1]], [[george:macro:UNLOCKSU|UNLOCKSU]], [[george:macro:UNPLUG|UNPLUG]], [[george:macro:UP|UP]], [[george:macro:WORDFIN|WORDFIN]]
22FL ...#SEG ANTIC70 [FRANK BLUNDELL
22KH ...#
22PD ...# COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
22T* ...#
22^= #DEF XA1=A1
23DW #LIS K0ANTIC
23YG 8HANTIC
24D6 #
24XQ # THIS ROUTINE CONNECTS A FILE TO A PROGRAM
25CB # ON ENTRY A GEXD BLOCK IS CHAINED AFTER THE CPA
25X2 #
26BL #DEF XCA=EVENT2
26W= #DEF T1=EWORK1
27*W #DEF T2=T1+1
27TG #DEF T3=T2+1
28*6 #DEF T4=T3+1
28SQ #DEF T5=T4+1
29#B #DEF T6=T5+1
29S2 #DEF T7=T6+1
2=?L #DEF T8=T7+1
2=R= #DEF T9=T8+1
2?=W #
2?QG #
2#=6 #
2#PQ SEGENTRY K1ANTIC,QK1ANTIC
2*9B SEGENTRY K2ANTIC,QK2ANTIC
2*P2 SEGENTRY K3ANTIC,QK3ANTIC
2B8L SEGENTRY K4ANTIC,QK4ANTIC
2BH2 ... SEGENTRY K77ANTIC,QK77ANTIC
2BN= #
2C7W ZLINK PAIR PERION,1
2C*N ...WDA 4HDA
2CCL ...SCA 12HICLSCAFILE
2CFJ ...XEWRARED +EWRARED [DIRECTORY FOR SU DOESNT EXIST
2CHG ...XEWSTUC +EWSTUC [SU Z TRAPS CLOSED
2CMG #
2D76 QK1ANTIC
2DLQ LDCT 4 AOLPT/8 [TYPE,
2F6B LDN 5 EXAOLPT [LENGTH FOR GETACTY
2FL2 GETACTX 4,5,1 [GET AOLPT ACTIVITY AND START
2G5L LDX 1 BPTR(2) [SETTING IT UP
2GK= MHUNTW 3,EWDAS,GEXD
2H4W LDX 0 JOBNO(2)
2HJG STO 0 JOBNO(1) [JOB NUMBER
2J46 LDX 0 EXCHNL(3)
2JHQ STO 0 EWCHAN(1) [CHANNEL NUMBER
2K3B LDN 0 1
2KH2 STO 0 ATMARK(1) [OLPA TYPE
2L2L LDX 0 GIVEX(3)
2LG= ANDN 0 1
2L^W SRC 0 1
2MFG ORS 0 GIVE(1)
2MP? ... LDX 0 EXOTRAP(3) [TRANSFER EXOFILE ENTRY
2MRW ... STO 0 EXTRAPS(1) [TRAPS FROM GEXD TO AOLPT
2M^6 LDX 2 FX1
2NDQ LINKSET 1,ZLINK(2)
2NYB LDX 0 CEFN(3)
2PD2 STO 0 EXNUM(1) [EXOFILE NUMBER
2PXL LDX 4 EOPMODE(3)
2QC= STO 4 EXMODE(1)
2QWW SBN 4 #600
2RBG MFINDEXOF 2,EXNUM(1)
2RW6 LDCT 0 #400
2S*Q STO 0 FRECHADD(1)
2STB STOZ CPRW1(1) [3
2T*2 STOZ CPRW2(1) [REPLY
2TSL STOZ CPRSW(1) [WORDS
2W#= LDX 7 1 [SAVE PTR TO AOLPT
2WRW LDX 5 ASUSN(2) [SERIAL NO FROM EXOF
2X?G MFINDSU 1,5 [X1-> ASTUC
2XR6 ... LDX 6 HUNIT(1) [PTR TO DEVICE LIST
2Y=Q LDX 1 7 [RESTORE AOLPT PTR
2YGJ ... BZE 5 ZEROSN
2YQB ... STO 6 CPPTR(1) [PTR TO DEVICE LIST
2^28 ...ZEROSN
2^=2 BZE 4 SCRA
2^#K ... UNLOCKSU 5 [UNLOCK + RELST HERE AS DISC
2^C8 ... RELST 5 [..MAY GO OFFLINE + MFINDSU FAILS
2^FR ... LDX 1 BPTR(2) [AOLPT PTR IN X1
2^JB ... MHUNTW 3,EWDAS,GEXD [GEXD PTR IN X3
2^L^ ... MFINDEXOF 2,EXNUM(1) [EXOF PTR IN X2
2^PL LDCT 4 4 [MASK FOR BIT 6
329= ANDX 4 EXMARK(2)
32NW SLL 4 5 [TO BIT 1
338G ORS 4 EXMAYBE(1)
33N6 LDX 0 ASUSN(2) [MOVE IN REPLIES
347Q STO 0 T2(1) [SERIAL NUMBER
34MB ADN 1 T3
3572 LDN 0 FNAMER(3) [NAME
35LL MOVE 0 3
366= SBN 1 T3
36KW LDX 0 FIP+3(2) [2ND LEVEL OVERFLOW
375G STO 0 T6(1)
37K6 LDX 0 FNAMER+3(3)
384Q STO 0 T7(1) [GENERATION/VERSION
38JB LDN 0 FIP+8(2)
3942 ADN 1 T8 [REST OF THE REPILES
39HL MOVE 0 2
3=3= NSCR LDX 2 FX2
3=GW FPCACA 2 [FIND PCA
3?2G LDCT 0 #6
3?G6 LDX 4 EXCHNL(3)
3?JG ... ORX 4 0 [TYPE/UNIT NO
3?RL ... SETNCORE 3,1,ADATA,ASUP
3?W2 ... LDN 0 6
3?YB ... STO 0 A1(1) [*DA
3#2Q ... BZE 6 NOGEO
3#56 ... LGEOG 6,6
3#7G ...NOGEO
3#9W ... STO 6 A1+1(1) [GEOG UNIT NO
3##= ... STO 5 A1+2(1) [SUSN
3#FB LDCT 1 #400 [OFF LINE BIT
3*DL ... PUTPERENT 4,1
3*Y= ROLPA [RECHAIN AOLPT
3BXG MHUNTW 3,EWDAS,GEXD
3CC6 NMOV LDX 0 GIVEX(3)
3CWQ BPZ 0 NCOM [JUMP IF NOT ONLINE COMMAND
3DBB FREECORE 3 [FREE GEXD
3DW2 ENDCOM
3F*L #
3FT= NCOM LDX 5 CNR(3)
3G#W ADN 5 1 [REPLY WORD
3GSG LDN 7 1 [ONE WORD ONLY IF MODE #1200
3H#6 SMO 6
3HRQ LDX 0 EXMODE
3J?B SBN 0 #600
3JR2 BZE 0 XSCR [JUMP IF SCRATCH
3K=L SMO 6
3KQ= LDN 2 T2
3L9W ADN 3 XA1
3LPG SBN 0 #400
3M96 BZE 0 NCRE
3MNQ LDN 7 8 [8 WORDS IF NOT CREATE
3N8B NCRE SMO 7
3NN2 MOVE 2 0 [MOVE IN REPLIES
3NT8 LDN 4 XA1
3P2B XADDR GETWORD 5,5,WRITE,6,7 [GEORGE ADDRESS OF OBJ PROG CA.
3P7J TESTREPNOT OK,XRV
3P#Q MHUNT 3,EWDAS,GEXD
3PFY ADX 4 3 [ADDRESS OF REPLIES IN GEXD
3PM6 TXL 6 7 [ X6=NO OF WORDS WE CAN ACCESS
3PS# BCC XMOV [J IF MOVE CAN BE DONE IN ONE GO
3P^G SMO 6
3Q6N MOVE 4 0 [MOVE AS MANY AS ALLOWED
3Q?W LDX 5 CNR(3)
3QF4 ADN 5 1
3QL= ADX 5 6 [UPDATE REQUIRED OBJ PROG ADDRESS
3QRD ... SBX 7 6 [NO OF WORDS STILL TO BE MOVED
3QYL SMO 6
3R5S LDN 4 XA1 [ADDRESS IN GEXD FROM WHICH TO MOVE
3R?2 BRN XADDR [J TO DO REST OF MOVE
3RD8 XMOV SMO 7
3RKQ MOVE 4 0 [MOVE IN REPLIES
3S5B FREECORE 3
3SK2 WORDFIN
3T4L RUNPROG [RESTART PROGRAM
3TJ= #
3W3W #
3WHG SCRA [SET SCRATCH REPLIES
3X36 LDEX 0 FIP+5(2)
3XGQ BZE 0 SCRB
3Y2B LDX 0 FDCELLS+5(2)
3YG2 SBN 0 1
3Y^L SCRB STO 0 T6(1) [LAST LBN
3^F= LDX 0 BKSIZE(3)
3^YW STO 0 T7(1) [BUCKET SIZE
42DG LDX 0 BREQ(3)
42Y6 STO 0 T8(1) [BLOCKS REQUESTED
434S ... LDX 5 ARUNIT(3)
439G ... STO 5 T9(1) [SERIAL NUMBER
43MJ ... LDN 6 0 [SUSN OF ZERO FOR SCRATCH
43PX ... BZE 5 XOUT
43S= ... FINDSU 2,5,XOUT
43YY ... LDX 6 HUNIT(2) [X6= DEVICE LIST POINTER
445L ...XOUT
44C2 LDCT 0 #20
44WL ANDX 0 EMARK(3)
45B= SLL 0 4
45TW STO 0 EXMAYBE(1) [SET MAYBE MARKER
46*G BRN NSCR
46T6 #
47#Q #
47SB XSCR LDN 7 4
48#2 SMO 6
48RL LDN 2 T6
49?= ADN 3 XA1
49QW BRN NCRE
4==G #
4=Q6 #
4?9Q #
4?PB # ANTICIPATED OPENS
4#92 ZREPLY #40000001 [REPLY FOR DIFFERENT BUCKET SIZE
4#NL QK4ANTIC
4*8= GEOERR 1,CREATE? [ILLEGAL ENTRY
4*MW QK2ANTIC
4B7G LDN 7 9 [9 WORD CONTROL AREA
4BM6 CHECKEXT XCA(2),7,ZRES,APETADDR(2),W,ZJ1,HLOCK1
4C6Q ZJ1 [CHECK PROGRAM C/A RESERVATIONS
4CLB #SKIP K6ANTIC>199-199
4D62 (
4DKL LDX 4 EXMODE(2)
4F5= CALL 0 ZMODE
4FJW )
4G4G LDX 3 XCA(2) [ADDRESS OF CONTROL AREA
4GJ6 LDX 1 APETADDR(2) [ADDRESS OF PCA
4H3Q FADDRESS 1,3,HLOCK1 [GET ABSOLUTE GEORGE ADDRESS
4HHB LDX 4 0(3) [LOAD TYPE/MODE WORD AND
4J32 STO 4 T1(2) [STORE WITH ONLINE REPLIES
4JGL #SKIP K6ANTIC>199-199
4K2= (
4KFW ANDN 4 #1777
4K^G CALL 0 ZMODE
4LF6 )
4LYQ LDX 4 EXMODE(2)
4MDB DLA 4 T1(2) [RESET MODE FROM ONLINE COMMAND
4MY2 LDX 4 XCA(2) [ADDRESS OF C/A
4NCL LDN 3 T1(2)
4NX= FINMOVE 1,4,3,7,HLOCK1 [MOVE C/A INTO OBJECT PROGRAM
4PBW XJ6 LDCT 4 256
4PWG ORS 4 GIVE(2) [SET GIVE MARKER
4QB6 LDX 1 FX1
4QTQ OLPFIN1 ZLINK(1)
4R*B #SKIP K6ANTIC>199-199
4RT2 (
4S#L ZMODE LDN 5 4
4SS= ZJ3 SBN 4 #100 [ENSURE MODES #100,#200,#300,#400
4T?W BZE 4 ZJ2
4TRG BCT 5 ZJ3
4W?6 GEOERR 1,WRNGMODE
4WQQ ZJ2 EXIT 0 0
4X=B )
4XQ2 ZRES TOPCA1 ZLINK(1) [AOLPT TO SLEEP
4Y9L UNPLUG [UNPLUG PROGRAM BEFORE...
4YP= ILLEGAL NOCA [...FAILING IT
4^8W #
4^NG QK3ANTIC
5286 LDN 7 5 [5 WORD CONTROL AREA
52MQ CHECKEXT XCA(2),7,ZRES,APETADDR(2),W,ZJ1A,HLOCK1
537B ZJ1A LDX 1 APETADDR(2) [ADDRESS OF PCA
53M2 LDN 4 T1(2)
546L LDX 3 XCA(2) [ADDRESS OF C/A
54L= FOUTMOVE 1,3,4,7,HLOCK1 [MOVE C/A INTO ACOMMUNE WORDS
555W LDX 4 EXMAYBE(2)
55KG BPZ 4 XJ3 [BRANCH IF NO CHECKING REQUIRED
5656 LDX 4 T3(2)
56JQ TXU 4 T7(2)
574B BCC XJ7 [SAME BUCKET SIZE?
57J2 XJ4 SMO FX1
583L LDX 4 ZREPLY [REPLY INDICATING DIFFERENT BUCKET..
58H= XJ5 LDX 3 XCA(2) [SIZE
592W ADN 3 1 [ADDRESS OF OBJECT PROG.REPLY WORD
59GG FADDRESS 1,3,HLOCK1 [INTO ABSOLUTE GEORGE ADDRESS
5=26 STO 4 0(3) [REPLY INTO OBJ PROG
5=FQ LDX 1 FX1
5=^B OLPFIN1 ZLINK(1) [GO ASLEEP WITH LINK TO PERION
5?F2 XJ7 LDX 4 T8(2) [FILE SIZE IN BLOCKS
5?YL TXL 4 T4(2)
5#D= BCC XJ3 [BRANCH IF FILE SIZE BIG ENOUGH
5#XW BZE 4 XJ4 [BRANCH IF ZERO BLOCKS
5*CG ORX 4 GSIGN [BRANCH IF TOO SMALL
5*X6 BRN XJ5
5BBQ XJ3 LDX 4 T1(2)
5BWB STO 4 T5(2) [TYPE/MODE TO ONLINE REPLIES
5CB2 LDN 3 T5(2)
5CTL LDX 4 XCA(2)
5D*= FINMOVE 1,4,3,7,HLOCK1 [OVERWRITE OBJ PROG C/A WITH...
5DSW BRN XJ6 [...ONLINE REPLIES
5F#G #
5F#R ...QK77ANTIC
5F#W ...#
5F#^ ...# ENTRY POINT FOR EXCHOFE MACRO
5F*4 ...#
5F*7 ... LDX 0 ACOMMUNE9(2)
5F*= ... STO 0 AWORK1(2) [PRESERVE REQD ACCESS MODES
5F*? ... LDX 0 ACOMMUNE6(2) [=0 FOR TRAP CHECKING,=1 FOR UPDATING
5F*# ... STO 0 AWORK3(2) [D&T LAST ACCESSED & -VE FOR D&T LAST
5F** ... SETNCORE 10,3,FILE,FABSNB [SET UP 10 WORD FABSNB
5F*D ... LDX 7 ACOMMUNE7(2) [X7 - 0=EXOF,1=DIR,2=ICL
5F*H ... LDX 6 WDA(1)
5F*L ... STO 6 A1+1(3) [FILL IN CHARS "DA"
5F*P ... LDX 6 ACES [AND SPACES IN
5F*S ... STO 6 A1+3(3) [DIRECTORY NAME
5F*X ... STO 6 A1+2(3)
5FB2 ... LDX 6 ACOMMUNE8(2) [SUSN IS PARAMETER
5FB5 ... MHUNTW 2,EWDAS,EXOF
5FB8 ... BZE 6 NEXOF [ZERO SUSN - GO GET IT FROM EXOF
5FB? ... BRN SNCON
5FBB ...NEXOF
5FBF ... LDX 6 ASUSN(2) [EWDAS-EXOF BLOCK
5FBJ ...SNCON
5FBM ... SLL 6 6 [PRESERVE L.S. 6 DIGITS
5FBQ ... LDN 4 6 [COUNT
5FBT ... LDN 1 A1+1(3)
5FBY ... ORX 1 GSIGN [A1+1.2
5FC3 ... LDN 5 0
5FC6 ...SNZER
5FC9 ... SLL 56 3
5FC# ... BNZ 5 STREM
5FCC ... BCT 4 SNZER
5FCG ... BRN STFIN
5FCK ...SNMOV
5FCN ... LDN 5 0
5FCR ... SLL 56 3 [GET NEXT DIGIT
5FCW ...STREM
5FC^ ... DCH 5 0(1) [STORE IN DIRECTORY NAME
5FD4 ... BCHX 1 £
5FD7 ... BCT 4 SNMOV
5FD= ...STFIN
5FD* ... LDX 1 FX1
5FDD ... BNZ 7 MISSY [J IF NOT EXOF
5FDH ... LDCT 0 #100
5FDL ... ANDX 0 FIP+5(2)
5FDP ... BZE 0 STNAM [J IF NOT A SYSTEM FILE
5FDS ... LDX 0 FIP(2)
5FDX ... TXU 0 SCA(1) [SYFLE OR ICLSCAFILE
5FF2 ... BCC STNAM [J IF ICLSCAFILE
5FF5 ...SHRTN
5FF8 ... LDN 0 4 [SHORTEN FILE-FABSNB
5FF? ... STO 0 A1(3) [IN ORDEN TO OPEN ENTRY
5FFB ... SMO FX2
5FFF ... STO 0 AWORK2
5FFJ ... BRN TOPEN [FOR DIRECTORY
5FFM ...MISSY
5FFQ ... SBN 7 1 [DIR OR ICL
5FFT ... BNZ 7 STNAM [J IF ICL
5FFY ... ADN 7 1 [RESTORE PARAM INDICATOR
5FG3 ... BRN SHRTN [J FOR DIR
5FG6 ...STNAM
5FG9 ... LDN 0 10
5FG# ... STO 0 A1(3) [SET HDDR
5FGC ... SMO FX2
5FGG ... STO 0 AWORK2
5FGK ... LDN 0 0
5FGN ... STO 0 A1+7(3)
5FGR ... STO 0 A1+8(3)
5FGW ... STO 0 A1+9(3)
5FG^ ... LDN 6 A1+4(3)
5FH4 ... BNZ 7 STICL [X7=0 FOR EXOF,=1 FOR ICL NOW
5FH7 ... LDX 4 FIP+4(2)
5FH= ... SRL 4 12
5FH* ... BNZ 4 STGEN [J IF GEN NUM NOT ZERO
5FHD ... LDCT 4 #100 [SET BIT2 FOR OPENDIR
5FHH ...STGEN
5FHL ... STO 4 A1+8(3) [STORE GENERATION NO
5FHP ... LDN 5 FIP(2) [GET LOCAL NAME FROM EWDAS-EXOF
5FHS ... BRN STLOC
5FHX ...STICL
5FJ2 ... LDN 5 SCA(1) [SET LOCAL NAME TO ICLSCAFILE
5FJ5 ...STLOC
5FJ8 ... MOVE 5 3 [MOVE IN LOCAL NAME
5FJ? ... BS 3,BFABEXO [INDICATE EXOFILE ENTRANT REQUIRED
5FJB ...TOPEN
5FJF ... OPENDIR OBRK,GENERAL,QUERY [OPEN REQUIRED ENTRY
5FJG ... LDX 5 AWORK3(2) [FUNCTION INDICATOR
5FJJ ... TESTREP OK,OPOK
5FJM ... BRN NOFE
5FJQ ...OBRK
5FJT ... GEOERR 1,BREAKIN
5FJY ...NOFE
5FJ^ ... BNZ 5 OKTDY [J IF NOT TRAP CHECKING
5FK3 ... LDX 0 AWORK2(2)
5FK6 ... SBN 0 4 [IF ORIGINAL FABSNB LENGTH
5FK9 ... BNZ 0 NOFE1 [NOT 4 THEN DIRECTORY NOT OPENED
5FK# ... MHUNTW 3,EWDAS,GEXD
5FKC ... OPTMESS XEWRARED(1),ESERL(3) [DIRECTORY DOESNT EXIST
5FKG ...NOFE1
5FKK ... SETREP NOFILE [NO ENTRY - NO TRAP CHECKS
5FKN ... LDX 4 GSIGN
5FKR ... BRN OKFIN
5FKW ...NOTRAP
5FKX ...#UNS ILOGACC
5FKY ...#SKI
5FK^ ... MFREE FILE,ENT
5FL2 ... LDX 0 AWORK2(2) [IF ORIGINAL LENGTH
5FL4 ... SBN 0 4 [OF FABSNB WAS NOT 4
5FL7 ... BNZ 0 NOTRAP1 [THEN NOT DIRECTORY SO J
5FL= ... MHUNTW 3,EWDAS,GEXD
5FL* ... OPTMESS XEWSTUC(1),ESERL(3) [SU TRAPS CLOSED
5FLD ...NOTRAP1
5FLH ... KEEPREP 5,NOTRAP
5FLL ... LDX 4 GSIGN
5FLP ... BRN OKCL
5FLS ...OPOK
5FLT ... BNZ 5 NOCHKTRP [J IF EXCHOFE IS ONLY UPDATING D&T
5FLX ... CHECKTRAPS [PUTS ACCESS MODES IN EXEC1
5FM2 ... LDX 0 EXEC1(2)
5FM5 ... ANDX 0 AWORK1(2) [MODES REQUIRED
5FM8 ... SBX 0 AWORK1(2)
5FM? ... BNZ 0 NOTRAP [J FOR FORBIDDEN ACCESS
5FMB ... LDX 4 EXEC1(2) [ACCESS MODES ALLOWED
5FMH ... KEEPREP 5,OK
5FMN ... BRN OKCL
5FMT ...NOCHKTRP
5FN2 ... MHUNTW 3,FILE,ENT
5FN7 ... BBUS 23,ECOPS(3),TANDD [J IF NOT DIRECTORY FOR D&T UPDATE
5FN# ... BACKSPACE [BACKSPACE BY NO OF TRAPS RECORDS ETC
5FNG ... MHUNTW 3,FILE,ENT
5FNH ...TANDD
5FNK ... LDX 0 EDATE [DATE
5FNN ... LDX 1 CLEANCT [TIME
5FNW ... BPZ 5 TDLA [J IF ONLY D&T LAST ACCESSED
5FP4 ... STO 0 EWRITDAY(3) [UPDATE DATE &
5FP7 ... STO 1 EWRITTIME(3) [TIME LAST WRITTEN
5FP= ...TDLA
5FP* ... STO 0 EDLA(3) [DATE &
5FPD ... STO 1 ETLA(3) [TIME LAST ACCESSED
5FPH ... LDX 0 GMTNOW
5FPL ... STO 0 EGMTLA(3) [TIMESINCE LAST ACCESS - DOWNTIME
5FPM ...WRITBACK
5FPP ... NAME 3,FILE,FWB
5FPS ... REWRITE [REWRITE RECORD
5FPX ... MFREE FILE,FWB
5FPY ...#UNS ILOGACC
5FP^ ...(
5FQ2 ... BRN XCLOSE1
5FQ3 ...OKCL
5FQ4 ... BNZ 5 XFRUST [J IF ACCESS NOT OK
5FQ5 ... LOGACCESS 2,AWORK1(2) [LOG ACCESS OF CONTENTS
5FQ6 ... BRN XCLOSE
5FQ7 ...XFRUST
5FQ8 ... LOGACCESS 7,AWORK1(2) [LOG FRUSTRATED ACCESS
5FQ9 ...XCLOSE
5FQ= ... MFREE FILE,ENT
5FQ? ...XCLOSE1
5FQ# ...)
5FQ* ...#UNS ILOGACC
5FQB ...#SKI
5FQC ...OKCL
5FQD ... CLOSETOP
5FQF ... PUTREP2 5
5FQG ...OKFIN
5FQH ... LDX 0 AWORK3(2)
5FQJ ... BNZ 0 OKTDY [J IF NOT TRAP CHECKING
5FQK ... BNZ 7 OKTDY [J IF PARAM NOT EXOF
5FQL ... MHUNTW 3,EWDAS,GEXD
5FQM ... STO 4 EXOTRAP(3) [PRESERVE TRAPS RECORD
5FQN ... LDX 0 AWORK2(2)
5FQQ ... STO 0 EXEC1(2)
5FQT ...OKTDY
5FQY ... MHUNT 3,FILE,FABSNB
5FR3 ... FREECORE 3 [FREE FILE-FABSNB
5FR6 ... UP
5FS6 XRV GEOERR 1,CONNECT
5G?Q #
5GRB #
5H?2 MENDAREA 30,K99ANTIC
5HQL #END
^^^^ ...72555322000100000000