{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: CONIPB8)}}
====== CONIPB8 ======
(George Source)
**Macros used:** [[george:macro:ALTLENG|ALTLENG]], [[george:macro:CHAIN|CHAIN]], [[george:macro:CHECKB|CHECKB]], [[george:macro:CLEAR|CLEAR]], [[george:macro:FADDRESS|FADDRESS]], [[george:macro:FINDJOBQ|FINDJOBQ]], [[george:macro:FOUTMOVE|FOUTMOVE]], [[george:macro:FPUT|FPUT]], [[george:macro:FREECORE|FREECORE]], [[george:macro:HUNT2|HUNT2]], [[george:macro:HUNT2B|HUNT2B]], [[george:macro:HUNT2J|HUNT2J]], [[george:macro:HUNT2OPT|HUNT2OPT]], [[george:macro:HUNTACT|HUNTACT]], [[george:macro:HUNTW|HUNTW]], [[george:macro:ILLEGALX|ILLEGALX]], [[george:macro:JBC|JBC]], [[george:macro:LINK|LINK]], [[george:macro:LOCKCA|LOCKCA]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:OLPFIN1|OLPFIN1]], [[george:macro:PAIR|PAIR]], [[george:macro:PROGRING|PROGRING]], [[george:macro:RELOFP|RELOFP]], [[george:macro:SCBB|SCBB]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:TESTPROG|TESTPROG]], [[george:macro:TICKLES|TICKLES]], [[george:macro:TOPCA1|TOPCA1]], [[george:macro:UNPLUG|UNPLUG]], [[george:macro:UNQUEUE|UNQUEUE]], [[george:macro:UP|UP]], [[george:macro:WORDSIN|WORDSIN]], [[george:macro:WORDSOUT|WORDSOUT]]
22FL SEG CONIPB,,JOHN BAILEY
22PD ...#OPT CONTROL=#34
22^= #LIS K0CONIPB>K0IPB>K0ALLGEO
23DW 8HCONIPB70
23YG #
24D6 #
24XQ # THIS SEGMENT DEALS WITH PERIS FOR A CONCEPTUAL IPB
25CB #
25X2 SEGENTRY K1CONIPB,XK1
26BL SEGENTRY K3CONIPB,XK3
26W= PJYMODE +JYMODE
27*W PJYNOBUF +JYNOBUF
27TG PJYCOUNT +JYCOUNT
28*6 PAIR LINK CONIPB,1
28SQ #
29#B #
29** ...VCON2 LDX 2 FX2
29B# ...VCON
29C? ... LDN 1 0
29D= ... LDX 0 AWORK2(2)
29F9 ... BNZ 0 YNOLP [J IF RUNNING IN OLPA
29G8 ... LDX 2 IPBRING(2)
29H7 ... SBN 2 IPBRING [FIND OLPA
29J6 ... LDN 1 CONCALEN [POINT TO 2ND CONTROL AREA
29K5 ...YNOLP HUNT2 2,AMXOR,CONTROL [FIND CONTROL AREA BLOCK
29L4 ... ADN 2 CONCA1(1) [[CONTROL AREA
29M3 ... SMO FX2
29N2 ... STO 2 AWORK4 [SAVE CA POINTER
29N^ ... LDX 2 FX2
29PY ... LDX 1 FX1
29QX ... EXIT 6 0
29S2 SCOK1 LDX 3 AWORK4(2)
2=?L STO 5 1(3) [SET REPLY IN OP CA
2=CH ...SCOK3
2=HD ...SCOK5 LDX 2 FX2
2=M* ... LDX 1 APETADDR(2) [APET
2=R= ... LDX 3 AWORK4(2) [STORED CA ADDR
2=X7 ... LDX 4 1(3) [REP WD VALUE
2?34 ... LDX 3 CONCAD(3) [PROGRAMS
2?6^ ... ADN 3 1 [PROGRAMS REP WD
2?=W ... FADDRESS 1,3,HLOCK1,2 [G ADDR OF REP WD
2?BR ... STO 4 0(3) [SET REP WD
2?DP ...ZLVIN
2?GN ... LDX 1 FX1
2?LK ... OLPFIN1 PAIR(1)
2?QG #SKI G4
2#=6 (
2#C# ...SCF5 LDX 2 1
2#JG ... LDX 1 6
2#PQ SCF4 CLEAR 1,0,HLOCKB1,2,2
2*9B FREECORE 2
2*P2 EXIT 5 0
2B8L RMG4 LDX 2 FX2
2BN= LDX 2 ACOMMUNE1(2) [CSTATE
2C7W SBN 2 A1
2CMG LDX 2 FPTR(2) [HLOCKDOWN
2D76 ... WORDSIN 1,6,5,4,HLOCKB2,2
2F6B BRN RMIN1
2FL2 )
2G5L #
2GK= # THIS ROUTINE MOVES THE DATA TO THE PROGRAM
2H4W # AND SUBTRACTS THS AMOUNT FROM THE O/L COUNT
2HJG #
2J46 RMIN LDX 6 3(1) [LOAD READ ADDRESS
2JHQ STOZ 1(1) [ZERO REPLY WORD
2K3B LDX 1 AWORK3(2) [PCA
2K5^ ... LDXC 5 IMOPTY(3)
2K8J ... BCS TCONZ [J IF CONTINUATION BLOCK
2K?7 ... NGN 5 #101
2K*Q ... ANDS 5 IBSW(3) [UNSET "SUSPEND 1WD END RD"
2KD* ...TCONZ
2KH2 LDN 5 IBSW(3) [START ADDRESS OF DATA
2L2L #SKI G4
2LG= (
2L^W LDX 2 AWORK2(2) [DATA BEEN PASSED WHILE READ UP
2MFG BZE 2 RMG4 [-> YES
2NDQ )
2NN2 ... WORDSIN 1,6,5,4,HLOCK2
2NX= ...#SKI G4
2P6G ...RMIN1
2P*S ... LDX 2 FX2
2QC= LDX 1 ACOMMUNE2(2) [ADDRESS OF IPBCCA
2QWW ADN 4 1
2RBG SBS 4 INLOAD(1) [SUBTRACT FROM O/L COUNT
2RW6 EXIT 7 0
2S*Q #
2STB # THIS ROUTINE CHECKS WHETHER READ ARE ALLOWED
2T*2 #
2TSL SROK LDX 3 ACOMMUNE1(2) [ADDRESS OF CSTATE BLOCK
2W#= CALL 5 RHRC
2WRW LDX 4 ICA(3) [IS AREAD UP ?
2X?G BNG 4 SROK1 [-> NO
2XR6 SROK2 LDCT 5 #420 [REJECTED OPERABLE REPLY
2Y=Q BRN SCOK1
2YQB SROK1 LDCT 5 #400 [ACCEPTED REPLY
2^=2 LDX 3 AWORK4(2) [ADDRESS OF OP CA
2^PL STO 5 1(3) [SET ACCEPTED REPLY
329= EXIT 7 0
32NW #
338G # THIS ROUTINE CHECKS WHETHER WRITES ARE ALLOWED
33N6 #
33WB ...SWOK HUNTW 3,AMXOR,IOUT
344L ... BPZ 3 SWOK1 [J IF LAST WRITE LIMITED...
34=W ...[ [... AS MUST BE LEGAL TO SEND NEW ONE
34F6 ... LDX 3 2
34MB SWOKH HUNT2J 3,AMXOR,ICONIN,,SWOK1 [DATA BLOCK TO BE READ IN
3572 LDX 4 IMOPTY(3) [TEST IF LAST READ LIMITED
35LL ORX 4 IBSW(3) [OR IF NEXT SEG VITAL
366= SLL 4 1
36KW BNG 4 SROK2 [-> YES
375G LDX 4 IMOPTY(3)
37K6 BNG 4 SWOKH
384Q SWOK1 EXIT 7 0
38JB #
3942 RFIC MHUNTW 2,AMXOR,ICONIN
39HL EXIT 1 0
3=3= #
3=GW # THIS ROUTINE FINDS THE REQUIRED BLOCKS
3?2G #
3?G6 RHRC LDX 3 IPBRING(2)
3?^Q SBN 3 IPBRING [IPBCCA
3#FB STO 3 ACOMMUNE2(2) [ADDRESS OF IPBCCA
3#^2 EXIT 5 0
3*DL #
3*Y= SUCB SBX 7 FX1
3BCW ... SETUPCORE 4,1,AMXOR,IOUT
3BXG ADX 7 FX1
3CC6 STOZ IMOPTY(1)
3CWQ EXIT 7 0
3DBB #
3DW2 SUCS LDX 3 FX2
3F*L SUCS1 HUNT2 3,AMXOR,CSTATE
3FT= LDX 2 FX2
3G#W ADN 3 A1
3GSG STO 3 ACOMMUNE1(2)
3H#6 EXIT 6 0
3HRQ #
3J?B SCCC ADX 6 FX1
3JR2 ...SCBB
3K=L ...SCBB1 LDX 7 6
3KQ= ... CALL 6 VCON2 [REFIND CA
3L9W ... LDX 6 7
3LPG ... LDX 7 AWORK4(2) [SAVE CA ADDR
3M96 EXIT 6 0
3MNQ #
3N8B SCBA SBX 6 FX1
3NN2 SCBA1 LDX 3 AWORK4(2)
3P7L CHECKB 3(3),2(3),RESV,APETADDR(2),5,SCCC,,,XK1
3PM= ADX 6 FX1
3Q6W EXIT 6 0
3QLG #
3R66 RHUT HUNTW 1,AMXOR,IOUT
3RKQ EXIT 6 0
3S5B #
3SK2 REST LDX 5 1 [SAVE LINK
3T4L CALL 6 RHUT [FIND IOUT BLOCK
3TJ= LDX 2 1
3W3W EXIT 5 0
3WHG #
3X36 SOLPA SBN 1 A1 [POINT TO START OF CSTATE
3XGQ HUNTACT AOLPT,2,1
3Y2B EXIT 6 0
3YG2 #
3Y^L # ILLEGAL ROUTINE
3^F= #
3^YW TODIL LDX 1 FX1
42DG LDX 5 PJYMODE(1)
42Y6 TODIE LDX 2 FX2
43CQ TOPCA1 PAIR(1)
43XB UNPLUG
44C2 ILLEGALX 5
44WL RESV LDX 1 FX1
45B= LDX 5 PJYNOBUF(1)
45TW BRN TODIE
468? ...PCNT LDX 1 FX1
46GN ... LDX 5 PJYCOUNT(1)
46T6 BRN TODIE
47#Q #
47SB XK1 STO 1 AWORK2(2)
48#2 LDX 1 APETADDR(2) [PCA ADDRESS
48RL LDX 3 EVENT2(2) [OP ADDRESS OF CA
49?= LOCKCA 1,3,3,2
49QW LDX 5 0(3) [MODE
4==G STO 3 AWORK4(2) [SAVE ADDRESS OF CA
4=Q6 ... LDX 1 FX1
4?9Q ANDX 5 BSP16 [ISOLATE MODE
4?PB STO 5 AWORK1(2) [SAVE MODE
4#92 LDN 4 #1000
4#NL TXU 5 4 [MODE #1000 ?
4*8= BCC T1000
4*9S ... CALL 6 VCON
4*?B ... LDN 6 4 [4 WD CA
4*#Y ... LDX 4 AWORK4(2) [ADDR FOR CA
4*BG ... LDX 1 APETADDR(2)
4*D4 ... LDX 3 EVENT2(2) [OP CA ADDR
4*FL ... SMO 4
4*H8 ... STO 3 CONCAD [SAVE CA ADDR
4*JQ ... FOUTMOVE 1,3,4,6,HLOCK1,2 [+MOVE CA INTO CONTROL BLOCK
4*L# ... LDX 3 AWORK4(2) [ADDR OF STORED CA
4*MW LDX 4 2(3) [COUNT OF DATA
4B7G BZE 4 PCNT [-> ZERO COUNT
4BM6 SBN 5 #11
4C6Q BPZ 5 TLEST [-> IF MODE #11,#12,#15
4CLB ADN 5 #10
4D62 TLEST LDN 4 5
4DKL TXL 5 4 [MODES > 6 ILLEGAL
4F5= BCC TODIL
4FJW SMO 5
4G4G BRN TBRAN [BRANCH TO APP. ROUTINE
4GJ6 TBRAN BRN T1M11
4H3Q BRN T2M12
4HHB BRN TODIL
4J32 BRN TODIL
4JGL BRN T1M11
4K2= #
4KFW # MODE 2 & 12
4K^G #
4LF6 T2M12 LDN 5 CHREAD
4LYQ CALL 6 SCBA
4MDB CALL 6 SUCS
4MY2 CALL 7 SROK [CHECK READ ALLOWED
4NCL HUNTW 3,AMXOR,ICONIN [IS THERE ANY DATA WAITING
4NX= BNG 3 T2ND [-> NO
4PBW LDX 4 APETADDR(2)
4PWG STO 4 AWORK3(2)
4QB6 T2OW LDX 4 ALOGLEN(3) [LENGTH OF BLOCK
4QTQ SBN 4 1 [LENGTH OF DATA
4R*B LDX 1 AWORK4(2) [GA OF CA
4RT2 LDX 5 2(1) [LENGTH OF READ
4S#L TXL 5 4
4SS= BCS T2LT [-> IF READ < LENGTH OF DATA
4T?W T2NL CALL 7 RMIN
4TRG LDX 1 AWORK4(2) [GA OF CA
4W?6 LDX 5 2(1) [LENGTH OF READ
4WQQ SBX 5 4 [REDUCE COUNT IN CA
4X=B ADN 5 1
4XQ2 DSA 5 1(1) [PUT REDUCED COUNT IN REPLY WORD
4Y9L FREECORE 3
4YP= LDCT 5 #010 [OPERABLE REPLY
4^8W LDX 1 AWORK4(2) [GA OF CA
4^NG T2SR ORS 5 1(1) [SET IN REPLY WORD
5286 TOTK LDX 3 AWORK2(2) [FX2 = OLPA
52MQ BNZ 3 SCOK3 [-> YES
537B LDX 1 ACOMMUNE1(2) [CSTATE
53M2 CALL 6 SOLPA
53NS ... LDX 7 2
53QL ... LDX 6 APETADDR(2)
53SD ...#SKI G4
53W= ... HUNT2 1,ADATA,HLOCKDOWN,2
53Y4 ... LDX 2 FX2
53^W ... SMO AWORK4(2)
543N ... LDX 3 CONCAD [OP CA ADDR
545G ... ADN 3 1 [REP WD
547# ... FADDRESS 6,3,HLOCKB1,1 [TRANS. TO G ADDR
5496 ... SMO AWORK4(2)
54=Y ... LDX 0 1 [REP WD ADDR
54#Q ... STO 0 0(3) [PUT IT IN PROGRAM
54BJ ...#SKI G4
54DB ... CALL 5 SCF5 [CLEAR LOCKDOWN ENTRIES
54D^ ... LDCT 0 #400
54FJ ... ORS 0 ICA(2) [SHOW READ FINISHED
54G8 ... LDX 2 7 [OLPA ADDR
54JB ...TICK
54LJ ... LDX 0 JOBNO(2)
54NQ ... STO 0 ACOMMUNE2(2)
54QY ... TICKLES 2,3 [TICKLE RELEVENT MEMBER
54T6 ... FINDJOBQ 3,ACOMMUNE2(2),(GEOERR) [FIND JOB BLOCK
54X# ... JBC TICK1,3,JBREPRI [J. IF REALTIME PIORITY CLEAR
54^G ... PROGRING LOCKOFF
553N ...TICK1
555W UP
55KG T2LT LDX 4 5 [SET UP CORRECT LENGTH
5656 SBN 5 1 [READ OF ONE WORD
56JQ BNZ 5 T2ME [-> NO
56NT ... LDX 0 AWORK2(2)
56SY ... BZE 0 VRCCA [J IF RUNNING IN IPBCCA
56^3 ... LDX 0 AWORK1(2)
5756 ... SBN 0 #12
5799 ... BNZ 0 NENRN [J IF NOT END READ
57*# ... LDXC 0 IMOPTY(3)
57FC ... BCS NENRN [J IF CONTINUATION BLOCK
57KG ... LDN 0 #100
57PK ... ANDX 0 IBSW(3)
57TN ... BNZ 0 T2ND [J IF SUSPEND 1WD END RD SET
57^R ...VRCCA
585W ...NENRN
589^ ... LDX 1 3
58B4 ...T2V LDX 7 1 [POINTER TO LAST VITAL SEGMENT
58G7 ... HUNT2J 1,AMXOR,ICONIN,,T2NV [HUNT FOR NEXT ICONIN
58L= ... LDCT 0 #200
58Q* ... ANDX 0 IBSW(1)
58WD ... BNZ 0 T2V [JUMP IF NEXT SEGMENT VITAL
596G ...T2NV LDCT 0 #100
59BK ... SMO 7
59Q# ... ORS 0 IBSW [SET LAST VITAL SEGMENT MARKER
5=63 ... LDX 1 AWORK4(2) [GA OF CA
5=FQ T2ME CALL 7 RMIN
5=^B LDN 5 1
5?F2 ADS 5 INLOAD(1) [UPDATE O/L COUNT
5?YL ADN 5 1
5#D= TXU 5 4 [READ OF ONE WORD
5#XW BCC T2NC [-> YES
5*CG LDX 7 ALOGLEN(3)
5*X6 SBX 7 4 [LENGTH OF DATA STILL TO BE READ
5BBQ LDN 6 IBSW(3) [START OF DATA BLOCK
5BWB LDX 5 6
5CB2 ADX 5 4 [START OF DATA STILL TO BE READ
5CTL SBN 5 1
5D*= SMO 7
5DSW MOVE 5 0 [OVERWRITE DATA READ BY DATA STILL
5F#G ADN 7 1 [ TO BE READ
5FS6 T2ERL LDCT 5 #600
5G?Q ORS 5 IMOPTY(3) [SET LIMIT MARKER
5GRB LDX 1 ALOGLEN(3)
5H?2 SBX 1 7
5HQL BZE 1 T2NC
5J== ALTLENG 3,7,RFIC
5JPW T2NC LDX 1 AWORK4(2)
5K9G LDX 6 AWORK1(2) [MODE
5KP6 SBN 6 2 [IS IT JUST A READ ?
5L8Q ... BNZ 6 TAWEN [-> NO, END READ
5LNB LDCT 5 #110 [SET LIMIT OPERABLE REPLY
5M82 BRN T2SR
5MML T2UL LDCT 5 #200
5N7= ORS 5 IMOPTY(3)
5NLW ERS 5 IMOPTY(3) [UNSET LIMIT MARKER
5P6G LDCT 5 #010
5PL6 BRN T2SR
5Q5Q T2ND LDX 0 EVENT2(2)
5QKB LDX 1 ACOMMUNE2(2) [CCA
5R52 STO 0 ICA(1) [OP ADDRESS OF CA IN IPBCCA
5RJL LDX 0 JTIME
5S4= STO 0 ITIME(1) [TIME IN IPBCCA
5SHW #SKI G4
5T3G (
5TH6 SETNCORE 9,1,ADATA,HLOCKDOWN
5W2Q CALL 6 SUCS [GET CSTATE ADDRESS
5WGB LDN 6 HLOCK1(2) [START OG LOCK ENTRIES
5X22 LDN 7 HLOCKB1(1) [START OF NEW LOCK ENTRIES
5XFL MOVE 6 8
5X^= LDN 7 2 [NO. OF ENTRIES
5YDW DCH 7 HLOCKBN(1)
5YYG SBN 3 A1
5^D6 CHAIN 1,3 [CHAIN INFRONT OF CSTATE
5^XQ CLEAR 2,2 [-> YES
6248 ...)
628L ... CALL 6 VCON2
62*4 ... LDX 6 AWORK4(2)
62FG ... SMO 6
62KY ... LDN 7 CONCALEN
62QB ... MOVE 6 CONCALEN [ MOVE CA TO 2ND ENTRY IN CONTROL BLO
62X2 BRN SCOK3
639C ...SMCWL LDX 2 7
63HS ... LDX 7 ALOGLEN(1)
63P3 ... SEGENTRY K90CONIPB
643D ... NULL [DISREGARD BSW
64*W ADX 7 4 [NEW LENGTH OF BLOCK
64BP ... BZE 2 WRTOK
64CJ ... ADN 2 1
64DC ... LDX 0 7
64F= ... SBX 0 2
64G5 ... BNG 0 WRTOK
64GY ... BNZ 0 SMLOVA [J UNLESS JUST RIGHTT LENGH FOR WRITE
64HR ... LDCT 0 #400
64JL ... SMO FX2
64KF ... ORS 0 ACOMMUNE9 [SET AC9 NON ZERO SO WE END THE WRITE
64L# ... BRN WRTOK
64M7 ...SMLOVA
64N2 ...[ J IF TOTAL BLOCK WITHIN BUFFER SIZE
64NT ... SMO FX2
64PN ... ADS 0 ACOMMUNE9 [SAVE REMAINDER CT.
64QH ... SBX 4 0
64RB ... LDX 7 2 [SET NEW LTH FOR IOUT
64S9 ...WRTOK
64TG ALTLENG 1,7,REST
65*6 CALL 6 RHUT
65SQ SBX 7 4 [ORIGINAL LENGTH
66#B ADX 1 7
66J8 ... SEGENTRY K91CONIPB
66^8 ... NULL
67B8 ... NULL [PLACE POINTER PAST BSW
67R= BRN SMCW1
68=W T5M15 LDX 1 ACOMMUNE2(2) [IPBCCA
68QG LDX 7 ICA(1) [IS A READ UP
69=6 BNG 7 SMCWX [-> NO
69C# ... ADN 7 1
69JG ...[ POINT TO REP WD
69PQ #SKI G4
6=9B (
6=P2 LDX 3 ACOMMUNE1(2) [CSTATE
6?8L SBN 3 A1
6?N= LDX 4 FPTR(3) [DATA/HLOCKDOWN BLOCK
6#7W FADDRESS APETADDR(2),7,HLOCKB1,4
6#MG LDX 1 APETADDR(2)
6*76 LDX 2 4
6*LQ CALL 5 SCF4 [CLEAR ENTRIES IN LOCKDOWN BLOCK
6B6B [ AND FREE THE BLOCK
6BL2 )
6C5L #SKI G3
6CK= (
6D4W LDX 2 APETADDR(2)
6DJG FADDRESS 2,7,HLOCK1
6F46 LDX 2 FX2
6FHQ )
6G3B LDX 3 7
6GH2 LDX 6 GSIGN
6H2L LDX 1 ACOMMUNE2(2) [IPBCCA
6HG= ORS 6 ICA(1) [UNSET READ MARKER
6H^W LDCT 6 #030 [NOT IMPLEMENTED/OPERABLE REPLY
6JFG ... STO 6 0(3) [SET REPLY
6J^6 BRN SMCWX
6K2# ...[
6K3G ...[
6K4N ...TAWEN SBN 5 2
6K5W ... BNZ 5 T2UL
6K74 ...[ [J IF NOT 1WD END READ
6K8= ... LDX 5 IBSW(3)
6K9D ... SLL 5 1
6K=L ... ORX 5 IMOPTY(3)
6K?S ... BNG 5 T2UL [J IF VITAL OR CONTINUATION
6K*2 ... LDN 5 #100
6KB8 ... ORS 5 IBSW(3) [SET "SUSPEND 1WD END READ"
6KCB ... BRN T2UL
6KDQ #
6KYB # MODE 1,5,11 & 15
6LD2 #
6LXL T1M11 LDN 5 CHWRITE
6MC= CALL 6 SCBA
6MWW CALL 6 SUCS
6NBG CALL 7 SWOK
6NW6 LDX 3 ACOMMUNE1(2) [CSTATE ADDRESS
6P*Q CALL 5 RHRC
6PTB LDX 1 AWORK1(2) [MODE
6Q*2 ANDN 1 4 [MODE 5 OR #15
6QSL BNZ 1 T5M15 [-> YES
6R#= SMCWX LDX 1 AWORK4(2)
6RRW LDX 4 2(1)
6S?G SMCW LDX 3 3(1) [OP ADDRESS OF BUFFER
6S## ... LDX 2 FX2
6S*6 ... STOZ ACOMMUNE9(2)
6S*Y ... MHUNTW 1,AMXOR,CSTATE
6SBQ ... LDX 1 A1(1)
6SCJ ... LDX 7 IDMDNPU(1) [GET BUFFER SIZE
6SDB ... ANDN 7 #7777
6SF8 ... BZE 7 WRLOK [J IF BEFORE INITIALISE
6SG2 ... LDX 0 4
6SGS ... SBX 0 7
6SHL ... BNG 0 WRLOK [J IF WRITE WITHIN BUFFER SIZE
6SJD ... BNZ 0 SMLOV [J IF WRITE =NOT = MAX LTH.
6SK= ... LDCT 0 #400
6SL4 ... ORS 0 ACOMMUNE9(2) [SET AC9 SO WE MARK WRITE ENDED
6SLW ... BRN WRLOK
6SMN ...SMLOV
6SNG ... STO 0 ACOMMUNE9(2) [ELSE SAVE REMAINDER COUNT
6SP# ... SBX 4 0
6SQ6 ...WRLOK
6SR6 CALL 6 RHUT [FIND IOUT BLOCK
6T=Q BPZ 1 SMCWL [-> IF THERE IS ONE
6TQB ADN 4 1 [UPDATE LENGTH OF NEW BLOCK
6W=2 CALL 7 SUCB
6WPL SBN 4 1 [RESET TO LENGTH OF DATA
6WXW ...SMCW1 LDX 7 1
6X66 ... CALL 6 VCON [FIND CA
6X#B ... LDX 1 7
6XGL ... LDX 7 4 [LENGTH OF MOVE
6XNW LDN 4 IBSW(1) [ADDRESS TO MOVE TO
6Y8G LDX 1 APETADDR(2)
6YN6 ... WORDSOUT 1,3,4,7,HLOCK2
6^7Q ... CALL 6 SUCS
6^MB CALL 5 RHRC
7272 LDCT 5 #110 [LIMITED , OPERABLE REPLY
72#8 ... LDX 0 ACOMMUNE9(2)
72FB ... BNZ 0 SMLFT [J IF REMAINDER CT. NONZERO
72LL LDX 6 AWORK1(2) [MODE
736= SBN 6 #10 [MODE 1 OR 5
73KW BNG 6 T1WN [-> YES
73TN ...SMLFT
745G CALL 6 RHUT
74K6 LDX 7 ALOGLEN(1)
754Q ADS 7 IOUTLOAD(3) [UPDATE O/L COUNT
75JB LDX 3 ACOMMUNE1(2) [CSTATE +A1
7642 LDX 3 0(3)
76HL ADX 3 BSTART(3)
773= CHAIN 1,BPTR(3)
77GW LDCT 5 #010 [OPERABLE REPLY
77LR ... LDX 0 ACOMMUNE9(2)
77QN ... ANDN 0 #7777
77WK ... ORX 5 0 [ADD IN REMAINDER CT.
782G SMCW2 LDX 3 ACOMMUNE2(2) [IPBCCA ADDRESS
78G6 LDEX 4 ATYPE(3) [IS IT WAITING?
78^Q BZE 4 T1WN [-> NO
79FB LDX 2 3
79^2 UNQUEUE
7=DL FPUT
7=Y= T1WN CALL 6 SCBB
7?CW LDX 3 7 [GA OF CA
7?XG STO 5 1(3)
7#C6 BRN SCOK3
7#WQ #
7*BB # MODE 1000
7*W2 #
7B*L T1000 CALL 6 SUCS
7BCN ... LDX 3 ACOMMUNE1(2)
7BFQ ... CALL 5 RHRC [FIND IPBCCA
7BHS ... LDN 4 0
7BKW ... LDX 7 ICA(3)
7BMY ... BNG 7 TNRDZ [J IF NO READ UP
7BQ2 ... LDCT 4 #20 [REJECTED REPLY
7BS4 ...TNRDZ ORX 4 GSIGN
7BW6 ... LDX 3 EVENT2(2)
7BY8 ... ADN 3 1 [REP WD ADDR
7C2= ... LDX 1 APETADDR(2)
7C4# ... FADDRESS 1,3,HLOCK1,2
7C6B ...[ GET G ADDR OF REP WD
7C8D ... STO 4 0(3) [SET REPLY
7C=G ... BPZ 7 ZLVIN [OLPFIN IF REJECTED
7C#W LDN 6 CHAINADD(2)
7CSG ORX 6 GSIGN [SET TOP BIT TO MAKE CHECK VALID
7D#6 HUNT2B 1,APERI,APERIRES,2
7DRQ T100A LDX 7 A1+1(1) [NEXT APERIRES ENTRY
7F?B TXU 6 7 [THIS OLPA'S ENTRY
7FR2 BCC T100B [-> YES
7G=L ADN 1 2 [UPDATE POINTER
7GQ= BRN T100A
7H9W T100B RELOFP A1(1)
7HPG #
7J59 ...XK3 LDXC 0 ICA(2)
7JDY ... BCS REN [J IF READ CANCELLED
7JSM ... STOZ AWORK2(2) [ENTRY POINT FOR CCA ACTIVITY
7K8B MHUNTW 1,AMXOR,CONDCB
7KN2 STO 2 ACOMMUNE2(2) [CCA
7L7L LDX 1 A1+FPTR(1)
7LM= STO 1 ACOMMUNE1(2) [CSTATE
7M6W CALL 6 SOLPA
7NKQ LDX 3 APETADDR(2)
7P5B SMO FX2
7PK2 STO 3 AWORK3
7PWB ... LDX 3 2
7Q7Q ... CALL 6 VCON2 [FIND CA
7QF6 ... LDX 7 AWORK4(2)
7QQG ... HUNT2OPT 3,AMXOR,ICONIN
7R3W LDX 1 7
7S36 BNG 3 WNRY [JUST REPLY -> YES
7T2B LDX 6 0(1)
7TG2 ANDX 6 BSP16 [ISOLATE MODE
7T^L STO 6 AWORK1(2)
7WF= BRN T2OW [MAIN READ PATH
7WYW WNRY LDX 3 ACOMMUNE1(2) [CSTATE
7XDG LDX 6 IPSTATUS(3) [CONCEPTUAL INOP
7XY6 BNG 6 WNIN [-> YES
7YCQ LDCT 6 #230 [T/O , OPERABLE & NOT IMP
7YXB WNSR STO 6 1(1) [SET IN REPLY
7^=2 ... CALL 5 RHRC [FIND OLPA
7^JL ... LDX 7 3
7^X= ...#SKI G4
829W ... HUNT2 1,ADATA,HLOCKDOWN,3
82JG ... SMO AWORK4(2)
82X6 ... LDX 3 CONCAD [OP CA ADDR
839Q ... ADN 3 1 [REP WD
83JB ... LDX 5 6 [SAVE REP WD SETTING
83X2 ... LDX 6 AWORK3(2) [APET
849L ... FADDRESS 6,3,HLOCKB1,1
84J= ... STO 5 0(3) [SET REP WD
84WW ...#SKI G4
859G ... CALL 5 SCF5 [CLEAR LOCKS
85J6 ... LDCT 0 #400
85WQ ... ORS 0 ICA(2) [SHOW READ FINISHED
863F ... LDX 3 7
8688 ... LDX 0 JOBNO(3)
86#X ... STO 0 ACOMMUNE2(2)
86FL ... TICKLES 3,3 [TICKLE RELEVENT MEMBER
86L* ... FINDJOBQ 3,ACOMMUNE2(2),(GEOERR) [FIND JOB Q BLOCK
86R4 ... JBC TICK2,3,JBREPRI
86XR ... PROGRING LOCKOFF
874G ...TICK2
879= ... CALL 5 RHRC [OLPA
87HW ... TESTPROG APETADDR(3) [LET IT GET SWAPPED OUT
87WG ...REN UP
889Q WNIN LDCT 6 #220 [T/O , INOPERABLE & NOT IMP
88PB BRN WNSR
8992 MENDAREA 50,K100CONIPB
89NL #END
^^^^ ...57544043003700000000