{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: CAPCA50)}}
====== CAPCA50 ======
(George Source)

**Macros used:** [[george:macro:CHAIN|CHAIN]], [[george:macro:CHANGEUP|CHANGEUP]], [[george:macro:CLEAR|CLEAR]], [[george:macro:FCAJO|FCAJO]], [[george:macro:FJOPCA|FJOPCA]], [[george:macro:FLIPS|FLIPS]], [[george:macro:GEOERR|GEOERR]], [[george:macro:MHUNTX|MHUNTX]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:TRACE|TRACE]]

<code - CAPCA50.txt>22FL    #SEG  CAPCA50                      [R.H.THOMPSON  F6
22^=    #OPT  K0CAPCA=0 
23DW    #LIS  K0CAPCA>K0ALLGEO  
23YG          8HCAPCA   
24D6    #   
24XQ    #   
25CB    #           THIS SEGMENT IS ENTERED BY THE CAPCA MACRO IN ORDER TO SWITC
25X2    #     CONTROL OF THE JOB FROM THE PROGRAM CONTROL ACTIVITY (PCA) TO THE 
26BL    #     PROCESSOR ACTIVITY (CPA). 
26W=    #           SEE P.R.M. FOR FULL USER SPECIFICATION. 
27*W    #   
27TG          SEGENTRY K1CAPCA,XX1C 
28*6          SEGENTRY K2CAPCA,XX2C 
28SQ    #SKIP G4
29#B    (   
29S2          SEGENTRY K3CAPCA,XX3C 
2=?L          SEGENTRY K4CAPCA  
2=R=          STOZ     ACOMMUNE1(2) 
2?=W    XX3C
2?QG          LDN   4  1
2#=6          BRN      ZG4A 
2#PQ    )   
2*9B    #   
2*P2    XX2C
2B8L          STOZ     ACOMMUNE1(2)        [INDICATE NO DATA BLOCKS 
2BN=    XX1C
2C7W    #SKIP G4
2CMG    (   
2D76          LDN   4  0
2DLQ    ZG4A
2F6B    )   
2FL2          FJOPCA   3,2  
2G5L    #SKI  K6CAPCA   
2GK=    (   
2H4W          LDCH  0  ATYPE(2) 
2HJG          SBN   0  APET/64  
2J46          BZE   0  ZZ2                 [ERROR NOT ISSUED BY PCA 
2JHQ    ZZ2E  GEOERR   1,XCAPCA            [CAPCA ISSUED AT INCORRECT ENVIRONMEN
2K3B    ZZ2   LDX   0  JMISC(3) 
2KH2          ANDN  0  #10                 [ERROR IF PROGRAM NOT MARKED STOPPED 
2L2L          BZE   0  ZZ2E 
2LG=    )   
2L^W    #SKI  K6CAPCA>99-99 
2MFG          TRACE    JOBNO(2),CAPCA   
2M^6    #SKIP G4
2NDQ    (   
2NYB          BNZ   4  ZG4C 
2PD2          CLEAR    2,0  
2PXL    ZG4B
2QC=    )   
2QWW          FLIPS    JMISC(3),20,23      [CHANGE PROG FROM STOPPED TO DORMANT 
2RBG          FCAJO    3
2RW6          LDX   4  ACOMMUNE1(2)        [GET TYPES OF DATA BLOCKS
2S*Q    N14 
2STB          BZE   4  N12                 [J NONE  
2T*2          SRL   45 12   
2TSL          MHUNTX   1,5                 [FIND DATA BLOCK 
2W#=          CHAIN    1,3                 [CHAIN DATA BLK AFTER COMMAND ACT.   
2WRW          BRN      N14                 [SEE IF ANYMORE DATA BLOCKS  
2X?G    N12   CHANGEUP 3                   [EXIT UP TO CPA  
2XR6    #SKIP G4
2Y=Q    (   
2YQB    #   
2^=2    #     CLEAR LOCKS & MARK LOCKDOWN LIST ENTRIES PASSIVE  
2^PL    ZG4C  CLEAR    2,1                 [CLEAR LOCKS BUT NOT LOCKDOWN LIST   
329=          LDN   4  HLOCKN*HLOCKLEN     [MARK NON ZERO ENTRIES PASSIVE   
32NW    ZG4D  SBN   4  HLOCKLEN 
338G          SMO      4
33N6          LDX   0  HLOCK1(2)
347Q          BZE   0  ZG4E 
34MB          ORX   0  CACT 
3572          SMO      4
35LL          STO   0  HLOCK1(2)
366=    ZG4E  BNZ   4  ZG4D 
36KW          BRN      ZG4B 
375G    )   
37K6    #   
384Q    #     MEND AREA 
38JB    #   
3942    #GAP  10
39HL    #END
^^^^ ...50567760000100000000
</code>