{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: CHINTEG867)}}
====== CHINTEG867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BXE|BXE]], [[george:macro:CAFSINFO|CAFSINFO]], [[george:macro:CHFILE|CHFILE]], [[george:macro:CLOSEWR|CLOSEWR]], [[george:macro:DOWN|DOWN]], [[george:macro:EXCHOFE|EXCHOFE]], [[george:macro:EXMESS|EXMESS]], [[george:macro:EXOFILE|EXOFILE]], [[george:macro:FIPPER|FIPPER]], [[george:macro:FPCACA|FPCACA]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:JDED|JDED]], [[george:macro:LADDP|LADDP]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFINDEXOF|MFINDEXOF]], [[george:macro:MFINDSU|MFINDSU]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MOVLONG|MOVLONG]], [[george:macro:OPENST|OPENST]], [[george:macro:OVER|OVER]], [[george:macro:PHOTO|PHOTO]], [[george:macro:PICKREP|PICKREP]], [[george:macro:PUTREP|PUTREP]], [[george:macro:READ|READ]], [[george:macro:READST|READST]], [[george:macro:RELST|RELST]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:TESTMOVE|TESTMOVE]], [[george:macro:TESTREP|TESTREP]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:TESTREPNOT|TESTREPNOT]], [[george:macro:TRUSTED|TRUSTED]], [[george:macro:UNLOCKSU|UNLOCKSU]]
22FL ... SEG CHINTEG,867
22^= ...#
23DW ...# COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
23YG ...#
24D6 #
24XQ SEGENTRY K1CHINTEG,QK1CHINTEG
25CB #
28SQ #
29#B ...# THIS SECTION CHECKS THAT A FILE WHICH HAS BEEN FOUND
29S2 ...# CAN BE OPENED,CHECKING INTEGRITY CODE,RETENTION
2=?L # PERIOD,ETC.JUMPS TO Z--- FOR ERROR ---,ELSE GOES TO
2=R= # CONNECT.
2?=W #
2?QG #
2#=6 QOLAY #100 [ )
2#PQ QREAD #200 [ )
2*9B QWRITE #300 [ )OPENING MODES
2*P2 QEOF #400 [ )
2BH2 ...XEWINS +EWINS
2BPY ...#
2BYW ...#DEF XA1=A1
2C7W #
2CMG #
2D76 QK1CHINTEG
2DLQ #
2G5L #SKI K6CHINTEG>199-199
2GK= (
2H4W TESTREP OK,OK
2HJG GEOERR 1,EXOREP
2J46 OK
2JHQ )
2K3B MHUNTW 2,EWDAS,EXOF [FIND DATA BLOCKS
2KH2 MHUNTW 3,EWDAS,GEXD
2L2L STOZ COPEN(2) [CLEAR COPEN AND BACK2 IN CASE
2LG= STOZ BACK2(2) [OF REENTRY,
2L^W LDN 0 #7777
2MFG ANDS 0 EXMARK(2) [ALSO B0-11 OF EXMARK
2MP# ... LDX 7 EOPMODE(3)
2M^6 ... FPCACA 1,FX2 [GET POINTER TO PCA
2Y=Q LDN 6 0 [
2YQB TRUSTED 1,NOTS,S [J IF NOT S-TRUSTED,
2^=2 LDCT 6 #400 [ELSE SET X6 NEG
2^PL ... BRN NOTQ
366= NOTS TRUSTED 1,NOTQ,Q [J IF NOT Q-TRUSTED,
36KW ORN 6 1 [ELSE SET X6 NON-ZERO
375G NOTQ LDX 1 FX1
37K6 LDCT 0 #100
384Q ANDX 0 FIP+5(2)
38JB BZE 0 NSYS [J UNLESS SYSTEM FILE
38KY ... BPZ 6 NUND [DONT CHECK FOR DEDICATED
38MG ... MFINDSU 1,ASUSN(2) [IF NOT S-TRUSTED
38P4 ... LADDP HUNIT(1),1 [POINTER TO APIA
38QL ... JDED 1,NUND [J IF S-TRUSTED - OK
38S8 ... LDN 6 8 [ERROR - S-TRUSTED ON NON-DED UNIT
38TQ ... LDN 7 2
38X# ... BRN ZERROR
38YW ...NUND
392D ... LDX 1 FX1
3942 LDCT 0 #20
39HL ORS 0 EXMARK(2) [SET SYFIL BIT IN EXMARK
3=3= TXU 7 QEOF(1)
3=GW BCC ZSYS [ERROR IF MODE *400,
3?2G BZE 6 ZSYS [OR PROGRAM NOT TRUSTED AT ALL
3?G6 TXU 7 QREAD(1)
3?^Q BCC XINT [J IF MODE *200,CHECK PASSED
3#FB BNG 6 STR [ELSE J IF PROGRAM S-TRUSTED
3#^2 ZSYS LDN 6 3 [ERROR,NOT SUFFICIENTLY TRUSTED,
3*DL LDN 7 2 [SET MESS AND REPLY
3*Y= BRN ZERROR [AND DEAL WITH ERROR
3BCW STR LDEX 4 FIP+5(2) [CHECK UNITS ARE NOT IN USE
3BXG ADN 4 1 [COUNT OF FILE AREAS+1
3CC6 LDX 0 ASUSN(2) [SERIAL NR OF FIP
3CWQ NSER LDN 1 BCCB [SEARCH FOR REFERENCE TO SUSN [X0];
3DBB NEXF LDX 1 BPTR(1) [!NOTE! COPEN IS USED AS A TEMPORARY
3DW2 TXU 1 CXCC [ COUNT DURING THIS CHECK
3F*L BCC YEND [J IF END OF CCB CHAIN
3FT= LDX 7 BACK2(1)
3G#W BNZ 7 NEND [J IF THIS IS AN EXOF,
3GSG YEND SMO COPEN(2) [ELSE ,THIS SUSN NOT FOUND
3H#6 LDX 0 FDCELLS(2) [LOOK FOR NEXT;SUSN IN X0
3HRQ LDN 7 6 [UPDATE POINTER TO CURRENT FD CELL
3J?B ADS 7 COPEN(2)
3JR2 BCT 4 NSER [J IF MORE CELLS TO CHECK NEXT SUSN,
3K=L STOZ COPEN(2) [ELSE CHECK PASSED
3KQ= LDCT 0 4
3L9W ORS 0 EXMARK(2) [SET S-TRUSTED BIT
3LPG LDX 7 EOPMODE(3) [RESTORE MODE
3M96 LDX 1 FX1 [& FX1
3MNQ BRN NSYS [AND CONTINUE
3N8B NEND TXU 0 ASUSN(1)
3NN2 BCC ZS [J IF FIP SUSN SAME
3P7L LDEX 7 FIP+5(1) [GET COUNT FIO AREAS
3PM= LDN 5 0 [POINTER TO FIRST AREA
3Q6W NEXS BZE 7 NEXF [J IF NO MORE AREAS,LOOK AT NEXT EXOF
3QLG SBN 7 1
3R66 ADN 5 6 [REDUCE COUNT AND UPDATE POINTER
3RKQ SMO 5
3S5B TXU 0 FDCELLS-6(1)
3SK2 BCS NEXS [J IF THIS AREA OF DIFFERENT SU
3T4L ZS LDN 6 4 [ELSE ERROR:-S-TRUSTED CANNOT BE OPEN
3TJ= LDN 7 7 [ED BECAUSE UNIT(S) IN USE
3W3W BRN ZERROR [J FOR ERROR
3WHG NSYS TXU 7 QOLAY(1)
3X36 ... BCC OVER [J IF MODE *100 TO CHECK TRUSTED
3XGQ TXU 7 QWRITE(1)
3Y2B BCS XINT [J IF MODE NOT *300 TO SKIP RP CHECK
3YG2 ...OVER BZE 6 RPCH [J TO CHECK RP IF PROGRAM NOT TRUSTED
3Y^L LDX 6 ENEWRP(3) [OR
3^F= BPZ 6 XINT [IF NEW RP IS NEGITIVE
3^YW RPCH LDX 0 FIP+7(2) [CHECK RP
42DG SRL 0 12
42Y6 ADX 0 FIP+6(2) [PURGE DATE
43CQ LDX 6 EDATE
43XB TXL 6 0
44C2 BCC XINT [J IF PURGE DATE EXCEEDED
44WL ... LDN 6 6 [ELSE ERROR,FILE NOT TO BE WRITTEN
45B= LDN 7 4
45TW BRN ZERROR
46*G XINT LDX 5 ASUSN(2) [CHECK IF FILE ALREADY OPEN:
46T6 LDX 6 HOME(2) [LOOK FOR EXOF WITH SAME ASUSN,HOME
47#Q LDN 4 0 [MARK IF ANY S-TRUSTEDS OPEN
47SB LDN 1 BCCB
48#2 XINA
48RL LDX 1 BPTR(1)
49?= TXU 1 CXCC
49QW BCC NOPE [J IF END OF CCB CHAIN,OR
4==G LDX 0 BACK2(1) [BLOCK IS NOT AN EXOF;FILE IS
4=Q6 BZE 0 NOPE [NOT ALREADY OPEN
4?9Q ORX 4 EXMARK(1) [ELSE REMEMBER S-BIT
4?PB TXU 5 ASUSN(1)
4#92 TXU 6 HOME(1)
4#NL BCS XINA [J IF DIFFERENT,LOOK AT NEXT
4*8= #SKI K6CHINTEG>199-199
4*MW (
4B7G LDX 4 FIP(2) [(CHECK THAT IDENTITY MATCHES)
4BM6 LDX 5 FIP+1(2)
4C6Q LDX 6 FIP+2(2)
4CLB TXU 4 FIP(1)
4D62 TXU 5 FIP+1(1)
4DKL TXU 6 FIP+2(1)
4F5= BCS XINC
4FJW LDX 4 FIP+4(2)
4G4G ERX 4 FIP+4(1)
4GJ6 SRL 4 12
4H3Q BNZ 4 XINC
4HHB LDCT 4 4 [(AND THAT WE ARE NOT S-TRUSTED)
4J32 ANDX 4 EXMARK(2)
4JGL BZE 4 XIND
4K2= GEOERR 1,S-OPEN
4KFW XINC GEOERR 1,NAMEHOME
4K^G XIND
4LF6 )
4LYQ LDCT 0 #100
4MDB ANDX 0 EXMARK(1)
4MY2 BZE 0 NGRG [J UNLESS OPEN TO GEORGE
4NCL LDN 6 5
4NX= LDN 7 1 [ELSE ERROR
4PBW BRN ZERROR
4PWG ...NGRG LDCH 0 FIP+5(2) [CHECK INTEGRITY CODE:-
5286 SRL 0 4
52MQ SBN 0 1
537B BZE 0 ZINTEG [FAIL IF IC=1 (1 USER ONLY)
53M2 LDX 6 7
546L SBN 6 #200
54L= LDX 4 EXMARK(1)
555W BPZ 4 READ [J IF CURRENTLY OPEN FOR READING
55KG SBN 0 2
5656 BZE 0 ZINTEG [FAIL IF IC=3 (1 WRITER OR N READERS
56JQ BNZ 6 ZINTEG [OR IF WE ARE A WRITER
574B BRN PASS [ELSE CHECK PASSED
57J2 READ SBN 0 1 [OPEN FOR READING,
59GG BZE 0 PASSA
5=26 BNZ 6 ZINTEG [FAIL IF IC=3 AND WE ARE A WRITER
5=FQ PASS LDX 4 BACK2(1) [IC CHECK PASSED
5=^B STO 4 BACK2(2) [SAVE EXOFILE NUMBER
5?F2 STO 4 CEFN(3) [
5?YL BRN UPD [GO TO FIP UPDATE
5#D= #
5*X6 PASSA BZE 6 PASS [NOT NEED TO CHECK IF READING
5BBQ LDX 4 BACK2(1)
5BWB CHFILE HOME(2),ASUSN(2),7,TBREAK,ZIF,XIPB,XNOC
5CB2 MHUNTW 2,EWDAS,EXOF
5CTL MHUNTW 3,EWDAS,GEXD
5D*= XNOC
5DSW MFINDEXOF 1,4
5F#G BRN PASS
5J== NOPE SLL 4 6 [FILE IS NOT ALREADY OPEN
5JPW BPZ 4 NOST [J IF NO S-TRUSTEDS OPEN
5K9G LDN 4 0 [ELSE CHECK THAT NONE OF OUR AREAS
5KP6 LDEX 5 FIP+5(2) [ARE ON UNIT IN USE BY S-TRUSTED
5L8Q LDX 0 ASUSN(2)
5LNB BRN NIC1
5M82 SAME BZE 5 NARE [J IF NO AREAS
5MML SBN 5 1 [UPDATE COUNT OF AREAS AND
5N7= ADN 4 6 [FD CELL POINTER
5NLW SMO 4
5P6G LDX 0 FDCELLS-6(2) [CHECK THIS FDCELL
5PL6 TXU 0 ASUSN(2)
5Q5Q BCC SAME [J IF ON HOME UNIT,NO NEED TO CHECK
5QKB NIC1 LDN 1 BCCB [FIND S-TRUSTED EXOFS
5R52 NIC LDX 1 BPTR(1)
5RJL TXU 1 CXCC
5S4= BCC SAME [J END OF CCB CHAIN
5SHW LDX 6 BACK2(1)
5T3G BZE 6 SAME [OR IF THIS IS NOT AN EXOF,
5TH6 LDCT 6 4
5W2Q ANDX 6 EXMARK(1)
5WGB BZE 6 NIC [OR IF NOT S-TRUSTED
5X22 TXU 0 ASUSN(1)
5XFL BCC ZSS [ERROR IF SAME HOME UNIT AS OUR AREA
5X^= LDEX 6 FIP+5(1) [CHECK FD CELLS IN EXOF FOUND
5YDW LDN 7 0
5YYG NFA BZE 6 NIC [J NO AREAS
5^D6 SBN 6 1
5^XQ ADN 7 6 [UPDATE...
62CB SMO 7
62X2 TXU 0 FDCELLS-6(1)
63BL BCS NFA [J THIS AREA NOT SAME UNIT AS OURS
63W= ZSS LDN 6 4 [ELSE ERROR,FILE CANNOT BE OPENED
64*W LDN 7 1 [BECAUSE A UNIT IT REQUIRES IS IN USE
64TG BRN ZERROR [BY AN S-TRUSTED
65*6 NARE LDX 7 EOPMODE(3) [RESTORE MODE
67R= NOST CHFILE HOME(2),ASUSN(2),7,TBREAK,ZIF,XIPB,XNOC1
68=W MHUNTW 3,EWDAS,GEXD
68QG MHUNTW 2,EWDAS,EXOF
69=6 XNOC1 LDX 6 2
6=9B LDX 5 ALOGLEN(2) [SAVE LOGLEN
6=P2 EXOFILE 6 [CHAIN IN EXOF AND ALLOCATE IT AN EFN
6?8L SMO 6
6?N= LDX 4 BACK2
6#7W STO 4 CEFN(3) [SAVE EFN
6#MG PHOTO 7
6*76 SETUPCORE 5,2,EWDAS,EXOF [CREATE NEW EXOF IN ACTIVITY CHAIN
6*LQ LDX 1 6 [X1 POINTS TO EXOF IN CCB CHAIN...
6B6B TESTMOVE 7,MEX
6BL2 MHUNTW 3,EWDAS,GEXD
6C5L MFINDEXOF 1,4 [EVEN IF
6CK= MEX STO 4 BACK2(2) [PUT EFN IN NEW EXOF
6D4W LDN 6 XA1(1) [COPY
6DJG LDN 7 XA1(2) [OLD EXOF
6F46 ... MOVLONG 6,7,5 [TO NEW,FOR UPDATING
6G3B LDX 7 EOPMODE(3) [RESTORE MODE
6GH2 [
6GHX ...UPD
6GLL ... LDX 1 FX1
6GMH ... TXU 7 QREAD(1)
6GND ... BCC SETRD [J IF MODE #200
6GP* ... TXU 7 QEOF(1)
6GQ= ... BCC SETAP [J IF MODE #400
6GR7 ... LDN 5 CWRITE [MODE IS #100 OR #300 SO
6GS4 ... TXU 7 QWRITE(1)
6GS^ ... BCS XOFLE [J IF MODE #100 NEEDING WRITE TRAPS
6GT= ... LDXC 1 ENEWG(3)
6GTH ... BCS XOFLE [J IF GEN NO NOT TO BE UPDATED
6GTW ... LDX 0 FIP+4(2)
6GWR ... SRL 0 12 [OLD GEN NO
6GXN ... TXU 0 1 [NEW GEN NO
6GYK ... BCC XOFLE [J IF SAME ELSE
6G^G ... ORN 5 CERASET [ERASE TRAPS ALSO NEEDED FOR #300
6H2C ... BRN XOFLE
6H3# ...SETRD
6H49 ... LDN 5 CREAD [NEED TO TEST FOR READ TRAPS
6H56 ... BRN XOFLE
6H63 ...SETAP
6H6Y ... LDN 5 CAPPEND [NEED TO TEST FOR APPEND TRAPS
6H7T ...XOFLE
6H8Q ... EXCHOFE EXOF,,5,XOCNT [EXOFILE LIBRARIAN TO CHECK TRAPS
6H94 ... TESTREP2 OK,XCHOK [J IF TRAPS ARE OK
6H=J ... TESTREPNOT NOFILE,XOERR [NO FILE - NO CHECKS,ELSE ERROR CASE
6H=Y ... LDX 0 EDSQ
6H?4 ... BNG 0 XOERR [J IF FULL SECURITY IN USE
6H?5 ... BRN XOCNT
6H?6 ...XCHOK
6H?7 ... SMO FX1
6H?8 ... TXU 7 QREAD
6H?9 ... BCS XCHOFW [J IF OPEN MODE NOT READ
6H?= ... EXCHOFE EXOF,,,XOCNT,A [D&T ACCESSED FOR EXOFILE ENTRY
6H?? ... BRN XOCNT
6H?# ...XCHOFW
6H?* ... EXCHOFE EXOF,,,XOCNT,AW [D&T WRITTEN+ACCESSED FOR NEW EXOF
6H?F ...XOCNT
6H#B ... MFINDEXOF 1,4 [RE-HUNT BLOCKS
6H*? ... MHUNTW 2,EWDAS,EXOF
6HB8 ... MHUNTW 3,EWDAS,GEXD
6HDX ... SBN 7 #200
6HG= BZE 7 XEND [J IF READ MODE
6H^W SBN 7 #100
6JFG BZE 7 WRT [J IF OUTPUT MODE
6J^6 LDX 0 FIP+4(2)
6KDQ ANDN 0 #7777
6KYB ADN 0 1 [ELSE ADD 1 TO VERSION
6LD2 DSA 0 FIP+4(2)
6LXL ADN 7 #200
6MC= BZE 7 PDAT [J IF OLAY TO INSERT DATE,ELSE
6MWW BRN REW [IF EOF MODE,J TO REWRITE FIP
6NBG WRT LDX 0 ENEWG(3) [OUTPUT MODE,
6NW6 ... BNG 0 NUPG [J IF GEN NO NOT TO BE UPDATED,
6P*Q SLL 0 12
6PTB LDX 4 FIP+4(2)
6Q*2 DSA 4 0
6QSL TXU 4 0
6R#= BCC NUPG [OR IF OLD GEN SAME AS NEW
6RRW STO 0 FIP+4(2) [PUT NEW GEN IF EXOF (IN ACTCHAIN)
6RTB ... LDX 4 CEFN(3)
6RTW ... LDX 6 EXOTRAP(3) [-VE FOR NON-OK REPLY FROM PREVIOUS
6RWB ... LDX 7 EXMARK(2) [EXCHOFE & X7 PRESERVES EXMARK
6RWW ... LDX 5 HOME(2) [PRESERVE THE FILE'S HOME
6RXB ... LDN 0 BOPEN+BSERL+BSPEC+BLOCK
6RXW ... STO 0 EXMARK(2) [SEE IF NEW EXOFILE
6RYB ... DOWN EXOPEN,1 [ALREADY EXISTS
6RYW ... TESTREP2 OK,XOERR [J IF SO - ERROR
6R^B ... MHUNTW 2,EWDAS,EXOF
6R^W ... MHUNTW 3,EWDAS,GEXD
6S2B ... STO 5 HOME(2) [REINSTATE FILE'S HOME
6S2W ... LDN 0 ANFOUND
6S3B ... ANDX 0 EMARK(3) [IS REPLY 'NOT FOUND'
6S3W ... BZE 0 ZFAIL [J IF NOT - TRANSFER ERROR
6S4B ... LDN 5 CWRITE [EXOFILE(REVGEN) MUST HAVE EXOFILE
6S4W ... EXCHOFE EXOF,,5,WRIT1 [ENTRY WITH WRITE TRAPS
6S54 ... TESTREP2 NOFILE,XCHNF,NOTRAP,XOERR
6S5= ... EXCHOFE EXOF,,,WRIT1,AW [D&T WRITTEN+ACCESSED FOR NEW EXOF
6S5D ... BRN WRIT1
6S5L ...XCHNF
6S5W ... LDX 0 EDSQ [NOFILE REPLY SO TEST FOR 'FULL'
6S6B ... BNG 0 XOERR [J IF FULL IN USE
6S6W ... BNG 6 WRIT1 [J IF PREVIOUS EXCHOFE ALSO HAD NOFIL
6S7B ... SMO FX1
6S7W ... LDX 6 XEWINS
6S8B ... DOWN CHINERR,7 [O/P THE NO LONGER SECURE MESSAGE
6S8W ...WRIT1
6S9B ... MHUNTW 2,EWDAS,EXOF
6S9W ... STO 7 EXMARK(2) [REINSTATE EXMARK
6S=B ... MHUNTW 3,EWDAS,GEXD
6S?G NUPG LDN 0 0
6SR6 DSA 0 FIP+4(2) [ZEROISE VERSION
6T=Q LDN 0 1
6TQB STO 0 FIP+10(2) [EOF=1
6W=2 LDX 0 ENEWRP(3)
6WPL SLL 0 1
6X9= BNG 0 PDAT [DO NOT UPDATE RP IF NEW RP HAS B1=1
6XNW SLL 0 11
6Y8G LDX 6 FIP+7(2)
6YN6 STO 0 FIP+7(2) [INSERT NEW DATA RP
6^7Q DSA 6 FIP+7(2)
6^MB PDAT LDX 0 EDATE [REWRITE DATE
7272 STO 0 FIP+6(2)
72LL REW LDX 4 CEFN(3) [WRITE FIP BACK
736= LDX 5 2 [SAVE POINTERS,ETC
73KW PHOTO 6
745G OPENST ASUSN(2) [SET UP TRANSFER SYSTEM
74K6 READST HOME(2),NKOR
754Q TESTREP OK,NKM1
75JB TESTREP EXFAIL,ZFAIL
7642 NKM3 GEOERR 1,CHINREP
76HL NKM1 LDX 2 5
773= TESTMOVE 6,NKM
77GW MHUNTW 2,EWDAS,EXOF
782G LDX 5 2
78G6 NKM LDX 1 ECOR(3) [AND GET POINTER TO AREA READ
78^Q NKOR LDN 0 FIP(2)
79FB ADN 1 2
79^2 MOVE 0 15 [MOVE FI&P TO BUFFER
7=DL PHOTO 6
7=Y= LDX 2 5
7?CW CLOSEWR W,HOME(2)
7?XG TESTREP OK,NKM2
7#C6 TESTREP EXFAIL,ZFAIL
7#WQ BRN NKM3
7*BB NKM2 LDX 2 5
7*W2 TESTMOVE 6,NK2
7B*L MHUNTW 3,EWDAS,GEXD [REHUNT IF NECESSARY
7BT= MHUNTW 2,EWDAS,EXOF
7C#W NK2 MFINDEXOF 1,4 [FIND COPY OF EXOF IN CCB CHAIN
7CSG LDN 5 FIP(2)
7D#6 LDN 6 FIP(1)
7DRQ MOVE 5 15 [COPY UPDATED FIP TO IT
7G=L FIPPER HOME(2),ASUSN(2),XBREAK,XFAIL,NOCS
7GQ= XFAIL MHUNTW 3,EWDAS,GEXD
7H9W MHUNTW 2,EWDAS,EXOF
7HPG NOCS MFINDEXOF 1,4
7JNQ LDCT 0 #400
7K8B ORS 0 EXMARK(1) [SET OPEN-FOR-WRITING MARKER
7KN2 [
7L7L [
7LM= XEND LDN 0 0
7M6W DSA 0 EXMARK(1)
7MLG LDN 0 1
7N66 ADS 0 COPEN(1)
7NKQ LDN 4 FIP(1)
7P5B LDN 5 FNAMER(3)
7PK2 MOVE 4 3
7Q4L LDX 0 FIP+4(1)
7QJ= STO 0 FNAMER+3(3)
7R3W LDX 6 ASUSN(1)
7RHG FREECORE 2
7S36 [
7S7J ...REL
7S#2 ...#UNS CAFSINT
7SDD ...(
7SJW ...# IF THE FILE IS BEING OPENED FOR WRITING, WE HAVE TO INFORM
7SP# ...# THE CAFS SUBSYSTEM OF THE EVENT
7STQ ...#
7T28 ... LDX 0 EOPMODE(3) [GET THE OPENING MODE
7T6L ... BXE 0 QREAD(1),NOTOFW [& JIF OPENING TO READ
7T?4 ... CAFSINFO OPENFILE,CEFN(3) [ELSE NOTIFY EVENT TO CAFS
7TCG ...#
7THY ...NOTOFW
7TNB ...)
7TSS ... EXMESS
7T^L ACROSS ANTIC,1 [CONNECT FILE
7WF= [
7WYW [
7X2B ...XOERR
7X2J ... LDX 7 EXEC1(2) [LENGTH OF FABSNB USED IN EXCHOFE
7X2L ... SBN 7 4
7X2W ... PICKREP 6 [SAVE REPLY
7X3B ... MFINDEXOF 3,4 [RE-HUNT EWDAS-EXOF IN CCB CHAIN
7X3W ... LDX 4 COPEN(3)
7X4B ... BNZ 4 XREP [J IF EXOFILE OPEN TO SOMEONE ELSE
7X4W ... FREECORE 3
7X5B ...XREP
7X5W ... PUTREP 6 [PUT REPLY BACK IN EXEC3
7X8= ... TESTREP NOTRAP,XITER,OK,XOK,NOFILE,XTEMP
7X8B ... GEOERR 1,XOFREPER
7X8F ...XOK
7X8G ... LDN 6 12 [EXOFILE ALREADY EXISTS MESS
7X8H ... LDN 7 2
7X8J ... ORX 7 GSIGN [-VE TO INDUCE OL *DA FAIL
7X8K ... BRN ZERROR
7X8W ...XTEMP
7X94 ... BZE 7 XSUNOP [J IF SYSFLE WAS WEXCHOFED
7X96 ... LDN 6 11 [EXOFILE ENTRY DOESNT EXIST MESS
7X98 ... BRN XINTREP
7X9= ...XSUNOP
7X9# ... LDN 6 13
7X9B ... BRN XINTREP
7X*B ...XITER
7X*N ... BZE 7 XSUNOP
7X*W ... LDN 6 10 [REPLIES FOR CHINERR
7XB8 ...XINTREP
7XBB ... LDN 7 2
7XBW ... BRN ZERROR
7XDG [
7XY6 [
7YCQ #
84NF ...XIPB
84SB MHUNTW 3,EWDAS,GEXD
852L ... LDN 0 APLINKF
85RL STO 0 EMARK(3)
86?= UNLOCKSU ESERL(3)
86KL ... MHUNTW 3,EWDAS,GEXD
86QW RELST ESERL(3)
88PB ZFAIL
8992 ACROSS CHINERR,2 [TRANSFER FAIL ON FIP REWRITE
89NL ZERROR
8=8= ACROSS CHINERR,3 [GENERAL ERROR
8=MW ZINTEG
8?7G LDX 7 BACK2(1) [SAVE EXOFILE NUMBER
8?M6 ACROSS CHINERR,4 [INTEGRITY CODE FAIL
8#LB ZIF ACROSS CHINERR,5
8*62 #
8*KL #
8B5= MENDAREA 30,K99CHINTEG
8BJW #END
^^^^ ...16052013000200000000