{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: CDCIPB864)}}
====== CDCIPB864 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:ALTLENG|ALTLENG]], [[george:macro:CCOUT|CCOUT]], [[george:macro:CHAIN|CHAIN]], [[george:macro:CONCISBY|CONCISBY]], [[george:macro:COOR3|COOR3]], [[george:macro:FCJOB|FCJOB]], [[george:macro:FPUT|FPUT]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHACTPR|FSHACTPR]], [[george:macro:FSHCODE|FSHCODE]], [[george:macro:FSHKILL|FSHKILL]], [[george:macro:FSHSKIP|FSHSKIP]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETACT|GETACT]], [[george:macro:HUNT|HUNT]], [[george:macro:HUNT2|HUNT2]], [[george:macro:HUNT2J|HUNT2J]], [[george:macro:HUNTACT|HUNTACT]], [[george:macro:HUNTW|HUNTW]], [[george:macro:IDFOFF|IDFOFF]], [[george:macro:IPBNULL|IPBNULL]], [[george:macro:LINK|LINK]], [[george:macro:LINKSET|LINKSET]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MURDER|MURDER]], [[george:macro:NAME|NAME]], [[george:macro:PAIR|PAIR]], [[george:macro:RTTEST|RTTEST]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETIDENT|SETIDENT]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:SUBRELT|SUBRELT]], [[george:macro:SUICIDE|SUICIDE]], [[george:macro:UNQUEUE|UNQUEUE]], [[george:macro:UP|UP]], [[george:macro:WHICHCON|WHICHCON]]
22FL ... SEG CDCIPB,,PHILIP TURNER
22^= ...#LIS K0CDCIPB>K0IPB>K0ALLGEO
23DW ... 8HCDCIPB70
23YG ...#
24D6 ...#
24XQ ...# THIS SEGMENT CLOSES DOWN THE CONCEPTUAL IPB
25CB ...#
25X2 ... SEGENTRY K1CDCIPB,TIDY
26BL ... SEGENTRY K2CDCIPB,X2CDCIPB
26W= ... SEGENTRY K3CDCIPB,X3CDCIPB
27*W ...PAIRC3
27TG ... LINK CDCIPB,3
28*6 ...TDGE GEOERR 1,BRIN
28SQ ...PAIR LINK IPBSCAN,5
28X* ... FSHCODE AORB
28^Y ...(
294H ...PAIRB LINK IPBSCANB,5
2976 ...)
299P ...[
29#B ...SCSS #40000000
29S2 ... #01110000
2=3S ...ZCLBT #56757777 [TO CLEAR BITS 1,5,10
2=?L ...#
2=R= ...# THIS ROUTINE FINDS THE REQUIRED BLOCKS
2?=W ...#
2?QG ...RHRC LDX 3 0(3) [ADDRESS OF CONDCB
2#=6 ... ADX 3 BSTART(3)
2#PQ ... STO 3 ACOMMUNE4(2) [ADDRESS OF CONDCB
2*9B ... HUNTACT AMOP,3
2*P2 ... STO 3 ACOMMUNE2(2) [ADDRESS OF IPBCCA
2B8L ... EXIT 5 0
2BN= ...#
2C7W ...TDMR LDX 2 5
2CMG ... SBX 7 FX1
2D76 ... BRN TENT
2DLQ ...TDM LDX 0 BACKCHAN(2)
2F6B ... BZE 0 TDMD
2FL2 ... COOR3 #62
2G5L ... LDX 2 5
2GK= ...
2H4W ...TENT LDEX 4 ATYPE(2)
2HJG ... BZE 4 TDM
2J46 ... UNQUEUE
2J83 ...TDMD LDX 2 5
2J?Y ... HUNT2 2,AMXOR,CSTATE
2JCT ... LDX 3 A1+BPTR(2) [RING TO CONDCB
2JHQ ... BZE 3 TDMX [JUMP NO RING
2JMM ... STOZ BPTR(3) [CLEAR CONDCB RING
2JRJ ... STOZ A1+BPTR(2) [CLEAR CSTATE RING
2JXF ...TDMX MURDER 5 [KILL OFF OLPA
2K3B ... ADX 7 FX1
2KH2 ... EXIT 7 0
2L2L ...#
2LG= ...SUCB SBX 7 FX1
2L^W ... SETNCORE 3,1,AMXOR,IOUT
2MFG ... ADX 7 FX1
2M^6 ... EXIT 7 0
2NDQ ...#
2NYB ...RFND MHUNTW 2,IDF,CONCEP
2PD2 ... EXIT 1 0
2PXL ...#
2QC= ...SUCS1 LDX 3 AWORK1(2) [OLPA
2QWW ... HUNT2 3,AMXOR,CSTATE
2RBG ... LDX 2 FX2
2RW6 ... ADN 3 A1
2S*Q ... STO 3 ACOMMUNE1(2)
2STB ... EXIT 6 0
2T*2 ...#
2TSL ...# THIS ROUTINE CHAINS A DATA BLOCK BEHIND THE CONDCB
2W#= ...#
2WRW ...SCDB1 CALL 6 SUCS1
2X?G ... CALL 5 RHRC
2XR6 ... CHAIN 1,3
2Y=Q ...
2YQB ... EXIT 7 0
2^=2 ...#
2^PL ...TIDY STO 3 AWORK1(2) [OLPA ADDRESS
329= ... STOZ AWORK2(2) [CLEAR MARKERS
32=M ...#
32#4 ...# THE CORRECTION TO BUG 8179 MEANS THAT WE CAN NO LONGER RELY
32*F ...# ON THE DEVICE NOT BEING BUSY AT RELEASE TIME!!!!
32BW ...#
32D? ...# THEREFORE WE HAVE TO WAIT FOR OUTSTANDING TRANSFERS TO COMPLETE
32FN ...#
32H5 ...XBUSY CONCISBY 3,TDHT [JIF NO TRANSFERS IN PROGRESS
32JG ... COOR3 #41 [ELSE WAIT A WHILE AND THEN
32KX ... BRN XBUSY [GO TO CHECK AGAIN
32M# ...#
32NW ...TDHT CALL 6 SUCS1
338G ... CALL 5 RHRC
33?5 ... LDCT 5 #200
33*N ... SMO ACOMMUNE1(2) [CSTATE
33D? ... ORS 5 IPSTATUS
33GW ...[ SET CPA CLOSING DOWN TO ...
33KF ...[ ... PREVENT FURTHER ATTACHES
33N6 ...#UNS CLSKI
347Q ...(
34MB ... LDXC 0 CONREL(3)
3572 ... BCS TDSR [J IF SET RELEASING
35LL ... LDCT 0 #400
366= ... ORS 0 CONREL(3) [TELL IPBCCA
36KW ... BRN TDCR [WAIT
375G ...TDSR ADXC 0 0
37K6 ... BCS TDBC [J IF IPBCCA READY
384Q ...)
38JB ...TDCR COOR3 #62
3942 ... BRN TDHT
39HL ...TDBC LDX 3 ACOMMUNE4(2) [CONDCB
3=3= ... HUNTW 1,IDF,CONCEP [IS THERE AN IDF BLOCK
3=GW ... BPZ 1 TDCS [-> YES
3?2G ... LDX 7 ARGNO(3) [NO. OF CONDCB ENTRIES
3?G6 ... SBN 7 1
3?^Q ... ANDN 7 #7777
3#FB ... SLL 7 1
3#^2 ... SETUPCORE 7,1,IDF,CONCEP
3*DL ... CALL 6 SUCS1
3*Y= ... CALL 5 RHRC
3BCW ... STOZ AWORK3(2)
3BXG ...TDCS LDX 3 ACOMMUNE4(2) [CONDCB
3CC6 ... LDN 6 A1(1)
3CWQ ... LDX 2 6 [POINT TO START OF BLOCK +A1
3DBB ... SMO FX2
3DW2 ... ADX 6 AWORK3
3F*L ... LDX 5 ALOGLEN(3)
3FT= ... LDN 3 A1(3) [START OF ENTRIES
3G#W ...TDSU SBN 5 CONDCBLEN [ANY ENTRIES LEFT
3GSG ...
3H#6 ... BZE 5 TDCL [-> NO
3HRQ ... ADN 3 CONDCBLEN
3J?B ... LDX 1 BPTR(3) [POINT TO ADEVS ENTRY IF NOT EMPTY
3JR2 ... BZE 1 TDSU [-> IF NULL ENTRY
3K=L ...#UNS CLSKI
3KQ= ...(
3L9W ... LDN 0 #400
3LPG ... ANDX 0 IDSTATUS(3)
3M96 ... BNZ 0 TDSU [J IF IPBCCA DEALING WITH THIS
3MNQ ...)
3MRW ... SEGENTRY K91CDCIPB [MENDED BY RETAINAH MACRO
3MX2 ...TDCOM LDN 0 AHRETREL
3N26 ... BZE 0 NRETAH [J IF AH NOT BE RETAINED
3N5= ... LDCT 0 #10
3N8B ... BRN TCLEAR
3N?G ...NRETAH
3NBL ... LDCT 0 #210
3NFQ ...[ UNSET AH AS WELL IF NOT RETAINING
3NJW ...TCLEAR
3NN2 ... ERS 0 FOURTHWD(1) [CLEAR ONLINE MARKER
3P7L ... STOZ BPTR(1) [CLEAR ADEVS ENTRY
3PM= ... STOZ BPTR(3) [CLEAR CONDCB ENTRY
3PR7 ... LDN 0 #1000
3PX4 ... ANDX 0 IDSTATUS(3) [X3 - ENTRY IN CONDCB
3Q2^ ... BNZ 0 TACT [J. IF IDENTIFIER INOP
3Q6W ... LDX 0 IDADIN(3) [ADDRESS OF AMOP
3QLG ... SMO 6
3R66 ... STO 0 0 [STORE IN IDF/CONCEP1 BLOCK
3RKQ ... LDX 0 IDNUM(3) [ACTUAL IDENTIFIER
3S5B ... SMO 6
3SK2 ... STO 0 1 [STORE IN IDF/CONCEP1 BLOCK
3T4L ...TDUD ADN 6 2
3TJ= ... BRN TDSU [GET NEXT ENTRY
3W3W ...TDCL SBX 6 2 [LENGTH OF BLOCK
3WHG ... SBN 2 A1
3X36 ... BZE 6 TDFC
3XGQ ... ALTLENG 2,6,RFND
3Y2B ... CALL 6 SUCS1
3YG2 ...TDRT LDX 7 GSIGN
3Y^L ... ERS 7 AWORK2(2)
3^F= ... LDX 3 ACOMMUNE1(2) [CSTATE
3^YW ... SBN 3 A1
42DG ... LDX 5 ALOGLEN(3)
42Y6 ... ADN 3 A1
43CQ ...TDCE ADN 3 CSTATELEN
43XB ... SBN 5 CSTATELEN
44C2 ... BZE 5 TDRF [-> NO
44WL ... LDX 1 BPTR(3) [POINT TO CROUTE ENTRY
45B= ... LDX 6 AWORK2(2)
45TW ... SLL 6 1 [FIRST TIME THROUGH
46*G ... BPZ 6 TDIY [-> YES
46T6 ...TDBG LDX 2 1
47#Q ... ADX 2 BSTART(1)
47SB ... HUNTACT AMOP,2
48#2 ... LDCT 0 4
48RL ...
49?= ... ANDX 0 IPBSW(2) [ONLINE USING CROUTE BLOCK
49QW ... BZE 0 TDAM [-> NO
4==G ... SMO FX2
4=Q6 ... SBX 3 ACOMMUNE1
4?9Q ... COOR3 #62
4?PB ... LDX 7 3
4#92 ... CALL 6 SUCS1 [FIND CSTATE BLOCK
4#NL ... ADX 3 7 [ADD DISPLACEMENT
4*8= ... LDX 1 BPTR(3) [POINT TO CROUTE ENTRY
4*MW ... BRN TDBG
4B7G ...TDAM LDX 6 BSTART(1)
4BM6 ... ADX 6 1 [POINT TO START OF CROUTE BLOCK
4C6Q ... SMO 6
4CLB ... LDX 7 ALOGLEN
4D62 ... SBN 7 CROUTELEN [ ONLY ONE ENTRY
4DKL ... BZE 7 TDFB [-> YES
4F5= ... SUBRELT 1 [REMOVE ELEMENT
4FJW ...
4G4G ... BRN TDCE
4GBX ...TDFB SUBRELT 1,1
4GP# ... FREECORE 6
4H3Q ... BRN TDCE
4HHB ...TDFC FREECORE 2
4J32 ... BRN TDRT
4JGL ...TDIY SBX 3 ACOMMUNE1(2)
4K2= ... STO 3 AWORK3(2) [SAVE X3
4KFW ... STO 5 AWORK4(2) [SAVE X5
4K^G ... CALL 7 SUCB
4LF6 ... NAME 1,IDF,CONNAME
4LYQ ... CALL 6 SUCS1
4MDB ... CALL 5 RHRC
4MY2 ... LDX 3 AWORK3(2) [RESTORE X3
4NCL ... ADX 3 ACOMMUNE1(2)
4NX= ... LDN 7 A1(1) [START OF DATA AREA
4PBW ... LDX 1 BPTR(3)
4PWG ... LDN 6 CONNM(1)
4QB6 ... MOVE 6 3 [MOVE TO NEW BLOCK
4QTQ ... LDX 5 AWORK4(2) [RESTORE X5
4R*B ... LDCT 6 #200
4RT2 ... ORS 6 AWORK2(2) [SET NOT FIRST TIME THROUGH
4S#L ... BRN TDBG
4SS= ...#UNS IDFMARK8
4SXP ... SEGENTRY K92CDCIPB [MENDED BY RETAINAH MACRO
4T38 ...TDRF LDN 0 AHRETREL
4T6M ... BNZ 0 TLEAVEAH [J IF ATTACHES TO BE RETAINED
4T=6 ... IDFOFF (GEOERR),TDGE,IDF,CONNAME,A1,1
4T*K ... BRN TDRELED
4TF4 ...TLEAVEAH
4TJH ... IDFOFF (GEOERR),TDGE,IDF,CONNAME,A1
4TN2 ...TDRELED
4TRG ...
4W?6 ... MFREEW IDF,CONNAME
4WQQ ... CALL 6 SUCS1
4X=B ... CALL 5 RHRC
4XQ2 ...#UNS CLSKI
4Y9L ...(
4YP= ... LDX 2 3
4^8W ... FPUT [WAKE IPBCCA
4^NG ...)
5286 ... LDX 5 AWORK1(2) [OLPA
52MQ ... CALL 7 TDMR [MURDER OLPA
537B ... HUNT 1,IDF,CONCEP
53M2 ... BNG 1 TDUP
546L ... GETACT AMSCAN,IPBTYPE
54BD ... FSHSKIP
54L= ... LINKSET BPTR(2),PAIR(1)
54RD ... FSHCODE AORB
54YL ... LINKSET BPTR(2),PAIRB(1)
555W ... MHUNTW 3,IDF,CONCEP
55KG ...
5656 ... CHAIN 3,BPTR(2)
56JQ ... HUNTACT AMSCAN,2
574B ... FPUT
5762 ...TDUP
577L ... RTTEST RTIME,,,CPA [J. IF PROG REALTIME.
579= ...XIT
57=W ... UP
57#G ...RTIME
57B6 ... FCJOB 2,,,CPA
57CQ ... LDN 0 1 [FIND JOB BLOCK
57FB ... SBS 0 AEXCO(2)
57H2 ... BRN XIT [DECREMENT CT. OF REALTIME PERIS
57JM ...[IDENTIFIER HAS BEEN FOUND TO BE INOP
57K# ...[ ROUTINE TO CALL SETIDENT FOR INOP. IDENTIFIER
57K^ ...[ACCUMULATORS REQUIRED ON EXIT X2,X3,X5,X6
57LC ...TACT SBX 6 2 [SAVE X2 IN X7
57LT ... LDX 2 FX2
57M? ... SBN 3 A1
57MY ... IPBNULL 3 [NULLIFY ADEV'S - CONDCB LINK
57NK ... LDX 0 3
57P= ... SBX 0 ACOMMUNE4(2)
57PX ... STO 0 ACOMMUNE5(2) [DISPLACEMENT TO CONDCB
57QJ ... SETIDENT 3 [RE-INITIALISE IDENTIFIER
57RW ... LDX 7 6
57SH ... CALL 6 SUCS1
57T8 ... LDX 6 7
57TT ... LDX 7 5
57WG ... CALL 5 RHRC
57X7 ... LDX 5 7
57XS ... LDX 3 ACOMMUNE4(2)
57YF ... ADX 3 ACOMMUNE5(2)
57^6 ... [DISPLACEMENT DOWN BLOCK
57^R ... ADN 3 A1
57^Y ... MHUNTW 1,IDF,CONCEP
5825 ... LDN 2 A1(1)
582= ... ADX 6 2
582Y ... BRN TDSU [ENSURE ENTRY REMOVED FROM IDF CONCEP
583L ...X2CDCIPB [ENTRY FOR SETIDENT MACRO
58H= ... LDX 5 ACOMMUNE8(2) [AMOP
592W ... LDX 6 ACOMMUNE9(2) [IDENT NO.
59GG ... GETACT AMSCAN,IPBTYPE
5=26 ... LDX 2 BPTR(2) [POINT TO AMSCAN
5=FQ ... LINKSET 2,PAIRC3(1) [LINK TO K3CDCIPB
5=^B ... STO 5 ACC5(2) [STORE AMOP ADDR
5?F2 ... STO 6 ACC6(2) [AND IDENT NUMBER
5?YL ... FPUT
5#D= ... UP
5#XW ...X3CDCIPB
5*2F ... FSHCODE B,SNOTINA1
5*54 ...(
5*7M ... FSHACTPR
5*== ...SNOTINA1
5*#T ...)
5*B7 ... STOZ AWORK1(2) [CLEAR MARKER WD.
5*CG ... LDN 7 1 [SHOW WE HAVE NOT CRASHCLOSED
5*M# ...RTVWT
5*X6 ... HUNT2J 3,AMXOR,ADEVS,5,X3NA
5BBQ ... LDX 4 6 [IDENT NO.
5BWB ...
5CB2 ... SBX 4 A1+FOURTHWD(3) [SUBTRACT LOWEST NUMBER
5CTL ... SLL 4 2 [DISP OF ENTRY IN ADEVS
5D*= ... ADX 3 4 [ADDRESS OF ENTRY
5DSW ... LDX 0 A1+BPTR(3)
5F#G ... BNZ 0 X3NA [J IF ALREADY RINGED
5FS6 ... LDCT 0 #160
5G?Q ... ANDX 0 A1+FOURTHWD(3)
5GRB ... BNZ 0 X3NA [J IF MOP OFF,OR REINITIALIS
5H?2 ... LDX 0 BIT10
5HQL ... ANDX 0 A1+FOURTHWD(3)
5J== ... BZE 0 X3CL [J IF READY TO REINITIALISE
5JB7 ... LDCT 0 #200
5JG4 ... ANDX 0 A1+FOURTHWD(3)
5JK^ ... BNZ 0 X3AHD [J IF B10 SET WHEN ATTACHED
5JPW ...X3WT COOR3 #62 [WAIT 4 SECS
5K9G ... BRN RTVWT
5KK9 ...X3CL
5KML ... LDX 0 AWORK1(2) [TEST IF DEALING WITH UNAV
5KQ3 ... BNG 0 X3UNAV
5KSF ... LDX 0 A1+FOURTHWD(3)
5L3P ... BNG 0 X3UNAV [J. IF UNAVAILABLE BIT SET
5L=^ ...X3CLA
5LG9 ... LDX 0 BIT9
5LPF ... ANDX 0 A1+FOURTHWD(3)
5LYP ... BNZ 0 X3ZE [J. IF CLOSED
5M82 ... BZE 7 X3WT [J IF ALREADY SENT CRASH CLOSE
5MML ... LDN 0 #127
5N7= ... STO 0 ACOMMUNE1(2)
5NLW ...X3CC CCOUT 6,5 [SEND CRASH CLOSE
5P6G ... LDN 7 0 [AND RESET MARKER TO SHOW WE HAVE
5PL6 ... BRN X3WT
5Q5Q ...X3ZE LDCT 0 1
5QKB ... ORS 0 A1+FOURTHWD(3)
5R52 ... ERS 0 A1+FOURTHWD(3) [UNSET B8
5RJL ... ACROSS IPBSCAN,5 [GO TO REINITIALISE
5RLQ ...X3NA
5RNW ... FSHCODE B,SNOTINA2
5RR2 ...(
5RT6 ... FSHKILL
5RX= ...SNOTINA2
5R^B ...)
5S3G ... SUICIDE
5S5M ...X3UNAV [IDENTIFIER UNAVAILABLE
5S6* ... BZE 7 X3CLA
5S74 ... LDX 0 BIT9
5S8F ... ANDX 0 A1+FOURTHWD(3)
5S9W ... BZE 0 X3OP [J. IF NOT CLOSED
5S=5 ... BRN X3ZE
5S=* ... LDX 0 AWORK1(2) [TEST IF OPEN ALREADY SENT
5S=S ... BNG 0 X3WT [J. TO WAIT
5S?? ... LDN 0 #120
5S#N ... STO 0 ACOMMUNE1(2)
5SB5 ... CCOUT 6,5 [SEND OPEN IDENTIFIER
5SBD ... LDX 0 GSIGN
5SBR ... STO 0 AWORK1(2) [MARK WD TO SHOW OPENING UNAV IDENT
5SC6 ... BRN X3WT [J TO WAIT FOR OPEN
5SCG ...X3OP LDN 0 #227 [2-WORD CRASH CLOSE AUTO-ANSWER
5SDX ... STO 0 ACOMMUNE1(2)
5SFK ... STOZ AWORK1(2) [CLEAR MARKER WD CLOSING NOW
5SG# ... BRN X3CC
5SHW ... MENDAREA 50,K100CDCIPB
5SJK ...X3AHD [B10 SET WHEN AHED-ONLINE BROKEN..
5SK# ...[ ...IN ON
5SL3 ... LDX 0 BIT10
5SLQ ... ERS 0 A1+FOURTHWD(3) [CLEAR BIT10
5SMF ... LDX 2 5
5SN8 ... WHICHCON (GEOERR),NAHNOW,,6 [SEE IF STILL AHED AND WHERE TO
5SNX ... LDX 7 6
5SPL ... SMO 5
5SQ* ... LDX 6 CPPTR [SET UP ACS FOR K4AHB
5SR4 ... ACROSS ATTACHB,4 [GO TO COMPLETE ATTACHMENT
5SRR ...NAHNOW [NO LONGER ATTACHED
5SSG ... HUNT2J 3,AMXOR,ADEVS,5,X3NA
5ST9 ... LDX 4 6
5STY ... SBX 4 A1+FOURTHWD(3)
5SWM ... SLL 4 2
5SXB ... ADX 3 4 [FIND CORRECT ADEVS ENTRY
5SY5 ... SMO FX1
5SYS ... LDX 0 ZCLBT
5S^H ... ANDS 0 A1+FOURTHWD(3) [CLEAR ATTACHMENT MARKERS
5T2= ... BRN X3WT [CONTINUE REINITIALISATION
5T3G ...#END
^^^^ ...54675744001700000000