{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: CONSET864)}}
====== CONSET864 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:AND|AND]], [[george:macro:BS|BS]], [[george:macro:COOR1|COOR1]], [[george:macro:COOR3|COOR3]], [[george:macro:CREATEB|CREATEB]], [[george:macro:DCA|DCA]], [[george:macro:DO|DO]], [[george:macro:DOWN|DOWN]], [[george:macro:ELSE|ELSE]], [[george:macro:FI|FI]], [[george:macro:FIXTRA|FIXTRA]], [[george:macro:FREEBAX|FREEBAX]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GPERI|GPERI]], [[george:macro:HUNTW|HUNTW]], [[george:macro:IF|IF]], [[george:macro:MFREE|MFREE]], [[george:macro:MONOUT|MONOUT]], [[george:macro:OPEN|OPEN]], [[george:macro:REPEAT|REPEAT]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:TESTRPN2|TESTRPN2]], [[george:macro:THEN|THEN]], [[george:macro:WHATBACK|WHATBACK]], [[george:macro:WHILE|WHILE]], [[george:macro:WRITED|WRITED]]
22FL #OPT K0CONSET=0
22^= #LIS K0CONSET>K0EMS>K0GREATGEO>K0ALLGEO
23DW #SEG CONSET
23YG 8HCONSET
24D6 [
24XQ [ THIS SEGMENT IS ENTERED AT THE END OF EARLY MORNING START
25CB [ DUE TO THE CONSOLE ACTIVITY'S LINK HAVING BEEN RESET
25X2 [ TO K1CONSET BY SETUP WHEN IT WAS ASLEEP. ITS JOB IS TO
26BL [ SEPARATE EMS OP'S LOG FROM NORMAL RUNNING. IN DME THIS
26W= [ IS A NEW PAGE, IN OTHER ENVIRONMENTS THREE BLANK LINES
27*W [ IN DME IT ALSO SETS UP AND OPENS THE RECALL FILE
27TG [
28*6 [
28SQ SEGENTRY K1CONSET,X1CONSET
29#B [
29S2 [
2=?L [ PRESET DATA
2=R= [
2?=W [
2?QG NAMEOFILE
2#=6 +10
2#PQ 12HSYSTEM
2*9B 12HRECALL FILE
2*P2 +1
2B8L +1
2BN= 4HB1
2C7W #DEF PAGESIZE=2 [BLOCKLETS PER PAGE
2CMG FIXTRA K90CONSET
2D76 SIZEOFILE 20 / (4/PAGESIZE) [IN BLOCKS
2DLQ [
2F6B [
2FL2 [ ENTRY POINT
2G5L [
2GK= [
2H4W X1CONSET
2HJG [
2J46 IF ENV,DME [IF DME THEN
2JHQ THEN
2K3B [
2KH2 [START NEW PAGE OF OPER LOG
2L2L [
2LG= DOWN OPERAPP,2
2L^W STOZ AWORK1(2) [SET "DON'T PAGEWAIT ON NEXT PAGE"
2MFG LDX 3 CONSCNTRL
2M^6 ADN 3 COVID+1
2NDQ BS 3,COAUTO [SET SCREEN 1 ON AUTO
2NYB [
2PD2 [ SET UP RECALL FILE
2PXL [
2QC= SETNCORE 10,3,FILE,FABSNB
2QWW LDN 4 NAMEOFILE(1)
2RBG LDN 5 HDREC(3)
2RW6 MOVE 4 10 [SET UP /FABSNB
2S*Q CREATEB 3 [SET UP A /CREATE
2STB LDN 4 1
2T*2 STO 4 CEORG(3) [BLOCKS/BUCKET
2TSL LDX 4 SIZEOFILE(1)
2W#= STO 4 CEINF3(3) [BLOCKS/REEL
2WD7 ...#UNS ANOTALLOC
2WJ4 ...#SKI
2WM^ ...(
2WRW WHATBACK ,SIZEOFILE(1),XFILERR [GET BS BLOCKS IN /FULLB
2WWF ...)
2W^4 ...#UNS ANOTALLOC
2X3M ...(
2X6= ... WHATBACK ,SIZEOFILE(1),XFILERR,,VSF [GET BS BLOCKS IN FULLB
2X8T ...)
2X?G OPEN XFILERR1,CREATE,WRITE,QUERY
2XR6 TESTRPN2 OK,XFILERR1 [OPEN FREES /CREATE AND /FULLB
2Y=Q LDX 3 CONSCNTRL
2YQB BS 3,CONSFILE [MARK FILE SET UP
2^=2 [
2^PL [ NOW WRITE AWAY ANY STORED PAGES
329= [
32NW SMO CONSCNTRL
338G LDX 4 COBLK [X4 = 1ST BUCKET TO BE USED
33N6 WHILE TRUE [WHILE PAGES IN CORE DO
347Q HUNTW 2,FILE,FRWB
34MB AND 2,PZ
3572 DO
35LL WRITED 4,1 [WRITE PAGE AWAY
366= TESTRPN2 OK,(GEOERR)
36KW ADN 4 PAGESIZE [UPDATE 'NEXT BUCKET' IN X4
375G REPEAT [REPEAT OVER STORED PAGES
37K6 SMO CONSCNTRL
384Q STO 4 COBLK ['NEXT BUCKET' UPDATED FROM X4
38JB RELFABS
3942 MFREE FILE,FABSNB [FREE THE /FABSNB
39HL ACROSS OPER,1
3=3= ELSE [ELSE (NOT DME)
3=GW DO [UNTIL NEWLINES WRITTEN OK DO
3?2G WHILE BUSY,CPPTR(2) [GET CONSOLE
3?G6 DO
3?^Q COOR3 #50
3#FB REPEAT
3#^2 LDX 0 FCANCEL+2
3*DL STO 0 FCANCEL+3 [STORE 2 NEWLINES
3*Y= STO 0 FCANCEL+4
3BCW LDN 0 1
3BXG DCA 3,DLA,0,MODE [MODE 1 FOR OUTPUT
3CC6 LDN 0 12
3CWQ DCA 3,DLA,0,COUNT [12 CHARACTERS
3DBB LDN 0 FCANCEL+2
3DW2 DCA 3,STO,0,CTSA [BUFFER START ADDRESS
3F*L GPERI 3,2 [ISSUE PERI
3FT= COOR1 [AND WAIT FOR IT TO FINISH
3G#W LDN 3 CPRW1(2)
3GSG IF MBAC,3,CONSFAIL,CONSINOP
3H#6 THEN
3HRQ STOZ AWORK2(2)
3J?B STOZ AWORK3(2)
3JR2 STOZ AWORK4(2)
3K=L ACROSS CONSOLE,1
3KQ= FI
3L9W REPEAT [REPEAT TILL NEWLINES WRITTEN OK
3LPG FI
3M96 [
3MNQ [
3N8B [ ERROR CASES
3NN2 [
3P7L XFILERR1
3PM= FREEBAX [ (FREE B/S IF OPEN FAILS)
3Q6W MFREE BSTB,EMPTYB
3QLG XFILERR
3R66 MFREE FILE,CREATE [ (FREE /CREATE IF ERROR ANYWHERE)
3RKQ MONOUT CNORECALL [ (MSG IF ERROR ANYWHERE)
3S5B LDX 3 CONSCNTRL
3SK2 BS 3,CONSNOFILE [MARK 'NO FILE'
3T4L WHILE TRUE [FREE ALL STORED PAGES
3TJ= HUNTW 1,FILE,FRWB
3W3W AND 1,PZ
3WHG DO
3X36 FREECORE 1
3XGQ REPEAT
3Y2B BRN RELFABS
3YG2 #END
^^^^ ...256577370002