{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: ATTACHA8)}}
====== ATTACHA8 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:ALTLEN|ALTLEN]], [[george:macro:BXGE|BXGE]], [[george:macro:BXU|BXU]], [[george:macro:CHEKLFN2|CHEKLFN2]], [[george:macro:CHNUMCOD|CHNUMCOD]], [[george:macro:COMERR|COMERR]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GSCAN|GSCAN]], [[george:macro:HUNTW|HUNTW]], [[george:macro:JV7900|JV7900]], [[george:macro:LGEOG|LGEOG]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:NAME|NAME]], [[george:macro:OUTNUM|OUTNUM]], [[george:macro:PARALYSE|PARALYSE]], [[george:macro:PARANUMB|PARANUMB]], [[george:macro:PARAPASS|PARAPASS]], [[george:macro:PARSORTX|PARSORTX]], [[george:macro:PHOTO|PHOTO]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SPARABEG|SPARABEG]], [[george:macro:SPARANOT|SPARANOT]], [[george:macro:SPARAPAS|SPARAPAS]], [[george:macro:TESTMOVE|TESTMOVE]], [[george:macro:TESTREP|TESTREP]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:TRACE|TRACE]], [[george:macro:ZERRORX|ZERRORX]], [[george:macro:ZERRORY|ZERRORY]]
22FL #SEG ATTACHA [JOHN BAILEY.
22^= ...#OPT K0ATTACHA=0
23DW ...#LIS K0ATTACHA>K0COMMAND>K0ALLGEO>K0GREATGEO
23YG #OPT K6ATTACH=0
24D6 8HATTACHA8
24XQ SEGENTRY K1ATTACHA,X1ATTACHA
25CB SEGENTRY K5ATTACHA,X5ATTACHA
25X2 #
26BL #
26W= #
27*W NAMCL #43540000
27TG RMASK #60077777
28*6 #
28SQ #
29#B #
29S2 # GET PARAMETER BEGINNING WITH U,L,OR CL ; CALL ON X7
2=?L #
2=R= NOLET LDCT 5 #510 [PRESET TO GET "I" PARAMETER
2?=W LDXC 0 AWORK3(2) [J. IF DEALING WITH IDENTIFIER NO.
2?QG ADXC 0 0
2#=6 BCS NOIDE
2#PQ LDCT 5 #540 [OTHERWISE LOOK FOR "L" PARAMETER
2*9B NOIDE LDN 4 1
2*P2 NAME SBX 7 FX1 [ENTRY FOR 'CL'
2B8L SPARABEG 1,4
2BN= ADX 7 FX1
2C7W EXIT 7 0
2CMG #
2D76 # GET PARAMETER FROM CPB/CUNI BLOCK & CONVERT TO BINARY ; CALL ON X7
2DLQ #
2F6B PASS SBX 7 FX1
2FL2 MHUNT 3,CPB,CUNI
2G5L NGX 0 ANUM(3)
2GK= BPZ 0 RCLUE [PARAMETER NULL OR MISSING
2H4W PHOTO 6
2HJG CHNUMCOD ,3
2J46 TESTREP CHNUMERR,URET [ENDCOM IF INVALID FORMAT
2JHQ TESTMOVE 6,NOMO
2K3B MHUNT 3,CPB,CUNI [RELOCATE AFTER COORDINATION
2KH2 NOMO LDX 6 ACOMMUNE1(2) [PICK UP CONVERTED PARAMETER
2L2L BZE 6 RFER
2L=D ... BNG 6 RFER
2LG= ADX 7 FX1
2L^W EXIT 7 0
2MFG #
2M^6 #
2NDQ #
2NYB # PARSORT MACRO ROUTINE PLUS HUNTING FOR A CPAR JSCE BLOCK
2PD2 #
2PXL RPARS
2QC= SBX 6 FX1
2QWW LDN 4 2
2RBG SMO 1
2RW6 LDX 5 NAMCL
2S*Q CALL 7 NAME
2STB MHUNT 3,CPB,CUNI
2T*2 LDX 0 ANUM(3)
2TSL BNG 0 W2
2W#= BZE 0 W2
2WRW LDEX 0 JPARNUM(3)
2X?G ERN 0 3
2XR6 W3 LDX 1 0
2Y=Q PARSORTX URET,1,NOCLUS
2YQB BRN W4
2^=2 W2 LDN 0 1
2^PL BRN W3
329= W4 MHUNTW 3,CPAR,JSCE
32NW BNG 3 URET
338G ADX 6 FX1
33N6 EXIT 6 0
347Q #
34MB #
3572 # SUBROUTINE WHICH ANALYSES THE CL PARAMETER
35LL RCLP SBX 7 FX1
366= STO 7 AWORK1(2)
36KW LDN 4 2
375G LDX 1 FX1
37K6 LDX 5 NAMCL(1) [4HCL00
384Q LDN 3 0 [ANALYSIS LEVEL
38JB SPARABEG 1,4,,3 [FIND CONCEPTUAL NAME PARAMETER
3942 MHUNT 3,CPB,CUNI
39HL LDX 0 ANUM(3)
3=3= BNG 0 RCLMI [NO NAME COMMAND ERROR
3=GW BZE 0 NONAM [NULL NAME INVALID
3?2G LDX 7 JPARNUM(3) [POSITION OF NAME IN CPB/CALAS BLOCK
3?G6 #
3?^Q #
3#FB LDX 0 CONTEXT(2)
3#^2 ANDN 0 #10
3*DL BZE 0 ROCAT [IF ATTACH HAS BEEN ISSUED FROM MOP
3*Y= ANDN 7 #77 [CONSOLE STORE THE POSITION OF CL
3BCW ORS 7 AWORK3(2)
3BXG #SKI K6ATTACH>199-199
3CC6 TRACE AWORK3(2),POJOFCL [POSITION OF CL IN COMMAND
3CWQ #
3DBB #
3DW2 ROCAT FREECORE 3 [PARAMETER IN CPB/CALAS BLOCK
3F*L LDN 3 0 [ANALYSIS LEVEL
3FT= PARALYSE #36,3,7 [ANALYSE CL PARAMETER
3G2D ...#UNS ANSTOOMANY
3G7L ... TESTREP2 TOOMANY,TOMP
3G#W CALL 7 NAME
3GSG CHEKLFN2 NONAM,NONAM [CHECK FOR VALID FORMAT.
3H#6 NAME 3,IDF,COINF [RENAME THE BLOCK WITH CONCEPTUAL NAM
3HRQ LDX 4 AWORK4(2) [IDENTIFIER/LINE NUMBER
3J?B SRL 4 12
3JR2 STO 4 JPARNUM(3) [ACT LINE/IDENTIFIER NO BITS 9-23
3K=L #SKI K6ATTACH>199-199
3KQ= GSCAN JPARNUM(3),IDFCOINF,5
3L9W #
3LPG SETNCORE 3,3,IDF,CONCEP [FOR PASSING INFORMATION TO XATTACH
3M96 LDX 6 AWORK4(2) [GEOGR AND ACT LINE/IDENTIFIER NOS
3MNQ STO 6 A1(3) [STORE IN IDF BLOCK
3N8B STOZ A1+1(3) [INITIALISE
3NN2 STOZ A1+2(3) [IDF/CONCEP
3P7L PARANUMB 4
3PM= LDX 7 AWORK1(2)
3Q6W ADX 7 FX1
3QLG BCT 4 XXR
3R66 EXIT 7 0
3RKQ XXR EXIT 7 1
3S5B #
3SK2 # SUBROUTINE WHICH ANALYSES THE L PARAMETER
3T4L # LINE PARAMETER IS SIMP : L5 , QUAL : L4(5) OR COMP : L(17,5(6),29)
3TJ= #
3W3W SLIN SBX 7 FX1
3WHG STO 7 AWORK2(2)
3X36 CALL 7 NOLET [CONCEP LINE/IDE GROUPS INTO CPB/CUNI
3XGQ TESTREP UNPAIR,NOPR
3Y2B MHUNT 3,CPB,CUNI
3YG2 LDX 7 ANUM(3)
3Y^L BZE 7 RCLUE [LINE GROUPS OMITTED
3^F= BNG 7 RCLUE [NAME QUALIFIER DOESN'T BEGIN WITH L
3^YW SRL 7 12 [HERE X4 CONTAINS 1 ; X6 CONTAINS 2
42DG BNZ 7 SING [NOT A SINGLE LINE NUMBER
42Y6 CALL 7 PASS
43CQ FREECORE 3
43XB MHUNTW 3,IDF,CONCEP
44C2 STO 6 A1+1(3) [STORE SINGLE LINE NO IN IDF/CONCEPT
44WL BRN REXIT
45B= SING FREECORE 3
45TW LDN 6 2 [PARAMETER POSITION
46*G PARALYSE ,,6
46GN ...#UNS ANSTOOMANY
46MW ... TESTREP2 TOOMANY,TOMP
46T6 SBN 7 2
47#Q BZE 7 ZCOMP [COMPOSITE : MORE THAN ONE LINE GROUP
47SB CALL 7 NOLET [CONCEP LINE/IDE GROUPS INTO CPB/CUNI
48#2 CALL 7 PASS
48RL FREECORE 3
49?= STO 6 AWORK1(2)
49QW SPARANOT 2 [NO OF IDENTIFIERS/LINES IN QUAL
4==G [PARAMETER
4=Q6 CALL 7 PASS [PASS IT IN X6
4?9Q FREECORE 3
4?PB ADN 6 2 [LENGTH OF THE IDF/CONCEP BLOCK
4#92 MHUNTW 3,IDF,CONCEP
4#NL PHOTO 5
4*8= ALTLEN 3,6,IDF,CONCEP [CHANGE THE LENGTH OF CONCEP BLOCK
4*MW TESTMOVE 5,NIXI
4B7G MHUNTW 3,IDF,CONCEP
4BM6 NIXI SBN 6 2 [NO OF LINES IN A QUALIFIED GROUP
4C6Q LDX 0 AWORK1(2) [THE FIRST L OR I NO
4CLB RXA1 STO 0 A1+1(3)
4D62 ADN 3 1
4DKL ADN 0 1
4F5= BCT 6 RXA1
4FJW STOZ A1+1(3) [NULLIFY LAST LOCATION
4G4G BRN REXIT
4GJ6 ZCOMP PARALYSE #34,,6 [SEPARATE LINE-GROUPS AT COMMAS
4GM= ...#UNS ANSTOOMANY
4GQB ... TESTREP2 TOOMANY,TOMP,UNPAIR,NOPR
4GTG ...#UNS ANSTOOMANY
4GYL ...#SKI
4H3Q TESTREP UNPAIR,NOPR
4HHB LDN 6 3 [ANALYSIS LEVEL
4J32 PARANUMB 4,6 [NUMBER OF LINE GROUPS
4JGL ADN 4 2
4K2= MHUNTW 1,IDF,CONCEP
4KFW PHOTO 5
4K^G ALTLEN 1,4,IDF,CONCEP [CHANGE THE LENGTH OF CONCEP BLOCK
4LF6 [TO CORRESPOND THE NO OF L/I
4LYQ TESTMOVE 5,XIXI
4MDB XIXI SBN 4 2 [NO OF PARAMETERS IN BRACKETS
4MY2 STOZ 5
4NCL ZXR LDN 6 3 [ANALYSIS LEVEL
4NX= PARAPASS 6 [ANALYSE 1ST/NEXT PARAMETER
4PBW CALL 7 PASS
4PWG FREECORE 3
4QB6 MHUNTW 1,IDF,CONCEP
4QTQ SMO 5
4R*B STO 6 A1+1(1) [STORE PARAMETER IN CONCEP
4RT2 ADN 5 1
4S#L BXU 5 4,ZXR [J. UNLESS PARAMETERS EXHAUSTED
4SS= SMO 5
4T?W STOZ A1+1(1) [NULLIFY LAST WORD IN IDF CONCEP
4TRG # NOW SORT THE LINE/IDENTIFIER NOS. INTO ASCENDING ORDER. IN X4 NO
4W?6 RGF4 LDX 3 1 [IDF/CONCEP ADDRESS
4WQQ RGF3 STOZ 7
4X=B RGF2 LDX 0 A1+2(3)
4XQ2 BZE 0 RGF1
4Y9L BXGE 0 A1+1(3),RHJ1 [J. IF THIS PAIR ALREADY WELL ORDERED
4YP= LDX 7 GSIGN [SET MARKER TO SHOW HAVE SWAPPED
4^8W LDX 4 A1+1(3) [SWAP LOCATIONS IN CONCEP
4^NG STO 0 A1+1(3)
5286 STO 4 A1+2(3)
52MQ RHJ1 BUX 3 RGF2 [J. TO DO NEXT COMPARISON
537B RGF1 BNZ 7 RGF4
53M2 LDX 1 FX1
546L REXIT LDX 7 AWORK2(2)
54L= LDEX 6 AWORK4(2)
54PB ...#UNS AV7900S
54SG ... FINDPERE 3,APGEOG,6,,AV7900,XNOPER
54XL ...#UNS AV7900S
552Q ...#SKI
5592 ... FINDPERE 3,APGEOG,6,,,XNOPER
55C= ... BNG 3 NOTX
55KG STO 3 AWORK2(2)
5656 ADX 7 FX1
56JQ EXIT 7 0
574B #
57J2 #
583L #
58H= X1ATTACHA
592W STOZ AWORK1(2)
59GG RPOC PARANUMB 6
5=26 LDXC 0 JSOURCE2(2) [J IF NOT FROM REMOTE CONSOLE -LOCAL
5=FQ BCC RLOC [OR MOP
5=^B ADXC 0 0 [J. IF NOT IPB TO REPORT
5?F2 BCC RNIPB [ERROR - THIS COMMAND IS NOT ALLOWED
5?YL [IN CHARACTER BUFFERING MPX SYSTEM
5#D= #
5#XW # AH OR CC AH COMMAND MUST HAVE COME FROM A REMOTE CONSOLE IN A
5*CG # IPB SYSTEM AND ADRESSES A LINE OF A MPX/UPX SYSTEM OR AN IDENTIFIE
5*X6 # OF AN IPB SYSTEM
5BBQ #
5BWB LDX 4 AWORK1(2)
5CB2 BZE 4 RCXY [J IF AH COMMAND
5CTL BZE 6 RFIPE [OTHERWISE CC AH -IN THIS CASE ITSELF
5D*= [FROM 7023-NO PARAMETERS
5DSW BCT 6 TOMP [CC AH ANY OTHER IDENTIFIER BUT
5F#G [ITSELF MUST HAVE ONLY ONE PARAMETER
5FS6 BRN RAXY
5G?Q RCXY BZE 6 MISS [NO PARAMETERS-ERROR
5GRB SBNC 6 2
5H?2 BCS RFIPE [AH ITSELF FROM 7023-ONE PARAMETER
5HQL BNZ 6 TOMP [AH SOMEONE ELSE FROM 7023-2 PARAMETE
5J== # AH OR DH AN IDENTIFIER WHICH BELONGS TO A CLUSTER FOR WHICH
5JPW # THE REMOTE CONSOLE ISSUING THE COMMAND IS THE NOMINATED CONSOLE
5K9G RAXY CALL 6 RPARS [CPAR/JSCE ADDR INTO X3
5KP6 LDX 0 GSIGN
5L8Q STO 0 AWORK3(2) [SET B0 - SOURCE IPB SYSTEM REMOTE
5LNB [CONSOLE
5M82 LDCT 4 #200 [SET MARK IF DEALING WITH IPB
5MML ANDX 4 JSCEB(3)
5N7= BZE 4 RCQY
5NLW ORS 4 AWORK3(2) [B1=1 FOR IPB, =0 FOR OTHER.
5P6G LDX 0 JSCEA(3)
5PL6 SLL 0 12 [B0-B11 IDENTIFIER NO
5Q5Q QUY LDEX 4 JSCEB(3)
5QKB ORX 0 4 [B0-B11 IDENTIFIER NO B15-B23 GEOGR.N
5R52 LDXC 3 JSCEP(3) [IF B0 NOT SET POINTER TO DCA
5RJL BCC RW1 [OTHERWISE CLUSTERING INYALID
5S4= BRN URET [AND ENDCOM
5SHW RCQY LDX 0 JSCEB(3) [MPX/UPX LINE ADRESSED
5T3G ANDX 0 BSB18 [SO GET LINE NO. INTO TOP HALF OF X0.
5TH6 SLL 0 3
5W2Q ANDX 0 HALFTOP
5WGB BRN QUY
5X22 #
5XFL # AH OR CC AH COMMAND MUST HAVE COME FROM A REMOTE CONSOLE IN A
5X^= # IPB SYSTEM WHICH TRIES TO ATTACH OR DETACH ITSELF
5YDW #
5YYG RFIPE LDN 4 #30 [ATTACH ITSELF REMOTE CONSOLE
5^3L ...#UNS AV7900S
5^6Q ... FINDPERE 3,APFOTY,4,R1,AV7900[FIND POINTER TO IPB DEVICE LIST
5^9W ...#UNS AV7900S
5^*2 ...#SKI
5^D6 FINDPERE 3,APFOTY,4,R1 [FIND POINTER TO IPB DEVICE LIST
5^XQ BNG 3 NOTX
62CB LGEOG 3,5 [GEOG NO IN X5
62X2 LDEX 0 JSOURCE2(2) [IS GEOG.NO THE SAME
63BL BXU 5 0,R1 [IF NOT TRY ONCE MORE
63W= LDX 0 GSIGN
64*W STO 0 AWORK3(2) [MARK IPB AND NO PARAMETER
64TG LDCT 0 #200
65*6 ORS 0 AWORK3(2)
65SQ LDX 0 JSOURCE1(2) [STORE GEOGR.AND IDENDTIFIER NOS
66#B SLL 0 12
66S2 ORX 0 5
67?L RW1 STO 0 AWORK4(2) [B0-B11 IDENTIFIER NO B15-B23 GEOGR.N
67R= STO 3 AWORK2(2) [STORE DCA POINTER
68=W RXXX LDX 0 AWORK1(2)
68QG BZE 0 SAHT [J IF AH COMMAND
69=6 #SKI K6ATTACH>199-199
69PQ (
6=9B TRACE AWORK1(2),A1
6=P2 TRACE AWORK2(2),A2
6?8L TRACE AWORK3(2),A3
6?N= TRACE AWORK4(2),A4
6#7W )
6#MG ACROSS DETACH,3 [FOR CC AH
6*76 SAHT
6*8T ...#UNS AV7900S
6*=J ...(
6*#? ...# THE ATTACH COMMAND IS NOT ALLOWED ON VIRTUAL 7900'S
6*B2 ...# UNLESS THE VIRTUAL 7900 TESTING SKIP K6VIPB IS SET > 599
6*CP ...#SKI K6VIPB>599-599
6*FD ...#SKI
6*H7 ... JV7900 AWORK2(2),VIRTUAL7900 [DISALLOW THE ATTACH COMMAND
6*JW ...)
6*LQ #SKI K6ATTACH>199-199
6B6B (
6BL2 TRACE AWORK1(2),A11
6C5L TRACE AWORK2(2),A12
6CK= TRACE AWORK3(2),A13
6D4W TRACE AWORK4(2),A14
6DJG )
6F46 CALL 7 RCLP
6FHQ BRN SEAL
6G3B CALL 7 SLIN
6GH2 BRN SEAL
6H2L #
6HG= # THIS COMMAND MUST HAVE COME FROM A LOCAL OPERATOR'S CONSOLE AND
6H^W # ADRESSES EITHER A LINE OF A MPX/UPX SYSTEM OR AN IDENTIFIER OF
6JFG # AN IPB SYSTEM
6J^6 #
6KDQ #
6KYB RLOC LDX 4 CONTEXT(2)
6LD2 BZE 6 MISS
6LXL ANDN 4 #10 [J IF COMMAND CAME FROM MOP CONSOLE
6MC= BNZ 4 RMOPA
6MWW LDX 0 AWORK1(2)
6NBG BZE 0 UVXY [J IF AH COMMAND
6NW6 BCT 6 TOMP [CC AH CAN HAVE ONLY ONE PARAMETER
6P*Q BRN YXVU
6PTB UVXY SBNC 6 2 [AH CAN HAVE ONLY TWO PARAMETERS
6Q*2 BCS MISS [WHEN ISSUED FROM CENTRAL OPS CONSOLE
6QSL BNZ 6 TOMP
6R#= YXVU CALL 6 RPARS [DO PARSORT MACRO AND HUNT FOR
6RRW LDCH 0 JSCEB(3) [JSCE BLOCK
6S?G BZE 0 UNIPL [J. IF POSSIBLY *UX WITHOUT LINE NO.
6SR6 SRL 0 3 [ELSE J. IF NOT IPB.
6T=Q SBN 0 6
6TQB BNZ 0 RMULT
6W=2 LDCT 0 #200 [MARK IPB ADRESSED FROM CEN.OP.CONS.
6WPL STO 0 AWORK3(2)
6X9= LDX 0 JSCEA(3) [IDENTIFIER NO
6XNW SLL 0 12
6Y8G LDEX 4 JSCEB(3) [GEOGR.NO
6YN6 BRN ROBA
6^7Q UNIPL LDCH 0 JSCEA(3)
6^MB SBN 0 12
7272 BNZ 0 RFER [J. IF NOT UNIPLEXER AFTER ALL.
72LL LDEX 4 JSCEA(3) [GEOGR. NO OF UNIPL.
736= BRN ROBA
73KW RMULT LDEX 0 JSCEB(3) [GEOGR. NO OF *MX OR *UX.L1
745G STOZ AWORK3(2)
74K6 LDX 4 JSCEB(3) [LINE NO. INTO TOP HALF OF X4.
754Q ANDX 4 BSB18
75JB SLL 4 3
7642 ANDX 4 HALFTOP
76HL ROBA ORX 4 0
773= STO 4 AWORK4(2)
77GW LDX 0 JSCEP(3)
782G STO 0 AWORK2(2) [LINE/IDENTIFIER AND GEOGR NO
78G6 BRN RXXX
78^Q #
79FB # THIS COMMAND MUST HAVE FROM A IPB MOP CONSOLE OR MPX MOP CONSOLE
79^2 # AND TRIES TO ATTACH THIS CONSOLE
7=DL #
7=Y= RMOPA LDCH 0 JSOURCE1(2)
7?CW LDX 4 0
7?XG SBN 4 #74
7#C6 BZE 4 RCHYB
7#WQ SBN 0 #30
7*BB BNZ 0 SMPX [J IF NOT IPB
7*W2 LDN 4 #30 [MOP IPB ATTACH
7*^6 ...#UNS AV7900S
7B4= ... FINDPERE 3,APFOTY,4,RR1,AV7900[FIND POINTER TO IPB DEVICE LIST
7B7B ...#UNS AV7900S
7B=G ...#SKI
7B*L FINDPERE 3,APFOTY,4,RR1 [FIND POINTER TO IPB DEVICE LIST
7BT= BNG 3 NOTX
7C#W LGEOG 3,5 [GEO.NO IN X5
7CSG LDEX 0 JSOURCE1(2) [IS GEOGR.NO THE SAME ?
7D#6 TXU 5 0
7DRQ BCS RR1
7F?B LDX 0 GSIGN
7FR2 STO 0 AWORK3(2)
7G=L LDCT 0 #200
7GQ= ORS 0 AWORK3(2) [B1 SET IPB ADRESSED
7H9W BRN SRF
7HPG SMPX LDN 4 #13 [MOP MULTIPLEXOR/UNIPLEXOR ATTACH
7J96 STOZ 6
7JNQ SMPDL FINDPERE 3,APFOTY,4,RRR1
7K8B BPZ 3 XDAL
7KN2 BNZ 6 NOTX
7L7L ADN 6 1
7LM= SBN 4 1
7M6W BRN SMPDL
7MLG XDAL LGEOG 3,5
7N66 LDEX 0 JSOURCE1(2) [GEOGR.NO THE SAME?
7NKQ BXU 0 5,RRR1
7P5B STOZ AWORK3(2) [SOURCE MPX,MPX ADRESSED
7PK2 SRF LDX 0 JSOURCE2(2) [IDENTIFIER/LINE NO
7Q4L SLL 0 12
7QJ= ORX 5 0
7R3W STO 5 AWORK4(2) [IDENTIFIER/LINE NO AND GEOGR NO
7RHG STO 3 AWORK2(2) [DCA POINTER
7S36 CALL 7 RCLP
7SGQ BRN RACR [IF NO I/L PARAMETERS J
7T2B CALL 7 SLIN
7TG2 #
7T^L #
7WF= #
7WYW RACR
7XDG #SKI K6ATTACH>199-199
7XY6 (
7YCQ MHUNTW 2,IDF,CONCEP
7YXB GSCAN A1(2),IDFCONCE,4
7^C2 )
7^WL ACROSS ATTACHC,1 [GO TO SEGMENT WHICH ATTACHES FROM A
82B= [MOP CONSOLE
82TW #
83*G #
83T6 # CHECK FOR LINE BUSY OR ALREADY ATTACHED ; INHIBIT SCAN & PROFLAG
84#Q #
84SB # AT THIS POINT THERE SHOULD BE IN
85#2 # AWORK1 NOTHING SPECIAL - CAN BE USED
85RL # AWORK2 DCA ADDRESS
86?= # AWORK3 B0-SET SOURCE IS REMOTE CONSOLE ON IPB,B0=0 IF SOURCE OP.
86QW # B1-SET IPB ADRESSED B1=0 MPX/UPX ADRESSED
87=G # ZERO IF IT IS. MPX/UPX SYSTEM
87Q6 # AWORK4 B0-B11 ACTUAL IDENTIFIER OR LINE NO B15-B23 GEOGR NO
889Q # IDF/COINF A1-B12-B23 ACTUAL LINE/IDENTIFIER NO
88PB # A2-B12-B23 LENGTH OF THE CONCEPTUAL NAME IN CHARS
8992 # A3 ON -CONCEPTUAL NAME
89NL # IDF/CONCEPT A1-B0-B11 ACTUAL IDENTIFIER OR LINE NO
8=8= #
8=MW #
8?7G SEAL
8?M6 #SKI K6ATTACH>199-199
8#6Q (
8#LB MHUNTW 2,IDF,CONCEP
8*62 GSCAN A1(2),IDFCONCE,4
8*KL )
8B5= ACROSS ATTACHB,1 [GO TO THE SEGMENT WHICH ATTACHES
8BJW [FROM A REMOTE OR LOCAL CONSOLE
8C4G #
8CJ6 #
8D3Q # THIS ENTRY IS FOR CANCEL ATTACH COMMAND FROM THE OPERATOR'S
8DHB # CONSOLE AND THIS SEGMENT JUST PROVIDES THE PARAMETER ANALYSIS
8F32 # THEN JUMPS ACROSS TO K3DETACH
8FGL #
8G2= X5ATTACHA
8GFW LDN 0 #4341 [MARK CANCEL ATTACH
8G^G STO 0 AWORK1(2)
8HF6 BRN RPOC
8HYQ #
8JDB #
8JY2
8KCL
8KX= #
8LBW # VARIOUS COMMAND ERRORS
8LWG #
8MB6 #
8MTQ MISS ZERRORX JPARMIS [PARAMETER MISSING
8N*B NLAL OUTNUM 6,0
8NT2 ZERRORX JLARGELINE [INVALID LINE NUMBER IN X6
8P#L NONAM ZERRORX JNOTCNAME [NOT A VALID CONCEPTUAL NAME
8PS= NOPR SPARAPAS
8Q?W ZERRORX ERUNPAIR [UNPAIRED BRACKETS
8QRG NOTX OUTNUM 4,0
8R?6 ZERRORX JUNITERR [NO IPB OR UPX OR MPX
8RQQ PFER LDN 6 2
8S=B SPARAPAS 6 [LINE GROUP INTO CPB/CUNI
8SB? ...XNOPER
8SG8 ... OUTNUM 4,0
8SL5 ... ZERRORX JNOPER
8SQ2 RFER ZERRORX APFERR [PARAMETER FORMAT ERROR
8T9L RCLUE LDN 6 0 [ERROR ROUTINE FOR COMPLEX PARAMETERS
8TP= LDN 4 2
8W8W SMO FX1
8WNG LDX 5 NAMCL
8X86 RFALR SPARABEG 1,4,5,6
8XMQ BRN RFER
8Y7B TOMP ZERRORX JTOOMANY [TOO MANY PARAMETERS
8YM2 RESV3 GEOERR 1,RESV3
8^6L REJOP GEOERR 1,REJOP
8^L= RCHYB ZERRORX CONOALVICO [THIS COMMAND IS NOT ALLOWED VIA THIS
925W [TYPE OF CONNECTION
92KG RNIPB ZERRORX JNOCHBS [THIS COMPAND IS NOT ALLOWED IN
9356 [CHARACTER BUFFERING SYSTEMS
9374 ...#UNS AV7900S
9392 ...(
93=Y ...VIRTUAL7900
93#W ... HUNTW 3,CPAR,JSCE
93BS ... BNG 3 RCHYB [REMOTE OP ATTACHING HIS OWN CONSOLE
93DQ ... ZERRORX JXALL [NOT ALLOWED TO USE UNIT %C
93GN ...)
93JQ ZERRORY
944B RCLMI COMERR JPARMIS,CONNA
94J2 RUNMI COMERR JPARMIS,JUNNO
953L RUNNU COMERR JPARNULL,JUNNO
95H= #
962W URET ENDCOM
96GG MENDAREA 40,K100ATTACHA
9726 #END
^^^^ ...67567751000800000000