{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: ATTRIBUT867)}}
====== ATTRIBUT867 ======
(George Source)
**Macros used:** [[george:macro:BXE|BXE]], [[george:macro:CHEKLFN2|CHEKLFN2]], [[george:macro:CLOSE|CLOSE]], [[george:macro:COMBRKIN|COMBRKIN]], [[george:macro:COMERRX|COMERRX]], [[george:macro:DOWN|DOWN]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GEOPACK|GEOPACK]], [[george:macro:HUNTW|HUNTW]], [[george:macro:IDFAT|IDFAT]], [[george:macro:IDFCCAT|IDFCCAT]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:LADDP|LADDP]], [[george:macro:LONGON1|LONGON1]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MOPASAT|MOPASAT]], [[george:macro:NAMEX|NAMEX]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:P|P]], [[george:macro:PARANUMB|PARANUMB]], [[george:macro:PARSORTX|PARSORTX]], [[george:macro:PROPERTY|PROPERTY]], [[george:macro:REPLACE|REPLACE]], [[george:macro:SAWCEN|SAWCEN]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:SPARABEG|SPARABEG]], [[george:macro:SPARANOT|SPARANOT]], [[george:macro:SPARAPAS|SPARAPAS]], [[george:macro:STEP|STEP]], [[george:macro:STEPAGAIN|STEPAGAIN]], [[george:macro:TESTNAMX|TESTNAMX]], [[george:macro:TESTREP|TESTREP]], [[george:macro:V|V]], [[george:macro:WRONG|WRONG]]
226N ... SEG ATTRIBUT,867,SECTION COMM,,G402
22?B ...[
22D4 ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
22JQ ...[
22PD ...#OPT K0ATTRIBUT=0
23DW ...#LIS K0PROPERTY>K0PROPSYS>K0ALLGEO>K0ATTRIBUT
23YG #
2429 ...#
243Y ...# EXERCISE TO THE READER
245M ...# -------- -- --- ------
247B ...#
2495 ...# REDUCE THE SEGMENT SIZE BY INCORPORATING THE 'CANCEL' OPTION AS
24=S ...# PART OF THE MAIN PATH (AND THUS AVOID MUCH DUPLICATION).
24#H ...#
24B= ...#
24D6 #
24XQ ...# THIS SEGMENT IMPLEMENTS THE ATTRIBUTE & CC ATTRIBUTE COMMANDS
25CB ...# IT HAS TWO MAIN ENTRY POINTS (+ 5 OTHERS FOR SHARED FILESTORE) :
25X2 # K1 ATTRIBUTE
26BL # K2 CC ATTRIBUTE
26W= #
27*W SEGENTRY K1ATTRIBUT,PATTRIBUTK1
27TG SEGENTRY K2ATTRIBUT,PATTRIBUTK2
27WR ... FSHENTRY K3ATTRIBUT,PFSHENT3,,PFSHENT3 [INITIAL TRANSFER TO 'A'
27Y4 ... [ FOR ATTRIBUTE COMMANDS ON 'B'
27^* ... FSHENTRY K4ATTRIBUT,,PFSHENT4,PFSHENT4 [RE-ENTRY TO 'B' FOR AU
282L ... [ COMMAND TO LOOK FOR APIA ENTRY ON B
283X ... FSHENTRY K5ATTRIBUT,PFSHENT5,,PFSHENT5 [INITIAL TRANSFER TO 'A'
2858 ... [ FOR CC ATTRIBUTE COMMAND ON 'B'
286F ... FSHENTRY K7ATTRIBUT,,PFSHENT7,PFSHENT7 [RE-ENTRY TO 'B' FOR CC AU
287Q ... [ COMMAND TO LOOK FOR APIA ENTRY ON B
2887 ... FSHENTRY K8ATTRIBUT,QLINKDOWN,,QLINKDOWN [ ENTRY POINT FOR UNANT.
288J ... [-ICIPATED CLOSEDOWN OF MC 'B'
2893 ...#
28=# ...#
28?K ...#
28*6 #
2=R= PUNCHTAPE +1
2?=W PRINTER +2
2?QG PUNCHCARD +4
2#=6 PIDF1 +10 [REDUNDANT - DELETE
2#PQ PIDF2 +11 [REDUNDANT - DELETE
2*9B PIDF3 +24 [REDUNDANT - DELETE
2*P2 PDRUM1 +9
2B8L PDRUM2 +25
2BN= PIPC +28
2C7W TEMEX #40000000 [DEFAULT :TEMP & EXCL/S
2CMG PROPERTY 8HPROPERTY
2D76 UNITCH 1HU [REDUNDANT - DELETE
2DLQ ONE #20000000 [REDUNDANT - DELETE
2F6B TWO #37777777 [REDUNDANT - DELETE
2FL2 TWOBITS #17777777 [REDUNDANT - DELETE
2G5L PCENTRAL 8HCENTRAL
2GK= NINE #777
2H4W #
2NYB #
2PD2 # ASSORTED MESSAGES TO THE OPERATOR:
2PXL #
2QC= ZPARMIS +JPARMIS [%C PARAMETER MISSING
2QWW ZPROPNA +JPROPNA [PROPERTY NAME
2RBG ZPROPSLO +JPROPSLO [UNIT %C MAY NOT BE GIVEN A PROPERTY
2RW6 ZATTLIM +JATTLIM [UNIT %C ALREADY HAS 5 ATTRIBUTIONS
2S*Q ZPROPUNK +JPROPUNK [PROPERTY NAME %C UNKNOWN
2STB ZPROPNOT +JPROPNOT [PROPERTY %C NOT ATTRIBUTED TO THIS U
2T*2 ZNLFNF +JNLFNF [%C IS NOT A CORRECTLY FORMED NAME
2TSL ZPROPNIDF +JPROPNIDF [UNIT %C MAY NOT BE GIVEN A'CONSOLE'P
2W#= ZTWOCONS +JTWOCONS [%C ALREADY HAS A'CONSOLE'PROPERTY AT
2WRW ZATTRIBUTE +JATTRIBUTE [THIS UNIT ALREADY HAS PROPERTY %C AT
2X?G ZCENTRALX +JCENTRALX [PROPERTY'CENTRAL'MAY NOT BE ATTRIBUT
2XR6 ZCLUS +JCLUS [%C IS NOT IN CORRECT CLUSTER
2Y2X ...ZTOOM +JTOOMANY [TOO MANY PARAMS
2Y5G ...ZJNCONSUS +JNCONSUS [ONLY CONSOLE PR IN USER
2Y6R ...XJOPUCON +JOPUCON [ONLY USER AND OP
2Y=Q #
2YQB # WAY OUT INCASE OF COMMAND ERROR
2^=2 QER1 COMERRX 6,7
2^PL #
2^SQ ...QER2
329W ...QUER6
32=S ... CALL 7 V [FREE IDFANDPROP SEMAPHORE
32NW CLOSE
338G QER3 COMERRX 6
33N6 #
347Q # LOADING OF REQUIRED ERROR MESSAGE
34MB #
34X7 ...XER LDX 6 ZJNCONSUS(1)
34^Q ... BRN QER2
352K ...YER LDX 6 XJOPUCON(1) [ONLY USER AND OP CONTEXT
353D ... BRN QER3
3572 PANON
35LL LDX 1 FX1
366= LDX 6 ZPARMIS(1)
36KW LDX 7 ZPROPNA(1)
375G BRN QER1
37K6 WRONG
384Q LDN 6 0
38JB SPARANOT 1,6
3942 LDX 6 ZPROPSLO(1)
39HL BRN QER2
3=3= UPFUL
3=GW LDN 4 0
3?2G SPARAPAS 4
3?G6 LDX 6 ZATTLIM(1)
3?^Q BRN QER2
3#FB PRUNK
3#^2 LDX 1 FX1
3*DL LDX 6 ZPROPUNK(1)
3*Y= BRN QER2
3BCW NOTAT
3BXG LDX 1 FX1
3CC6 LDX 6 ZPROPNOT(1)
3CWQ BRN QER2
3DBB PFORMAT
3DW2 LDX 1 FX1
3F*L LDX 6 ZNLFNF(1)
3FT= BRN QER3
3G#W XIDF
3GSG LDN 6 0
3H#6 SPARANOT 1,6
3HRQ LDX 6 ZPROPNIDF(1)
3J?B BRN QER2
3JR2 TWOCONS
3K=L LDN 5 0
3KQ= SPARAPAS 5
3L9W LDX 6 ZTWOCONS(1)
3LPG BRN QER2
3M96 XGOTT
3MNQ LDX 1 FX1
3N8B LDX 6 ZATTRIBUTE(1)
3NN2 BRN QER2
3P7L XCENTRAL
3PM= LDX 1 FX1
3Q6W LDX 6 ZCENTRALX(1)
3QLG BRN QER3
3R66 XCLUS
3RKQ LDN 5 0
3S5B SPARAPAS 5
3SK2 LDX 6 ZCLUS(1)
3T4L BRN QER2
3TJ= #
3W3W # THIS SUBROUTINE PICKS UP THE NEXT PARAM,CHECKS THAT IT IS NOT'CENT
3WHG # SETS UP FILE NAME BLOCK&OPENS:SYS.PROP.,FREE FILE NAME BLOCK,FIND
3X36 # PROP.NAME IN :SYS.PROP.,EXIT.
3XGQ #
3XNC ...NAMEX
3^?# ... SBX 7 FX1
3^F= CHEKLFN2 PANON,PFORMAT
3^YW LDX 4 ACES [SPACEFILL BED FOR NAME
42DG STO 4 AWORK1(2)
42Y6 STO 4 AWORK2(2)
43CQ STO 4 AWORK3(2)
43XB LDN 0 APARA(3)
44C2 LDN 1 AWORK1(2)
44WL LDEX 2 ANUM(3)
45B= MVCH 0 0(2) [MOVE PROP NAME INTO AWORK WORDS
45TW LDX 1 FX1
46*G LDX 2 FX2
46T6 TESTNAMX 2,AWORK1(2),PCENTRAL(1),NOTCENT,4
46X4 ...#UNS G402
46^2 ... JBS XCENTRAL,2,EXOPCOM
472Y ... LDN 0 1 [PR CENTRAL
474W ... CALL 4 SUSER
476S ... BZE 0 XCENTRAL [J IF NO-USER
47SB NOTCENT
4?PB ... P IDFANDPROP,PBRKIN [SET SEMAPHORE
4*8= OPENSYS SBRKIN,PROPERTY,GENERAL,CAREFUL
4*MW [OPEN :SYSTEM.PROPERTY
4HHB STEP STEP [STEP AND COMPARE NAMES
4J32 BZE 3 OUT [END OF FILE: PROPERTY UNKNOWN
4JGL TESTNAMX 3,APROPNAME(3),AWORK1(2),STEP,4
4K2= OUT ADX 7 FX1 [EXIT FROM SUBROUTINE
4KFW EXIT 7 0
4LRG ...XBRK CLOSE
4LYQ SBRKIN
4L^7 ... CALL 7 V
4L^J ...PBRKIN
4M23 ... LDN 0 1
4M3# ... CALL 4 SUSER
4M4K ... BNZ 0 SUSERBI [J IF USER CONTEXT
4M5W ... GEOERR 1,BREAKIN? [CAN'T BREAKIN FROM OPERATOR'S CONSOL
4M77 ...SUSERBI
4MDB COMBRKIN [COMMAND ENDS IF BREAK-IN
4NCL #
4NX= #
4PBW #
4PWG # THIS SUBROUTINE FINDS THE UNIT RECORD IN DEVICE LIST,CHECKS IS LOC
4QB6 # OUTPUT DEVICE,EXIT.
4QTQ #
4R*B #
4RT2 UNIT1 SBX 7 FX1
4S#L TXU 0 PRINTER(1) [IS PERIPHERAL A LP?
4SS= BCC PERND
4T?W TXU 0 PUNCHCARD(1) [OR CP?
4TRG BCC PERND
4W?6 TXU 0 PUNCHTAPE(1) [OR TP?
4WQQ BCC PERND
4X=B TXU 0 PDRUM1(1) [SLOW DRUM
4XQ2 BCC PERND
4Y9L TXU 0 PDRUM2(1) [FAST DRUM
4YP= BCC PERND
4^8W TXU 0 PIPC(1) [IPB
4^NG BCC PERND
5286 ADX 7 FX1
52MQ EXIT 7 0
537B PERND ADX 7 FX1
53M2 EXIT 7 1
546L #
5#XW # THIS SUBROUTINE PASSES ACROSS CH'S AFTER'PROPERTY'OR'PR'(IF NONE-ER
5*CG # EXIT.
5*X6 PRPARAM
5BBQ SBX 7 FX1
5BWB LDN 6 8
5CB2 XAGAIN
5CTL LDN 4 0
5D*= SPARABEG 1,6,PROPERTY(1),4 [PUT THE CH'S AFTER PR IN BLOCK
5DSW MHUNT 1,CPB,CUNI
5F#G LDX 4 ANUM(1)
5FS6 BNG 4 PR [BRANCH IF ABSENT
5G?Q BZE 4 PANON [BRANCH IF NULL
5GRB ADX 7 FX1
5H?2 EXIT 7 0
5HQL PR
5J== SRL 6 2
5JPW BZE 6 PANON [NOT LONG OR SHORT FORM
5K9G FREECORE 1
5KP6 BRN XAGAIN [TRY SHORT FORM
5KW? ...SUSER ANDX 0 CONTEXT(2) [USER,MOP
5KY2 ... EXIT 4 0
5KY8 ...#UNS G402
5KYB ...(
5KYJ ...XUSE JBS OPCOM1,2,EXOPCOM
5KYQ ... BNG 6 XUSER
5KYY ...)
5K^6 ...#UNS G402
5K^# ...#SKI
5K^P ...XUSE BNG 6 XUSER [1 PARAM IN USER CONTEXT
5L3D ... LDX 6 ZTOOM(1)
5L57 ... BRN QER3
5L5K ...[
5L63 ...[ FREE SEMAPHORE
5L6F ...[
5L6X ...V
5L7* ...[
5L7R ... V IDFANDPROP
5L89 ... EXIT 7 0
5L8Q #
5LNB #
5LNR ...# THIS SUBROUTINE RELEASES ANY ACTS. WAITING FOR PROPERTIES TO BE
5LP8 ...# CHANGED ON PERIPH. INDICATED IN CPAR/JSCE BLOCK. NO COORDINATION.
5LPK ...RELEASE
5LQ2 ... MHUNTW 2,CPAR,JSCE
5LQC ... GEOPACK 6,JSCEA(2)
5LQS ... LONGON1 ATTRIBUTE,6 [RELEASE WAITERS
5LR9 ... EXIT 7 0
5LRL ...#
5LS3 ...#
5M82 #
5MML #
5N7= # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
5NLW #
5P6G PATTRIBUTK1
5PL6 #
5Q5Q #
5QKB # ENTRY POINT FOR ATTRIBUTE COMMAND.
5R52 ...# CALLS PARSORTX TO ANALYSE UNIT NO,
5RJL ...# CALL PRPARAM,CALL NAMEX,IF PROP.NAME. UNKNOWN -ERROR,CALL UN
5S4= # CHECK COMMAND ISSUED LOCALLY&IF PROPERTY ALREADY AU'D&IF ALREADY
5SHW # 5 PROP'S AU'D TO PERIPH,(IF ANY FO THESE CONDITIONS FOUND TRUE-ERROR)
5SYB ...# IF PROPERTY PERMANENT,
5T#W ...# SET UP WRITE BLOCK,MOVE CURRENT RECORD IN :SYSPROP TO WRITE BLOCK,PU
5TPB ...# FRH&UNIT NO. IN WRITE BLOCK,ADD 1 TO COUNT OF AU'S,REPLACE OLD RECORD
5W5W ...# IN :SYS.PROP,WITH NEW RECORD,CLOSE :SYS.PROP,WAKE UP ACTIVITIES WAIT
5WGB # IN STYLE 'ATTRIBUTE'
5X22 ...# IF REMOTE DEVICE, DONT BOTHER :SYSPROP,JUST DO "IDFAT"
5YYG #
5^D6 #
624D ... LDN 1 0
6262 ... PARANUMB 6,1
627J ... SBN 6 2
6296 ... LDN 0 1
62=N ... CALL 4 SUSER
62=W ... BNZ 0 XUSE [J IF USER CONTEXT
62?4 ... LDN 0 #10
62?D ... CALL 4 SUSER
62?S ... BNZ 0 YER [J IF MOP AND NO USER
62*2 ...#UNS G402
62B8 ...OPCOM1
62CB LDN 7 1
62X2 ... PARSORTX PREND1,7,,,INCOUT,GROPE
63BL HUNTW 3,CPAR,JSCE
63W= BNG 3 PREND1
648L ...XUSER
64*W CALL 7 PRPARAM [PASS ACROSS PROP.NAME
64YL ...PFSHENT3
653Q ... CALL 7 NAMEX [CHECK PROPERTY NAME EXISTS (ALSO
656W ... [ GRASPS IDFANDPROP SEMAPHORE & OPENS
65=2 ... [ :SYSTEM.PROPERTY)
65?J ... STOZ AWORK4(2)
65*6 BZE 3 PRUNK
65HR ... LDN 0 1
65L2 ... CALL 4 SUSER
65L9 ...#UNS G402
65LD ...(
65LM ... BZE 0 OPCOM2
65LW ... JBC XUSR,2,EXOPCOM
65M5 ...OPCOM2
65M# ...)
65MH ...#UNS G402
65MQ ...#SKI
65N9 ... BNZ 0 XUSR [J IF USER CONTEXT
65SQ MHUNTW 2,CPAR,JSCE
66#B LDX 4 JSCEP(2)
66S2 LDCH 0 JSCEA(2)
67?L LDX 7 JSCEB(2)
67R= BPZ 7 XLOCAL
68=W BRN PIDFUNIT
68QG XLOCAL
69=6 LDX 6 JSCEA(2)
69PQ ANDX 6 NINE(1)
6=9B LDX 7 APROPGROUP(3)
6=P2 BNG 7 XIDF
6?8L CALL 7 UNIT1
6?N= BRN WRONG
6#8B ...YFLCHECK
6#96 ... SEGENTRY K50ATTRIBUT
6#9W ... LDX 0 APROPNO(3)
6#=D ... SLL 0 1
6#=P ... BNG 0 YFLEND
6#?J ... MHUNTW 2,CPAR,JSCE
6##6 ... LDX 2 JSCEP(2)
6##N ... JBC YFLEND,2,FLP4B
6#*= ... SMO FX2
6#*S ... LDX 5 AWORK4
6#BB ... DOWN FORMLOOP,3
6#BY ... TESTREP WRONG,WRID
6#C9 ... STEPAGAIN
6#CG ... SMO FX2
6#D4 ... STO 5 AWORK4
6#D? ...SKB1
6#DP ...YFLEND
6#DY ... SEGENTRY K55ATTRIBUT
6#L= ... LDN 5 4
6#MG ... LADDP 4,2 [X2-> APIA ENTRY FOR PERIPHERAL
6*LQ LDX 7 APROPNO(3)
6B6B XATT1
6BL2 TXU 7 APERPROP+1(2)
6C5L BCC XGOTT [PROPERTY
6CK= ADN 2 1 [HAS ALREADY
6D4W BCT 5 XATT1
6DJG ... SBN 2 4 [X2-> APIA ENTRY
6F46 #
6FHQ LDN 5 4
6G3B XNFREE
6GH2 LDX 4 APERPROP+1(2)
6H2L BZE 4 XFREE
6HG= ADN 2 1
6H^W BCT 5 XNFREE
6JFG BRN UPFUL
6J^6 XFREE
6KDQ STO 7 APERPROP+1(2)
6KH8 ...UPDPROP
6LBL ... LDX 0 APROPNO(3)
6LC4 ... SLL 0 1
6LCG ... BPZ 0 REL1
6LD2 LDX 4 ATTCOUNT(3)
6LQC ... ADN 4 8
6MPL ... SETUPCORE 4,2,FILE,FWB [FOR NEW RECORD
6MWW STEPAGAIN
6NNW ... MHUNTW 2,FILE,FWB
6NW6 LDX 1 ATTCOUNT(3)
6P*Q ADN 1 7
6PTB LDN 4 FRH(3)
6Q*2 LDN 5 FRH+A1(2)
6QSL MOVE 4 0(1)
6R#= ADX 2 ATTCOUNT+A1(2)
6RRW STO 6 APROPATT+A1(2)
6S?G SBX 2 ATTCOUNT(3)
6SR6 LDN 4 1
6T=Q ADS 4 ATTCOUNT+A1(2)
6TQB ADS 4 FRH+A1(2)
6TRY ... REPLACE
6TTG ...REL1
6TX4 ... CALL 7 RELEASE [REL. WAITERS FOR PROP ON THIS PERIPH
6W28 ... BRN PEND
6W3Q ...YA5
6WPL #
6X9= PIDFUNIT
6XNW LDX 7 APROPGROUP(3) [ONLY ALLOW ATTRIB OF
6Y8G BZE 7 PNCONS [CONSOLE PROP IF
6Y*N ...#UNS G402
6YGW ... JBS PNCONS,2,EXOPCOM
6YN6 SAWCEN CENTRAL,XCLUS [COMMAND CAME FROM CENTRAL
6^7Q PNCONS
72LL LDX 4 APROPNO(3)
736= LDX 5 APROPGROUP(3)
73R4 ... IDFAT XBRK,5,4,RMTERR,UPFUL,TWOCONS,XGOTT,XCLUS
745G [STORE ATTRIB'N IN I;F
74*# ... CALL 7 RELEASE [REL. WAITERS FOR PROP CHANGE ON THIS
74K6 BRN PEND
74K* ...XNPEND
74MJ ...XUSR LDX 6 APROPNO(3) [PROP NO
74NB ... ANDX 6 BITS22LS
74P8 ... SBN 6 1
74Q2 ... BZE 6 XUC [ J IF CENTRAL
74QS ... LDX 7 APROPGROUP(3)
74RL ... BPZ 7 XER [J IF NOT A CONSOLE PROPERTY
74SD ... ADN 6 1
74T= ...XUC BXE 6 JSOURCE3(2),PEND [SAME PR-DONT SAVEIT
74W4 ... LDN 0 #10
74WW ... CALL 4 SUSER
74XN ... BZE 0 XNMOP [J IF NOT MOP
74YG ... MOPASAT 4 [SAVE JSOURCE3 INTO APERI/ASSOCS0
74^# ... LDX 2 FX2
7526 ...XNMOP STO 6 JSOURCE3(2)
752Y ... BRN PEND
754Q #
75JB #
7642 PATTRIBUTK2
76HL #
773= #
77GW # ENTRY POINT FOR CANCEL ATTRIBUTE.
782G ...# CALL PARSORTX TO ANALYSE UNIT NO. - IF LOCAL
78^Q # CALL PRPARAM,CALL NAMEX, IF PROP. UNKNOWN-ERROR,CALL UNIT1,TEST IF PRO
79FB ...# AU'D(IF NOT ERROR),ZEROIZE PROP.WORD,RESET X2,SET UP WRITE BLOCK,MOVE
79^2 ...# OLD RECORD IN :SYS.PROP TO WRITE BLOCK,STORE FRH &COUNT(-1)IN WRITE
7=DL # BLOCK,MOVE ALL UNIT NO. WORDS(EXCEPT THAT TO BE CANCELLED)FROM OLD
7=Y= ...# RECORD TO WRITE BLOCK RECORD,REPLACE,CLOSE :SYS.PRO
7?CW # WAKE UP ACTIVITIES WAITING,END.
7?XG ...# IF REMOTE, DO "IDFCCAT" INSTEAD OF BOTHERING :SYS.PROP.
7*W2 #
7B*L LDN 7 1
7BT= ... PARSORTX PREND1,7,,,INCOUT,GROPE
7C#W HUNTW 3,CPAR,JSCE
7CSG BNG 3 PREND1
7D#6 CALL 7 PRPARAM
7DPD ...PFSHENT5
7DRQ CALL 7 NAMEX
7F3J ... STOZ AWORK4(2)
7F?B BZE 3 PRUNK
7FR2 MHUNTW 2,CPAR,JSCE
7G=L LDX 4 JSCEP(2)
7GQ= LDX 0 JSCEA(2)
7H9W SRL 0 18
7HPG LDX 7 JSCEB(2)
7J96 BPZ 7 XLOCALC
7JNQ BRN PIDFCC
7K8B XLOCALC
7KN2 LDX 6 JSCEA(2)
7L7L ANDX 6 NINE(1)
7LM= CALL 7 UNIT1
7M6W BRN WRONG
7MLG LDN 5 4
7NKQ LADDP 4,2
7P5B LDX 7 APROPNO(3)
7PK2 XATTC1
7Q4L TXU 7 APERPROP+1(2)
7QJ= BCC XGOTTC
7R3W ADN 2 1
7RHG BCT 5 XATTC1
7S36 BRN NOTAT
7SGQ XGOTTC
7T2B SBN 5 1
7TG2 BZE 5 XLAST
7T^L XCAN
7WF= LDX 7 APERPROP+2(2)
7WYW BZE 7 XLAST
7XDG STO 7 APERPROP+1(2)
7XY6 ADN 2 1
7YCQ BCT 5 XCAN
7YXB XLAST
7^C2 LDN 5 0
7^WL STO 5 APERPROP+1(2)
7^YJ ...UPDPROP2
82B= MHUNT 1,CPB,CUNI
82TW FREECORE 1
82^R ... LDX 0 APROPNO(3) [TEMPORARY PROP ATTRIBS...
835N ... SLL 0 1 [NOT RECORDED IN :SYS.PROP..
839K ... BPZ 0 REL2 [SO J IF TEMP
83*G LDX 7 ATTCOUNT(3)
83T6 ADN 7 6
84M6 ... SETUPCORE 7,2,FILE,FWB
84SB STEPAGAIN
85LB ... MHUNTW 2,FILE,FWB
85RL LDN 4 APROPNO(3)
86?= LDN 5 APROPNO+A1(2)
86QW MOVE 4 6
87=G STO 7 FRH+A1(2)
87Q6 SBN 7 7
889Q STO 7 ATTCOUNT+A1(2)
88PB LDX 5 ATTCOUNT(3)
8992 XPRATT [DE-ATTRIBUTE PROPERTY IN SYSPROP
89NL TXU 6 APROPATT(3)
8=8= BCC XUNITATT
8=MW LDX 4 APROPATT(3)
8?7G STO 4 APROPATT+A1(2)
8?M6 ADN 3 1
8#6Q ADN 2 1
8#LB BCT 5 XPRATT
8*62 BRN PDELE
8*KL XUNITATT
8B5= ADN 3 1
8BJW LDX 1 5
8C4G SBN 1 1
8CJ6 BZE 1 PDELE
8D3Q LDN 4 APROPATT(3)
8DHB LDN 5 APROPATT+A1(2)
8F32 MOVE 4 0(1)
8F4C ...PDELE
8F5S ... REPLACE
8F79 ...REL2
8F8L ... CALL 7 RELEASE [REL WAITER FOR PROP CHANGE ON DEVICE
8F?D ... BRN PEND
8F#T ...YA7
8FTP ...YA8
8FYH ...#
8G2= PIDFCC
8GFW LDX 7 APROPGROUP(3)
8G^G BZE 7 PNCONSC
8HF6 SAWCEN CENTRAL,XCLUS
8HYQ ...PNCONSC [DE-ATTRIBUT FROM THE IDF
8KX= LDX 4 APROPNO(3)
8LBW LDX 5 APROPGROUP(3)
8LWG BPZ 5 XCONSNOT
8MB6 ORX 4 TEMEX(1)
8MTQ BRN XCONSIS
8N*B XCONSNOT
8NT2 ANDX 4 BITS22LS
8P#L XCONSIS
8PPN ... IDFCCAT XBRK,4,RMTERR,NOTAT
8PSP ... CALL 7 RELEASE [REL WAITER FOR PROP CHANGE ON DEVICE
8PT8 ...WRID
8PTP ...PEND
8QMC ...PREND2
8QN7 ... CALL 7 V [RELEASE IDFANDPROP SEMAPHORE
8QPL ... [ (MUST ALWAYS BE DONE ON 'A')
8QRG CLOSE
8SQ2 PREND1
8T9L ENDCOM
8TLJ ...RMTERR
8WTB ... BRN PREND2
8X=* ...#
8XKD ...#
8XMQ #
8Y7B #END
^^^^ ...04777046000200000000