{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: CLOSEIPB864)}}
====== CLOSEIPB864 ======
(George Source)
**Macros used:** [[george:macro:BXE|BXE]], [[george:macro:DCA|DCA]], [[george:macro:DFJUMPN|DFJUMPN]], [[george:macro:DISENGPER|DISENGPER]], [[george:macro:DSCA|DSCA]], [[george:macro:FINDPEREC|FINDPEREC]], [[george:macro:FSHCODE|FSHCODE]], [[george:macro:FSHSKIP|FSHSKIP]], [[george:macro:JDISENG|JDISENG]], [[george:macro:JEXOTIC|JEXOTIC]], [[george:macro:JFREE|JFREE]], [[george:macro:JIPCM|JIPCM]], [[george:macro:JONL|JONL]], [[george:macro:JRESET|JRESET]], [[george:macro:JSBUSY|JSBUSY]], [[george:macro:JWRONG|JWRONG]], [[george:macro:OP|OP]], [[george:macro:PMCORES|PMCORES]], [[george:macro:RESETIPC|RESETIPC]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:TRACEX|TRACEX]]
23DW #SEG CLOSEIPB8 [R.WEYAND
23YG #LIS K0CLOSEIPB>K0POST>K0ALLGEO
24D6 8HCLOSEIPB
24XQ #
25CB ... SEGENTRY K1CLOSEIPB,XK1CLOSEIPB
26BL #
26DJ ...# ENTRY POINTS FOR SHFS - BEWARE THEY ARE NOT COMPILED IN STD. G3 !!
26GG ...#
26JD ... FSHCODE AORB
26LB ...(
26N# ... SEGENTRY K2CLOSEIPB,XK2CLOSEIPB
26Q= ... SEGENTRY K3CLOSEIPB,XK3CLOSEIPB
26S8 ...)
26W= #
27*W # THIS SEGMENT SENDS END OF IPB OUTPUT AND CLOSE DOWN MESSAGES TO ALL
27TG # IPB'S ON THE INSTALLATION AND ISSUES A DIS TO EACH
28*6 #
28SQ #
29#B PMRW +0 [REPLY WORD
29S2 PMCHA +0 [CHAINING WORD
2=?L PMADDR1 #400:0,#01030000 [END OF IPB OUTPUT
2=R= ...#DEF PMLEN1=0?-PMADDR1
2?=W PMADDR2 #400:0,#01110000 [CLOSE DOWN
2?QG ...#DEF PMLEN2=0?-PMADDR2
2#=6 PMADDR
2#PQ #REP 66
2*9B +0
2*P2 ...#DEF PMLEN=0?-PMADDR
2B8L SSMASK #770000
2BN= ROILL #30000
2C7W READCT +0 [COUNT OF NO. OF READS ATTEMPTED
2C*4 ... SEGENTRY K50CLOSEIPB
2CG= ...SLAB1 8H
2CGH ... +0
2CGS ... 8H
2CH5 ... +0
2CHB ... 8H
2CHM ... +0
2CHY ... 8H
2CJ9 ... +0
2CJG ... 8H
2CJR ... +0
2CK4 ... 8H
2CK* ... +0
2CKL ...S 8H
2CKX ... +0
2CL8 ... 8H
2CLF ... +0
2CLQ ... SEGENTRY K99CLOSEIPB
2CM3 ... -3
2CMG #
2D76 #
2DLQ # THIS SUBROUTINE CHECKS THE REPLY TO A PERI.
2F6B # IT EXITS 0 IF THE PERI WAS REJECTED
2FL2 # IT EXITS 1 IF THE IPB WAS INOPERABLE OR REPLY INDICATED ERROR
2G5L # IT EXITS 2 IF THE REPLY INDICATED TIMED OUT AND/OR NOT IMPLEMENTED
2GK= # IT EXITS 3 IF THE PERI TERMINATED NORMALLY
2H4W # X6 CONTAINS THE LINK AND PMCA+1 CONTAINS THE REPLY WORD
2HJG # IT OVERWRITES X0.
2J46 #
2JHQ #
2K3B REPCHEK
2K5^ ...#SKI K6IPB>100-100
2K8J ...(
2K?7 ... LDX 0 IREP1(2)
2K*Q ... STO 0 GEN0 [DENOTES PERI TYPE TO TRACE ROUTINE
2KD* ...)
2KH2 PERI 0 2
2L2L ... LDX 0 PMRW(1)
2LG= BPZ 0 TER [J IF TRANSFER TERMINATED
2L^W SLC 0 5
2MFG BPZ 0 OP [J IF IPB OPERABLE
2M^6 RINOP EXIT 6 1 [OTHERWISE EXIT INOPERABLE
2NDQ OP SRC 0 1
2NYB BNG 0 REJ [J IF REJECTED
2PD2 ...WAIT LDX 0 PMRW(1) [SEE IF TRANSFER HAS TERMINATED
2PXL BNG 0 WAIT [WAIT FOR TERMINATION
2QC= TER SLC 0 5
2QWW BPZ 0 RINOP [J IF INOPERABLE
2RBG SRC 0 2
2RW6 BNG 0 RINOP [J IF ERROR
2S*Q SLC 0 1
2STB ... BNG 0 REJ [J IF NOT IMPLEMENTED
2T*2 SRC 0 3
2TSL BNG 0 NOTIMP [J IF TIMED OUT
2TT3 ...#SKI K6IPB>100-100
2TTD ...(
2TTT ... LDX 0 ASWITCH1
2TW= ... SLL 0 7
2TWM ... BPZ 0 TRACEX [SWITCH NOT SET(BY MOP TRACE COMMAND)
2TX4 ...[TRACES (ONLINE) SUCCESSFUL CC TRANSFERS IF "MOP TRACE" SWITCHED ON
2TXF ... STO 3 GEN3
2TXW ... STO 4 GEN4
2TY? ... STO 5 GEN5
2TYN ... LDN 5 0
2T^5 ... LDX 4 GEN0
2T^G ... SMO FXPM1
2T^X ... LDEX 0 PMRW
2W2# ... NGX 0 0
2W2P ... BZE 4 TRACEL1 [READ PERI
2W36 ... ADX 0 ICOUNT(2)
2W3H ... SBN 0 PMLEN
2W3Y ...TRACEL1
2W4* ... ADN 0 PMLEN
2W4Q ... LDX 3 2
2W57 ... ADN 3 ISCTSA
2W5J ... BZE 4 TRACEL2 [READ PERI
2W5^ ... SBN 3 ISCTSA-ICTSA
2W6B ...TRACEL2
2W6R ... LDX 3 0(3)
2W78 ...TRACEL3
2W7K ... SMO 5
2W82 ... '177 0 0(3)
2W8C ... 8HCLOSEIPB
2W8S ... ADN 5 1
2W99 ... BCT 0 TRACEL3
2W9L ... LDX 3 GEN3
2W=3 ... LDX 4 GEN4
2W=D ... LDX 5 GEN5
2W=T ...TRACEX
2W?= ...)
2W#= EXIT 6 3 [EXIT IF OK
2WRW NOTIMP
2X?G EXIT 6 2 [EXIT FOR TIMED OUT/NOT IMPLEMENTED
2XR6 REJ EXIT 6 0 [EXIT FOR REJECTED
2Y=Q #
2YQB #
2^=2 # THIS SUBROUTINE SETS UP THE CONTROL AREA FOR A READ PERI.
2^PL # IT OVERWRITES X0
329= # THE LINK IS X6
32NW #
338G #
33D# ...SETRD
33N6 ... JSBUSY 2,SETRD [WAIT TILL READ FINISHES
33XY ... LDN 0 2 [MODE FOR READ
347Q DSCA 2,DLA,0,MODE [MODE FOR READ IN DL - SPOUT AREA
34MB LDN 0 PMLEN [LENGTH OF BUFFER
3572 DSCA 2,DLA,0,COUNT [SET COUNT IN DL
35LL ... LDN 0 PMADDR(1) [BUFFER ADDRESS
366= DSCA 2,STO,0,CTSA [SET TRANSFER START ADDRESS
36KW ... LDCT 0 #400
375G ... ORN 0 PMCHA(1)
37K6 DSCA 2,STO,0,CHADD [SET CHAINING ADDRESS IN SPOUT
384Q ... LDN 0 PMRW(1)
38JB DSCA 2,STO,0,REP1 [SET R.W IN SPOUT
3942 EXIT 6 0
39HL #
39JS ... FSHCODE AORB
39L2 ...(
39M8 ...XK2CLOSEIPB [ ENTRY TO SEND FIRST GEORGE BROKEN
39NB ... LDX 1 FXPM1 [ MESSAGE TO ALL IPC'S FOR SHFS
39PJ ... NGN 7 1 [ SET ENTRY POINT MARKER
39QQ ... BRN PCCLOSE
39RY ...#
39T6 ...XK3CLOSEIPB [ ENTRY POINT FOR SECOND GEORGE
39W# ... LDX 1 FXPM1 [ BROKEN MESSAGE
39XG ... LDN 7 0 [ SET ENTRY MARKER
39YN ... BRN PCCLOSE
39^W ...)
3=3= #
3=GW XK1CLOSEIPB
3=QN ... LDX 1 FXPM1 [BASE ADDRESS OF THIS SEGMENT
3?2G LDN 4 24 [SET TYPE TO IPB
3?G6 NUNIT FINDPEREC 2,APFOTY,4,RFR2 [DOES THE UNIT EXIST?
3?M# ... FSHSKIP [ FOR SHARED FILESTORE OMIT IPC CLOSE
3?SG ...( [ -ALREADY BEEN DONE ON EARLIER ENTRY
3?^Q #SKIP IPCV1
3#FB BNG 2 PCCLOSE [J TO CHECK FOR IPC
3#^2 #SKIP IPCV1-1
3*DL ... BNG 2 (JPMSEG) [J IF NO MORE
3*H9 ...)
3*KS ... FSHCODE AORB [ FOR SHFS IPC CLOSE HAS ALREADY BEEN
3*NC ...( [ SO JUST RETURN TO NEXT OVERLAY
3*R2 ... BNG 2 (JPMSEG)
3*TK ...)
3*Y= JWRONG 2,RFR2 [J IF WRONGED
3BCW JEXOTIC 2,RFR2 [J IF EXOTIC
3BK4 ... JONL 2,PFOUND [JIF ONLINE TO JUST SEND'CLOSEDOWN'
3BQ= ... JFREE 2,PFOUND [JIF UNALLOCATED:JUST SEND'CLOSEDOWN'
3BXG LDN 0 9 [MODE INTO DL ENTRY
3CC6 DCA 2,STO,0,MODE
3CWQ LDN 0 PMLEN1 [COUNT INTO DL
3DBB DCA 2,DSA,0,COUNT
3DW2 ... LDN 0 PMADDR1(1) [BUFFER ADDRESS IN DL
3F*L DCA 2,STO,0,CTSA
3FT= ... LDCT 0 #400 [SET CHAINING ADDRESS IN DL
3G#W ... ORN 0 PMCHA(1)
3GSG DCA 2,STO,0,CHADD [NUMBER - NO CHAINING
3H#6 ...P1 LDN 0 PMRW(1) [SET RW ADDR IN CURRENT AREA
3HRQ DCA 2,STO,0,REP1
3J?B CALL 6 REPCHEK [WRITE END OF IPB OUTPUT AND
3JR2 [CHECK REPLY
3K=L BRN TINP1 [ISSUE READ IF WRITE REJECTED
3KQ= BRN PMDIS [ONLY DIS IF INOPERABLE
3L9W BRN P1 [TRY AGAIN IF NOT IMPLEMENTED OR
3LPG [TIMED OUT
3M96 ... LDX 0 PMRW(1) [SEE IF WRITE WAS
3MNQ ANDN 0 #777 [ENDED AND
3N8B BZE 0 OK1 [J IF NOT
3NN2 TINP1 CALL 6 SETRD [ISSUE READ IF WRITE REJECTED
3P7L [OR ENDED
3PM= CALL 6 REPCHEK [CHECK REPLY
3Q6W BRN PMDIS [JUST DIS IF READ REJECTED
3QLG BRN PMDIS [OR INOPERABLE
3R66 NULL [TRY AND WRITE AGAIN IF NOT IMP.
3R*Y ...P1AGAIN
3RKQ LDN 0 #11 [OR TIMED OUT
3S5B DCA 2,DSA,0,MODE [OR IF READ TERMINATED OK
3SK2 LDN 0 PMLEN1 [SET UP CONTROL
3T4L DCA 2,DSA,0,COUNT [AREA AGAIN
3TJ= ... LDN 0 PMADDR1(1) [FOR END OF IPB OUTPUT
3W3W DCA 2,STO,0,CTSA
3WHG BRN P1
3X36 #
3XGQ #
3Y2B # COME HERE IF END OF IPB OUTPUT WAS WRITTEN SUCCESSFULLY
3YG2 #
3Y^L #
3^F= OK1 CALL 6 SETRD [NOW TRY TO READ REPLY
3^YW P2 CALL 6 REPCHEK [CHECK REPLY
42DG BRN PMDIS [J TO DIS UNIT IF READ REJECTED
42Y6 BRN PMDIS [OR IF IPB INOPERABLE
43CQ BRN P2R [J IF TIME OUT OR NOT IMP.
43XB ... STOZ READCT(1)
44C2 [OR TIME OUT
44WL ... LDX 0 PMRW(1)
45B= ANDN 0 #777 [ISOLATE REMAINDER COUNT
45TW LDN 6 PMLEN [AND GET COUNT OF NO. OF WORDS
46*G SBX 6 0 [INPUT INTO X6
46T6 SBN 6 1 [SUBTRACT 1 FOR BLOCK STATUS WORD
47#Q BZE 6 PMDIS [DIS IF ONLY 1 WORD READ - THIS
47SB [SHOULD NOT HAPPEN
4885 ... LDN 3 1 [INITIALISE MODIFIER FOR INPUT BUFF
48HS ...NXT SMO 1 [GET NO. OF WDS. IN NEXT MESSAGE
48XH ... LDCH 5 PMADDR(3)
49*8 ... BZE 5 RESETRRWA [J IF ZERO - NO MORE SUPERVISORY
49QW [SEGMENTS SO READ AGAIN
4==G SBX 6 5 [UPDATE NO. OF WDS. LEFT TO LOOK AT
4=JX ... SMO 1
4=X# ... LDX 0 PMADDR(3) [ISOLATE
4?9Q SRC 0 12 [SUPERVISORY
4?PB ANDN 0 #77 [CODE
4#92 SBN 0 35
4#NL ... BZE 0 PFOUND [J IF END OF REMOTE OUTPUT(35)
4*8= SBN 0 2
4*MW BZE 0 TILL [J IF ILLEGAL (37)
4B7G SBN 0 16
4BC# ... BZE 0 P1CC [FAIL(53):CRASH CLOSE THE IDENTIFIER
4BM6 ... SBN 0 5
4BWY ... BZE 0 P1CC [UNAVAILABLE(58):CRASH CLOSE THE IDEN
4C6Q ...NXT1 BZE 6 RESETRRWA [READ AGAIN IF NO INPUT LEFT AND
4CLB [HAVE NOT FOUND REQD. SUPERVISORY SG
4D62 ... ADX 3 5 [UPDATE INPUT BUFFER MODIFIER
4DKL BRN NXT [LOOK AT NEXT INPUT SEGMENT
4F26 ...TILL SMO 1
4FBL ... LDX 0 PMADDR+1(3)
4FR6 ... ANDX 0 SSMASK(1)
4G7L ... BXE 0 ROILL(1),PFOUND [J IF ILLEGAL FOR END OF IPB OUTPUT
4GJ6 BRN NXT1
4GK3 ...P1CC LDN 0 #0127 [CONVERT THE END OF IPB OUTPUT
4GKY ... SLL 0 12 [SEGMENT TO A CRASH CLOSE SEGMENT
4GLT ... STO 0 PMADDR1+1(1)
4GMQ ... SMO 1 [TRANSFER THE IDENTIFIER NUMBER TO IT
4GNM ... LDX 0 PMADDR(3)
4GPJ ... DSA 0 PMADDR1+1(1)
4GQF ... LDX 5 6 [PRESERVE READ REMAINDER COUNT
4GRB ...P4 LDN 0 PMRW(1) [SEND 'CRASH CLOSE'
4GS? ... DCA 2,STO,0,REP1
4GT8 ... CALL 6 REPCHEK
4GW5 ... BRN P4R [REJECTED : FORGET IT
4GX2 ... BRN PMDIS [INOPERABLE : DIS
4GXX ... BRN P4 [NOT IMP OR TIME OUT : REPEAT
4GYS ...P4R LDX 6 5 [RESTORE READ REMAINDER COUNT
4G^P ... BRN NXT1 [CHECK REMAINING INPUT
4H2L ...#
4H3Q ...P2R LDX 0 READCT(1)
4HHB SBN 0 IMREPT
4J32 BZE 0 PMDIS [GIVE UP IF TIMED OUT IMREPT TIMES
4JGL ADN 0 IMREPT+1 [OTHERWISE ADD 1 TO COUNT OF
4K2= ... STO 0 READCT(1) [NO. OF READS
4K=4 ...RESETRRWA
4KFW ... LDN 0 PMRW(1) [SET RW ADDR IN SPOUTED AREA
4K^G DSCA 2,STO,0,REP1
4LF6 BRN P2 [AND TRY AGAIN
4LYQ #
4MDB #
4MY2 # COME HERE TO ISSUE 'CLOSE DOWN' COMMAND
4NCL #
4NX= #
4PBW PFOUND
4PWG LDN 0 #11 [SET UP CONTROL AREA
4QB6 DCA 2,DSA,0,MODE [FOR CLOSE DOWN
4QTQ LDN 0 PMLEN2
4R*B DCA 2,DSA,0,COUNT
4RT2 ... LDN 0 PMADDR2(1)
4S#L DCA 2,STO,0,CTSA
4SDH ... LDCT 0 #400 [SET CHAINADD IN DL IN CASE 1ST PERI
4SJD ... ORN 0 PMCHA(1)
4SN* ... DCA 2,STO,0,CHADD
4SS= ...P3 LDN 0 PMRW(1) [SET RW ADDR IN CURRENT AREA
4T?W DCA 2,STO,0,REP1
4TRG CALL 6 REPCHEK [WRITE AND CHECK REPLY WORD
4W?6 BRN TINP2 [TRY TO READ IF WRITE REJECTED
4WQQ BRN PMDIS [DIS IF INOPERABLE
4X=B BRN P3 [REPEAT IF NOT IMP. OR TIME OUT
4XQ2 ... LDX 0 PMRW(1) [LOOK TO SEE IF
4Y9L ANDN 0 #777 [WRITE ENDED AND
4YP= BZE 0 PMDIS [J IF NOT
4^8W TINP2 CALL 6 SETRD [TRY TO READ IF WRITE REJECTED
4^NG [OR ENDED
5286 CALL 6 REPCHEK [CHECK REPLY WORD
52MQ BRN PMDIS [DIS IF READ REJECTED
537B BRN PMDIS [OR IF IPB INOPERABLE
53M2 NULL
546L BRN PFOUND [TRY TO WRITE AGAIN IF TIMED OUT
54L= [OR NOT IMPLEMENTED OR OK
555W PMDIS DISENGPER 2
55KG ... STOZ READCT(1) [ZEROISE TIMED OUT COUNT FOR
5656 [NEXT UNIT
56JQ BRN RFR2 [J TO SEE IF THERE IS ANOTHER
583L PCCLOSE
58H= LDN 4 28 [SET TYPE FOR IPC
592W FINDPEREC 2,APFOTY,4,PRA [LOOK FOR IPC ENTRY
59GG ... BNG 2 (JPMSEG)
5=^B # SEND 'GEORGE BROKEN' MESSAGE TO REMOTE PROCESSOR
5?F2 JDISENG 2,PCC1 [INOPERABLE
5?J6 ... FSHCODE AORB
5?M= ...(
5?QB ... BZE 7 PCCLOSE1
5?TG ...)
5?YL DSCA 2,LDX,3,CHADD
5#8D ... SBN 3 CHAINADD
5#D= JIPCM DS,PCC1,3 [OR DIALOGUE SUSPENDED
5#N4 ...PCCLOSE1
5#XW RESETIPC 2
5*X6 BPZ 0 PCC1 [RESET REJECTED
5BBQ LDX 5 JTIME
5BWB ADN 5 5000/K9
5CB2 PCC8 JRESET 2,PCC7
5CTL DFJUMPN 2,RGM,PCC1 [REMOTE PROCESSOR NOT UNDER GEORGE
5D*= # SET UP WRITE CONTROL AREA
5DSW PCC3 LDN 0 #11 [SET UP C.A.
5F#G DCA 2,DSA,0,MODE
5FS6 LDN 0 3
5G?Q DCA 2,DSA,0,COUNT
5GRB ... LDN 0 PMCADDR(1)
5H?2 DCA 2,STO,0,CTSA
5HQL ... LDN 0 PMRW(1)
5J== DCA 2,STO,0,REP1
5JPW ... LDCT 0 #400
5K9G ... ORN 0 PMCHA(1)
5KP6 DCA 2,STO,0,CHADD
5KPP ...#
5KQ# ... FSHCODE AORB
5KQX ...(
5KRG ... BZE 7 PMSTD [ J. IF ENTRY FOR STD. G3 BROKEN MESS
5KRH ... LDN 6 8
5KRJ ...SDA
5KRK ... LDX 0 SLAB1(1) [TEST IF REQUD TO BREAK MASTER.
5KRL ... BXE 0 ACES,SD1 [NO BREAK REQUIRD.
5KRM ... BZE 0 SD2 [BREAK MASTER REGUARDLESS OF TYPE
5KRN ... SMO GONRDUMP
5KRP ... LDX 0 0 [LD. SLAVES GEOERR.
5KRQ ... SMO GONRDUMP
5KRR ... LDX 3 1
5KRS ... TXU 0 SLAB1(1)
5KRT ... TXU 3 SLAB1+1(1)
5KRW ... BCC SD2
5KRX ... ADN 1 3
5KRY ... BCT 6 SDA
5KR^ ... BRN SD1
5KS2 ...SD2
5KS3 ... LDX 0 SLAB1+2(1)
5KS4 ... BRN STONO [PASS -2 TO MASTER MACHINE.
5KS5 ...SD1
5KS6 ... LDX 3 FX2 [ ELSE WE NEED TO ALTER THE MESSAGE
5KSN ... PMCORES 3,TERFX2 [ CHECK THAT FX2 IS LEGAL
5KT? ... LDX 0 JOBNO(3) [ GET JOB NO FOR CURRENT ACTIVITY
5KTW ... BZE 0 USEACTN [ IF NO USER CONTEXT USE ACT NO
5KWF ... LDCT 6 #400 [ ELSE SET BIT 0 TOSHOW JOB NO USED
5KX4 ... ORX 0 6
5KXM ... BRN STONO [ J. TO PUT IN MESSAGE
5KY= ...TERFX2
5KYT ... NGN 0 1 [ IF FX2 ILLEGAL - SET JOB/ACT NO=-1
5K^D ... BRN STONO [ J. TO PUT IN MESSAGE
5L23 ...USEACTN
5L2L ... LDX 0 ACTNUM(3) [ USE ACTIVITY NO. IF NO USER CONTEXT
5L39 ... BNZ 0 STONO [ JIF NOT ACT NO. 0
5L3S ... LDCT 6 #400 [ ELSE SET BIT 0 OF ACT NO. TO LOOK
5L4C ... ORX 0 6 [LIKE JOBNO(0 LOOKS LIKE 2ND MESSAGE)
5L52 ...STONO
5L5K ... STO 0 PMCADDR+1(1) [ PUT JOB/ACT NO IN SECOND WORD
5L68 ... ADX 0 PMCADDR(1) [ RECALCULATE CHECKSUM
5L6R ... NGS 0 PMCADDR+2(1) [ AND STORE IN LAST WORD
5L7B ...PMSTD
5L7^ ...)
5L8Q # ISSUE PERI & CHECK REPLY
5LNB PERI 0 2
5M82 LDX 5 JTIME
5MML ADN 5 5000/K9
5N7= ...PCC2 LDX 0 PMRW(1)
5NLW BPZ 0 PCC5 [TERMINATED
5P6G TXL 5 JTIME
5PL6 ... BCC PCC2 [WAIT
5PQ3 ... FSHCODE AORB
5PTY ...#SKI
5P^T ...(
5Q5Q BRN PCC1 [TIMED-OUT
5Q8* ...)
5Q=Y ... FSHCODE AORB
5Q*H ...(
5QD6 ... BRN PCC9
5QGP ...)
5QKB ...PCC5 SLC 0 5
5S4= BPZ 0 PCC1 [INOPERABLE
5SHW SRC 0 2
5T3G BNG 0 PCC1 [RESET
5T65 ... FSHCODE AORB
5T8N ...(
5T?? ... SLC 0 1 [JIF ALREADY IMPLEMENTED
5T*W ... BPZ 0 PCC1
5TDF ...)
5TH6 # CONTENTION LOST,ACCEPT INPUT
5W2Q LDN 0 #12
5WGB DSCA 2,DSA,0,MODE
5X22 LDN 0 11
5XFL DSCA 2,DSA,0,COUNT
5X^= ... LDN 0 PMADDR(1)
5YDW DSCA 2,STO,0,CTSA
5YYG ... LDN 0 PMRW(1)
5^D6 DSCA 2,STO,0,REP1
5^XQ ... LDCT 0 #400
62CB ... ORN 0 PMCHA(1)
62X2 DSCA 2,STO,0,CHADD
63BL # ISSUE READ PERI & CHECK REPLY
63W= LDX 5 JTIME
64*W ADN 5 5000/K9
64TG PERI 0 2
65*6 ...PCC4 LDX 0 PMRW(1)
65SQ BPZ 0 PCC6 [TERMINATED
66#B TXL 5 JTIME
66S2 ... BCC PCC4 [WAIT
66XX ... FSHCODE AORB
673S ...#SKI
677P ...(
67?L BRN PCC1 [TIMED-OUT
67B9 ...)
67DS ... FSHCODE AORB
67HC ...(
67L2 ... BRN PCC9
67NK ...)
67R= ...PCC6 LDX 0 PMADDR(1)
69=6 ANDN 0 #77
69PQ SBN 0 #71
6=9B BZE 0 PCC1 [INITIALISE MESSAGE
6=?5 ... FSHCODE AORB
6=#S ...(
6=BH ... SBN 0 6
6=D= ... BNZ 0 PCC3 [JIF NOT ERROR CODE
6=F^ ... LDN 0 #1000 [ ELSE CHECK WHETHER
6=HN ... ANDX 0 PMADDR(1) [ 'GEORGE BROKEN' MESSAGE
6=KC ... BNZ 0 PCC1 [ J. TO GIVE UP IF IT WAS !
6=M6 ...)
6=P2 BRN PCC3
6?8L PCC1
6?N= )
6?RB ... FSHCODE AORB
6?WG ...(
6?^L ... BNZ 7 PRA [DONT DO 'DIS' IF NOT LAST TIME
6#4Q ...)
6#58 ... FSHCODE AORB
6#5L ...(
6#64 ... SMO FXPMDR
6#6G ... LDX 0 ERRORTYPE
6#6Y ... BNG 0 PRA
6#7B ...)
6#7W DISENGPER 2 [DISENGAGE UNIT
6#=5 ... FSHCODE AORB
6### ...(
6#BH ... LDX 0 GSIGN
6#DQ ... SMO FXPMDR
6#G^ ... ORS 0 ERRORTYPE
6#K8 ...)
6#MG BRN PRA
6B6B PCC7 TXL 5 JTIME
6BL2 ... BCC PCC8
6C5L BRN PCC1
6C7T ... FSHCODE AORB
6C=4 ...(
6C#? ...PCC9
6CBG ... RESETIPC 2
6CDP ... BRN PCC1
6CGY ...)
6CK= ...PMCADDR #03001077
6D4W +0
6DJG ... #74776701
6G3B #END
^^^^ ...11713310001300000000