{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: CONTINUE867)}}
====== CONTINUE867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:CLEANUP|CLEANUP]], [[george:macro:COMERRX|COMERRX]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FREEBUFF|FREEBUFF]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FREELINK|FREELINK]], [[george:macro:HLSINFORM|HLSINFORM]], [[george:macro:HLSINFRT|HLSINFRT]], [[george:macro:LINK|LINK]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:PARAPASS|PARAPASS]], [[george:macro:PROGBRKIN|PROGBRKIN]], [[george:macro:RUNPROG|RUNPROG]], [[george:macro:RVHOOK|RVHOOK]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SIX|SIX]], [[george:macro:TICKLER|TICKLER]]
22FL ... SEG CONTINUE,,CENT(COMMAND PROCESSOR),,G400
22^= ...[
23DW ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
23YG ...[
24D6 [ THE ENTRY POINTS
24XQ [ THESE ENTRY POINTS MUST BE KEPT FIXED WITHIN THE SEGMENT
254Y ...#UNS G400
25=6 ...# THIS CHAPTER IS MODIFIED FOR G3PLUS-IH MK2
25CB SEGENTRY K1CONTINUE,QENTRY1
25X2 BRN (GEOERR)
26BL SEGENTRY K3CONTINUE,QENTRY3 [ENTRY FROM DC
26W= [
27*W SEGENTRY K4CONTINUE,QENTRY4 [ENTRY FROM COMPROB
27TG SEGENTRY K5CONTINUE,QENTRY5 [ENTRY FROM COMPROB
28*6 SEGENTRY K21CONTINUE,QENTRY21 [RE-ENTRY FROM HLS
28SQ SEGENTRY K22CONTINUE,QENTRY22 [RE-ENTRY FROM HLS
29#B [
29S2 # THIS SEGMENT CONTAINS THE ENTIRE CODING FOR THE CONTINUE COMMAND.
2=?L # IT DELETES ALL COMMAND PROCESSOR LEVELS UP TO AND INCLUDING THE
2=R= # TOP BREAK IN LEVEL,CLOSING DOWN ANY MACRO DEFINITION FILES
2?=W # ASSOCIATED WITH THESE LEVELS.RETURN IS THEN MADE TO THE
2?QG # COMMAND PROCESSOR SO THAT THE JOB MAY BE RESUMED AT THE POINT
2#=6 # AT WHICH IT WAS BROKEN IN ON
2#PQ [
2*9B QENTRY3
2*P2 [ ENTRY FROM DISCONNECT
2B8L STOZ AWORK1(2) [INDICATE NO PARAM
2BN= BRN XK71
2C7W [
2CMG QENTRY1
2D76 SEGENTRY K70CONTINUE
2DLQ BRN XK71 [MENDED TO NULL IF REPORTNEST ON
2F6B STOZ AWORK1(2) [INDICATE NO CA PARAMETER
2FL2 PARAPASS [OBTAIN PARAMETER
2G5L MHUNT 3,CPB,CUNI
2GK= LDX 6 ANUM(3)
2H4W BNG 6 XK71 [NO PARAMETER
2HJG BZE 6 XK71
2J46 LDX 6 APARA(3)
2JHQ ORN 6 #7777
2K3B ERN 6 #7777
2KH2 TXU 6 XCA(1)
2L2L BCS XERROR [PARA NOT "CA" - FORMAT ERROR
2LG= STO 6 AWORK1(2) [SET MARKER NON-ZERO - REPORT MASK
2L^W [TO BE RETAINED FROM TOP B-I LEVEL
2MFG XK71
2M^6 SEGENTRY K71CONTINUE
2NDQ LDX 5 EXT+10(2) [LOAD BREAK IN TYPE AND LEVEL
2NYB ANDN 5 #7777
2PD2 CLEANUP 5,3
2PXL LDX 3 EXT+3(2) [COUNT OF INT ISS LEVELS CLEARED &UT
2QC= BZE 3 NOII
2QWW NAGAIN
2RBG FREELINK [FREE LINK FOR INT ISS. COMMAND
2RW6 BCT 3 NAGAIN
2S*Q NOII
2STB MHUNTW 2,CPB,CALAS
2T*2 LDX 3 FPTR(2)
2TSL LDX 6 CPBFSD(2) [LOAD ORIGINAL BREAK IN TYPE
2W#= LDX 1 FX2
2WRW DCH 6 EXT+10(1)
2X?G [
2XR6 SEGENTRY K72CONTINUE
2Y=Q BRN XK73 [MENDED TO NULL IF REPORTNEST ON
2YQB LDX 6 AWORK1(1)
2^=2 BZE 6 XK73 [NEST REPORTING LEVEL
2^PL LDX 6 CMXMSK(2) [RETAIN REPORTING MASK FROM TOP B-I
329= STO 6 AMXMSK(1) [LEVEL
32NW XK73
338G SEGENTRY K73CONTINUE
33N6 FREECORE 2
347Q FREECORE 3
34MB LDX 6 MASKC(1)
3572 ERS 6 CONTEXT(2)
35LL SBN 5 1
366= STO 5 CPLEV(2) [SET NEW CPLEVEL
36KW MHUNTW 3,CPB,CALAS
375G [
37K6 SEGENTRY K74CONTINUE
384Q BRN XK75 [MENDED TO NULL IF REPORTNEST ON
38JB LDX 6 AWORK1(2)
3942 BZE 6 NOCA
39HL LDX 6 AMXMSK(2) [RETAIN REPORT MASK FROM TOP
3=3= STO 6 CMXMSK(3) [B-I LEVEL
3=GW BRN XK75
3?2G NOCA
3?G6 LDX 6 CMXMSK(3) [NEST REPORTING LEVEL I.E. REVERT TO
3?^Q STO 6 AMXMSK(2) [MASK FROM NEXT LEVEL UP
3#FB XK75
3#^2 SEGENTRY K75CONTINUE
3*68 ...#UNS G400
3*?B ... RVHOOK 3
3*DL LDX 5 CMFMSK(3) [ COPY TRACING LEVEL
3*Y= STO 5 AMFMSK(2) [ INTO CPAT
3BCW #SKI CALLS
3BXG (
3CC6 FJOCA 3
3CWQ CLEARPROG 3
3DBB )
3DW2 BRN TCONT
3F*L QENTRY21
3FT= HLSINFRT SJBRKIN,STOPPED
3G#W SJBRKIN
3GSG LDCH 4 EXT+10(2)
3H#6 LDN 0 2
3HRQ DCH 0 EXT+10(2)
3J?B BRN STOPJB
3JR2 QENTRY4
3K=L HLSINFORM SAVEABLE,STOPPED,JOBNO(2),,,,XSTLINK(1)
3KQ= QENTRY5 [ FROM CONTINUE - END OF BREAKIN
3L9W TCONT
3LPG LDCH 4 EXT+10(2)
3M96 LDCT 0 #020 [ CLEAR BREAKIN MARKER
3MNQ STO 0 EXT+10(2)
3N8B STOPJB
3NN2 TXU 4 PHIVE(1)
3P7L BCS PACK
3PM= LDXC 0 JOBEVENTS(2)
3Q6W BCS PBRKIN
3QLG TICKLER JOBNO(2) [LIFT ANY MP SUSPENSIONS...
3R66 [ [(RELIED ON BY OP'S MOP BREAK IN)
3RKQ LDN 6 #4000
3S5B ANDX 6 CONTEXT(2)
3SK2 BNZ 6 RUN [J IF FULLY STARTED
3T4L HLSINFORM SAVEABLE,FSTART,JOBNO(2),,,,XFSLINK(1)
3TJ= BRN RUN
3W3W )
3WHG PBRKIN
3X36 PROGBRKIN
3XGQ QENTRY22
3Y2B HLSINFRT RUN,FSTART
3YG2 RUN
3Y^L FREEBUFF [ FREEBUFF CPAT
3^F= HLSINFORM RUNBK,RESUME,JOBNO(2)
3^YW RUNBK
42DG RUNPROG [RE ENTER PROGRAM
42Y6 PACK
43CQ TXU 4 SIX(1)
43XB BCS PAK
44C2 ENDCOM
44WL PAK TXU 4 THREE(1)
45B= BCS READA
45TW LDXC 0 JOBEVENTS(2)
46*G BCS READA
46T6 MHUNTW 2,CLB
47#Q LDX 4 ANUMCHA(2)
47SB STO 4 APARANUM(2)
48#2 ACROSS ALASB,1
48RL READA
49?= ACROSS COMPRO,10
49QW [
4==G [
4=Q6 XSTLINK
4?9Q LINK CONTINUE,21
4?PB XFSLINK
4#92 LINK CONTINUE,22
4#NL [
4*8= MASKC #60000
4*MW [
4B7G THREE +3
4BM6 PHIVE +5
4C6Q SIX +6
4CLB [
4D62 PSERR +APFERR [ PARAMETER FORMAT ERROR MESSAGE
4DKL XERROR
4F5= LDX 5 PSERR(1)
4FJW NGN 6 1
4G4G COMERRX 5,6
4GJ6 #
4H3Q # DATA CONSTANT FOR NESTED REPORT
4HHB XCA 4HCA00
4J32 #
4JGL MENDAREA 20,K99CONTINUE
4K2= #END
^^^^ ...054242530002