{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: CHARGESC867)}}
====== CHARGESC867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:ADDRESS|ADDRESS]], [[george:macro:ANYRCTPS|ANYRCTPS]], [[george:macro:BC|BC]], [[george:macro:BS|BS]], [[george:macro:BSON|BSON]], [[george:macro:BXE|BXE]], [[george:macro:BXGE|BXGE]], [[george:macro:BXL|BXL]], [[george:macro:BXU|BXU]], [[george:macro:COBJUNUSE|COBJUNUSE]], [[george:macro:COBJUSE|COBJUSE]], [[george:macro:COOR1Y|COOR1Y]], [[george:macro:COOR2|COOR2]], [[george:macro:FCAJO|FCAJO]], [[george:macro:FINDJOBQ|FINDJOBQ]], [[george:macro:FINDPEREC|FINDPEREC]], [[george:macro:FINDPUC|FINDPUC]], [[george:macro:FINDTP|FINDTP]], [[george:macro:FLIPS|FLIPS]], [[george:macro:FON|FON]], [[george:macro:FON1|FON1]], [[george:macro:FPCAJO|FPCAJO]], [[george:macro:FPUT|FPUT]], [[george:macro:FREZKICK|FREZKICK]], [[george:macro:GETACTOP|GETACTOP]], [[george:macro:GETGMILL|GETGMILL]], [[george:macro:HLSAV|HLSAV]], [[george:macro:HUNTMISB|HUNTMISB]], [[george:macro:ICT|ICT]], [[george:macro:ISSTOP|ISSTOP]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:JENV|JENV]], [[george:macro:JENVNOT|JENVNOT]], [[george:macro:JMBAC|JMBAC]], [[george:macro:LA|LA]], [[george:macro:LINK|LINK]], [[george:macro:LINKSET|LINKSET]], [[george:macro:LTYPE|LTYPE]], [[george:macro:MBSXD|MBSXD]], [[george:macro:MELRERING|MELRERING]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:ON|ON]], [[george:macro:PAIR|PAIR]], [[george:macro:PCATEST|PCATEST]], [[george:macro:REDUCELL|REDUCELL]], [[george:macro:RINGTP|RINGTP]], [[george:macro:SCHEDULE|SCHEDULE]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETBIT|SETBIT]], [[george:macro:STOPIT|STOPIT]], [[george:macro:TEST|TEST]], [[george:macro:TESTTP|TESTTP]], [[george:macro:TICKLE|TICKLE]], [[george:macro:TIMESET|TIMESET]], [[george:macro:TRACE|TRACE]], [[george:macro:TRUEDORM|TRUEDORM]]
22FL ...#SEG CHARGESC841 [OWEN N JOHN :CENT
22KH ...[
22PD ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1983
22T* ...[
22^= #OPT K0CHARGESC=0
23DW #LIS K0CHARGESC>K0ALLGEO>K0LLS
23YG 8HCHARGESC
24D6 #
24XQ # ENTRY POINT FROM BLANKET ACTIVITY TO DETERMINE WHETHER A SPRING
25CB # CLEAN,ENGAGE BUTTON OR CONSOLE INTERRUPT HAS OCCURRED AND TO TAKE
25X2 # THE APPROPRIATE ACTION
26BL #
26W= SEGENTRY K1CHARGESC,XX1C
27*W SEGENTRY K2CHARGESC,XX2C
27TG SEGENTRY K9CHARGESC,XX9C
28*6 SEGENTRY K7CHARGESC,XX7C
28SQ SEGENTRY K13CHARGESC,MRED1
28X* ...#UNS AV7900S
28^Y ...(
294H ... SEGENTRY K14CHARGESC,TIMOUTRETUR [RETURN FROM K4VIPBPERI WHICH
2976 ... [TIMES OUT VIRTUAL 7900 TRANSFERS
299P ...)
29#B SEGENTRY K90CHARGESC
29S2 XX1C
2=?L NULL
2=*4 ...#UNS ENHOPER
2=BG ...(
2=CY ... BSON IGNORENGAGE,TEMS [IF ENGMESS(X) IN PROGRESS ..
2=FB ... [THEN LEAVE EBA FOR IT TO USE
2=GS ...)
2=J= ...#UNS ENHOPER
2=KN ...#SKI [TESTED AT 'NOTOC'
2=M* ...(
2=R= BSON EMSBIT,TEMS
2?34 ...)
2?=W LDX 5 EBAL
2?QG SLL 5 4
2#=6 LDX 3 EBAL
2#PQ SLL 3 3
2*9B ADX 5 3
2*P2 SBN 5 24 [SO THAT [X5]=([EBAL]-1)*24
2B8L LDX 3 EBAL
2BN= TEST LDX 4 EBA-1(3) [LOAD WORD IN E.B.A
2C7W BNZ 4 SFOUND [JUMP IF ANY BIT SET
2CMG NOCO1 SBN 5 24
2D76 BCT 3 TEST [ROUND AGAIN
2DLQ #
2F6B # IF NO ENGAGE BUTTON BIT FOUND,TEST FOR SPRING CLEAN
2FL2 #
2FM3 ...#SKI JSKI34 [IMPROVED ERROR LOGGING
2FN4 ...(
2FP5 ...TEMS SMO ELPIA
2FQ6 ... LDX 3 ELCPT [LOAD CPPTR WORD OF PIA
2FR7 ... BZE 3 TSEAN [JUMP IF NO ERROR LOGGED
2FSW ... JENVNOT TEMSA,DME
2FWK ... LDX 0 BELOGACT
2FY# ... BZE 0 TSEAN [DONT ATTEMPT DME ERROR LOGGING UNTIL
2G23 ... [ACTIVITY FOR IT IS SET UP
2G3Q ...TEMSA
2G5F ... ACROSS PERFLOGS,3
2GCR ...TSEAN NGN 5 24
2GDS ...)
2GFT ...#SKI JSKI34<1$1
2GGW ...TEMS NGN 5 24
2GHX ...)
2GH^ ...#UNS ADUALDME
2GJ3 ...(
2GJ5 ...# CHECK APROCNO FOR ANY PROCESSOR FAILS OR RECOVERIES
2GJ7 ...# AND ARRANGE FOR PERFAIL,4 TO OUTPUT MESSAGES
2GJ9 ...#
2GJ? ... MBSXD 0,BPROCFAIL,BPROCREC
2GJ* ... ANDX 0 APROCNO
2GJC ... BZE 0 SPRCLN [BR IF NO PROCESSOR FAILS OR RECOVERI
2GJF ... GETACTOP SPRCLN,IPCA,IPCOP [OPTIONALLY SETUP ACT. BLOCK BR TO
2GJH ... [SPRCLN IF NOT SETUP (BLANKET CANNOT
2GJK ... [WAIT FOR CORE
2GJM ... LDX 2 BPTR(2)
2GJP ... LINKSET 2,OCPFAILINK(1)
2GJR ... FPUT
2GJT ...SPRCLN
2GJX ...)
2GK= LDX 3 JTIME [LOAD NO. OF SPRING CLEAN INTERRUPTS
2H4W SBX 3 CLEANCT [SUBTRACT REMEMBERED COUNT
2HJG BNZ 3 XX9C
2J46 STO 5 K5 [SET K5 NEGATIVE AND COORDINATE
2JHQ COOR1Y
2K3B BRN XX1C
2K7? ...#
2K?8 ...# ENGAGE BUTTON BIT FOUND SET
2KC5 ...#
2KH2 SFOUND
2L2L LDN 1 0
2LG= NEXT LDCT 6 256
2L^W SRL 6 0(1)
2MFG BZE 6 NOCO1 [NECESSARY IN CASE WE SKIPPED A BIT
2M^6 ANDX 6 EBA-1(3)
2NDQ BNZ 6 THIS
2NYB NOCO2 BUX 1 NEXT
2PD2 THIS STO 1 ACOMMUNE7(2) [DUMP MODS. IN CASE IT IS A FREE
2PXL STO 3 ACOMMUNE8(2) [PERIPHERAL FOR WHICH AN ACTIVITY
2QC= STO 5 ACOMMUNE9(2) [CANNOT BE SET UP(I.E. NO CORE)
2QWW ADX 5 1 [X5 NOW GEOG. NO. OF PERIPHERAL
2RBG ERS 6 EBA-1(3) [CLEAR MARKER BIT
2RNX ... FINDPEREC 3,APINT,5,,,,PZERO [GET POINTER TO DEVICE LIST
2RQ4 ... BPZ 3 PZERO
2RR9 ... JENV STAR,CMESTAR
2RSB ... '142 0 0
2RTH ... BRN PZERO
2RWN ...STAR
2RXT ...
2R^2 ... '171 0 14
2S27 ...
2S3# ...PZERO
2S*Q ...#SKI K6CHARGESC>99-99
2SFM ...(
2SKJ ...#UNS ENHOPER
2SPF ... BSON EMSBIT,NEMSTRACE [DON'T TRACE IN EMS
2STB TRACE 3,!EBUTTON
2S^? ...#UNS ENHOPER
2T58 ...NEMSTRACE
2T95 ...)
2T*2 LTYPE 3,6 [GET PERIPHERAL TYPE
2TSL ERN 6 #77
2W#= BNZ 6 NOTOC [JUMP IF NOT O/C
2WRW FON #50
2X?G ON CONSW
2XR6 BRN XX1C
2Y=Q NOTOC
2Y=X ...#
2Y?4 ...# FOR THE SHARED FILESTORE ENHANCEMENT WE MUST RECOGNISE ENGAGE
2Y?9 ...# BUTTONS ON THE IPB (DEVICE TYPE 28) DURING EMS ON THE 'B' MACHINE
2Y?B ...#
2Y?H ...# NB THIS MODIFICATION RELIES ON THE INCLUSION OF THE DME 'OPER'
2Y?N ...# ENHANCEMENT (COMPILED WHEN 'ENHOPER' IS SET)
2Y?T ...#
2Y#2 ...#
2Y*C ...)
2Y*W ...#UNS ENHOPER
2YF2 ...(
2YFJ ... BSON EMSBIT,XX2D [RE-INSERT BIT IF EMS
2YM= ...)
2YQB ACROSS ENGAGE,1 [DEAL WITH ENGAGE BUTTON
2YQQ ...#
2YR6 ...XX2D
2^=2 #
2^PL # ACTIVITY BLOCK CANNOT BE SET UP FOR FREE DEVICE AT THE MOMENT
329= XX2C
32NW LDX 1 ACOMMUNE7(2) [RESTORE MODS
338G LDX 3 ACOMMUNE8(2)
33N6 LDX 5 ACOMMUNE9(2)
347Q LDCT 6 256
34MB SRL 6 0(1)
3572 ORS 6 EBA-1(3) [RE-INSERT ENGAGE BUTTON BIT
35LL BRN NOCO2 [CHECK REMAINING DEVICES
366= #
36KW #
375G # THIS SEGMENT IS MAINLY CONCERNED WITH A NUMBER OF SPRING CLE
37K6 # TASKS AND IS ENTERED WHEN GEORGE RECIEVES A PERIODIC INTERRUPT FRO
384Q # EXECUTIVE. ALSO CONTAINED IN THIS SEGMENT ARE THE ROUTINES FOR CHA
38JB # TIME TO JOBS.
3942 #
39HL #
3=3= P4 PAIR EVENTS,4 [FOR GEORGE INITIATED EVENT
3?G6 TD5 PAIR EVENTS,3 [MESSAGE OUTPUT AND VARIOUS UPDATES
3?JP ...#UNS ADUALDME
3?M# ...(
3?PX ...OCPFAILINK
3?SG ... LINK PERFLOGS,2
3?X5 ...)
3?^Q WTIME +FONINTP*1000 [TIME BETWEEN WAKE UPS(MILLISECS)
3#^2 TCJC +CJMOD
3*DL SCADJ +8000000
3BCW PK9 +K9
3BXG MIDNIGHT 1000*60*60*2/K9*12 [NO. OF K9'S IN 1 DAY
3CWQ TJDECAY +FDECAY
3DBB XINDIC #40004000
3DW2 TON +100
3F*L THOU +1000
3FT= XINCDT #10001 [ADTO INCREMENTOR
3FWS ...[ MASK FOR ASTOP BITS ASTOPTIM,ASTOPJOB,ASTOPBIN &
3FYB ...[ B15-23 (PERIPHERAL FAILURE)
3F^Y ...[
3G3G ...MASTOP1 #30004777
3G54 ...[
3G6L ...[ MASK FOR ASTOP BITS ASTOPEXEC,ASTOPTP,ASTOPPUC &
3G88 ...[ UNUSED BITS(B4 & B6-11)
3G9Q ...[
3G?# ...MASTOP2 #42773000
3G?K ...TOPAMRHP #40007777 [MAX AMR FOR HI PRI MEMBERS
3G?N ...TOPAMR #00007777 [MAX AMR FOR ORD MEMBERS
3G?W ...[
3G?^ ...[
3G#4 ...[ LOCAL IDENTIFIERS FOR WORK SPACE IN BAT
3G#7 ...[
3G#= ...[
3G#D ...#DEF MILLAVAIL=ACOMMUNE1 [AMOUNT OF MILL TIME AVAILABLE TO THI
3G#W [
3GSG [ EXCEPTION CASES FROM LATER ON
3H#6 [
3HRQ PHAIL [SET REMEMBRANCE
3J?B BS ,CDTGAFAIL
3JR2 BRN XEND
3K=L NOMIN
3KQ= JBS MIDN,,CDTMIDN [JIF WE MISSED MIDNIGHT
3L9W LDX 4 AWORK1(2)
3LPG BNZ 4 TRYAGAIN
3M96 JBS TRYAGAIN,,CDTGAFAIL [J IF GETACT FAILED LAST TIME
3MNQ BRN XEND
3N8B #
3NN2 #
3P7L # SUBROUTINES USED IN TIME CHARCING
3PM= #
3Q6W # FIRSTLY : CONVERT COUNT OF CHAP CHANGES IN X6,INCLUDING REMAINDER
3QLG # FROM LAST TIME IN X7
3R66 # STORE NEW REMAINDER IN ATUSE OF CPA
3RKQ # LINK X4,U3->JOBBLOCK,X2->CPA,INCREMENTS X5 (= TOTAL TIME FOR JOB)
3S5B XCHARGE
3SK2 FCAJO 2,3
3T4L XCHARGE1
3TJ= LDX 7 ATUSE(2)
3W3W MPA 6 CHAPTIME
3WHG DVD 6 BEATTIME [CONVERT TIME
3X36 ADX 5 7 [INCREMENT TOTAL USED
3XGQ STO 6 ATUSE(2) [STORE REMAINDER
3Y2B EXIT 4 0
5#F2 ...[ SUBROUTINE TO DECANT PROGRAM TIMERS, CONVERT TO MILLISECONDS,ACCUMULAT
5#F8 ...[ AND UPDATE TIME USED FOR EACH MEMBER.
5#FB ...[ X1 -> PCA, LINK X7 (MOVED), [ X1 -> PCA, LINK X7 (MOVED), X4,X5,X6,X7
5#FJ ...TIMERS
5#FQ ... STO 7 GEN3 [REMEMBER LINK
5#FY ... [STARTING AT LAST MEMBER
5#G6 ... LDN 7 ATM4-ATM1 [-> MEL RELATIVE TO ATM1
5#G# ... LDN 6 4 [NUMBER OF MEMBER
5#GG ...TM1 SMO 7
5#GN ... LDXC 5 ASU1(1)
5#GW ... BCS TM2 [NO MEMBER
5#H4 ... SMO 7
5#H= ... LDX 5 ATM1(1) [TIME USED
5#HD ... DVS 4 BEATTIME [CONVERT TO MILLISECONDS
5#HL ... SMO 7
5#HS ... STO 4 ATM1(1) [LEAVE REMAINDER
5#J2 ... SMO 6
5#J8 ... ADS 5 ATU1-1(1) [TIME USED
5#JB ... ADS 5 GEN1 [ACCUMULATE TIME USED
5#JJ ...TM2 SBN 7 ATM2-ATM1 [UPDATE TO NEXT MEL
5#JQ ... BCT 6 TM1 [NEXT MEMBER
5#JY ... BRN (GEN3)
5#K6 ...[
5#K# ...[ SUBROUTINE TO CALCULATE NEW RATINGS FOR ALL MEMBERS IN PCA
5#KG ...[X1 -> PCA, LINK X7 (MOVED), X0,X4,X5,X6,X7 DESTROYED, X2=FX2
5#KN ...[RATING:=K*RATING+(1-K)TIME USED/TIME AVAILABLE
5#KW ...[FORMATS - K AND RATING ARE FRACTIONS E.G. 1/2=#20000000
5#L4 ...[ - TIMES ARE SINGLE LENGTH INTEGERS
5#L= ...[RATING FROM THIS CALCULATION IS TRANSFORMED TO FORM USED IN AMR BY :-
5#LD ...[ A.MULT FRACTION BY 64 -> INTEGER FROM 0 TO 63
5#LL ...[ B. SUB FROM 63 -> INTEGER FROM 63 TO 0
5#LS ...[I.E. SMALL MILL USE GIVES LARGE NUMBER AND POSITION NEAR FRONT OF RING.
5#M2 ...[
5#M5 ... SEGENTRY K50CHARGESC [ FOR CPIFORMS RESTORE TIME MACRO
5#M8 ...RATINGS
5#MB ... STO 7 GEN3 [LINK
5#MJ ... LDXC 0 ATU1(1) [J IF NOT PLUGGED IN DURING
5#MQ ... BCC (GEN3) [ LAST 1/5 SEC
5#MY ... JBS XPLUG,3,JBPLUG [J IF STILL PLUGGED IN
5#N6 ... LDX 0 BITS22LS
5#N# ... ANDS 0 ATU1(1) [CLEAR BEEN PLUGGED IN MARKER
5#NG ...XPLUG
5#NN ... LDX 2 1 [SET X2->PCA TO ACCESS ASU WORDS
5#NW ... LDN 7 4 [4 MEMBERS
5#P4 ... LDCT 0 #600 [-> CHAR 3
5#P= ... ORX 1 0 [CHAR PTR TO MILL RATING
5#PF ...RAT1
5#PL ... LDXC 0 ASU1(2) [J IF MEMBER DOESN'T EXIST
5#PS ... BCS RAT4
5#Q2 ... LDCH 6 AMR1(1) [OLD MILL RATING
5#Q8 ... LDN 4 63 [CONVERT TO A FRACTION APPROXIMATING
5#QB ... SBX 4 6 [PROPORTION OF MILL
5#QJ ... SRC 4 7 [MEMBER CAN USE
5#QQ ... MPY 4 AMILLDECAY1 [K*RATING AS DOUBLE LENGTH FRACTION
5#QY ... [MOST SIG PART IN X4 USED ONLY
5#R6 ... LDXC 5 ATU1(1) [TIME USED
5#R# ... ERS 5 ATU1(1) [ATU1 SET IF ALREADY SET
5#RG ... MPY 5 AMILLDECAY2 [(1-K)TIME USED AS DOUBLE LENGTH MIXE
5#RN ... [X5 INTEGRAL PART, X6 FRACTIONAL
5#RW ... DVR 5 AMILLAVAIL [QUOTIENT IN X6 IS A FRACTION
5#S4 ... BVCR RAT2
5#S= ... LDN 6 0 [MIN POSS RATING
5#SD ... BRN RAT3
5#SL ...RAT2
5#SS ... ADX 4 6
5#T2 ...[CONVERT TO INTEGER < 63 - SEE SR ANNOTATION
5#T8 ... SLC 4 7 [CONVERT TO ONE CHAR
5#TB ... ANDN 4 #77
5#TJ ... LDN 6 63
5#TQ ... SBX 6 4
5#TY ...RAT3 DCH 6 AMR1(1) [NEW RATING
5#W6 ...RAT4 ADN 1 1
5#W# ... ADN 2 AFW2-AFW1
5#WG ... BCT 7 RAT1 [NEXT MEMBER
5#WN ... SBN 1 4 [X1 -> PCA
5#WW ... LDX 2 FX2
5#X4 ... BRN (GEN3)
5#X? ...#UNS AV7900S
5#X# ...(
5#X* ...#
5#XB ...# SUBROUTINE TO TEST FOR THE EXISTENCE OF VIRTUAL 7900'S AND IF TRUE
5#XC ...# TO CALL ON K4VIPBPERI TO PERFORM THE TIMING OUT OF VIRTUAL 7900
5#XD ...# WMC TRANSFERS WHICH HAVE BEEN STORED FOR 3 FONINTP SECONDS.
5#XF ...# ON EXIT X2 IS -VE OR = FX2
5#XG ...# LINK IN X7
5#XH ...TIMOUTV7900
5#XJ ... HUNTMISB 2,APERI,AV7900
5#XK ... BNG 2 (7) [NO VIRTUAL 7900 DEVICE LIST PRESENT
5#XL ... ACROSS VIPBPERI,4 [>>>>
5#XM ...# RETURN IS TO LABEL TIMOUTRETUR
5#XN ...)
5#XW [
5#YJ ...[
5#^= ...[ SUBROUTINE TO TEST TYPE OF PCA & IF TP TO POINT TO PUC.
5#^Y ...[
5*2L ...TESTPCA
5*3# ... PCATEST 1,NORM,,PUC
5*42 ... FINDPUC 1,1
5*4N ...PUC EXIT 7 1
5*5B ...NORM EXIT 7 0
5*64 ...[
5*6Q ...[
5*7D ...[ SUBROUTINE TO LOCATE TP, REMEMBERING IF PUC IS CURRENT ACTIVITY
5*86 ...[
5*8S ...TPLOC
5*9G ... FPCAJO 2,3
5*=8 ... TESTTP 2,TPLOC1
5*=W ... LDX 5 2 [X5 = PUC PCA ADDRESS
5*?J ... FINDTP 2,2
5*#= ...TPLOC1
5*#Y ... LDX 1 ADATUM(2) [TP DATUM
5**L ... EXIT 6 0
5*B# ...[
5*CG [ RCTP SPASMODIC INTERRUPTS
5*X6 [
5BBQ RCTP LDN 4 0
5BWB SBS 3 ASPASMODIC
5CB2 NGX 0 ASPASMODIC
5CTL BNG 0 RCTP1 [JUMP UNLESS TIME FOR SPASMODIC INTER
5D*= LDX 0 INTERRUPT
5DSW STO 0 ASPASMODIC
5F#G LDN 4 1
5FS6 RCTP1 LDX 7 3
5G?Q LDN 3 BJOBQ
5GRB RCTP2 LDX 3 FPTR(3)
5H?2 TXU 3 CXJO
5HQL BCC RCTP10 [JUMP IF END OF JOB QUEUE
5J== JBC RCTP2,3,JBRCTP [J IF NOT RCTP
5JPW RCTP3 LDN 5 0
5K9G BZE 4 RCTP5 [JUMP IF NO SPASMODIC INTERRUPT
5KP6 JBC RCTP2,3,JBSI [J IF NOT SWAPPED IN
5L8Q ... CALL 6 TPLOC [LOCATE TP
5NLW LDCT 0 #10
5P6G ORS 0 31(1) [SET BIT 5 OF TP WORD 31
5PL6 RCTP5 JBC RCTP2,3,JBPLUG [J IF NOT PLUGGED IN
5Q5Q BNZ 4 RCTP7 [JUMP IF WE HAVE JUST SET TP WORD 31
5QKB ... CALL 6 TPLOC [LOCATE TP
5T3G LDX 0 31(1)
5TH6 BZE 0 RCTP2 [JUMP IF NO EVENT TO DEAL WITH
5W2Q RCTP7 BNZ 5 RCTP8 [JUMP IF PUC IS CURRENT ACTIVITY
5WGB LDX 0 ASU1(2)
5X22 BZE 0 STP
5XFL LDCT 0 #40
5X^= ANDX 0 ASU1(2)
5YDW BNZ 0 SMP
5YYG STP SETBIT 16,ARM1(2) [SET 'P' BIT
5^D6 BRN RCTP2
5^XQ SMP ERS 0 ASU1(2) [TICKLE TP MEMBER 0
62CB BRN RCTP2
62X2 RCTP8 LDX 6 1 [PRESERVE TP DATUM
63BL LDX 1 5 [RESTORE PUC PCA ADDR
63W= LDX 0 ASTOP(1)
6445 ... BNG 0 RCTP2 [JUMP IF PUC DEALING WITH AN EVENT
649Y ...[
64CR ...[ THE FOLLOWING CORRECTS B2996 WHICH STOPS CHARGESC SETTING WRONG
64KL ...[ BIT IN PUC - ASTOP AND THUS SETTING ALL OF B0-15
64RF ...[ 16TH JUNE 1975 :CENT
64^# ...[
6577 ... BS 1,ASTOPTP
65*6 ISSTOP 1,RCTP9
65SQ LDX 0 ASTOP(1)
66#B BNG 0 RCTP9 [JUMP IF PUC DEALING WITH EVENT
66S2 LDX 0 ANM(1)
67?L ANDN 0 3
67R= SLL 0 6
68=W SMO 6
68QG ORS 0 31 [SET TP WORD 31 = CURRENT PUC MEM
69=6 LDCT 0 #600
69PQ ORX 1 0
6=9B LDCH 6 ALMT(1) [PICK UP MODES OF CURRENT PUC MEMBER
6=P2 SRC 6 8
6?3C ... SMO 5
6?*S ... LDX 1 ADATUM
6?N= LDX 0 GMSK1
6#7W ANDS 0 9(1)
6#MG ORS 6 9(1) [SET PUC MODES IN PUC WORD 9
6*76 LDX 1 5
6*LQ LDX 0 ASTOP(1)
6B6B ANDX 0 GMSK2
6BL2 ADN 0 #1000
6C5L ERS 0 ASTOP(1) [SET B14 OF PUC STOP WORD
6CK= SBN 0 #2000
6D4W ADS 0 ASTOP(2) [TRANSFER PUC STOP BITS TO TP
6DJG RINGTP 5
6F46 LDX 1 5
6FHQ ...RCTP9 BC 1,ASTOPTP
6G3B BRN RCTP2
6GH2 RCTP10
6H2L LDX 3 7 [RESTORE COUNT OF K9S
6HG= LDX 1 FX1
6H^W LDX 2 FX2
6JFG BRN RCTP11
6J^6 [
6KDQ [ YER ACTUAL SPRING CLEAN
6KYB [ THAT IS : UPDATE TIMERS
6LD2 [ CHECK IF TIME FOR OUTPUTS
6LXL [ AND COREJAMS ETC
6MC= [ AND SCHEDULE
6MWW [
6NBG XX9C [ENTRY FROM SPRING CLEAN
6NW6 ANYRCTPS RCTP
6P*Q RCTP11
6PTB ADS 3 CLEANCT
6Q*2 ADS 3 APROCTIME [STEP P.C. CLOCK
6QSL SBS 3 CJDELAYCNT1 [ADJUST DELAY COUNTS FOR CORE JAM
6R#= SBS 3 CJDELAYCNT2 [RECLAIMING ROUTINES ONE AND TWO
6RRW SBS 3 CJDELAYCNT3
6S3N ... SBS 3 AMRREORDER [TIMER FOR REORDER OF PROG. RING
6S?G REDUCELL 3
6SR6 LDX 1 FX1
6T5H ... BSON EMSBIT,NOCYCLE [ELSE NON-EXISTENT ASWINT FPUT BY SCH
6W=2 ADS 3 CYCLECORE
6WPL ...NOCYCLE
745G MPY 3 PK9(1) [TIME SINCE LAST ENTERED IN MILLISECS
74K6 SBS 4 FONINT [STEP DOWN FON INTERVAL
74Q# ...#UNS IMR
74XG ... STO 4 AMILLAVAIL [REMEMBER FOR CALCULATING MILL RATING
754Q
75JB LDN 4 0 [CLEAR MARKER WORD
7642 COBJUSE
76HL BXL 0 COBJQUOTA,NOCAN [J IF OQ NOT MET
773= JMBAC NOCAN,,ASWOQMISS,ASWREALBAD
77GW LDN 4 1 [B23 = > OK MESSAGE
782G NOCAN
78G6 STO 4 AWORK1(2)
78^Q TIMESET XX7C,MINUTE,NOMIN
799J ... BNG 7 NOMIN
79FB MIDN
79^2 BS ,CDTMIDN [MIDNIGHT MARK IN CASE GETACT FAILS
7=DL LDX 0 XINDIC(1)
7=Y= ORS 0 ADTO [SO TIME AND DATE AENT
7?CW ORN 0 #10 [DATE CHANGE
7?XG ORS 0 AWORK1(2) [MIDNIGHT SET MARKERS
7#C6 MINUTE
7#WQ LDX 0 XINCDT(1)
7*BB ADS 0 ADTO [INCREMENT TIME & DATE O/P COUNTERS
7*DK ...#UNS ENHOPER
7*GS ...(
7*K3 ... ON GNUTIME [SET 'REFRESH OPER TIME'
7*M= ... FON #50 [WAKE CONSOLE ACTIVITY
7*PF ... [(ONLY LOOKS AT SWITCH IN DME ELSE RE
7*RN ...)
7*W2 TRYAGAIN
7B*L GETACTOP PHAIL,ACTCDT
7BT= BC ,CDTMIDN [ALL CLEAR
7C#W BC ,CDTGAFAIL [CLEAR FAILED GETACT BIT
7CSG LDN 4 2
7D#6 ORS 4 AWORK1(2) [GNT UPDATE :B22
7DRQ LDX 0 ADTO
7F?B ANDN 0 #7777
7FR2 BXL 0 ATINT,NOTIM
7G=L ERS 0 ADTO
7GQ= LDN 4 #4000 [MARKER TIME O/P
7H9W ORS 4 AWORK1(2)
7HPG NOTIM LDX 0 ADTO
7J96 SRL 0 12
7JNQ BXL 0 ADINT,NODAT
7K8B SLL 0 12
7KN2 ERS 0 ADTO
7L7L LDX 4 GSIGN [MARKER DATE O/P
7LM= ORS 4 AWORK1(2)
7M6W NODAT LDN 0 1
7MLG ... LDX 5 APERCOUNT
7N66 ... BXL 5 IPROGREP,NOPRO
7PK2 LDN 4 4 [PERCOUNT MARKER
7Q4L ORS 4 AWORK1(2)
7QJ= STOZ APERCOUNT
7R3W NOPRO
7R?N ... ADS 0 APERCOUNT
7RHG LDX 4 AWORK1(2)
7S36 LDX 2 BPTR(2)
7SGQ LINKSET 2,TD5(1)
7T2B STO 4 ACC4(2)
7TG2 FPUT
7TPS ...XEND
7T^L ... BSON EMSBIT,T10 [OMIT TICKLING ETC. IF EMS
7W9D ... FREZKICK
7WF= COOR2 #41 [WAKE UP ANY ACTIVITY WAITING IN UNPL
7WYW [END OF ON-LINE PERI TRANSFER
7XDG [
7XY6 [
7YCQ [BASICALLY THIS WAKES UP PROGRAMS WHICH HAVE DONE A MODE #200
7YXB [PERI TO A CONCEPTUAL SCANNER. MODE #200 REQUESTS THE PROGRAM BE GIVEN A
7^C2 [& WOKEN UP @ REGULAR INTERVALS. SEGMENT COMMXC PROCESSES THE PERI & SET
7^WL [AMXOR/INTRPT BLOCK CONTAINING THE INFORMATION NECESSARY FOR CHARGESC TO
82B= [THE PROGRAM AS REQUIRED
82TW R5 HUNTMISB 3,AMXOR,INTRPT
83*G BNG 3 TICK6
83T6 LDX 6 INTENT(3)
84#Q TICK4 LDN 7 1
84SB LDN 5 INTRECLEN(3)
85#2 SBSC 7 INTNEXT(3)
85RL BCC TICK5
86?= FINDJOBQ 1,INTJOBNO(3),(GEOERR)
86QW FPCAJO 1,1
86WR ... PCATEST 1,NORM5,NORM5
872N ... FINDTP 1,1
876K ...NORM5
87=G ADDRESS 1,INTFLAG(3),1
87Q6 LDX 4 INTTIME(3)
889Q ADSC 4 INTNEXT(3)
88PB ORS 7 0(1)
88^8 ...
8992 ...[
89DS ...[ THE FOLLOWING CURES B3222 CONCERNING FACT THAT NEW
89NL ...[ CHARGESC USED TICKLE MACRO BUT NO JOBNUM !!
89YD ...[ DONE 11TH JULY 75 :CENT
8=8= ...[
8=D4 ... TICKLE INTJOBNO(3)
8=MW TICK5 LDX 3 5
8?7G BCT 6 TICK4
8?M6 LDX 1 FX1
8#6Q LDX 2 FX2
8#LB TICK6
8*62 [
8*KL [
8B5= #
8BJW # STEP BACK THE P.C. CLOCK IF NECESSARY
8C4G #
8CJ6 #
8D3Q # SET X6 = AMOUNT TO STEP BACK PC CLOCK AND ADJUST JCTLR
8DHB # OR ZERO IF NO STEPPING BACK REQUIRED
8F32 # USED BY NEXT SEARCH OF JOB QUEUE
8FGL #
8G2= LDX 0 SCADJ(1)
8GFW LDN 6 0
8G^G BXGE 0 APROCTIME,R1 [J IF NO A
8HF6 LDX 6 0
8HYQ SRL 6 1 [HALT TO BE SUBTRACTED
8JDB SBS 6 APROCTIME
8JY2 #
8KCL # EMPTY EXECUTIVE OBJ PROG TIMERS INTO JOB BLOCK
8KX= # THEN (FOR EACH JOB WITH A PLUGGED IN CORE IMAGE) CHECK ITS STOP WO
8LBW # SEE WHETHER IT IS NECESSARY TO ACTIVATE THE PCA TO DEAL WITH A PSE
8LWG # PROGRAM EVENT, I.E. ONE WHICH IS NOT THE RESULT OF OBEYED OBJECT P
8MB6 #
8MTQ R1
8N2Y ... STOZ AWORK2(2) [ FOR CPIFORMS RESTORE TIME MACRO
8N86 ... STOZ AWORK3(2) [ FOR CPIFORMS RESTORE TIME MACRO
8N*B STO 6 AWORK1(2)
8NT2 LDN 3 BJOBQ
8P#L T11 LDX 3 FPTR(3) [GET NEXT IN JOB Q
8PS= BXE 3 CXJO,T10 [TEST IF EQUALS BASE
8Q?W LDEX 4 JMISC(3)
8QRG BZE 4 T11 [J NO CORE IMAGE
8R?6 SMO FX2
8RQQ LDX 0 AWORK1
8S=B SBS 0 JCTLR(3)
8SQ2 HLSAV 3,SET,SAVING,JOBQ,T11
8T9L FCAJO 2,3 [X2 -> CPA
8TP= LDX 6 ACTCHCH(2)
8W8W STOZ ACTCHCH(2)
8WNG JBS PLUG,3,JBPLUG [J IF PLUGGED IN
8X86 LDN 5 0
8XMQ CALL 4 XCHARGE1
8Y7B LDN 4 0
8YM2 ADSC 5 HTIMEJ+1(3)
8^6L ADS 4 HTIMEJ(3)
9822 ... JBC RATE1,3,JBDORM
9827 ... LDX 0 JCTLR(3)
982# ... ADN 0 1000/K9*3
982F ... BXGE 0 APROCTIME,RATE1
982L ...#UNS ISTDP
982R ...#SKI
982Y ... BC 3,JBRUN [MRK NON RUNNABLE
9835 ...#UNS ISTDP
983= ... TRUEDORM 3 [MAKE TRUELY DORM.AS DORM.FOR > 3SECS
983C ... BRN T11
983J ...[ CALCULATE MILL RATING
983P ...RATE1 FPCAJO 1,3
983W ... CALL 7 TESTPCA [CHECK RCTP
9843 ... BRN NORM2
9848 ...PUC2 CALL 7 RATINGS [CALCULATE MILL RATINGS FOR PUC
984* ... FINDTP 1,1 [SET UP FOR TP
984G ...NORM2 CALL 7 RATINGS [CALCULATE MILL RATINGS
984M ... LDX 1 FX1
984S ... BRN T11
984^ ...PLUG FPCAJO 1,3
9853 ... STO 1 GEN4 [REMEMBER CURRENT PCA
9856 ... STO 6 GEN2 [REMEMBER CHCHS
985? ...[ EMPTY PROGRAM MILL TIMERS AND CALCULATE MILL RATING
985D ... STOZ GEN1 [TO ACCUMULATE TIME YSED
985K ... CALL 7 TESTPCA [CHECK PCTP
985Q ... BRN NORM3
985X ...PUC3 CALL 7 TIMERS [DECANT FOR PUC PCA
9864 ... CALL 7 RATINGS [CALCULATE MILL RATINGS FOR PUC
9869 ... FINDTP 1,1 [SET UP FOR TP PCA
986B ...NORM3 CALL 7 TIMERS [DECANT TIMERS
986H ... CALL 7 RATINGS [CALCULATE MILL RATINGS
986N ... LDX 5 GEN1 [TOTAL MILL USED
986T ... LDN 4 0
9872 ... ADSC 5 GPROGTIME+1 [UPDATE VARIOUS TIMERS
9877 ... ADS 4 GPROGTIME
987# ... ADSC 5 HCLOCKTIME+1(3)
987F ... ADS 4 HCLOCKTIME(3)
987L ...[
987R ...[ CHARGE TIME SPENT IN PCA AND OLPAS
987Y ...[
988= ... LDX 6 GEN2
988C ... CALL 7 TESTPCA [CHECK RCTP
988J ... BRN NORM1
988P ...PUC1 ADX 6 ACTCHCH(1)
988W ... STOZ ACTCHCH(1)
9893 ... FINDTP 1,1
9898 ...NORM1 ADX 6 ACTCHCH(1)
989* ... STOZ ACTCHCH(1)
989G ... LDX 1 APRB(1) [X1 -> PRB
989M ...TOUR LDXC 0 0(1)
989S ... BCS PRBEND [J IF END
989^ ... LDXC 2 1(1)
98=6 ... BCC ROUND [J IF ONLINE
98=? ... ADX 6 ACTCHCH-CHAINADD(2)
98=D ... STOZ ACTCHCH-CHAINADD(2)
98=K ...ROUND BDX 1 TOUR [BACK AGAIN
98=Q ...PRBEND
98=X ... CALL 4 XCHARGE [CONVERT TO MILLISECONDS
98?4 ... LDX 2 GEN4 [X2 -> CURRENT PCA
98?9 ... LDX 1 FX1
98?B ...[
98?H ...[ UPDATE TIMERS IN JOB BLOCK AND SET STOP WORD IF TIME-UP CONDITION
98?N ...[
98?T ... LDN 4 0
98#2 ... ADSC 5 HTIMEJ+1(3) [JOB TIMER
98#7 ... ADS 4 HTIMEJ(3)
98## ... SBSC 5 APROGTIME+1(3) [PROGRAM TIMER
98#F ... SBS 4 APROGTIME(3)
98#L ... ADS 5 HTIMES(3) [SLOT TIME USED
98*5 ... LA ASTOPTIM,5
98*= ... LDX 6 APROGTIME(3)
98*C ... BNG 6 STOPIT [J IF PROG TIME UP
98*J ... LA ASTOPJOB,5
98*P ... LDXC 7 HTIMEJ+1(3)
98*W ... LDX 6 HTIMEJ(3)
98B3 ... TXL 7 ATIMEJ+1(3)
98B8 ... TXL 6 ATIMEJ(3)
98B* ... BCS T12 [NOT JOBTIME UP
98BG ...STOPIT
98BM ... ORS 5 ASTOP(2)
98F2 T12 LDX 5 ASTOP(2)
9=CG BZE 5 T11 [J NO STOP BITS SET
9*SW BNG 5 T11 [J IF B0 SET
9BJ2 ...[ IF ANY OF ASTOPTIM,ASTOPJOB,ASTOPBIN OR B15-23(PERIPHERAL
9BM= ...[ FAILURE) SET IN ASTOP,THEN WE NEED TO FPUT PCA.UNLESS??
9BQG ...[
9BTQ ... LDX 0 MASTOP1(1)
9B^2 ... ANDX 0 ASTOP(2)
9C4= ... BZE 0 T11
9C7G ...[ UNLESS ANY OF ASTOPEXEC,ASTOPTP,ASTOPPUC OR UNUSED BITS SET
9C=Q ...[ AS WELL(B4 & B6-11)
9CB2 ...[
9CF= ... LDX 0 MASTOP2(1)
9CJG ... ANDX 0 ASTOP(2)
9CMQ ... BNZ 0 T11
9CRB T11A
9D?2 ISSTOP 2,T11 [TEST IF PROGRAM REALLY STOPPED (3D)
9DQL LDX 5 ASTOP(2)
9F== BNG 5 T11 [J IF B0 TYPE EVENT JUST HAPPENED
9GP6 LDN 1 P4(1) [LINK FOR K4CHARGESC
9H8Q T15
9HNB LINKSET 2,0(1)
9J82 FLIPS ASTOP(2),,0 [SET 'ACTIVE' STOP BIT
9JML FPUT [PUT PCA ON LIST
9K7= BRN T11
9N52 #
9NJL #
9NKS ...#UNS AV7900S
9NM2 ...(
9NN8 ...# DECANT GEORGES TIMER(K7) INTO GEOTIME(DOUBLE LENGTH FIXED CORE
9NPB ...# WORD).
9NQJ ...# CHECK IF FONINTP SECONDS HAVE ELAPSED AND IF SO
9NRQ ...# WAKE UP THE ACTIVITIES WHICH ARE WAITING IN CERTAIN STYLES
9NSY ...# AND TIME OUT VIRTUAL 7900 WMC TRANSFERS WHICH HAVE BEEN STORED FOR
9NW6 ...# 3 FONINTP SECONDS.
9NX# ...)
9NYG ...#UNS AV7900S
9N^N ...#SKI
9P2W ...(
9P4= # CHECK IF FONINTP SECONDS HAVE ELAPSED AND IF SO WAKE UP THE ACTIVI
9PHW # WHICH ARE WAITING IN CERTAIN STYLES. ALSO DECANT GEORGES TIMER(K7)
9Q3G # GEOTIME(DOUBLE LENGTH FIXED CORE WORD).
9Q?# ...)
9QH6 #
9R2Q #
9R*X ...T10
9RP4 ...[
9S49 ...[ THIS CURES BUG 2780,WHEREBY EXEC IDLE TIME(K30+K45) EXCEEDS 8.6M
9SCB ...[ IN TIME PERIOD FONINT(4SECS) IT WILL NOW BE UPDATED EVERY S-C
9SQH ...[ DONE 16TH MAY 75 :CENT
9T5N ...[
9T7N ...[ WITH CME, OVERFLOW WORD INCLUDED. THIS ZERO IN NON-CME.
9T9N ... LDXC 5 K30+K45
9T?N ... LDX 4 K30+K35+15 [SAFEGUARD- SEE COMMENT ON GEOTIME
9T*N ... SBSC 5 K30+K45
9TCN ... SBS 4 K30+K35+15
9TFS ...[
9TMW ...[ THE FOLLOWING CURES BUG 3342 - EXEC NOW TIMES IN MILLI SECS
9TTY ...[ NOT BEATS
9W42 ...[
9W#M ... DVD 4 THOU(1)
9WK# ... ADSC 4 K30+K45
9WT^ ... LDN 4 0
9X6L ... ADS 4 K30+K35+15
9X#Q ... SRL 56 24
9XGW ... ADSC 6 EXECIDLE+1
9XP2 ... ADS 5 EXECIDLE
9XX6 ...[
9XX= ...[ IN CME,DECANT SYSTEM IDLE SIMILARLY TO EXEC IDLE TIME
9XXB ...[
9XXG ... JENVNOT NOTCME,CME
9XXL ... LDX 5 K30+K45+1
9XXQ ... DVS 4 THOU(1)
9XXW ... STO 4 K30+K45+1
9XY2 ... LDN 4 0
9XY6 ... ADSC 5 IDLESYS+1
9XY= ... ADS 4 IDLESYS
9XYB ...NOTCME
9XYJ ...#UNS ICT
9Y26 ...(
9Y3N ...# FOR ICT ENHANCEMENT: ACCUMULATE GEORGE'S MILL TIME
9Y5= ...# FROM ALL GEORGE'S MILL TIMERS
9Y6S ... GETGMILL 4,5
9Y8B ...)
9Y9Y ...#UNS ICT
9Y?G ...#SKI
9Y*4 ...(
9YBL LDXC 5 K7
9YW= LDX 4 K7X
9^*W SBSC 5 K7 [ SAFEGUARD 'COS EXEC CAN INCREMENT..
9^TG SBS 4 K7X [ MILL TIME BETWEEN ANY TWO...
=2*6 [ GEORGE INSTRUCTIONS
=2SQ DVD 4 BEATTIME [CONVERT GEORGE TIME TO MILLISECONDS
=3#B ADSC 4 K7 [ SAFEGUARD AS ABOVE...
=3S2 LDN 4 0 [ STORE REMAINING BEATS IN K7
=4?L ADS 4 K7X
=4HD ...)
=4R=
=5=W SRL 56 24 [DOUBLE LENGTH
=5QG ADSC 6 GEOTIME+1
=6=6 ADS 5 GEOTIME [UPDATE MILLISEC COUNT
=6*= ... LDX 4 FONINT
=6C# ... BPZ 4 T10A [J NO WAKING NECESSARY
=6HG ... LDX 0 WTIME(1)
=6LL ... ADS 0 FONINT [RESET FON INTERVAL
=6PQ #SKI K6CHARGESC>12-12
=79B (
=7P2 TRACE GEOTIME+1,######SC
=88L TRACE CHCHCOUNT,CHCHCT
=8N= )
=97W FON1 [AWAKEN THE SLEEPING
=9MG LDN 2 BFREE
==76 LDN 0 0 [FOR COUNT OF NUMBER OF F/C BLOCKS
==LQ ZAG LDX 2 FPTR(2) [GET NEXT
=?6B ADN 0 1 [INCREMENT COUNT
=?L2 TXU 2 BFREE+1 [ARE WE AT END?
=#5L BCS ZAG [IF NOT JUMP BACK
=#K= SRA 0 1 [DIVIDE BY 2
=*4W LDN 2 BFREE
=*JG QUIK LDX 2 FPTR(2) [LOCATE MID POINT
=B46 BCT 0 QUIK
=BHQ STO 2 CMIDFREE [STORE IT
=C3B #SKI K6CHARGESC>199-199
=CH2 TRACE 2,CMIDFREE
=CH3 ...#UNS AV7900S
=CH4 ...(
=CH5 ... CALL 7 TIMOUTV7900
=CH6 ...TIMOUTRETUR [RETURN FROM K4VIPBPERI
=CH7 ...)
=CH8 ...T10A
=CHM ...[
=CHW ...[ CHECK IF PROGRAM RING CORRECTLY ORDERED MOVING AS NECESSARY
=CJ5 ...[
=CJ6 ... NGX 0 AMRREORDER
=CJ7 ... BNG 0 T10B [J IF NOT TIME TO REORDER
=CJ8 ... SEGENTRY K53CHARGESC [FOR CPIFORMS REST. TIME MACRO
=CJ9 ... LDN 0 AMRTIME
=CJ= ... STO 0 AMRREORDER
=CJ# ...#UNS IMRSTAT
=CJH ...(
=CJQ ... STOZ GEN1 [NO. OF PLUGGED IN PROGS
=CJ^ ... STOZ GEN2 [NO. OF RE-ORDERINGS
=CK8 ...)
=CKC ... LDN 3 BPROG [START WITH HIGH PRIORITY
=CKL ... LDX 4 TOPAMRHP(1) [CONTAINS AMR OF LAST MEMBER
=CKT ... LDN 7 GMEL [FINISHING POINT
=CL4 ...ORDER LDX 3 FPTR(3)
=CL? ... BXE 3 7,SECTEND
=CL# ...#UNS ICT
=CL* ...(
=CLB ... LDN 0 GPDA
=CLC ... BXE 0 APD(3),ORDER [IGNORE GEORGE MEMBER ELEMENTS
=CLD ...)
=CLG ...#UNS IMRSTAT
=CLP ...(
=CLY ... LDN 0 1
=CM7 ... ADS 0 GEN1
=CMB ...)
=CMK ... LDCH 2 ARM(3) [MEMBER NUMBER
=CMS ... SMO APD(3)
=CN3 ... LDX 5 AMR1-ASTOP(2)
=CN= ... BXGE 4 5,OKORD [J IF IN CORRECT ORDER
=CNF ... LDX 5 APD(3)
=CNN ... SBN 5 ASTOP [-> PCA
=CNX ... LDX 6 2 [MEMBER NO
=CP6 ... MELRERING 5,6
=CP* ...#UNS IMRSTAT
=CPJ ...(
=CPR ... LDN 0 1
=CQ2 ... ADS 0 GEN2
=CQ9 ...)
=CQD ...OKORD LDX 4 5 [RESET AMR OF LAST MEMBER
=CQM ... BRN ORDER
=CQW ...SECTEND
=CR5 ...[ REORDERING IS FINISHED IF FINISHING POINT IS FOR ORDINARY MEMBERS
=CR# ...[ IF NOT RESET TO DO ORDINARY MEMBERS
=CRH ... BXU 7 GMELPTR,SCHED
=CRQ ... LDX 4 TOPAMR(1)
=CR^ ... LDN 7 BPROG
=CS8 ... BRN ORDER
=CS9 ... NULL [ FOUR WORD GAP
=CS= ... NULL [ FOR
=CS? ... NULL [ CPIFORMS
=CS# ... NULL [ RESTORE TIME MACRO
=CSC ...SCHED
=CSG ... SEGENTRY K54CHARGESC [FOR CPIFORMS RESTORE TIME MACRO
=CSL ...#UNS IMRSTAT
=CST ...(
=CT4 ... LDN 4 1
=CT? ... ADS 4 IMRCHECK [NO. OF TIMES ORDER CHECKED
=CTG ... LDX 0 GEN1
=CTP ... SRL 0 1
=CTY ... BXGE 0 GEN2,SCHED1
=CW7 ... ADS 4 IMRCHAOS [HALF MELS MOVED
=CWB ...SCHED1
=CWK ...[ADD NO OF REORDERS TO A VECTOR
=CWS ... LDN 0 IMRMOVEN-IMRMOVE
=CX3 ... BXGE 0 GEN2,SCHED2
=CX= ... ADS 4 IMRMOVEN [MORE MOVES THAN ALLOWED FOR
=CXF ... BRN SCHED3
=CXN ...SCHED2
=CXX ... SMO GEN2
=CY6 ... ADS 4 IMRMOVE
=CY* ...SCHED3
=CYJ ...)
=D2L #
=DG= # SET CORE UNJAMMING SUM USING COUNT OF NUMBER OF ACTIVITIES ON QUEU
=D^W # OR OTHERWISE WHICH HAVE BEEN REFUSED A REQUEST FOR CORE(CFAIL), AN
=FFG # NECESSARY ENTER CORE UNJAMMER; OTHERWISE ENTER PROGRAM CONTROLLER
=F^6 # REVIEW RUNNING OF PROGRAMS.
=GDQ #
=GYB ...T10B
=HD2 LDX 5 CFAIL [LOAD COUNT OF OUTSTANDING CORE REQUE
=HXL LDX 7 CJCLAST [LOAD LAST COUNT OF WAITING ACTIVITIE
=JC= STO 5 CJCLAST [STORE NEW COUNT
=JWW BZE 5 WC50 [J NO ACTIVITIES WAITING
=KBG TXL 5 7 [TEST IF LESS WAITING THAN LAST TIME
=KW6 BCC WC100 [NO
=L*Q WC50 LDX 6 CJSUM [LOAD CURRENT SUM
=LTB MPY 6 TJDECAY(1)
=M*2 DVR 6 TON(1) [DECAY IT
=MSL STO 7 CJSUM [STORE DECAYED PART OF NEW SUM
=N#= WC100
=NRW #SKI JPSCF
=P?G (
=PR6 [
=Q=Q [
=QQB [
=R=2 LDN 3 0
=RC8 ...#UNS ISTDP
=RJB ... COBJUNUSE
=RWS ... ADX 0 CFREE [ IF 'CFREE+ACHAP'