{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: ATTACHB866)}}
====== ATTACHB866 ======
(George Source)
**Macros used:** [[george:macro:ABANDCOM|ABANDCOM]], [[george:macro:ACROSS|ACROSS]], [[george:macro:ATT7020|ATT7020]], [[george:macro:ATTACH|ATTACH]], [[george:macro:CCOUT|CCOUT]], [[george:macro:CHAIN|CHAIN]], [[george:macro:COOR2|COOR2]], [[george:macro:COOR3|COOR3]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:ERROR|ERROR]], [[george:macro:FMOPACT|FMOPACT]], [[george:macro:FPUT|FPUT]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHCODE|FSHCODE]], [[george:macro:FSHKILL|FSHKILL]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HUNT2J|HUNT2J]], [[george:macro:HUNTW|HUNTW]], [[george:macro:ICT|ICT]], [[george:macro:IPBCOUNT|IPBCOUNT]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:OUTBLOCK|OUTBLOCK]], [[george:macro:OUTNULL|OUTNULL]], [[george:macro:OUTNUM|OUTNUM]], [[george:macro:OUTPARAM|OUTPARAM]], [[george:macro:RING2CHK|RING2CHK]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETIDENT|SETIDENT]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SUICIDE|SUICIDE]], [[george:macro:TERROR|TERROR]], [[george:macro:ZERRORX|ZERRORX]], [[george:macro:ZERRORY|ZERRORY]]
22FL #SEG ATTACHB [PHILIP TURNER
22^= #OPT K0ATTACH=0
23?M ...#OPT K0ATTACHB=0
23L4 ...#LIS K0ATTACHB>K0ATTACH>K0COMMAND>K0ALLGEO>K0GREATGEO
23YG #OPT K6ATTACH=0
24D6 8HATTACHB
24XQ #
25CB #
25X2 #
26BL SEGENTRY K1ATTACHB,X1ATTACHB
26W= SEGENTRY K3ATTACHB,X3ATTACHB
2764 ... SEGENTRY K4ATTACHB,X4ATTACHB
27*W #
27TG #
28*6 #
28SQ RECCON +CONRECLEN
29#B RMASK #60077777
29S2 RIDICON +CONDCBLEN
29^8 ...TYPDCB +AMXOR+ADCB
2=6B ...TYPCONS +CONSA+I7023
2=?L #
2=R= RCOUT SBX 7 FX1
2?=W LDX 2 FX2
2?QG STO 0 ACOMMUNE1(2) [SUPERVISORY SEG CODE
2#=6 LDX 0 AWORK4(2) [ACTUAL IDE.NO
2#PQ SRL 0 12
2*9B CCOUT 0,AWORK1(2)
2*P2 ADX 7 FX1
2B8L EXIT 7 0
2BN= # SEARCH FOR ALINES/ADEVS BLOCK AND CREATE IN X2 POINTER TO
2C7W # AN ENTRY,WHOSE LINE/IDENTIFIER NO. *4 IS IN X6
2CMG #
2D76 SEEK LDX 2 FX2
2DLQ LDX 6 AWORK4(2)
2F6B ANDX 6 HALFTOP
2FL2 SRL 6 10
2G5L LDX 0 AWORK3(2)
2GK= SLL 0 1
2H4W BPZ 0 RZ [J IF NOT IPB ADRESSED
2HJG FMOPACT 2,AWORK2(2),IPB [FIND IPBIN
2J46 SMO FX2
2JHQ STO 2 AWORK1 [IPBIN ADDR
2K3B HUNT2J 2,AMXOR,ADEVS,,(7)
2KH2 LDX 0 A1+FOURTHWD(2) [SUBTRACT THE LOWEST IDENTIFIER NO.
2L2L SLL 0 2 [MULTIPLIED BY 4
2LG= SBX 6 0
2L^W BRN MBLK
2MFG RZ FMOPACT 2,AWORK2(2)
2M^6 SMO FX2
2NDQ STO 2 AWORK1 [AMOP ADDR
2NYB HUNT2J 2,AMXOR,ALINES,,(7)
2PD2 MBLK ADX 2 6
2PXL EXIT 7 1
2PY5 ...WTCC LDX 2 FX2
2PYJ ... LDEX 5 AWORK4(2)
2P^3 ... BZE 5 ZNTL [J IF NOT ATTACH COMMAND
2P^G ... LDX 5 CONTEXT(2)
2P^^ ... ANDN 5 #20
2Q2D ... BZE 5 ZNTL [J IF NOT OP ATTACH
2Q2X ... LDN 5 100
2Q3B ...ZNTL
2Q3T ...WTCCA SBX 4 FX1
2Q4# ... BZE 5 ZTLNY [J IF MESSAGE NOT REQD
2Q4R ... BCT 5 ZTLNY [J IF NOT TIME FOR MESSAGE
2Q5= ... SMO FX2
2Q5P ... LDX 5 AWORK4
2Q68 ... SRL 5 12 [IDENT NUMBER
2Q6M ... OUTNUM 5,0
2Q76 ... MONOUT JAHCCW
2Q7K ... LDN 5 0
2Q84 ...ZTLNY COOR3 #41
2Q8H ... ADX 4 1
2Q92 ... CALL 7 SEEK [FIND ADEVS
2Q9F ... BRN RNDV [JIF NONE
2Q9Y ... LDCT 0 #200
2Q=C ... ANDX 0 A1+FOURTHWD(2)
2Q=W ... BZE 0 (4) [J IF NO LONGER ATTACHED
2Q?* ... EXIT 4 1
2Q?S ...[
2Q#? ...ZDHNL SMO FX2
2Q#Q ... LDX 4 AWORK4
2Q*9 ... SRL 4 12 [IDENT NO.
2Q*N ... OUTNUM 4,0
2QB7 ... ZERRORX JAHCCLIN
2QC= #
2QFT ...TIPQ SMO FX2
2QJD ... LDX 0 AWORK3
2QM3 ... SLL 0 1
2QPL ... BPZ 0 (7) [EXIT IF NOT IPB
2QS9 ... EXIT 7 1
2QSD ...ZCL8 [SUB TO UNSET B8 IN 4W FOR ERROR
2QSM ... CALL 7 TIPQ
2QSW ... BRN NIRJ
2QT5 ... CALL 7 SEEK
2QT# ... BRN NIRJ
2QTH ... LDCT 0 1
2QTQ ... ORS 0 A1+FOURTHWD(2)
2QT^ ... ERS 0 A1+FOURTHWD(2)
2QW8 ...# UNSET BIT 8
2QWC ...NIRJ EXIT 4 0
2QWW X1ATTACHB
2RBG #
2RW6 #
2S*Q # CHECK FOR LINE BUSY OR ALREADY ATTACHED ; INHIBIT SCAN & PROFLAG
2STB #
2T*2 # AT THIS POINT THERE SHOULD BE IN
2TSL # AWORK1 NICHTS BESONDERES - CAN BE USED
2W#= # AWORK2 DCA ADDRESS
2WRW # AWORK3 B0-SET SOURCE IS REMOTE CONSOLE ON IPB,B0=0 IF SOURCE OP.
2X?G # B1-SET IPB ADRESSED B1=0 MPX/UPX ADRESSED
2XR6 # ZERO IF IT IS. MPX/UPX SYSTEM
2Y=Q # AWORK4 B0-B11 ACTUAL IDENTIFIER OR LINE NO B15-B23 GEOGR NO
2YQB # IDF/COINF A1-B12-B23 ACTUAL LINE/IDENTIFIER NO
2^=2 # A2-B12-B23 LENGTH OF THE CONCEPTUAL NAME IN CHARS
2^PL # A3 ON -CONCEPTUAL NAME
329= # IDF/CONCEPT A1-B0-B11 ACTUAL IDENTIFIER OR LINE NO
32NW #
338G #
33N6 CALL 7 SEEK [FIND AMXOR/ALINES BLOCK
33YJ ... BRN RMESS1 [BLOCK ABSENT -UNIT IS MOPPED OFF
3493 ... CALL 7 TIPQ
34=# ... BRN NIPB1 [J IF NOT IPB
34?K ... SMO FX2
34#W ... LDX 3 AWORK1 [AMOP ADDR
34*3 ... SEGENTRY K41ATTACHB
34*8 ... NULL
34** ... LDX 0 BIT9
34*G ... ANDX 0 IPBSW(3)
34*M ... BNZ 0 VNOCON
34*S ... SEGENTRY K42ATTACHB
34B7 ... LDXC 0 IPBSW(3)
34CD ... BCC NIPB1 [J IF NOT INOP
34DP ... SMO FX2
34G2 ... LDEX 7 AWORK4
34H? ... OUTNUM 7,0
34JJ ... ZERRORX JAHCINOP
34KT ...NIPB1
34MB LDCH 4 A1+FOURTHWD(2)
3572 LDX 0 4
35LL ANDN 0 #10 [BEING MOPPED OFF-B2 SET
366= BNZ 0 RMESS
369B ... LDX 0 A1+FOURTHWD(2)
36#G ... ANDN 0 #17
36CL ... SBN 0 13
36GQ ... BZE 0 XERL
36H6 ... LDN 0 #4000
36HG ... SLL 0 1
36HW ... ANDX 0 A1+FOURTHWD(2)
36J= ... BNZ 0 XSWOUT
36JL ... LDN 0 #200
36K2 ... ANDX 0 A1+FOURTHWD(2)
36KB ... BNZ 0 XSWNA
36KW LDX 0 4
375G ANDN 0 #22
37K6 SRC 0 2
384Q BNG 0 NOLIN [B4 SET : CPA BEING SET UP
388M ... BNZ 0 TECHA [B1 SET ATTACHED ALREADY
38#J ... CALL 7 TIPQ
38DF ... BRN NIPB2 [J IF NOT IPB
38JB ... LDCT 0 1
38N? ... ANDX 0 A1+FOURTHWD(2)
38S8 ... BNZ 0 NOLIN [BUSY IF B8 SET
38Y5 ...NIPB2
3942 LDX 1 A1+BPTR(2)
39HL BZE 1 NOTBU [LINE/IDENTIFIER NOT'BUSY
3=3= LDEX 0 A1+FOURTHWD(2)
3=GW SMO FX2
3?2G LDX 5 AWORK3
3?G6 SLL 5 1
3?^Q BPZ 5 UZ2
3*Y= ... BZE 0 NOLINA [IDENTIFIER BUSY
3BCW SBN 0 5
3BXG ... BNZ 0 NOLINA
3CC6 BRN XAT
3CWQ #
3DBB #
3DW2 UZ2 ANDN 0 #77
3FT= ERN 0 ASENTMACH
3G#W BZE 0 XAT [ATTACH SENTINEL LINE AUTOMATICALLY
3GSG ERN 0 ASENTMACH$APCTMACH
3H#6 BNZ 0 NOLIN [MOP CONSOLE : LINE BUSY
3HRQ SBN 1 A1+FPTR
3J?B ATT7020 NOLIN,XAT [CHECK WHETHER POLLING IDLY
3JR2 #
3K=L #
3KQ= NOTBU ANDN 4 #73 [UNSET B3 IF SET TO INAIBIT SCAN
3L9W SMO FX2
3LPG LDX 0 AWORK3
3M96 SLL 0 1
3MNQ BPZ 0 RSMX [J IF NOT IPB ADRESSED-IDENTIFIER
3N8B LDCT 0 1
3NN2 ORS 0 A1+FOURTHWD(2)
3P7L DCH 4 A1+FOURTHWD(2)
3PM= BRN XAT
3Q6W RSMX ORN 4 #40 [SET B0 TO INHIBIT PROFLAG FOR LINES
3QLG DCH 4 A1+FOURTHWD(2)
3R66 #
3RKQ #
3S5B #
3SK2 ...XAT ATTACH XBROKE,NOEX,ONAL,NOLAV,TACH,TOOL,(GEOERR),ZOLREL [DOWN
3T4L #
3TJ= #
3W3W RETES CALL 7 SEEK [FIND ALINES BLOCK
3WHG BRN RMESS [ABSENT-MOPPED OFF MESSAGE
3X36 LDCH 0 A1+FOURTHWD(2) [OR WHEN BEING MOPPED OFF-ERROR
3XGQ LDX 4 0
3Y2B SRC 0 4
3YG2 BNG 0 RMESS [B2 SET -MOPPING OFF
3Y^L ORN 4 #20 [SET BIT 1
3^F= SMO FX2
3^YW LDX 7 AWORK3
42DG SLL 7 1
42Y6 BNG 7 REST [J IF IPB IDE ADRESSED
43CQ ANDN 4 #37 [FOR MPX UNSET B0 TO RELEASE PROFLAG
43XB DCH 4 A1+FOURTHWD(2)
44C2 BRN OMES
44WL #
45B= #
45TW REST DCH 4 A1+FOURTHWD(2)
46*G ... LDX 4 A1+FOURTHWD(2)
47#Q LDCH 0 4
48#2 SBN 0 5
48RL BZE 0 OMES
48T* ...#UNS ISUMBI
48X4 ...(
48YR ... SLC 4 7
492G ... BNG 4 OMES
4949 ... SLC 4 2
495Y ...)
497M ...#UNS ISUMBI
499B ...#SKI
49?= SLC 4 9
49QW BNG 4 OMES [IDENTIFIER ALREADY CLOSED?
49Y4 ... LDX 0 BIT10
4=5= ... ORS 0 A1+FOURTHWD(2)
4==G LDN 0 #127 [CRASH CLOSE SUPERVISORY SEG
4=Q6 CALL 7 RCOUT
4?9Q ...RI14 CALL 4 WTCC [WIT 4 SECS
4?PB ... BRN ZDHNL
4#92 LDX 0 A1+FOURTHWD(2)
4#NL SLC 0 9 [CLOSE IMPLEMENTED?
4*8= BNG 0 RI13 [IF NOT WAIT 4SECS AND TRY AGAIN
4*MW ... BRN WTCCA [RETURN TO WAIT
4BM6 RI13 SRC 0 4 [ONLINED?
4C6Q BNG 0 OMES [IF CL ONLINE ENDCOM
4CLB LDX 0 BIT10
4D62 ORS 0 A1+FOURTHWD(2) [SET B10 TO INDICATE OPENING
4DKL LDN 0 #120 [OPEN SUPER SEG
4F5= CALL 7 RCOUT
4FJW ...RI15 CALL 4 WTCC
4G4G ... BRN ZDHNL
4GJ6 LDX 0 A1+FOURTHWD(2) [IDE OPENED?
4H3Q SLC 0 9
4HHB BPZ 0 RI16
4J32 ... BRN WTCCA
4K2= RI16 SRC 0 4 [IF CL ONLINED ENDCOM
4KFW BNG 0 OMES
4K^G LDN 0 #121 [START INPUT
4LF6 CALL 7 RCOUT
4LYQ #
4MDB OMES STOZ 6
4MJS ...RJOUR LDX 5 6
4MP= ...# SAVE X6 THROUGH SUBROUTINE
4MTN ... CALL 4 ZCL8
4N26 ...# CLEAR BIT 8 IN 4W FOR IPB
4N6J ... LDX 6 5
4N?2 ... ACROSS ATTJOUNL,1
4NCL #
4NX= #
4PBW URET ENDCOM
4PWG #
4QB6 #
4QTQ ONAL LDX 0 AWORK3(2)
4R*B SLL 0 1
4RT2 BNG 0 ZNIPB
4S#L ACROSS ATTACHC,5 [IF MPX CL ONLINE
4SS= #
4T?W #
4TRG #
4TWL ...#UNS ICT
4T^Q ...RCOOR COOR3 ADEVLIN
4W4W ...#UNS ICT
4W82 ...#SKI
4W?6 RCOOR COOR2
4WQQ #
4X=B #
4XQ2 # THIS ENTRY ATTACHES AN IDENTIFIER TO A CONCEPTUAL WHICH ALREADY
4Y9L # HAS BEEN ONLINED
4YP= #
4^8W X3ATTACHB
4^NG ZNIPB CALL 7 SEEK
5286 BRN RCOOR [IF IPB CL ONLINE
52?= ... LDX 0 A1+FOURTHWD(2)
52BB ... ANDN 0 #17
52FG ... SBN 0 13
52JL ... BZE 0 XERL
52K2 ... LDN 0 #4000
52KB ... SLL 0 1
52KQ ... ANDX 0 A1+FOURTHWD(2)
52L6 ... BNZ 0 XSWOUT
52LG ... LDN 0 #200
52LW ... ANDX 0 A1+FOURTHWD(2)
52M= ... BNZ 0 XSWNA
52MQ LDX 0 A1+FOURTHWD(2)
537B ANDN 0 #77
53M2 SBN 0 5
546L BNZ 0 XQ1
54L= LDCT 0 #201
555W ORS 0 A1+FOURTHWD(2)
5563 ... LDX 0 BIT10
5568 ... ORS 0 A1+FOURTHWD(2)
556* ... ERS 0 A1+FOURTHWD(2)
556K ... LDX 2 A1+BPTR(2)
557# ... BZE 2 XQ1
5583 ... SBN 2 A1
558Q ... LDX 0 ATYPE(2)
559F ... SRL 0 12
55=8 ... SMO FX1
55=X ... TXU 0 TYPDCB
55?L ... BCS RCH1 [J IF NOT ADCB
55#* ...SHUNT
55*4 ... LDX 2 BPTR(2)
55*R ... LDX 0 ATYPE(2)
55BG ... BPZ 0 SHUNT [J. IF NOT ACTIVITY
55C9 ... SLC 0 1
55CY ... BPZ 0 SHUNT [J. IF NOT ACTIVITY
55DM ... SRC 0 1
55FB ... SRL 0 12
55G5 ... SMO FX1
55GS ... TXU 0 TYPCONS
55HH ... BCS RCH1 [J. IF NOT CONSA/I7023
55J= ... FPUT [WAKE UP CONSA/I7023
55M4 ... CALL 4 WTCC [SEND MSG
55PW ... BRN ZDHOL [J IF AH CANCELLED
55SN ... LDX 0 A1+BPTR(2)
55XG ... BZE 0 RCH1 [J IF NO LONGER RINGED
562# ... BRN WTCCA [J TO WAIT
5656 XQ1 LDCT 0 #211
56JQ ORS 0 A1+FOURTHWD(2) [SET BITS 1 ,5 AND 8
56L^ ...#UNS ISUMBI
56P8 ...(
56RC ... LDN 0 #40
56TL ... ANDX 0 A1+FOURTHWD(2)
56XT ... BNZ 0 RCH1
5724 ...)
572D ... LDX 0 BIT9
572S ... ANDX 0 A1+FOURTHWD(2)
5738 ... BNZ 0 RCH1 [J IF ALREADY CLOSED
573J ... LDX 0 BIT10
573Y ... ORS 0 A1+FOURTHWD(2)
574B LDN 0 #126 [CLOSE
57J2 CALL 7 RCOUT
583L ...RCH1 CALL 4 WTCC
58H= ... BRN ZDHOL [J IF NO LONGER ATTACHED
592W LDX 0 A1+FOURTHWD(2) [CRASH CLOSE IMPLEMENTED
59GG SLC 0 9
5=26 BNG 0 RCH2
5=5F ... BRN WTCCA
5=8S ...ZDHOL SMO FX2
5=#7 ... LDX 7 AWORK4
5=CG ... LDEX 0 7
5=GT ... BZE 0 XGONE [J IF NOT COMMAND
5=L8 ... SMO FX2
5=PH ... LDX 0 CONTEXT
5=SW ... ANDN 0 #20
5=Y9 ... BZE 0 XGONE [J IF MOP ATTACH
5?3J ... SRL 7 12 [IDENT NUMBER
5?6X ... OUTNUM 7,0
5?== ... ERROR JAHCCLIN
5?*K ... BRN XGONE
5?F2 RCH2 SETNCORE 3,1,AMXOR,ICONIN
5?YL HUNT2J 1,AMXOR,CROUTE,AWORK1(2),XGONE
5#D= HUNTW 3,IDF,COINF
5#XW LDX 0 ANUM(3) [CHECK WHETHER THE CONCEPTUAL NAME
5*CG ADN 0 3 [IN CROUTE CORRESPONDS TO THE ONE
5*X6 SRL 0 2 [IN COINF
5BBQ SBN 0 2
5BWB LDEX 4 ARINGNO(1) [NO. OF ENTRIES IN CROUTE BLOCK.
5CB2 LDX 6 ACES
5CTL LDX 7 ACES
5D*= LDX 5 APARA(3) [PICK UP NAME WE'RE LOOKING FOR
5DSW BNG 0 SATE [(SPACEFILLED TO 12 CHARACTERS).
5F#G LDX 6 APARA+1(3)
5FS6 BZE 0 SATE
5G?Q LDX 7 APARA+2(3)
5GRB SATE TXU 5 A1+CONNM(1) [TEST NAME AGAINST THIS ENTRY.
5H?2 TXU 6 A1+CONNM+1(1)
5HQL TXU 7 A1+CONNM+2(1)
5J== BCC SOK [J. IF FOUND.
5JPW ADN 1 CROUTELEN [OTHERWISE STEP ON TO NEXT.
5K9G BCT 4 SATE
5K#F ...XGONE CALL 7 SEEK
5KFJ ... BRN RNDV
5KG? ... SEGENTRY K91ATTACHB [MENDED BY RETAINAH MACRO
5KH2 ... LDN 0 AHRETREL
5KHP ... BZE 0 WCLAH [J IF AH CANCELLED BY RELEASE
5KJD ... LDCT 0 #11 [CLEAR ONLINE AND BIT 8
5KK7 ... BRN WCLBT
5KKW ...WCLAH
5KLM ... LDCT 0 #211
5KTW ...WCLBT ORS 0 A1+FOURTHWD(2)
5L55 ... ERS 0 A1+FOURTHWD(2)
5L## ...RNDV LDX 2 FX2
5LHH ... LDX 7 AWORK4(2)
5M37 ... SRL 7 12
5MGR ... SETIDENT AWORK1(2),7 [REINITIALISE IDENT
5N2C ... BRN Z3
5N5N ...NOSTAT
5N8^ ... COOR3 #62 [WAIT
5N#= ... LDX 2 FX2
5NCH ... HUNT2J 1,AMXOR,CROUTE,AWORK1(2),XGONE
5NGS ... HUNTW 3,IDF,COINF
5NL5 ... SBX 1 5 [X1 PTS TO CSTATE RING IN CROUTE
5NPB ...SOK LDX 5 BSTART(1) [SAVE CROUTE DISPLACEMENT
5NSM ... LDX 0 A1+BPTR(1)
5NXY ... BZE 0 NOSTAT [J IF NOT RINGED
5P39 ... LDX 1 A1+FPTR(1) [X1 PTS TO CROUTE RING IN CSTATE
5P6G ADX 1 BSTART(1) [POINTER TO THE TOP OF CSTATE
5P=C ... LDCT 0 #200
5PB# ... ANDX 0 A1+IPSTATUS(1)
5PG9 ... BNZ 0 XGONE
5PL6 LDX 1 A1+FPTR(1) [POINTER TO A1 OF CONDCB
5Q5Q LDX 5 1
5QKB LDX 0 JPARNUM(3) [CONCEP IDENTIFIER NO
5R52 SRL 0 12
5RJL SBX 0 IDNUM(1) [MINUS LOWEST IDE -1 ON THE CONCEPTUA
5S4= SMO FX1
5SHW MPA 0 RIDICON [CONDCBLEN-ABS.POINTER TO AN ENTRY
5T3G [IN X1
5TH6 LDX 6 JPARNUM(3)
5W2Q ANDN 6 #7777
5W*7 ... TXU 6 IDNUM(1)
5WMJ ... BCS XGONE [J IF NO LONGER ATTACHED
5X22 CALL 7 SEEK [FIND AGAIN ADEVS ENTRY
5XFL ... BRN RNDV
5X^= LDN 6 1
5YDW SMO FX2
5YYG LDX 0 AWORK1
5^D6 STO 0 IDADIN(1) [STORE IPBIN ADDR IN CONDCB
5^XQ LDX 0 A1+FOURTHWD(2)
62CB BPZ 0 Z2
62X2 ORN 6 #4000
63BL Z2 ORS 6 IDSTATUS(1) [SET RELEVANT BITS IN CONDCB
63FQ ... LDCT 0 #11
63JW ... ORS 0 A1+FOURTHWD(2)
63LD ... LDCT 0 1
63N2 ... ERS 0 A1+FOURTHWD(2) [UNSET BIT 8
63R6 ... STOZ IDSTATUS+1(1) [UNSET CM CT ETC
644G ... RING2CHK A1(2),0(1) [ENRING ADEVS AND CONDCB ENTRIES
64*W IPBCOUNT 0,IDADIN(1),2
64TG ORS 0 IDSTATUS(1)
65*6 HUNTW 2,AMXOR,ICONIN
65SQ ... SMO 5
66#B ... LDX 0 IDSTATUS
66S2 SLL 0 4
67?L BPZ 0 Z4
67R= FREECORE 2
68=W BRN Z3
68QG Z4 LDX 0 GSIGN
69=6 STO 0 IBSW(2)
69PQ LDCT 0 #141
6=9B SRL 0 3
6=P2 LDX 6 IDNUM(1)
6?8L ORX 0 6 [IDE.FREE + ACT IDE.NO
6?N= STO 0 IPBIDE(2)
6#7W SBN 5 A1 [CHAIN ICONIN IN FRONT OF THE
6#MG SMO 5 [CONDCB
6*76 LDX 6 BPTR
6*LQ CHAIN 2,6
6*RH ...
6*Y# ...Z5 LDX 2 5
6B55 ...Z6 LDX 2 BPTR(2)
6B9W ... LDX 0 ATYPE(2)
6BBM ... TXL 0 CACT
6BHD ... BCS Z6
6BN9 ... SRL 0 12
6BT2 ... SBN 0 AMOP+IPBCCA
6B^R ... BZE 0 Z7
6C6J ... COOR3 #62
6C87 ... CALL 7 SEEK
6C9Q ... BRN RMESS
6C?* ... LDX 2 A1+FPTR(2)
6C#Y ... ADX 2 BSTART(2)
6CBH ... BRN Z6
6CD6 ...Z7 LDN 0 3
6CK= ADS 0 INLOAD(2) [ADD 3 TO THE OVERLOAD COUNT
6D4W LDX 2 FX2
6D=4 ...Z3 LDEX 0 AWORK4(2)
6DC= ... BNZ 0 NZUI [J IF ATTACH COMMAND
6DD5 ... FSHCODE B,NOKILLA
6DDY ...(
6DFR ... FSHKILL
6DGL ...NOKILLA
6DHF ...)
6DJD ... SUICIDE
6DPL ...NZUI
6DWS ... LDX 0 CONTEXT(2)
6F4Q ... ANDN 0 #10
6F=N ... BNZ 0 ZACLT [J IF MOP ATTACH
6FDL ... TERROR URET [JUST ENDCOM IF HAD ERROR MESSAGE
6FLW ... BRN OMES
6FT6 ...[ ACCROSS TO ATTJOUNL TO SEND ATTACHED
6G3B ZACLT ACROSS LOGOUT,7 [FOR MOP ATTACH
6GH2 #
6H2L #
6HG= #
6H^W #
6JFG # VARIOUS COMMAND ERRORS ; RELEASE PROFLAG IF ATTACH UNSUCCESSFUL
6J^6 #
6KDQ UNCAL CALL 7 SEEK [FIND ALINES BLOCK
6KYB BRN RMESS [ABSENT
6LD2 LDCT 0 #400
6LXL ANDX 0 A1+FOURTHWD(2)
6MC= ERS 0 A1+FOURTHWD(2) [UNSET BIT 0 IF SET
6MJD ... TERROR URET
6MPL ...[ J IF XATTACH ALREADY SENT ERROR MESS
6MWW ZERRORY
6NBG #
6NDD ...RMESS1
6NGB ... LDN 7 #10
6NJ# ... SMO FX2
6NL= ... ANDX 7 CONTEXT
6NN8 ... BNZ 7 ZACLT
6NQ6 ... LDN 6 7
6NS4 ... BRN RJOUR
6NW6 RMESS LDN 7 #10
6P*Q SMO FX2
6PTB ANDX 7 CONTEXT
6Q*2 BNZ 7 ZACLT
6QSL LDN 6 1
6R#= BRN RJOUR
6RRW #
6S?G #
6SR6 RESV3 GEOERR 1,RESV3
6T=Q REJOP GEOERR 1,REJOP
6TQB #
6W=2 RCHYB ZERRORX CONOALVICO [THIS COMMAND IS NOT ALLOWED VIA THIS
6WPL [TYPE OF CONNECTION
6X9= #
6XNW XBROKE
6Y8G ABANDCOM
6YN6 SMO FX2
6^7Q LDX 0 AWORK3 [J IF IPB
6^MB SLL 0 1
7272 BNG 0 RUSA
72LL CALL 1 UNCAL
736= +CONNOTEX [CONCEPTUAL DOES NOT EXIST
73KW RUSA ZERRORX CONNOTEX
745G #
74K6 NOLAV MHUNT 3,IDF,COINF
754Q LDX 4 ANUM(3)
75JB ANDN 4 #7777
7642 OUTPARAM 4,APARA,IDF,COINF
76?S ... OUTNULL
76HL LDX 0 AWORK3(2)
773= SLL 0 1
77GW BNG 0 UI2
782G CALL 1 UNCAL
78G6 +CONFULL
78SH ...UI2 CALL 4 ZCL8
796Y ... ZERRORX CIPBFULL
79FB +CONFULL [NO CONCEP LINES AVAILABLE
79^2 #
7=2? ...TECHA CALL 7 TIPQ
7=3J ... BRN TECH [J IF NOT IPB
7=4T ... LDCT 0 #10
7=66 ... ANDX 0 A1+FOURTHWD(2)
7=7C ... BZE 0 TECH [J IF B5 NOT SET
7=8N ... LDX 0 A1+BPTR(2)
7=9^ ... BZE 0 TECH [J IF RING NULL
7=?= ... LDN 0 #400
7=#H ... SMO A1+BPTR(2)
7=*S ... ANDX 0 IDSTATUS
7=C5 ... BNZ 0 NOLIN [BUSY NOT ATTACHED IF CC AH SET
7=DL TECH LDN 6 2
7=R3 ...RJLEAVE8
7?5D ... ACROSS ATTJOUNL,1
7?CW #
7?XG TACH LDN 6 3
7#C6 BRN RJOUR
7#WQ #
7*BB UNX CALL 1 UNCAL
7*W2 +CONUNTAL [UNIT ALREADY ATTACHED
7B*L #
7BT= TOOL LDN 6 4
7C#W BRN RJOUR
7CCF ...VNOCON
7CG4 ... SMO FX2
7CJM ... LDEX 7 AWORK4
7CM= ... OUTNUM 7,0
7CPT ... ZERRORX AV7900Y
7CQ4 ...XSWOUT
7CQ? ... SMO FX2
7CQG ... LDEX 7 AWORK4
7CQP ... OUTNUM 7,0
7CQY ... ZERRORX JERTGEO
7CR7 ...XSWNA
7CRB ... SMO FX2
7CRK ... LDEX 7 AWORK4
7CRS ... OUTNUM 7,0
7CS3 ... ZERRORX JSWOREQ
7CSG #
7D#6 NOLIN LDN 6 5
7D*F ... CALL 7 TIPQ
7DBS ... BRN RJOUR [J IF NOT IPB
7DD7 ... LDX 2 FX2
7DFG ... LDX 3 AWORK1(2) [AMOP ADDR
7DGT ... LDCT 0 #200
7DJ8 ... SMO IPBRING(3)
7DKH ... ANDX 0 IPBSW-IPBRING
7DLW ... BZE 0 RJLEAVE8 [J IF NOT OVERLOADED
7DN9 ... LDX 6 AWORK4(2)
7DPJ ... LDEX 7 6 [GEOG NO.
7DQX ... LDN 5 4
7DS= ... OUTBLOCK 5
7DTK ... SRL 6 12 [IDENT NO.
7DWY ... OUTNUM 6,0
7DY? ... OUTNUM 7,0
7D^L ... ZERRORX JAHLIOV
7F2^ ...NOLINA
7F4# ... LDX 2 FX2
7F5M ... LDX 6 AWORK4(2)
7F72 ... SRL 6 12 [IDENT NO.
7F8* ... OUTNUM 6,0
7F9N ... ZERRORX JAHINU
7F?B #
7FR2 NOEX SMO FX2
7G=L LDX 0 AWORK3
7GQ= SLL 0 1
7H9W BNG 0 QUX1
7HPG CALL 1 UNCAL
7J96 +CONNOTEX [CONCEPTUAL DOES NOT EXIST
7J=T ...XERL LDX 2 FX2
7J#J ... LDX 6 AWORK4(2)
7JB? ... SRL 6 12
7JD2 ... OUTNUM 6,0
7JFP ... ZERRORX JAHERL
7JHH ...QUX1 CALL 4 ZCL8
7JNP ... TERROR URET [J IF XATTAXH ALREADYSENT ERROR MESSA
7JTY ... ZERRORX CONNOTEX
7K8B #
7K8^ ...ZOLREL
7K9J ... LDN 6 6
7K=7 ... BRN RJOUR
7K=Q ...[
7K?* ...X4ATTACHB
7K?Y ... LDX 0 CACT
7K#H ... STO 0 AWORK3(2) [SHOW IPB
7K*6 ... STO 6 AWORK2(2) [AMOP ADDR
7K*P ... SETNCORE APARA+3-A1,3,IDF,COINF
7KB# ... MHUNTW 2,IDF,CONNAME
7KBX ... ADN 3 APARA [POINT TO ADDR OF CONCEP NAME
7KCG ... ADN 2 A1+1
7KD5 ... MOVE 2 3 [MOVE IN NAME
7KDN ... LDN 0 12
7KD^ ... SBN 3 APARA
7KF? ... STO 0 ANUM(3)
7KFW ... SBN 2 A1+1
7KGF ... LDX 0 A1(2)
7KH4 ... SLL 0 12
7KHM ... ORX 0 7
7KJT ... STO 0 JPARNUM(3)
7KKD ... FREECORE 2 [FREE CONNAME BLOCK
7KL3 ... SLL 7 12 [IDENT NO TO TOP HALF
7KLL ... STO 7 AWORK4(2) [TOP HALF ZERO TO SHOW NOT AH COMMAND
7KLQ ... CALL 7 SEEK
7KLW ... BRN XSUCS
7KM2 ... LDX 0 A1+FOURTHWD(2)
7KM6 ... ANDN 0 #17
7KM= ... SBN 0 5
7KMB ... BZE 0 X3ATTACHB
7KMG ... LDX 0 A1+BPTR(2)
7KML ... BZE 0 X3ATTACHB
7KMQ ...XSUCS SUICIDE
7KN2 #
7L7L #
7LM= MENDAREA 50,K100ATTACHB
7M6W #
7MLG #
7N66 #
7NKQ #END
7P5B
7PK2
7Q4L
^^^^ ...61421513000600000000