{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: BSPRUNE867)}}
====== BSPRUNE867 ======
(George Source)
**Macros used:** [[george:macro:ALTLEN|ALTLEN]], [[george:macro:BC|BC]], [[george:macro:BITDEFS|BITDEFS]], [[george:macro:BS|BS]], [[george:macro:BSUJ|BSUJ]], [[george:macro:BXE|BXE]], [[george:macro:BXGE|BXGE]], [[george:macro:BXL|BXL]], [[george:macro:BXU|BXU]], [[george:macro:CLOSETHROW|CLOSETHROW]], [[george:macro:DELETE|DELETE]], [[george:macro:DOWN|DOWN]], [[george:macro:DUMP|DUMP]], [[george:macro:FC|FC]], [[george:macro:FIELDDEF|FIELDDEF]], [[george:macro:FILEFORM|FILEFORM]], [[george:macro:FULLBPAS|FULLBPAS]], [[george:macro:GEOERR|GEOERR]], [[george:macro:IFUJSTAT|IFUJSTAT]], [[george:macro:JBC|JBC]], [[george:macro:JBCC|JBCC]], [[george:macro:JBS|JBS]], [[george:macro:JFNZ|JFNZ]], [[george:macro:JFZ|JFZ]], [[george:macro:JMBAC|JMBAC]], [[george:macro:JMBS|JMBS]], [[george:macro:LF|LF]], [[george:macro:LOCFCB|LOCFCB]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:NAME|NAME]], [[george:macro:OPENDIR|OPENDIR]], [[george:macro:OPENRELN|OPENRELN]], [[george:macro:OUTNULL|OUTNULL]], [[george:macro:OUTPACKX|OUTPACKX]], [[george:macro:OUTPAR|OUTPAR]], [[george:macro:QSTEPC|QSTEPC]], [[george:macro:READAGAIN|READAGAIN]], [[george:macro:REWRITE|REWRITE]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:STEP|STEP]], [[george:macro:STEPAGAIN|STEPAGAIN]], [[george:macro:STEPREWRITE|STEPREWRITE]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:TESTREPNOT|TESTREPNOT]], [[george:macro:TRACE|TRACE]], [[george:macro:UJFROZEN|UJFROZEN]], [[george:macro:UJRV|UJRV]], [[george:macro:UP|UP]], [[george:macro:VFREEW|VFREEW]]
22FL ... SEG BSPRUNE,83,PETER CAMPBELL,BSUNJ
22H* ...[
22K4 ...[
22LR ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
22NG ...[
22Q9 ...[
22RY ...#OPT G297 = 0
22TM ...#SKI G297&1
22XB ...# WITH UGUG EDIT M297 (PUT DEADWOOD OFFLINE)
22^= #DEF Z=K6BSPRUNE>599-599
23DW SEGENTRY K1BSPRUNE,X1BSPRUNE
23H5 ...#SKI ARETRV
23K# ...(
23MH ... SEGENTRY K100BSPRUNE
23PQ ... +150
23R^ ...)
23SG ...#UNS FEFSNO
23T3 ...#SKI
23TJ ... FIELDDEF FEFSNO,6,EBLL,5
23W8 ... BITDEFS AWORK3,21,XBCOOR,XBRV,XBSTATS
23YG TOTIM +864000/K9*100 [NO.OF CLEANCTS IN 24 HRS
24D6 NARK 8HARCH(M) [USED IN BSCHUCKED MESSAGE
24XQ [FOR ARCHIVED FILES
25CB [
25X2 [ AWORK4 CONTAINS NO OF CLEANCTS SPENT WAITING FOR DIRECTORIES
25YJ ...#SKI G297&1
2626 ...(
263N ...X1BSPRUNE
265= ... LDX 4 EDATE
266S ... SEGENTRY K77BSPRUNE [ TO ALLOW RESTORE-TIME CHOICE OF
268B ... SBX 4 INSTPARAM+3 [ I.P. SPECIFYING HOW OLD DEADWOOD IS (DAYS)
269Y ... STO 4 G297DEAD
26?G ... BRN ZREAD
26*4 ...)
26BL ZRST7
26W= DOWN BSUJSTAT,7
27*W ZREAD
27KN ... LDX 2 FX2
27TG #SKI Z
28*6 TRACE 4,WHYLEFT
28JY ...#SKI G297&1$1
28SQ X1BSPRUNE
29#B STOZ AWORK4(2)
29S2 ZREAD1
2=?L STEP [READ NEXT RECORD
2=R= BZE 3 PLAST [JUMP IF END OF FILE
2?=W LDX 0 ERES-A1(3) [JUMP IF NOT NAME RECORD
2?QG BNZ 0 ZREAD1
2?T5 ...[ CLEAR PARTRES BIT WHICH HAS BEEN INCORRECTLY LEFT SET
2?XN ...[ BY BACKMAP. BUG 8284.
2#2? ... JBCC ZPARTRES,3,BNPARTRES
2#4W ... STEPREWRITE
2#7F ...ZPARTRES
2#=6 LDX 1 3
2#PQ SBN 1 A1
2*9B #SKI Z
2*P2 (
2B8L TRACE ELOC1(1),BSUFILE
2BN= TRACE ELOC2(1),BSUF2
2C7W TRACE ELOC3(1),DBSUF3
2CMG TRACE EINF2(1),EINF2
2D76 TRACE ECOPS(1),ECOPS
2DLQ )
2F6B [ IS THIS A FILESTORE FILE?
2FL2 JMBS ZREAD,1,BELIB,BEWORK[DONT THROW OFF WORK/NON FILES
2HJG LDX 4 ECOPS(1) [COUNT
2J46 SRL 4 15 [ OF BLOCKS
2JHQ SMO FX2 [ IN
2K3B STO 4 AWORK1 [ AWORK1
2KH2 BZE 4 ZREAD [ZERO LENGTH FILE-DONT THROW OFF
2L2L [ OR AN EMPTY DIRECTORY
2LG= LDEX 4 ECOPS(1) [J IF FILE NOT ONLINE
2L^W BZE 4 ZREAD
2MFG ZFILE
2M^6 JBS ZREAD,1,BETEMP [TEMP FILE - NO STATS SINCE MK 6
2NDQ LDX 4 EUSE1(1)
2NYB BNZ 4 ZDIR [J IF FILE IS A DIRECTORY
2PD2 JBC XCTHROW,1,BEONLINE [J IF FILE CAN BE THROWN OFF-LINE
2PXL BZE 7 ZREAD
2QC= LDN 6 8 [CATEGORY 8 (NOT TO GO OFF LINE)
2QWW BRN ZRST7
2RBG XCTHROW
2RFL ... LDX 4 EALLOC(1) [CHECK IF ON SPECIAL RES
2RJQ ... ANDN 4 #77
2RMW ... SBN 4 48
2RR2 ... BPZ 4 ZREAD
2RW6 # DO NOT CHECK FILES FORMULA IF ARCHIVE BIT SET
2S*Q JMBS SGREATER,1,BEARCHIVE,BESYSARCH [J IF ARCHIVED
2STB TFORM
2SX^ ...#SKI G297&1
2T2J ...(
2T57 ... LDX 4 G297DEAD
2T7Q ... BXGE 4 EDLA(1),SGREATER
2T=* ...)
2T*2 [ CALCULATE FILE'S VALUE OF FORMULA IN X3 4
2TJS ... STO 7 ACOMMUNE2(2)
2TSL ... CALL 7 SRFFORM
2W4D ... LDX 7 ACOMMUNE2(2)
2W#= BNZ 3 SGREATER [JUMP IF GREATER THAN SINGLE LENGTH
2WRW #SKI Z
2X?G TRACE 4,FORMULA
2XR6 BXGE 4 FORMULA,SGREATER [JUMP IF FILE >FOORMULA
2Y=Q BZE 7 ZREAD [JUMP IF STATS NOT REQUIRED
2YQB LDN 6 30 [CAT 30
2^=2 BRN ZRST7
2^PL SGREATER
329= MHUNTW 3,FILE,FABSNB [FABSNB CONTAINE ABSOLUTE NAME OF DIR
32NW LDX 4 A1(3)
338G BXL 4 ALOGLEN(3),NALTA
33N6 ADN 4 6 [IF NECESSARY INCREASE LENGTH
347Q ALTLEN 3,4,FILE,FABSNB [OF FABSNB
34MB STEPAGAIN
3572 LDX 1 3
35LL SBN 1 A1
366= MHUNTW 3,FILE,FABSNB
36KW NALTA
375G LDX 2 A1(3) [X2 BECOMES RECORD HEADER +
37K6 ADX 2 3 [BASE ADDRESS OF FABSNB + A1
384Q ADN 2 A1 [=FIRSTFREE WORD
38JB ADN 1 ELOC1 [LOCAL NAME
3942 MOVE 1 5 [MOVE FIRST FIVE WORDS TO FABSNB
39HL SBN 1 ELOC1
3=3= LDX 0 ELAN(1) [STORE LANGUAGE WORDIN
3=GW STO 0 5(2) [6TH WORD OF LOCAL NAME
3?2G LDN 0 6 [UPDATE RECORD HEADER
3?G6 ADS 0 A1(3)
3?^Q [THE FILE'S LOCAL NAME IS THE BOTTOM ONE IN THE FABSNB
3#FB [THE TOP FILE OPEN IS THE SUPERIOR USER'S DIRECTORY
3#^2 LDX 6 1
3*DL [ STORE POINTER TO RECORD
3*Y= LOCFCB 2 [LOOKS FOR FCB OF FILE
3B84 ... LDX 2 FX2
3BCW LDX 1 6
3BXG LDN 0 6 [IN FILE CCHAIN
3CC6 SBS 0 A1(3) [UPDATE RECORD HEADER
3CWQ TESTREPNOT OK,ZFILEFREE [JUMP IF FCB NOT FOUND
3DBB [ FCB HAS BEEN FOUND SO FILE IS LEFT ON LINE
3DQ5 ... LDN 6 16
3F5S ... IFUJSTAT 7
3FFH ... BRN ZREAD
3FT= ZFILEFREE
3G#W [FCB NOT FOUND BUT MAY BE FROZEN
3GSG LDX 0 EAUTOCOUNT(1) [TEST IF FROZEN TO LISTFILE
3H#6 LDN 6 20 [CAT 20
3HRQ BNZ 0 ZFROZEN
3J?B LDX 0 ESVCT(1) [ TEST IF HLS SAVED
3JR2 LDN 6 36 [CAT 36
3K=L BZE 0 NOTFROZEN [JUMP IF NOT FROZEN
3KQ= ZFROZEN [OR IF
3L9W UJFROZEN NOTFROZEN [FROZEN BUT YO BE PUT OFF LINE
3LPG SP43
3M96 BZE 7 ZREAD
3MNQ BRN ZRST7
3N8B NBLST GEOERR 1,NO BLIST
3NN2 XFREEFRB
3P7L ... LDX 2 FX2
3PM= ... JBC SP43,2,XBCOOR
3QLG MFREEW FILE,FRB
3R66 # FREE THE FRB IF IT WAS CREATED
3RKQ BRN SP43
3S5B NOTFROZEN
3S64 ...#SKI ARETRV
3S6Q ...(
3S7D ... LDX 2 FX2
3S86 ... BC 2,XBRV
3S8S ... UJRV XCHUCK
3S9G ...# DO NOT RETAIN RETRIEVES IF FORMULA < 500
3S=8 ... JFZ XCHUCK,1,FEGMTRV
3S=W ... LF 1,FEGMTRV,0
3S?J ... LDX 4 GMTNOW
3S#= ... SBX 4 0
3S#Y ...# X4 = GMTNOW - GMTRV
3S*L ... SLL 4 8
3SB# ... SRL 4 8
3SC2 ...# TOP BITS ARE CLEAR IF RESULT WAS NEGATIVE
3SCN ... SMO FX1
3SDB ... BXGE 4 K100BSPRUNE,XCHUCK
3SF4 ... BS 2,XBRV
3SFQ ...XCHUCK
3SGD ...# THE XBRV BIT IS SET IF INSIDE THE ' PROTECTED ' PERIOD
3SH6 ...)
3SHS ... STO 1 5 [ STORE POINTER TO RECORD
3SK2 QSTEPC ,STEPCOOR [ PERFORMS A STEP IFF IT CAN DO SO WI
3T4L [ COORDINATING , OTHERWISE JUMP TO STEPCOOR
3TJ= LDX 2 FX2
3TWM ... BC 2,XBCOOR
3W94 ... LDX 1 5
3WHG BRN STEPNOCO
3X36 STEPCOOR
3XGQ READAGAIN
3Y2B STEP
3YG2 MHUNTW 1,FILE,FRB
3Y^L ... BS 2,XBCOOR
3^F= STEPNOCO
3^YW # POINTERS X1,X3 HAVE THE SAME APPEARANCE WHETHER OR NOT THERE WAS A
42DG # A COORDINATION
42Y6 LDX 5 1(3) [RESIDENCE NUMBER
43CQ STO 5 AWORK2(2)
43XB LDX 6 BSAB
44C2 LDX 2 BMISC [PICK UP BASE OF MISC CHAIN
44WL RMISC
45B= LDX 2 FPTR(2) [PICK UP NEXT BLOCK
45TW BXE 2 CXMI,NBLST [JUMP IF END OF CHAIN
46*G BXU 6 ATYPE(2),RMISC [JUMP IF NOT BSLIST
46T6 BXU 5 BACK1(2),RMISC [JUMP IF WRONG RESIDENCE
47#Q JMBS NEEDS,2,BSLJAM,BSLTHRESH
47SB JMBS NEEDS,1,BESYSARCH,BEARCHIVE
48#2 LDN 6 26 [BELOW THRESHOLD AND NOT ARCHIVED
48RL BRN XFREEFRB
49?= NEEDS JBS NDUMP2,1,BEDUMP
49DD ...#UNS FTS2REVERT
49KL ... JFNZ SPNEEDS,1,FEFSNO [ IGNORE CHECK IF ALIEN
49QW LDX 4 EINC(1)
4==G #SKI Z
4=Q6 TRACE 4,INCRMENT
4?9Q MHUNTW 1,FILE,INCUNJ
4#92 # STORE POINTER TO INCUNJ
4#NL LDX 6 A1(1)
4*8= SBN 6 INCUNR+2-A1 [NO.OF UNRELIABLE INCREMENTS
4*MW BZE 6 NOUNREL2 [J IF NO UNREL.INCS
4B7G UNREL2
4BM6 ADN 1 1 [INCREASE POINTER
4C6Q BXU 4 INCUNR(1),SP42 [J UNLESS INC.UNRELIABLE
4CLB [
4D62 [ IN UNRELIABLE INC THAT NEEDS REDUMPING,AND IS ON JAMMED UNIT
4DKL [
4F5= LDN 6 10 [CAT 10-INC UNRELIABLE
4FJW BRN NDUMP3 [GO ADD TO COUNT OF BLKS TO BE DUMPED
4G4G [
4GJ6 [
4H3Q [
4HHB SP42 BCT 6 UNREL2 [RETURN IF CHECK NOT ENDED
4J32 NOUNREL2
4JGL BXL 4 INCUNR+1(1),SPNEEDS [J IF INC MADE WHEN UJ STARTED
4K2= [
4KFW [ INCREMENT NOT MADE WHEN UJ STARTED
4K^G [
4LF6 LDN 6 12 [CATEGORY 12-INC NOT MADE AT START UJ
4LYQ BRN XFREEFRB
4MDB NDUMP2 [NEVER DUMPED
4MY2 LDN 6 14
4NCL NDUMP3 [ADD SIZE OF FILE TO AMOUNT NOT DUMPD
4NX= SMO FX2
4PBW LDX 3 AWORK1 [NO.OF BLOCKS IN FILE
4PWG JBC XFREEFRB,2,BSLJAM
4QB6 [ OTHERWISE ADD TO BSNDUMP
4QTQ ... MHUNTW 1,FILE,INCUNJ
4R*B ADS 3 BSNDUMP(1) [ADD TO NO.OF BLOCKS NOT DUMPED
4RT2 #SKI Z
4S#L TRACE BSNDUMP(1),NOT DUMP
4SS= BRN XFREEFRB
4T?W SPNEEDS
4T*Y ... LDX 2 FX2
4TD2 ... JBC ZNOFRB,2,XBCOOR
4TG4 ... MFREEW FILE,FRB
4TJ6 ...# FREE FRB IF IT WAS CREATED
4TL8 ...ZNOFRB
4TN= ...#SKI ARETRV
4TQ# ...(
4TSB ... LDX 2 FX2
4TWD ... JBC NOTRVD,2,XBRV
4TYG ... LDN 6 56 [ CAT 56 FILE RECENTLY RV'ED
4W2J ... IFUJSTAT 7
4W4L ... BRN ZREAD
4W6N ...NOTRVD
4W8Q ...)
4W?6 [ STATISTICS ABOUT FILE ON JAMMED UNIT THAT IS THROWN OFF
4WQQ LDN 6 28
4X=B ... IFUJSTAT 7
4^NG SP10 [FOLE'S DIRECTORY HAS ONLY BEEN
5286 [ STEPPED NOT READ A COPY OF BLOCKS RECORD IS NEEDED TO
52MQ [FREE ITS BACKING STORE
537B READAGAIN
53M2 MHUNTW 1,FILE,FRB
546L NAME 1,BSTB,FULLB
54L= FULLBPAS 1,2 [FREE BLOCKS
555W DELETE [DELETE BLOCKS RECORD
55KG READAGAIN [READ NAME RECORD
5656 MHUNTW 1,FILE,FRB
56JQ NAME 1,FILE,ENT
574B MHUNTW 3,FILE,FABSNB
57J2 LDX 4 A1(3)
583L SBN 4 5 [SET UP POINTER AT LAST USERNAME
58H= BPZ 4 NMAST
592W ADN 4 2 [MASTER ONLY 4 WORDS NOT 6
59GG NMAST
5=26 SMO FX2
5=FQ STO 7 AWORK3 [TEMP STORAGE FOR STATS SWITCH
5=^B ADN 4 A1(3)
5?F2 LDN 6 JPDUSERNAME
5?YL LDN 5 3
5#D= CALL 7 PACKMESS [%A- USERNAME
5#XW MHUNTW 3,FILE,ENT
5*CG LDN 4 ELOC1(3)
5*X6 LDN 6 JPDLOCNAME
5BBQ CALL 7 PACKMESS [%B- LOCALNAME
5BWB LDN 5 1 [REST ARE ALL 1 WORD PARAMETER
5CB2 MHUNTW 3,FILE,ENT
5CTL LDN 4 EGEN(3)
5D*= LDN 6 JPDGENNUM
5DSW CALL 7 PACKMESS [%C- GENERATION NUMBER
5F#G MHUNTW 3,FILE,ENT
5FS6 LDN 4 ELAN(3)
5G?Q LDN 6 JPDLANGUAGE
5GRB CALL 7 PACKMESS [%D- LANGUAGE
5H?2 SMO FX2
5HQL LDN 4 AWORK2
5J== LDN 6 JPDNUMA
5JPW CALL 7 PACKMESS [%E- RESIDENCE NUMBER
5K9G SMO FX2
5KP6 LDN 4 AWORK1
5L8Q LDN 6 JPDBLOCKCT
5LNB CALL 7 PACKMESS [%F- SIZE
5M82 MHUNTW 3,FILE,ENT
5MML LDN 4 EGMTLA(3)
5N7= LDN 6 JPDNUMB
5NLW CALL 7 PACKMESS [%G- GMT LAST ACCESSED
5P6G MHUNTW 3,FILE,ENT
5PL6 LDN 4 EAVACC(3)
5Q5Q LDN 6 JPDNUMC
5QKB CALL 7 PACKMESS [%H- AVE ACCESS TIME
5R52 OUTPAR NULL [%I- NULL PARAMETER
5RJL MHUNTW 3,FILE,ENT
5RSD ... LDN 5 0
5S#4 ... JMBAC ZPARS2,3,BEARCHIVE,BESYSARCH
5T3G ADN 5 1
5TH6 JBC ZMESS,3,BESYSARCH
5W2Q ADN 5 1
5WGB ZMESS LDN 4 NARK(1)
5X22 LDN 6 JPDVARCHAR
5XFL CALL 7 PACKMESS [%J - ARCHIVED FILE
5XGK ... BRN ZPARS
5XHJ ...ZPARS2
5XJH ... OUTNULL
5XKG ...ZPARS
5XLF ... SEGENTRY K10BSPRUNE
5XMD ... BRN MESSEND
5XNC ... MHUNTW 1,FILE,ENT
5XPB ... CALL 7 SRFFORM [RECALCULATE FORMULA
5XQ* ... STO 3 ACOMMUNE2(2)
5XR# ... STO 4 ACOMMUNE3(2)
5XS? ... LDN 4 ACOMMUNE3(2)
5XT= ... LDN 5 1
5XW9 ... LDN 6 JPDNUMA
5XX8 ... CALL 7 PACKMESS
5XY7 ... SEGENTRY K11BSPRUNE
5X^= MESSEND
5YDW SMO FX2
5YYG LDX 7 AWORK3 [RESTORE STATS SWITCH
5^D6 ... MONOUT BBSCHUCKED
5^XQ BZE 7 RENAME
62CB BZE 5 NOTARC [J IF NOT ARCHIVED
62X2 LDN 6 44
63BL SBN 5 1
63W= BZE 5 NOTMAN [J IF NOT MANAGER ARCHIVED
64*W ADN 6 2
64TG NOTMAN
65*6 DOWN BSUJSTAT,7 [FOR ARCHIVED FILE
65SQ NOTARC
66#B DOWN BSUJSTAT,9 [FOR FILE THROWN OFF
66S2 RENAME
67?L MHUNTW 1,FILE,ENT
67R= NAME 1,FILE,FWB
68=W LDX 0 ECOPS(1)
68QG SRL 0 15 [KEEP NUMBER OF BLOCKS
69=6 SLL 0 15 [BUT STOZ NUMBER OF COPIES
69PQ STO 0 ECOPS(1) [NO COPY NOW
69^J ... FC 1,FEGMTRV [ CLEAR GMTRV FIELD
6=9B #SKI K6BSUNJAM>99-99
6=P2 TRACE ELOC1(1),FILE DEL
6?8L REWR
6?N= REWRITE [REWRITE DIRECTORY ENTRY
6#7W MFREEW FILE,FWB
6#MG BRN ZREAD1 [LOOK AT NEXT FILE,DIR NOW OPEN IN GE
6*76 ...# S/R FOR CALCULATING FILE FORMULA
6*LQ ...SRFFORM
6B6B ... FILEFORM
6BL2 ... EXIT 7 0
6WPL # S/R FOR BSCHUCKED MESAGE
6X9= PACKMESS
6XNW SBX 7 FX1
6Y8G OUTPACKX 4,5,6
6YN6 ADX 7 FX1
6^7Q EXIT 7 0
6^MB # ANOTHER ONLINE DIRECTORY HAS BEEN FOUND
7272 ZDIR
72LL LDN 6 8
736= IFUJSTAT 7
73KW READAGAIN [NAME RECORD OF DIRECTORY
745G MHUNTW 3,FILE,FABSNB
74K6 LDX 4 A1(3)
754Q BXL 4 ALOGLEN(3),NALT
75JB ADN 4 6
7642 ALTLEN 3,4,FILE,FABSNB [INCR.LENGTH OF FTREENAME BLOCK
76HL MHUNTW 3,FILE,FABSNB
773= NALT ADX 3 A1(3)
77GW ADN 3 A1 [ADJUST POINTER IN FTREENAME
782G LDX 0 HCOLUSER
78G6 STO 0 0(3)
78^Q ADN 3 1
79FB MHUNTW 2,FILE,FRB
79^2 NAME 2,FILE,ENT
7=DL ADN 2 EUSE1
7=Y= #SKI Z
7?CW TRACE EUSE1-ELOC1(2),DIRECTRY
7?XG MOVE 2 3 [MOVE NEW NAME ACROSS
7#C6 STOZ 3(3)
7#WQ STOZ 4(3)
7*BB MHUNTW 1,FILE,FABSNB
7*W2 MHUNTW 2,FILE,FLOCNB
7B*L ADN 2 A1
7BT= ADX 1 A1(1)
7C#W ADN 1 A1
7CSG MOVE 1 6 [MOVE NEW NAME INTO THE FLOCNB
7D#6 MHUNTW 1,FILE,FABSNB
7DRQ LDN 0 6
7F?B ADS 0 A1(1) [INCREASE RECORD HEADER
7FR2 NGX 6 CLEANCT
7G=L OPENRELN XBRK,GENERAL,QUERY [OPEN NEW DIRECTORY
7GQ= ADX 6 CLEANCT
7H9W ADS 6 AWORK4(2)
7HPG #SKI Z
7J96 (
7JNQ TRACE 6,CCTOPENR
7K8B TRACE EXEC3(2),RQOPREP
7KN2 )
7L7L TESTREP2 OK,ZREAD1
7LM= BRN NODIR [IF NO GOOD PULL UP TO PREVIOUS DIREC
7M6W # THIS PULLS YOU UP FROM ONE LEVEL TO THE NEXT
7MLG PULLUP
7N66 #SKI Z
7NKQ TRACE A1(1),PULLUP
7P5B ... CLOSETHROW [CLOSE PRESENT DIRECTORY
7PK2 BRN RFTREE
7Q4L NODIR
7QJ= BZE 7 RFTREE
7R3W DOWN BSUJSTAT,8 [WRITE RECORD ABOUT DIRECTORY
7RHG RFTREE
7S36 OPENDIR XBRK,GENERAL,QUERY [OPEN NEXT DIRECTORY UP
7SGQ MHUNTW 1,FILE,FABSNB
7T2B LDN 0 6 [REDUCE COUNT IN FABSNB
7TG2 SBS 0 A1(1) [ I.E. GO UP A LEVEL IN TREE
7TPS ... VFREEW FILE,ENT
7T^L TESTREPNOT OK,TLAST
7WF= # IF REPLY OK - FRNN F/ENT AND READ NEXT ENTRANT IN
7WYW # SUPERIOR DIRECTORY
7XY6 BRN ZREAD1
7YCQ TLAST
7YXB # IF CANT OPEN DIRECTORY CHECK IF NEED STATISTICS
7^C2 # AND THEN GO UP ANOTHER LEVEL
7^WL LDN 3 NODIR-PULLUP
82B= BRN SLAST
82TW PLAST LDN 3 0
83*G SLAST
87=G MHUNTW 1,FILE,FABSNB
87Q6 LDX 0 A1(1) [CHECK IF UP TO MASTER YET
889Q SBN 0 4
88PB SMO 3 [IF NOT PULLUP OR NODIR
8992 BNZ 0 PULLUP
89DS ...#
89NL LDX 2 FX2
8=8= LDX 0 AWORK4(2) [CLEANCTS SPENT WAITING
8=MW STO 0 ACOMMUNE1(2)
8?7G UP
8?M6 XBRK GEOERR 1,BRK BSUJ [BREAKIN
8#6Q MENDAREA 20,K99BSPRUNE
8#LB #END
^^^^ ...03243145000400000000