{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: CONNECTA867)}}
====== CONNECTA867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BITDEFS|BITDEFS]], [[george:macro:BSJ|BSJ]], [[george:macro:BSOFF|BSOFF]], [[george:macro:BSON|BSON]], [[george:macro:BXL|BXL]], [[george:macro:CJOBLOCK|CJOBLOCK]], [[george:macro:CNSOURCE|CNSOURCE]], [[george:macro:DICTJOB|DICTJOB]], [[george:macro:DOWN|DOWN]], [[george:macro:FCAJO|FCAJO]], [[george:macro:FINDJOBQ|FINDJOBQ]], [[george:macro:FJOBLOCK|FJOBLOCK]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FON|FON]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HLSINFORM|HLSINFORM]], [[george:macro:HUNT2|HUNT2]], [[george:macro:HUNTACTF|HUNTACTF]], [[george:macro:HUNTW|HUNTW]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:LIMBO|LIMBO]], [[george:macro:MONOUT|MONOUT]], [[george:macro:OUTMILL|OUTMILL]], [[george:macro:OUTPACKX|OUTPACKX]], [[george:macro:OUTPAR|OUTPAR]], [[george:macro:PERCOUNT|PERCOUNT]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETCMXSK|SETCMXSK]], [[george:macro:SKIP|SKIP]], [[george:macro:SUBJOB|SUBJOB]], [[george:macro:SUBJOBJ|SUBJOBJ]], [[george:macro:TEMPQ|TEMPQ]], [[george:macro:USERJOB|USERJOB]]
22FL ... SEG CONNECTA,867,SECTION CENT
22^= #
234B ...#
237G ...[
23=L ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
23*Q ...[
23DW SEGENTRY K1CONNECTA,XK1
23YG FSHENTRY K2CONNECTA,XK2,,XK2
24D6 FSHENTRY K3CONNECTA,XK3,,XK3
24XQ FSHENTRY K4CONNECTA,XK4,,XK4
25CB FSHENTRY K5CONNECTA,XK5,,XK5
25X2 FSHENTRY K7CONNECTA,XK7,,XK7
266S ... FSHENTRY K8CONNECTA,XK8,,XK8
26BL #
26HS ...[ SEGENTRY K25CONNECTA USED BY RESTORE TIME MACROS PRESETRP
26M? ...[ SEGENTRY POINTS K70, K71, K71, & K73CONNECTA USED BY
26QQ ...[ RESTORE TIME MACRO REPORTNEST
26W= #
27*W # THIS SEGMENT IS THE SECOND PART OF THE CONNECT COMMAND. IT WAS
27TG # CREATED BECAUSE THE ORIGINAL SEGMENT BECAME TOO BIG AND BECAUSE
28*6 # OF THE EXTRA CODE REQUIRED FOR THE SHARED FILESTORE SPECIAL
28SQ #
29#B #
29J8 ... SEGENTRY K25CONNECTA
29S2 PRAMXMSK +AMXMSKPR
2=?L XONE +1
2=R= THREE +3
2?=W [
2?QG SEEKJBLK
2#=6 CJOBLOCK 3 [ LOOK FOR JOBBLOCK
2#PQ EXIT 5 0
2*9B [
2*P2 [
2B8L TEMPQ
2BN= SBX 5 FX1
2D76 HLSINFORM XHLSB,CONNECT,6
2DLQ XHLSB FINDJOBQ 2,6,(GEOERR)
2F6B FCAJO 2
2FL2 LDX 0 CONTEXT(2)
2G5L ANDN 0 #4000
2GK= LDX 2 FX2
2H4W ADX 5 FX1
2HJG BZE 0 (5)
2TSL SBS 4 HLSCOUNT+1
2W#= ADS 4 HLSCOUNT
2WRW LDX 0 HLSCOUNT
2X?G ORX 0 HLSCOUNT+1
2YQB BPZ 0 (5)
2^=2 XHLSCTX
2^PL GEOERR 1,HLSCOUNT
329= #
32NW XNOTINB2
33N6 XOUTPACK
347Q SBX 7 FX1
34MB OUTPACKX 3,4,5
3572 ADX 7 FX1
35LL EXIT 7 0
35N3 ...[
35PD ...[
35QT ...#UNS CMXMSK
35S= ...(
35TM ...[ SUBROUTINE TO SET CMXMSK
35X4 ...SRCMX
35YF ... SETCMXSK 3
35^W ... EXIT 5 0
363? ...)
364N ...[
366= [
36KW [ SWITCHES FOR KEEPING TRACK OF JOBCOUNTS ETC
375G BITDEFS AWORK4,18,XADDJOBJ,XCHECKPW,XADDJOB,SRCALL,MESSOP,NOTDC
37K6 [
384Q [
38JB XK1
3942 LDX 6 AWORK3(2)
39HL LDX 3 FX2 [FIND 'Z' COMMAND ACTIVITY
3=3= TACT HUNTACTF CPAT,3
3=GW TXU 6 JOBNO(3)
3?2G BCS TACT [J THIS C.A. NOT 'Z'
3?G6 CNSOURCE 3,7
3?^Q STO 3 7 [REMEMBER ADDR.(SHOULD BE LOCKED)
3#FB UNT2 HUNT2 3,CPB,CALAS
3#^2 LDEX 1 CPBCPLEV(3) [GET CP LEVEL
3*DL BNZ 1 UNT2 [J NOT LEVEL 0
3*Y= LDX 1 FX2
3BCW UNT4 HUNT2 1,CLB,0 [GET Y'S CALAS AT LEVEL 0
3BXG LDEX 0 CPBCPLEV(1)
3CC6 BNZ 0 UNT4
3CWQ LDX 1 BPTR(1)
3DBB STOZ CPBCPLEV(3)
3DW2 LDCT 0 #300 [MASK FOR FILE TYPE
3F*L ANDX 0 CPBFSD(3)
3FT= ORX 0 CPBFSD(1)
3G#W STO 0 CPBFSD(3)
3GSG LDX 3 7
3H#6 SMO FX1
3HRQ LDX 4 PRAMXMSK [SET REPORT TTYLES TO ALLBUT,COMMANDS
3J?B STO 4 AMXMSK(3)
3J#4 ...[
3J#Q ...#UNS CMXMSK
3J*D ...(
3JDW ... SEGENTRY K70CONNECTA
3JFJ ... BRN XK71 [MENDED IF REPORTNEST ON
3JGF ... CALL 5 SRCMX
3JHB ... LDX 3 7
3JJ# ...[
3JK2 ...XK71
3JP6 ... SEGENTRY K71CONNECTA
3JPS ...)
3JR2 LIMBO 7,3
3K=L BNZ 7 XNOCHANGE
3KQ= LDN 4 #14
3L9W ERS 4 CONTEXT(3) [SWITCH 'Z' FROM OFFLINE TO ONLINE
3LPG ... FINDJOBQ 3,6,(GEOERR)
3M96 LDCT 4 #400 [LOAD OFFLINE IN BIT
3MNQ ERS 4 JMISC(3) [MARK '2' AS ONLINE
3MWC ...[
3P?M ...[
3PF# ...XNOCHANGE
3PM= JBC NOSUBJ,2,XADDJOB
3Q6W SUBJOBJ
3QLG NOSUBJ
3RKQ LDN 0 1
3S5B ANDX 0 CONTEXT(2)
3T4L BZE 0 NOUSE3
3WHG JBC NOUSE3,2,NOTDC
3X36 #SKI BILASJ
3XGQ BSJ NDJOB
3Y2B USERJOB [GET USERNAME FROM JOBLOCK
3YG2 DICTJOB 2 [REDUCE COUNT OF USER'S JOBS BY 1
3Y^L NDJOB
42DG BNZ 7 XSUB
42Y6 SUBJOBJ
43CQ BRN XSYS
43XB XSUB SUBJOB [SUBTRACT 1 FOR LIMBO JOB
44C2 XSYS
46*G LDX 0 CONTEXT(2)
46T6 BNG 0 SYSIS
47#Q LDN 3 0
47SB ANDN 0 #4000
48#2 BZE 0 XJOBLIST [J IF NOT FULLY STARTED
48RL BSOFF HLSBIT,XJOBLIST [J IF HLS
49?= LDN 3 #6000
49QW ERS 3 CONTEXT(2) [MAKE T.S. TEMPORARILY
4==G XJOBLIST
4D62 DOWN JOBLIST,2
4DKL #
4F5= XNOTINB1
4G4G ERS 3 CONTEXT(2) [SET TS/FS AS BEFORE DOWN
4GJ6 SYSIS
4H3Q NOUSE2
4HHB # DELETE 'Y'S JOBLOCK
4J32 CJOBLOCK 2
4JGL FJOBLOCK 2
4K2= NOUSE3
4KFW LDX 3 FX2
4K^G TACT2 HUNTACTF CPAT,3
4LF6 TXU 6 JOBNO(3)
4LYQ BCS TACT2
4MDB STO 3 7
4MY2 LDCT 4 #010
4NCL SMO 7
4NX= ORS 4 JOBEVENTS [SET 'CONNECTED' MARKER
4PBW BSON HLSBIT,XNOTFS [J IF PRE-HLS
4PWG LDX 2 7
4QB6 LDN 6 0
4QTQ LIMBO ,7
4R*B BNZ 0 WCONT [LIMBO MEANS NOT FULLY STARTED
4RT2 LDX 6 JOBNO(2)
4S#L BRN WCONT
4SS= XNOTFS
4T?W LDN 5 0
4TRG SMO 7
4W?6 STO 5 AWORK1 [ZEROISE MESSAGE MARKER WORD
5J== LIMBO ,7
5JPW BNZ 0 W1 [LIMBO MEANS NOT FULLY STARTED
5K9G SMO 7
5KP6 LDX 4 CONTEXT
5L8Q ANDN 4 #4000
5LNB BZE 4 W1 [J IF BACKGROUND JOB NOT F.STARTED
5M82 ANDX 4 CONTEXT(2)
5MML BZE 4 W2 [J IF MOP JOB NOT F.STARTED
5N7= JBC WCONT,2,NOTDC
5NLW W4 LDX 4 HLSCOUNT+1
5P6G SBN 4 1 [REDUCE NO. OF BACKGROUND JOBS
5PL6 BNG 4 XHLSCTX
5Q5Q STO 4 HLSCOUNT+1
5QKB TXL 4 BACKGROUND
5R52 BCC WCONT [J.IF COUNT NOT LESS THAN LIMIT SET
5RJL FON #32 [WAKE UP ANY BCCKGROUND ACTIVITIES
5S4= BRN WCONT [WAITING TO BE FULLY STARTED
5SHW W2 LDX 4 HLSCOUNT [LOAD COUNT OF F.ST. MOP JOBS
5T3G TXL 4 IMOPLIMIT
5TH6 BCC W3 [J IF COUNT NOT LESS THAN LIMIT SET
5W2Q ADN 4 1 [INCREASE MOP COUNT
5WGB STO 4 HLSCOUNT [BY 1
5X22 BRN W4
5XFL W3 LDN 4 #6000 [ SET BACKGROUND
5X^= SMO 7 [ JOB TO BE
5YDW ERS 4 CONTEXT [ TENT. STARTED
5YYG FJOCA 2,7
5^D6 NGNC 0 1
5^XQ ANDS 0 JURGE(2) [CLEAR JOBQ FS BIT
62CB LDX 2 FX2
62X2 BRN W4
63BL W1 LDX 4 CONTEXT(2)
63W= ANDN 4 #4000
64*W BZE 4 WCONT [J IF MOP JOB NOT FULLY STARTED
64TG LDX 4 HLSCOUNT
65*6 SBN 4 1
65SQ BNG 4 XHLSCTX
66#B STO 4 HLSCOUNT
66S2 TXL 4 IMOPLIMIT
67?L BCC W5
67R= FON #31 [WAKE UP ACT WTING ON MOPLIMIT
68=W W5
68QG JBS WCONT,2,NOTDC
69=6 LDX 4 HLSCOUNT+1
69PQ BXL 4 BACKGROUND,W6
6=9B LDN 4 #6000
6=P2 ERS 4 CONTEXT(2) [MAKE Y TEN. STARTED
6?8L FJOCA 2
6?N= NGNC 0 1
6#7W ANDS 0 JURGE(2) [CLEAR JOBQ FS BIT
6#MG LDX 2 FX2
6*76 BRN WCONT
6*LQ W6 ADN 4 1
6B6B STO 4 HLSCOUNT+1 [ADD 1 TO HLSCOUNT+1
6BL2 #
6C5L XNOTINB3
6D4W WCONT
6DJG LIMBO ,7
6F46 SMO 7
6FHQ ERS 0 EXT+11 [UNSET LIMBO BIT
6G3B #
6GH2 WB3
6H2L #
6HG= FON #43 [WAKE UP CONNECTED 'Z'
6H^W BSON HLSBIT,XGOPST [J IF PRE-HLS
6JFG # INFORM THE JOB STARTER PROGRAM OF THE CHANGE OF STATUS OF THE
6J^6 # CONNECTED JOB
6KDQ BZE 6 XGOPST
6KYB LDN 4 1
6LD2 CALL 5 TEMPQ
6LXL XGOPST
6MC= JBS NDISCT,2,NOTDC
6MWW JBC NOADJ,2,XADDJOBJ
6NBG SUBJOB [KEEP MOP COUNT OK
6NW6 NOADJ
6P*Q LDX 6 JOBNO(2)
6PTB DOWN DSCNCT,3 [SWITCH JWELL SLOTS ETC.
6Q*2 STOZ CPPTR(2)
6QSL LDN 5 CPPTR(2)
6R#= LDN 6 CPPTR+1(2)
6RRW MOVE 5 3
6S?G STOZ JSOURCE1(2)
6SR6 STOZ JSOURCE2(2)
6T=Q STOZ AMXMSK(2)
6T#7 ...#UNS CMXMSK
6T*J ...(
6TB^ ... SEGENTRY K72CONNECTA
6TDB ... BRN XK73
6TFR ... LDX 3 2
6TH8 ... CALL 5 SRCMX
6TJK ...[
6TL2 ...XK73
6TMC ... SEGENTRY K73CONNECTA
6TNS ...)
6TQB STOZ JOBEVENTS(2)
6W=2 LDN 5 #14 [CHANGE FROM MOP
6WPL ERS 5 CONTEXT(2) [TO OFFLINE
6X9= XBBC2 HUNTW 1,AMXOR,BBC
6XNW BNG 1 XNBBC2
6Y8G FREECORE 1
6YN6 BRN XBBC2
6^7Q XNBBC2
6^MB CALL 5 SEEKJBLK
7272 LDCT 5 256
72LL ORS 5 JMISC(3) [MARK OFFLINE
77GW BSON HLSBIT,YNOTFS [J IF PRE-HLS
782G # INFORM HLS OF CHANGE OF STATUS OF DISCONNECTED JOB
7?CW YWAIT
7?XG LDX 6 JOBNO(2)
7#C6 NGN 4 1
7#WQ CALL 5 TEMPQ
7*BB YNOTFS
7*W2 OUTPAR TIMENOW
7B*L OUTMILL
7BT= LDN 4 1
7C#W LDN 5 JPDJOBTYPE
7CSG LDX 7 JSOURCE3(2)
7D#6 BZE 7 XCENTRAL
7DRQ LDN 3 THREE(1)
7F?B CALL 7 XOUTPACK
7FR2 LDN 3 JSOURCE3(2)
7G=L LDN 5 JPDPROPS
7GQ= CALL 7 XOUTPACK
7H9W BRN PARAMOUT
7HPG XCENTRAL
7J96 LDN 3 XONE(1)
7JNQ CALL 7 XOUTPACK
7K8B OUTPAR SKIP
7KN2 PARAMOUT
7L7L LDN 0 #400
7LM= ANDX 0 CONTEXT(2)
7M6W BNZ 0 XSK
7MLG FJOCA 3,2
7N66 LDX 0 HCLOCKTIME(3)
7NKQ LDX 1 HCLOCKTIME+1(3)
7P5B BNZ 0 NSK1
7PK2 SRA 1 5
7Q4L SBN 1 1875
7QJ= BNG 1 XSK
7R3W NSK1
7RHG OUTPAR PROGMILL
7S36 BRN NSK
7SGQ XSK
7T2B OUTPAR SKIP
7TG2 NSK
7T^L MONOUT JTYPE
7WF= PERCOUNT
7WYW ... ACROSS CONTINUE,3
7XDG NDISCT
84SB ACROSS SUICIDE,1 [KILL 'Y'
85#2 #
9XCB #
9XX2 #END
^^^^ ...730230660001