{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: CONTRACT866)}}
====== CONTRACT866 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:ALTLEN|ALTLEN]], [[george:macro:CHUCK|CHUCK]], [[george:macro:CHUCKWR|CHUCKWR]], [[george:macro:CLOSEWR|CLOSEWR]], [[george:macro:DOWN|DOWN]], [[george:macro:FIPPER|FIPPER]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:LOCKM|LOCKM]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFINDEXOF|MFINDEXOF]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MOVLONG|MOVLONG]], [[george:macro:OPENST|OPENST]], [[george:macro:PHOTO|PHOTO]], [[george:macro:PLOCKSU|PLOCKSU]], [[george:macro:PROGBRKIN|PROGBRKIN]], [[george:macro:READSAVE|READSAVE]], [[george:macro:READST|READST]], [[george:macro:RELST|RELST]], [[george:macro:RUNPROG|RUNPROG]], [[george:macro:SAVEST|SAVEST]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:SMUSEST|SMUSEST]], [[george:macro:STEPBACK|STEPBACK]], [[george:macro:SUSEST|SUSEST]], [[george:macro:TESTMOVE|TESTMOVE]], [[george:macro:TESTREP|TESTREP]], [[george:macro:TESTREPNOT|TESTREPNOT]], [[george:macro:TRACE|TRACE]], [[george:macro:TWAIT|TWAIT]], [[george:macro:UNLOCKSU|UNLOCKSU]], [[george:macro:WORDST|WORDST]], [[george:macro:XY|XY]]
22FL ...#SEG CONTRACT70 [FRANK BLUNDELL
22^= #LIS K0CONTRACT
23DW 8HCONTRACT
23YG #
24D6 # THIS SEGMENT DEALS WITH CONTRACT FOR PERMANENT FILES
24XQ # ON ENTRY CURRENT ACTIVITY IS CPA
25CB # THE CONTROL AREA HAS BEEN CHECKED AND A GEXD BLOCK IS CHAINED
25X2 # AFTER THE CURRENT ACTIVITY CONTAINING DETAILS OF THE PERI
26BL #
26W= #
27*W #
27TG #
28*6 #
28SQ SEGENTRY K1CONTRACT
29#B MHUNTW 3,EWDAS,GEXD
29S2 STOZ AWORK1(2) [COUNT OF BUCKETS
2=?L STOZ AWORK2(2) [COUNT OF AREAS
2=R= MFINDEXOF 1,CEFN(3)
2?=W NGX 5 BREQ(3)
2?QG LDX 4 FIP+8(1)
2#=6 ANDN 4 #77
2#PQ DVS 4 4 [X5=BUCKETS TO BE REMOVED
2*9B #SKI K6CONTRACT>199-199
2*P2 (
2B8L TRACE CEFN(3),CONTRACT
2BN= TRACE 5,
2C7W BZE 4 XA
2CMG XB GEOERR 1,CONTRACT
2D76 XA
2DLQ )
2F6B LDEX 0 FIP+5(1) [NUMBER OF AREAS
2FL2 SBN 0 1
2G5L SLL 0 1
2GK= LDX 4 0
2H4W SLL 0 1
2HJG ADX 4 0 [X4=POINTER TO LAST CELL
2J46 STO 4 AWORK3(2)
2JHQ LDEX 7 FIP+5(1)
2K3B #SKI K6CONTRACT>199-199
2KH2 BZE 7 XB [ERROR IF NO AREAS-SHOULD BE DONE
2L2L LDX 6 EOPMODE(3) [BY EXTEND
2LG= SBN 6 #400
2L^W XD BNZ 6 XCB
2MFG SMO 4
2M^6 LDX 0 FDCELLS-1(1)
2NDQ TXL 0 FIP+10(1)
2NYB BCS XC
2PD2 XCB SMO 4
2PXL LDX 0 FDCELLS+5(1)
2QC= SMO 4
2QWW SBX 0 FDCELLS-1(1) [BUCKETS IN THIS AREA
2RBG ADX 0 AWORK1(2) [ADD IN TOTAL SO FAR
2RW6 TXL 5 0 [
2S*Q BCS XC [JUMP IF THIS WOULD BE TOO MUCH
2STB STO 0 AWORK1(2) [RESET TOTAL SO FAR
2T*2 LDN 0 1
2TSL ADS 0 AWORK2(2) [ADD 1 TO COUNT OF AREAS TO REMOVE
2W#= TXU 5 AWORK1(2)
2WRW BCC XC [JUMP IF TOTAL EXACTLY ENOUGH
2X?G SBN 4 6 [UPDATE CELL POINTER
2XR6 BCT 7 XD [JUMP IF MORE AREAS
2Y=Q #
2YQB # AWORK2 NOW CONTAINS A COUNT OF AREAS TO BE REMOVED
2^=2 # AWORK3 NOW CONTAINS A POINTER TO THE LAST AREA
2^PL #
329= XC LDX 0 ASUSN(1)
32NW STO 0 HMUNIT(3) ['HOME' UNIT SERIAL NUMBER
338G STO 0 ARUNIT(3) [TEMPORARY-AREA UNIT=HOME UNIT
33N6 STOZ AWORK1(2) [WILL CONTAIN A COUNT OF BUCKETS
347Q [REMOVED
34MB #
3572 SUSEST ASUSN(1),XE [GET HOME UNIT ONLINE
35LL XG MHUNTW 3,EWDAS,GEXD
366= MFINDEXOF 1,CEFN(3)
36KW LDCT 0 #20
375G ANDX 0 EXMARK(1)
37K6 BZE 0 XF [JUMP IF NOT SYSTEM FILE OPEN FOR
384Q [WRITING
38JB LDX 0 HMUNIT(3)
3942 STO 0 ESERL(3) [STORE SUSN FOR EXOPEN
39HL LDX 5 BACK2(1) [SAVE EXOFILE NUMBER
3=3= LDX 4 ALOGLEN(1) [GET LOGICAL LENGTH
3=GW LDX 7 EMARK(3)
3#FB PLOCKSU HMUNIT(3),SMA,SNA [LOCK HOME UNIT
3#^2 SETUPCORE 4,2,EWDAS,EXOF [GET ANOTHER EXOF
3*DL MFINDEXOF 1,5
3*Y= STO 5 BACK2(2)
3BCW ADN 1 A1
3BXG ADN 2 A1
3CC6 ... MOVLONG 1,2,4 [COPY EXOF
3DBB LDN 0 BOPEN+BSPEC+BSERL+BLOCK
3DW2 STO 0 EXMARK-A1(2)
3F*L DOWN EXOPEN,1 [GO TO REFIND FILE
3FT= TESTREP OK,XH [JUMP IF OK
3G#W TESTREP EXFAIL,XJ
3GSG GEOERR 1,EXOREP
3H#6 XH MHUNTW 2,EWDAS,EXOF [
3HRQ MFINDEXOF 1,5
3J?B LDX 0 HOME(2) [RESET HOME
3JR2 STO 0 HOME(1)
3JY8 ...#UNS IPBD
3K5B ...#SKI
3K=L LDX 4 1 [SAVE EXOF POINTER
3KQ= FREECORE 2 [FREE SPARE EXOF
3L9W MHUNTW 3,EWDAS,GEXD
3LPG STO 7 EMARK(3)
3M96 UNLOCKSU HMUNIT(3) [UNLOCK HOME UNIT
3MB# ...#UNS IPBD
3MHG ...#SKI
3MNQ LDX 1 4 [RESET EXOF POINTER
3MR* ...#UNS IPBD
3MTY ...(
3MYH ... MHUNTW 3,EWDAS,GEXD
3N36 ... MFINDEXOF 1,5
3N5P ...)
3N8B #
3NN2 #
3P7L XF LDX 2 FX2
3PM= LDX 7 AWORK2(2) [X7 HOLDS COUNT OF AREAS TO REMOVE
3Q6W #SKI K6CONTRACT>199-199 [
3QLG (
3R66 BNZ 7 XFA [ERROR IF NO AREAS TO BE REMOVED-
3RKQ GEOERR 1,ZEROAREA [SHOULD BE DEALT WITH BY EXTEND
3S5B XFA
3SK2 )
3T4L LDX 6 AWORK3(2) [X6=POINTER TO CURRENT FDCELL
3TJ= #
3W3W # CONTRACT LOOP
3WHG #
3X36 ZB LDX 4 1
3X8# ...#UNS IPBD
3X*G ...#SKI
3XGQ PHOTO 5
3Y2B SMO 6
3YG2 LDX 0 FDCELLS(1)
3Y^L STO 0 ARUNIT(3) [GET AREA SUSN
3^F= TXU 0 HMUNIT(3)
3^YW BCC XL [JUMP IF SAME AS HOME UNIT
42DG SUSEST ARUNIT(3),XM [OTHERWISE GET IT ONLINE
42G9 ...#UNS IPBD
42HY ...(
42KM ...XN MHUNTW 3,EWDAS,GEXD
42MB ...XL LOCKM HMUNIT(3),ARUNIT(3),SAX,SBX [GET LOCK OUTS IN ORDER
42P5 ...)
42QS ...#UNS IPBD
42SH ...#SKI
42W= ...(
42Y6 XN TESTMOVE 5,XL
43CQ MHUNTW 3,EWDAS,GEXD
45B= XL PLOCKSU HMUNIT(3),SAA,SBA [LOCK HOME MNIT
45TW LDX 1 4
46*G TESTMOVE 5,XP
46K# ...)
46T6 MHUNTW 3,EWDAS,GEXD
47#Q MFINDEXOF 1,CEFN(3)
47SB XP SMO 6
48#2 LDX 5 FDCELLS+5(1)
48RL SMO 6
49?= SBX 5 FDCELLS-1(1) [X5=BUCKETS IN THIS AREA
49QW STO 5 CELLA+5(3)
4==G ADS 5 AWORK1(2) [ADD TO CUMULATIVE TOTAL
4=Q6 SMO 6
4?9Q LDX 0 FDCELLS-1(1)
4?PB SMO 6
4#92 STO 0 FDCELLS+5(1) [MAKE LAST AREA LOOK EMPTY
4#NL LDX 4 1
4*8= OPENST HMUNIT(3)
4*MW LDX 1 4
4B7G LDX 5 HOME(1) [FIP CELL BS ADDRESS
4BM6 LDN 4 133 [CONTROL HEADER ADDRESS
4C6Q READSAVE 4,XQ [READ AND SAVE C/H
4CLB TESTREP OK,XR
4D62 XV TESTREP EXFAIL,R1
4DKL XS GEOERR 1,TRANS1
4F5= XR LDX 1 ECOR(3)
4FJW XQ STO 1 AWORK2(2) [SAVE ADDRESS OF C/H
4G4G READSAVE 5,XT [READ AND SAVE FIP
4GJ6 TESTREPNOT OK,XV
4H3Q LDX 1 ECOR(3)
4HHB XT STO 1 AWORK3(2) [SAVE ADDRESS OF FIP
4J32 LDX 4 1(1) [POINTER TO FIRST FDCELL
4JGL BZE 4 R2 [JUMP IF NO MORE CELLS
4K2= READSAVE 4,XW [READ AND SAVE CELL
4KFW TESTREPNOT OK,XV
4K^G LDX 1 ECOR(3)
4LF6 XW STO 1 AWORK4(2) [SAVE ADDRESS OF CELL
4LYQ LDN 2 CELLA(3)
4MDB MOVE 1 5 [SAVE COPY OF CELL
4MY2 LDX 0 0(1)
4NCL SMO FX2
4NX= LDX 2 AWORK3
4PBW STO 0 1(2) [STORE POINTER TO NEXT AREA
4PWG LDEX 0 7(2)
4QB6 SBN 0 1 [REDUCE COUNT OF FILE AREAS
4QTQ DEX 0 7(2)
4R*B CHUCKWR C,2,XY [CHUCK ANDWZITE FIP CELL
4RT2 TESTREP OK,XY
4S#L YD TESTREP EXFAIL,R3
4SS= BRN XS
4T?W XY LDX 0 HMUNIT(3)
4TRG TXU 0 ARUNIT(3)
4W?6 BCC YA [JUMP IF AREA ON HOME UNIT
4WQQ LDX 2 FX2 [OTHERWISE CELL IS CHAINED INTO
4X=B [VACANT CHAIN
4XQ2 SMO AWORK2(2)
4Y9L LDN 1 7 [X1=POINTER TO VACANT CHAIN
4YP= YC LDX 0 0(1)
4^8W TXL 0 4
4^NG BCC YB [JUMP IF NEXT CELL HAS HIGHER ADDRESS
5286 BZE 0 YB [OR IF THIS IS LAST CELL
52MQ READST 0(1),YC [READ NEXT CELL
537B TESTREPNOT OK,YD
53M2 LDX 1 ECOR(3)
546L BRN YC
54L= YB SMO AWORK4(2)
555W STO 0 0 [STO ADDRESS OF NEXT CELL IN WORD 0
55KG SAVEST C,1 [OF CELL BEING FREED
5656 LDX 5 1 [SAVE VACANT CELL AND CORE POINTER
56JQ CHUCKWR C,AWORK4(2),YE [CHUCK AND WRITE CELL BEING FREED
574B TESTREPNOT OK,YD
57J2 YE SMO 5
583L STO 4 0 [STORE ADDRESS OF CELL BEING FREED
58H= CLOSEWR C,5 [WRITE CELL AND CLOSE UNIT
592W TESTREPNOT OK,YD
59GG MHUNTW 3,EWDAS,GEXD
59LC ...#UNS IPBD
59Q# ...#SKI
59W9 ...(
5=26 UNLOCKSU HMUNIT(3)
5?YL YHA PLOCKSU ARUNIT(3),YHA,R4A
5#D= MHUNTW 3,EWDAS,GEXD
5#N4 ...)
5#XW #
5*CG OPENST ARUNIT(3) [OPEN AREA UNIT
5*X6 LDN 4 133
5BBQ READSAVE 4,YF [READ AND SAVE C/H
5BWB TESTREP OK,YG
5CB2 YH TESTREP EXFAIL,R4
5CTL BRN XS
5D*= YG LDX 1 ECOR(3)
5DSW YF STO 1 AWORK2(2) [SAVE CORE ADDRESS C/H
5F#G ADN 1 6 [ADDRESS OF START OF FOREIGN CHAIN
5FS6 LDN 4 0
5G?Q YKB LDX 1 0(1)
5GRB BZE 1 R5 [JUMP IF END OF CHAIN-SCA CORRUPT-
5H?2 [FOREIGN CELL MISSING
5HQL READSAVE 1,YJ [READ AND SAVE CELL
5J== TESTREPNOT OK,YH
5JPW LDX 1 ECOR(3)
5K9G YJ LDX 0 1(1)
5KP6 TXU 0 CELLA+1(3)
5L8Q BCS YK [STARTING BLOCK
5LNB LDX 0 2(1)
5M82 TXU 0 CELLA+2(3) [ENDING BLOCK
5MML BCS YK
5N7= LDX 0 3(1)
5NLW BZE 0 YK
5P6G TXU 0 HMUNIT(3)
5PL6 BCC YL
5Q5Q YK BZE 4 YKA [JUMP IF NO CELL SAVED
5QKB CHUCK C,4 [OTHERWISE CHUCK IT
5R52 YKA LDX 4 1 [REMEMBER CURRENT CELL
5RJL BRN YKB
5S4= YL [CELL FOUND
5SHW BNZ 4 YLA [JUMP IF A1PREVIOUS CELL
5T3G SMO AWORK2(2)
5TH6 LDN 4 6 [OTHERWISE USE C/H BASE
5W2Q SAVEST C,4
5WGB YLA STO 1 AWORK4(2) [SAVE ADDRESS OF CELL BEING FREED
5X22 LDX 0 0(1)
5XFL SMO 4
5X^= STO 0 0 [STORE NEW POINTER
5YDW CHUCKWR C,4,YAA [CHUCK AND WRITE PREVIOUS CELL
5YYG TESTREPNOT OK,YH
5^D6 MHUNTW 3,EWDAS,GEXD
5^XQ YAA LDX 0 ARUNIT(3)
62CB SMO AWORK4(2)
62X2 STO 0 3 [RESET SERIAL NUMBER IN CELL
63BL #
63W= # THE NEXT PIECE OF CODE CHAINS THE AREA INTO THE UNALLOCATED
64*W # CHAIN ON THE APPROPRIATE UNIT
64TG # THIS IS THE AREA UNIT IF AREA UNIT IS NOT HOME UNIT
65*6 # OR THE HOME UNIT IF HOME UNIT=AREA UNIT
65SQ # IN BOTH CASES:-
66#B # AWORK2=CORE ADDRESS OF CONTROL HEADER
66S2 # AWORK4=CORE ADDRESS OF CELL BEING FREED -THIS
67?L # MAYBE EITHER THE ORIGINAL FILE AREA CELL(HOME UNIT) OR THE
67R= # CELL FROM FOREIGN CHAIN (AREA UNIT)
68=W #
68QG #
69=6 #
69PQ #
6=9B YA LDX 2 FX2
6=P2 SMO AWORK2(2)
6?8L LDN 1 5 [ADDRESS OF UNALLOCATED CHAIN
6?N= LDN 4 0
6#7W YR LDX 1 0(1) [ADDRESS OF NEXT CELL
6#MG BZE 1 YPB
6*76 READSAVE 1,YN [READ AND SAVE CELL
6*LQ TESTREPNOT OK,YH
6B6B LDX 1 ECOR(3)
6BL2 YN LDX 0 CELLA+1(3)
6C5L TXL 0 1(1) [
6CK= BCS YP [JUMP IF THIS BLOCK NO. > OUR BLOCK
6D4W BZE 4 YQ [JUMP IF CELL NOT FOUND
6DJG CHUCK C,4 [CHUCK PREVIOUS CELL
6F46 YQ LDX 4 1 [SAVE AEERESS OF CURRENT CELL
6FHQ BRN YR
6G3B YP CHUCK C,1 [CHUCK CURRENT CELL
6GH2 YPB BNZ 4 YPA
6H2L SMO AWORK2(2)
6HG= LDN 4 5 [SET X4 TO START OF UNALLOCATED CHAIN
6H^W YPA
6JFG LDX 1 4
6J^6 LDX 2 AWORK4(2)
6KDQ WORDST 2 [GET BS ADDRESS OF CELL
6KYB LDX 5 EWK(3)
6LD2 LDX 0 0(1)
6LXL STO 0 0(2) [SET POINTER IN CELL BEING FREED
6MC= CHUCKWR C,2,YS [AND CHUCK AND WRITE IT
6MWW TESTREPNOT OK,YH
6NBG LDX 1 4
6NW6 YS STO 5 0(1) [STORE ADDRESS OF CELL BEING FREED
6P*Q CLOSEWR C,1 [IN CURRENT CELL AND CLOSE AND WRITE
6PTB TESTREPNOT OK,YH
6Q*2 MHUNTW 3,EWDAS,GEXD
6RRW MFINDEXOF 2,CEFN(3)
6S?G XYB FIPPER HOME(2),ASUSN(2),XYB,XYC,NOC
6SR6 XYC MHUNTW 3,EWDAS,GEXD
6T=Q NOC
6W=2 LDX 0 HMUNIT(3) [
6WPL TXU 0 ARUNIT(3) [
6X9= BCC ZA [JUMP IF AREA=HOME UNIT
6XNW UNLOCKSU ARUNIT(3)
6XW4 ...#UNS IPBD
6Y3= ... MHUNTW 3,EWDAS,GEXD
6Y8G RELST ARUNIT(3) [UNLOCK AND RELEASE AREA UNIT
6Y#C ...#UNS IPBD
6YD# ...#SKI
6YJ9 ...(
6YN6 MHUNTW 3,EWDAS,GEXD
6^7Q LOCKSU HMUNIT(3) [LOCK HOME UNIT
6^CJ ...)
6^MB ZA MHUNTW 3,EWDAS,GEXD
7272 MFINDEXOF 3,CEFN(3) [FIND EXOF
72LL LDX 4 ALOGLEN(3)
736= SBN 4 6
73KW LDEX 0 FIP+5(3) [SUBTRACT 1 FROM COUNT OF AREAS
745G SBN 0 1
74K6 DEX 0 FIP+5(3)
754Q ALTLEN 3,4 [ALTER LENGTH OF EXOF
75JB SBN 6 6 [UPDATE AREA POINTER
7642 MHUNTW 3,EWDAS,GEXD
76HL UNLOCKSU HMUNIT(3) [UNLOCK HOME UNIT
76NS ...#UNS IPBD
76W2 ... MHUNTW 3,EWDAS,GEXD
773= MFINDEXOF 1,CEFN(3)
77GW BCT 7 ZB [BACK FOR NEXT AREA
782G ACROSS CONTEND,1 [GO AND SET REPLIES
78G6 #
78^Q #
79FB #
79^2 #
7=DL #
7=Y= # AREA UNIT NOT ONLINE -CHECK FOR MODE #4000 AND SET REPLIES
7?CW # IF PRESENT OTHERWISE GET UNIT ONLINE
7?XG #
7#C6 ...XM MHUNTW 3,EWDAS,GEXD
7*BB LDCT 0 #10
7*W2 ANDX 0 EMARK(3)
7B*L ... BNZ 0 SCA1 [JUMP IF MODE #4000 SET
7BT= ... SMUSEST ARUNIT(3),SB,SA
7C#W BRN XN [JUMP IF ONLINE
7CSG [CANTDO HAS OCCURED
7D6X ...#UNS IPBD
7DF# ...#SKI
7DRQ (
7F?B SBA MHUNTW 3,EWDAS,GEXD
7FR2 RELST HMUNIT(3)
7G=L )
7GQ= SB LDX 0 AWORK1(2)
7H9W ... BNZ 0 SCA1 [JUMP IF CONTRACT HAS BEEN STARTED
7HPG LDCT 7 #400 [OTHERWISE FAIL
7J96 BRN SCA
7JHH ...#UNS IPBD
7JTY ...#SKI
7K8B (
7KN2 SAA MHUNTW 3,EWDAS,GEXD
7L7L RELST HMUNIT(3)
7LM= )
7M6W SA LDN 7 1 [BREAKIN
7MLG LDX 0 AWORK1(2)
7N66 ... BZE 0 SMA [JUMP IFNO AREAS REMOVED YET
7NKQ SCA ACROSS CONTEND,2 [GO AND SET REPLIES ETC
7NQY ...SCA1 LDN 7 0
7NY6 ... BRN SCA
7P5B #
7PK2 # HOME UNIT NOT ONLINE-CHECK FOR MODE #4000
7Q4L # AND GET UNIT ONLINE IF NOT PRESENT -OTHERWISE SET REPLIES
7QJ= #
7R3W XE MHUNTW 3,EWDAS,GEXD
7RHG LDCT 0 #10
7S36 ANDX 0 EMARK(3)
7SGQ BNZ 0 SL [JUMP IF MODE #4000 SET
7SQJ ...#UNS IPBD
7T2B ... LDN 7 0
7T=8 ... SMUSEST HMUNIT(3),SN,SM
7TG2 BRN XG [JUMP IF ONLINE OK
7TTP ...#UNS IPBD
7W9D ...#SKI
7WK7 ...(
7WYW SMA MHUNTW 3,EWDAS,GEXD
7XDG RELST HMUNIT(3)
7YCQ SM MHUNTW 3,EWDAS,GEXD
7YXB FREECORE 3 [CONTRACT HAS NOT BEEN
7^C2 STEPBACK [STARTED SO PROGRAM CAN REPEAT
7^WL PROGBRKIN [THE PERI
7^X9 ...)
7^XS ...#UNS IPBD
7^YC ...(
7^^2 ...#
7^^K ...# IPB INOP WHEN GETTING HOME UNIT LOCK-OUT
8228 ...#
822R ...SNA NGNC 7 1
823B ...#
823^ ...# BREAKIN WHEN WAITING FOR IPB WHEN GETTING HOME UNIT LOCK OUT
824J ...#
8257 ...SMA LDN 7 0
825Q ... MHUNTW 3,EWDAS,GEXD
826* ... RELST HMUNIT(3)
826Y ...#
827H ...# BREAKIN WHEN WAITING FOR HOME UNIT TO COME ONLINE
8286 ...#
828P ...SM MHUNTW 3,EWDAS,GEXD
829# ... LDX 6 HMUNIT(3)
829X ... FREECORE 3
82=G ... STEPBACK [TAKE ONE ORF ONR
82?5 ... BZE 7 NIPB [J IF BREAKIN
82?N ... TWAIT 6,NIPB [WAIT FOR IPB
82#? ... RUNPROG [TRY AGAIN
82#W ...NIPB PROGBRKIN
82*F ...)
82B= #
82TW #
83*G #
83MX ...#UNS IPBD
842# ...#SKI
84#Q (
84SB SNA MHUNTW 3,EWDAS,GEXD
85#2 RELST HMUNIT(3)
85RL )
86?= SN ACROSS CONTEND,9 [CANTDO
86QW #
87=G #
87Q6 SL ACROSS CONTEND,3 [CONTRACT NOT YET STARTED
889Q # [SET REPLY 6
88PB #
8992 #
89NL #
8=8= #
8=MW #
8?7G #
8?M6 # AREA UNIT SCA CORRUPT
8#6Q #
8#LB #
8*62 R5 ACROSS CONTEND,10
8*KL #
8B5= # FAILURE DURING EXOPEN
8BJW #
8C4G XJ ACROSS CONTEND,4
8CJ6 #
8D3Q # SCA CORRUPT ON HOME UNIT
8DHB R2 ACROSS CONTEND,5
8F32 #
8FGL #
8G2= # ERROR WHILST WRITING TO AREA UNIT OR FIP CELL
8GFW #
8G^G R3 ACROSS CONTEND,7
8HF6 #
8HYQ #
8JDB # FAIL BEFORE DOING ANY WRITING - EXOF MUST BE RESET
8JY2 #
8KCL R1 ACROSS CONTEND,8
8KX= #
8LBW #
8LJ4 ...#UNS IPBD
8LP= ...R4 ACROSS CONTEND,11
8LWD ...#UNS IPBD
8M3L ...#SKI
8M8S ...(
8MB6 R4A NGNC 7 1
8MTQ R4 LDN 7 0
8N*B R4B ACROSS CONTEND,11 [FAIL ON AREA UNIT
8N*L ...)
8N*W ...#
8NB6 ...#
8NBB ...#UNS IPBD
8NBL ...(
8NBW ...#
8NC6 ...# BREAKIN WHEN GETTING LOCK-OUT FOR AREA AND OR HOME UNITS
8NCB ...#
8NCL ...SAX MHUNTW 3,EWDAS,GEXD
8NCW ... LDX 5 HMUNIT(3)
8ND6 ... TXU 5 ARUNIT(3)
8NDB ... BCC SAAC [J IF AREA=HOME
8NDL ... RELST ARUNIT(3) [RELEASE AREA UNIT
8NDW ...SAAC BRN SA [REPORT BREAKIN
8NF6 ...#
8NFB ...# IPB DOWN ON LOCKM
8NFL ...#
8NFW ...SBX LDX 4 ACOMMUNE9(2) [SUSN WE WERE TRYING FOR WHEN IPB FAI
8NG6 ... MHUNTW 3,EWDAS,GEXD
8NGB ... LDX 5 HMUNIT(3)
8NGL ... TXU 5 ARUNIT(3)
8NGW ... BCC SAAB [J IF HOME=AREA
8NH6 ... RELST ARUNIT(3) [RELEASE AREA
8NHB ...SAAB RELST 5 [AND HOME UNIT
8NHL ... TWAIT 4,SAF [WAIT FOR IPB
8NHW ...#
8NJ6 ...# AT THIS POINT WE COULD DO A STEPBACK-RUNPROG BUT WE
8NJB ...# MAY HAVE ALREADY REMOVED SOME AREAS,IN WHICH CASE THE PROG
8NJL ...# MAY CONTRACT MORE THAN IT WISHED.INSTEAD THE DISCS ARE GOT AGAIN
8NJW ...# AND THE CONTRACT LOOP RE-ENTERED. OF COURSE THERE IS A CHANCE
8NK6 ...# THAT THE FILE COULD HAVE BEEN CONTRACTED IN THE OTHER PROCESSOR
8NKB ...# IN WHICH CASE A ERROR WOULD BE REPORTED AS THE COUNT OF AREAS
8NKL ...# COMPARED TO THE NUMBER WE HAVE WOULD NOT TALLY.
8NKW ...#
8NL6 ... SUSEST 5,XXE [GET HOME UNIT ONLINE AGAIN
8NLB ...SAAD MHUNTW 3,EWDAS,GEXD [SET UP CONDITIONS
8NLL ... MFINDEXOF 1,CEFN(3) [..TO RE-ENTER
8NLW ... BRN ZB [..CONTRACT LOOP
8NM6 ...# NOT ONLINE-DEMAND IT
8NMB ...XXE MHUNTW 3,EWDAS,GEXD
8NML ... LDCT 0 #10
8NMW ... ANDX 0 EMARK(3)
8NN6 ... BNZ 0 SCE [J IF ADDITIVE MODE #4000
8NNB ... SMUSEST 5,SCD,SAF [GET HOME UNIT ONLINE
8NNL ... BRN SAAD [JOIN CONTRACT LOOP
8NNW ...# BREAKIN
8NP6 ...SAF LDN 7 0
8NPB ... LDX 0 AWORK1(2)
8NPL ... BZE 0 SM [J IF NO AREAS REMOVED YET
8NPW ... LDN 7 1
8NQ6 ...SCAF ACROSS CONTEND,12
8NQB ...SCE LDN 7 0
8NQL ... BRN SCAF
8NQW ...# CANTDO
8NR6 ...SCD LDX 0 AWORK1(2)
8NRB ... BNZ 0 SCE [J IF AREAS REMOVED
8NRL ... LDCT 7 #400
8NRW ... BRN SCAF
8NS6 ...)
8NT2 #
8P#L #
8PS= #
8Q?W MENDAREA 30,K99CONTRACT
8QRG #END
^^^^ ...77342544000100000000