{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: BMQUESTB866)}}
====== BMQUESTB866 ======
(George Source)
**Macros used:** [[george:macro:BXE|BXE]], [[george:macro:BXU|BXU]], [[george:macro:DEMMESS|DEMMESS]], [[george:macro:DOWN|DOWN]], [[george:macro:EMSCONWT|EMSCONWT]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GEOSTOP|GEOSTOP]], [[george:macro:HUNTMISB|HUNTMISB]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:NEXTCH|NEXTCH]], [[george:macro:OUTPACK|OUTPACK]], [[george:macro:OUTPACKX|OUTPACKX]], [[george:macro:POP|POP]], [[george:macro:PRQUERY|PRQUERY]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:UP|UP]], [[george:macro:VOP|VOP]]
22FL ... SEG BMQUESTB,866,EDWARD MOON,BMAP
22^= ... SEGENTRY K5BMQUESTB,PRQUERY
23DW ... SEGENTRY K7BMQUESTB,PRERASE
23YG ... SEGENTRY K8BMQUESTB,Z8BMQUEST
24D6 ...[THIS SEGMENT CONTAINS 3 ENTRIES THAT USE TO BE
24XQ ...[ IN BMQUEST BEFORE THAT SEGEMENT WAS SPLIT INTO
25CB ...[BMQUEST AND BMQUESTB
25X2 ...[*******************************************************************
26BL ...[
26W= ...[ TABLE OF USERS WHICH MAY NOT BE ERASED IF
27*W ...[ PARTIAL RESTORES FAIL
27TG ...[
28*6 ...VSFTABLE
28SQ ... 12HMANAGER
29#B ... 12HSYSTEM
29S2 ... 12HJOURNAL
2=?L ... 12HDUMPER
2=R= ... 12HLIB
2?=W ... 12HMACROS
2?QG ... SEGENTRY AVSFTABLE
2#=6 ...#ALT AVSFPTR=AVSFTABLE
2#PQ ...#GAP ANOPRERASE*3
2*9B ... SEGENTRY AVSFTABEND
2*P2 ... +0
2B8L ...RELOADING +12,12HRELOADING
2BN= ...XMTUNAV 20HTAPE NOT AVAILABLE
2C7W ...XABANDONED 16HABANDONED :
2CMG ...SP #20
2D76 ...Y #71
2DLQ ...N #56
2F6B ...OUTPACK
2FL2 ... SBX 7 FX1
2G5L ... OUTPACKX 2,5,6
2GK= ... ADX 7 FX1
2H4W ... EXIT 7 0
2HJG ...[
2J46 ...[********************************************************** PRQUERY
2JHQ ...[
2K3B ...[ ENTRY POINT TO ASK FOR A PM IF THE PRQUERY R.T.M. HAS
2KH2 ...[ BEEN USED AND A DIRECTORY IS FOUND CORRUPT.
2L2L ...[
2LG= ...PRQUERY
2L^W ... LDX 2 BSACHAPTR
2MFG ... POP PRQUERY,2,FTABWAIT
2M^6 ... DEMMESS BMPRQUERY [ ASK IF A PM IS WANTED
2NDQ ... MHUNTW 3,CONBUFF,EMSIN [ HUNT FOR REPLY BLOCK
2NYB ... LDX 2 3
2PD2 ... LDX 4 A1(3)
2PXL ... BZE 4 PRNOCHAR [ CHECK IF NULL REPLY
2QC= ...NXPRCH
2QWW ... LDCH 5 A1+1(3)
2RBG ... BXE 5 SP(1),NXCHPR [ IGNORE LEADING SPACES
2RW6 ... BXE 5 N(1),UPAGAIN [ IF N(O), CARRY ON WITH P.R.
2S*Q ... BXU 5 Y(1),PRNOCHAR [ REPEAT QUESTION IF NOT Y(ES)
2STB ... GEOERR 1,PRQUERY [ ELSE GEOERR TO GET A PM
2T*2 ...NXCHPR
2TSL ... BCHX 3 £
2W#= ... BRN NXPRCH
2WRW ...PRNOCHAR
2X?G ... FREECORE 2
2XR6 ... LDX 2 BSACHAPTR
2Y=Q ... VOP 2,FTABWAIT
2YQB ... BRN PRQUERY
2^=2 ...UPAGAIN
2^PL ... FREECORE 2
329= ... LDX 2 BSACHAPTR
32NW ... VOP 2,FTABWAIT
338G ... UP [ TO CONTINUE WITH P.R.
33N6 ...[
347Q ...[*********************************************************** PRERASE
34MB ...[
3572 ...[ ENTRY POINT TO CHECK IF ERASURE DUE DUE TO FAILED P.R.
35LL ...[ IS ALLOWED - IF NOT GRELOAD ELSE GO BAK UP TO CALLING ROUTINE
366= ...[
36KW ...[
375G ...PRERASE
37K6 ... HUNTMISB 3,FI,FRESTUSER
384Q ... SMO FRNXT(3)
38JB ... LDN 3 FRUSE(3) [ POINTER TO THIS USER
3942 ... LDN 2 VSFTABLE(1) [ POINTER TO START OF TABLE OF USERS
39HL ...NEXTVSF [ WHO MAY NOT BE EASED
3=3= ... LDX 4 0(2)
3=GW ... BZE 4 NOTINTAB [ 0 INDICATES END OF TABLE
3?2G ... LDX 5 1(2)
3?G6 ... LDX 6 2(2)
3?^Q ... TXU 4 0(3) [ COMPARE ALL 3 WORDS
3#FB ... TXU 5 1(3) [ OF USERNAME
3#^2 ... TXU 6 2(3)
3*DL ... SEGENTRY K80BMQUESTB [ FOR NOPRERASE MACRO
3*Y= ... BCS NORELOAD [ NULL IF %A WAS ABSENT
3BCW ... EMSCONWT
3BXG ... LDX 1 FX1
3CC6 ... GEOSTOP RELOADING(1) [ IF NAME IS FOUND IN TABLE
3CWQ ...NORELOAD
3DBB ... SEGENTRY K81BMQUESTB [ FOR NOPRERASE MACRO
3DW2 ... ADN 2 3 [ UPDATE TABLE POINTER
3F*L ... BRN NEXTVSF
3FT= ...NOTINTAB
3G#W ... LDX 2 BSACHAPTR
3GSG ... POP NOTINTAB,2,FTABWAIT
3H#6 ...NOTINTAB2
3HRQ ... HUNTMISB 3,FI,FRESTUSER
3J?B ... SMO FRNXT(3)
3JR2 ... LDN 2 FRUSE(3)
3K=L ... LDN 5 3
3KQ= ... LDN 6 JPDUSERNAME
3L9W ... CALL 7 OUTPACK
3LPG ... DEMMESS GRPRERREQ
3M96 ... MHUNTW 3,CONBUFF,EMSIN
3MNQ ... LDX 2 3
3N8B ... LDX 4 A1(3)
3NN2 ... BZE 4 ZPRNOCHAR
3P7L ...NEXTCH
3PM= ... LDCH 5 A1+1(3)
3Q6W ... BXE 5 SP(1),NEXCH2
3QLG ... BXE 5 Y(1),ZUPAGAIN
3R66 ... BXU 5 N(1),ZPRNOCHAR
3RKQ ... EMSCONWT
3S5B ... LDX 1 FX1
3SK2 ... GEOSTOP RELOADING(1)
3T4L ...NEXCH2
3TJ= ... BCT 3 £
3W3W ... BRN NEXTCH
3WHG ...ZPRNOCHAR
3X36 ... FREECORE 2
3XGQ ... BRN NOTINTAB2
3Y2B ...ZUPAGAIN
3YG2 ... FREECORE 2
3Y^L ... LDX 2 BSACHAPTR
3^F= ... VOP 2,FTABWAIT
3^YW ... UP [ IF NOT FOUND IN TABLE
42DG ...[
42Y6 ...[************************************************************* Z8BMQUEST
43CQ ...[
43XB ...[ ENTRY TO OUTPUT TAPE UNAVAILABLE MESSAGE
44C2 ...[ AND TO CHECK IF USER IS ERASEABLE.
44WL ...[
45B= ...Z8BMQUEST
45TW ... HUNTMISB 3,FI,FRESTUSER
46*G ... SMO FRNXT(3)
46T6 ... LDN 2 FRUSE(3)
47#Q ... LDN 5 3
47SB ... LDN 6 JPDUSERNAME
48#2 ... CALL 7 OUTPACK
48RL ... LDN 2 XABANDONED(1)
49?= ... LDN 5 4
49QW ... LDN 6 JPDVARCHAR
4==G ... CALL 7 OUTPACK
4=Q6 ... LDN 2 XMTUNAV(1)
4?9Q ... LDN 5 5
4?PB ... LDN 6 JPDVARCHAR
4#92 ... CALL 7 OUTPACK
4#NL ... MONOUT BMPARTRES
4*8= ... DOWN BMQUESTB,7
4*MW ... UP
4B7G ...#END
^^^^ ...541625220001