{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: COOR865)}}
====== COOR865 ======
(George Source)
**Macros used:** [[george:macro:APGA|APGA]], [[george:macro:BC|BC]], [[george:macro:BRUSEN|BRUSEN]], [[george:macro:BXE|BXE]], [[george:macro:BXGE|BXGE]], [[george:macro:BXL|BXL]], [[george:macro:BXU|BXU]], [[george:macro:CHAIN|CHAIN]], [[george:macro:COOR1X|COOR1X]], [[george:macro:ENTRUST|ENTRUST]], [[george:macro:FIXTRA|FIXTRA]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FON|FON]], [[george:macro:FPCAJO|FPCAJO]], [[george:macro:FREEBUFF|FREEBUFF]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHCODE|FSHCODE]], [[george:macro:FSHSKIP|FSHSKIP]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GEOEVENTS|GEOEVENTS]], [[george:macro:HLSWAITS|HLSWAITS]], [[george:macro:ICT|ICT]], [[george:macro:JBC|JBC]], [[george:macro:JBCC|JBCC]], [[george:macro:JBS|JBS]], [[george:macro:JBSS|JBSS]], [[george:macro:JMBS|JMBS]], [[george:macro:LABFIX|LABFIX]], [[george:macro:LINKSET|LINKSET]], [[george:macro:MBI|MBI]], [[george:macro:ON|ON]], [[george:macro:SHLSQ|SHLSQ]], [[george:macro:SQOSS|SQOSS]], [[george:macro:SQOSS2|SQOSS2]], [[george:macro:SQUMP|SQUMP]], [[george:macro:SQUMP2|SQUMP2]], [[george:macro:STEMPQ|STEMPQ]], [[george:macro:SUNDUMP|SUNDUMP]], [[george:macro:TRACE|TRACE]], [[george:macro:TRANSEND|TRANSEND]], [[george:macro:TRANSFIX|TRANSFIX]], [[george:macro:TRUEDORM|TRUEDORM]], [[george:macro:USEST|USEST]]
22FL ...#OPT K0COOR=0
22^= #LIS K0COOR>K0KERNEL>K0ALLGEO
23DW #SEG COOR70 [RUTH PORTER
23YG #OPT K6COOR=K6KERNEL>K6ALLGEO
24D6 #
24XQ # THE FOLLOWING PIECE OF PROGRAM IS THE COORDINATOR, WHICH
25CB # DEALS WITH THE ACTIVITY LIST AND QUEUE. IT ENTERS ACTIVITIES
25X2 # WHICH EXECUTIVE PUTS ON THE LIST AND SWITCHES GEORGE OFF
26BL # USING GEOEVENTS WHEN NONE LEFT,BESIDES OTHER SECONDARY FUNCTIONS
26W= #
27*W # THE FON ROUTINE WHICH FREES WAITING ACTIVITIES.
27TG #
285# ... FIXTRA K1COOR
28*6 LABFIX HSON1
28SQ SON1 [ONLY WAKE UP 1ST ON Q,SET MARKER
29#B LDCT 2 #777 [WHEN NEGATED LATER WILL LEAVE
29S2 STO 2 GEN6 [LS 9 BITS CLEAR
2=?L BRN SONN
2=R= LABFIX HSON
2?=W SON STOZ GEN6
2?QG SONN STO 1 FLINK
2#=6 STO 0 FONSTYLE [DUMP WAITING STYLE
2#PQ SOON [ENTRY FROM LONGON ROUTINE
2*9B LDX 1 FLOWQ
2*P2 SLOOP LDX 2 1 [SEARCH QUEUE
2B8L LDX 1 0(2)
2BN= SBN 2 FLOWQ
2C7W BZE 2 SCW2 [J IF BACK TO BEGINNING
2CMG ADN 2 FLOWQ-CHAINADD
2D76 LDEX 0 ATYPE(2) [COMPARE WAITING STYLES
2DLQ SBX 0 FONSTYLE [COMPARE WITH SPECIFIED STYLE
2F6B BNZ 0 SLOOP [J IF NO MATCH
2FL2 SOO NGX 0 GEN6
2G5L BPZ 0 SONO [J IF NOT LONGON1
2GK= LDEX 0 CLONG1(2)
2H4W SNO BNZ 0 SLOOP
2HJG SONO DSA 0 ATYPE(2)
2J46 LDX 0 CHAINADD(2) [JOIN UP QUE]E CHAN
2JHQ SMO BACKCHAN(2)
2K3B STO 0 0 [CHAINADD OF PREVIOUS
2KH2 LDX 0 BACKCHAN(2)
2L2L SMO CHAINADD(2)
2LG= STO 0 1 [BACKCHAN OF NEXT
2L^W #SKI K6COOR>499-499
2MFG TRACE 2,FON OFFQ
2M^6 LDCT 0 #10
2NDQ ANDX 0 CLONG1(2) [CLEAR BC BIT
2NYB ERS 0 CLONG1(2)
2PD2 #
2PXL # NOW PUT THIS ACTIVITY ON THE END OF K3 LIST
2QC= #
2QWW ADN 2 CHAINADD
2R33 ...#UNS ICTON
2R78 ...(
2R?* ... STO 1 ASFDUMP
2RCG ... LDCH 1 ACRIT-CHAINADD(2)
2RHM ... LDX 0 BITS22LS
2RMS ... SMO 1+GMELRTAB(1)
2RR^ ... ANDS 0 ASU [DESUSPEND RELEVANT GMEL
2RY6 ... FIXTRA K80COOR
2S4? ... LDN 1 K3 [ICT ON:- LDX 1 ACTLIS(1)
2S8D ... STO 1 FPTR(2)
2S#K ... LDX 0 BPTR(1)
2SDQ ... SMO 0
2SJX ... STO 2 FPTR
2SP4 ... STO 0 BPTR(2)
2ST9 ... STO 2 BPTR(1)
2S^B ... LDX 1 ASFDUMP
2T5H ... FIXTRA K81COOR
2T9N ...)
2T*T ...#UNS ICTON
2TG2 ...#SKI
2TL7 ...(
2TQ# ... LDN 0 K3
2TWF ... STO 0 0(2) [BACK BEFORE FWD - CLEAN FOR EXEC
2W2L ... LDX 0 K3+1 [LAST ONE
2W6R ... SMO 0
2W=Y ... STO 2 0 [NEW LAST
2WC5 ... STO 0 1(2) [PREVIOUS LAST
2WH= ... STO 2 K3+1 [NEW LAST
2WMC ...)
2WRW LDXC 0 GEN6
2X?G BCS SCW2 [J TO END IF FON & ONLY 1 REQD
2XR6 BRN SLOOP [GO TO GET NEXT
2Y=Q #
2YQB # COOR2, ENTRY USED AT END OF TIME QUOTA
2^=2 #
2^PL LABFIX HSOOR2
329= SOOR2
32NW STO 0 FLINK [DUMP LINK
338G LDN 1 K8
33N6 TXU 1 K8
347Q BCS SIN [J IF GHOST LIST NOT EMPTY
34MB LDN 1 K3
3572 TXU 1 K3 [TEST IF K3 LIST IS ALSO EMPTY
35BS ... FIXTRA K90COOR
35LL BCC SCW2 [YES, J TO RE-ENTER CHAPTER
35MP ...#UNS ICTON
35NS ...(
35R2 ... BRN SIN [ICT ON:- LDX 2 FX2
35S5 ... LDCH 1 ACRIT(2)
35S* ... BXL 1 ASFNO,SOOR2P [J IF WITHIN MAX AP
35SK ... LDX 1 ASFNO1 [OTHERWISE TAKE LOWEST
35ST ...SOOR2P
35T8 ... ADN 1 1
35W? ...SOOR2LOOP
35XB ... LDX 2 ACTLIS-1(1)
35YF ... BXU 2 FPTR(2),SIN [J IF ACT ON LIST
35^J ... BCT 1 SOOR2LOOP
362M ... BRN SCW2
363Q ... FIXTRA K91COOR
364T ...)
366= SIN SQOSS [PROCESS LINK
36KW SQUMP2 [DUMP ACCUMULATORS
375G #
377D ...#
379B ...# LABEL FOR EXECUTIVE/G3 CONCURRENCY (FOR 2960 DUAL DME) ROUTINE
37?# ...# AT END OF CHCH TO PASS OVER CURRENT ACTIVITY AND GO ON TO NEXT.
37*= ...#
37C8 ... FIXTRA CURFIX3
37F6 ... LABFIX CURFIX3
37H4 ...#
37K6 LABFIX FLIST
384Q ... LDX 1 COOR1X
38JB #
3942 # THE ROUTINE FOR PUTTING AN ACTIVITY ON THE (END OF) THE LIST.
39HL LABFIX HSPUT
3=3= SPUT
3=GW #SKI K6COOR>999-999
3?2G TRACE 2,ON LIST
3?G6 #SKI K6COOR>11-11
3?^Q (
3#FB LDX 0 ATYPE(2)
3#^2 TXL 0 CACT
3*DL BCC SACTY
3*Y= GEOERR 0,NOT ACTY
3BCW SACTY
3BXG )
3CC6 STO 1 FLINK [DUMP LINK
3CLY ...TRUE2
3CWQ ADN 2 CHAINADD
3DBB #SKI K6COOR
3DW2 (
3F*L LDX 0 BPTR(2)
3FT= BZE 0 ZONCE
3G#W GEOERR 0,LISTKNOT
3GSG ZONCE
3H#6 )
3HD# ...#UNS ICTON
3HJG ...(
3HNN ... FIXTRA K92COOR
3HSW ... BRN X93COOR [ICT ON:- LDCH 1 ACRIT-CHAINADD(2)
3HTN ... BXL 1 ASFNO,XPUTP [ENSURE LOWEST PRIORITY..
3HWG ... LDX 1 ASFNO1 [..IS AS SET BY USER
3HX# ... DCH 1 ACRIT-CHAINADD(2)
3HY6 ...XPUTP
3H^4 ... LDX 0 BITS22LS
3J5= ... SMO 1+GMELRTAB(1)
3J9D ... ANDS 0 ASU [DESUSPEND RELEVANT GMEL
3J*L ... LDX 1 ACTLIS(1)
3JFS ... STO 1 FPTR(2)
3JL2 ... LDX 0 BPTR(1)
3JQ8 ... SMO 0
3JWB ... STO 2 FPTR
3K2J ... STO 0 BPTR(2)
3K6Q ... STO 2 BPTR(1)
3K=Y ... BRN SCW2
3KC6 ... FIXTRA K93COOR
3KH# ...X93COOR
3KMG ...)
3KRN ... LDN 0 K3
3KXW ... STO 0 0(2) [BACK BEFORE FWD - CLEAN FOR EXEC
3L44 ... LDX 1 K3+1 [LAST ONE
3L8= ... STO 2 0(1) [NEW LAST
3L#D ... STO 1 1(2) [PREVIOUS LAST
3LDL ... STO 2 K3+1 [NEW LAST
3LJS ... FIXTRA INOSTDP1
3LPG SCW2 LDX 2 FX2 [RESET X2
3M96 LDX 1 FX1 [ AND X1
3MNQ BRN (FLINK)
3MPF ...#UNS ISTDP
3MQ8 ...(
3MQX ...#
3MRL ...# TRUEDORM ENTRY TO KICK PCA TO SWAPOUT PROGRAM
3MS* ... LABFIX HTRUED
3MT4 ... STO 1 FLINK
3MTR ... BNZ 2 TRUE1 [J IF JOBQ ADDRESS ALREADY LOADED
3MWG ... BRUSEN SCW2
3MX9 ... FJOCA 2,FX2
3MXY ...TRUE1
3MYM ... LDEX 0 JMISC(2)
3M^B ... BZE 0 SCW2 [J IF NO CORE IMAGE
3N25 ... JBC SCW2,2,JBSI
3N2S ... JMBS SCW2,2,JBBEING,JBPLUGGING,JBNSW,JBREEF
3N3H ... BC 2,JBRUN
3N3Q ...#UNS INOSTDP
3N3^ ... FIXTRA INOSTDPCOOR
3N4= ... MBI 2,JBBEING,JBSI
3N4^ ... FPCAJO 2,2
3N5N ... LINKSET 2,ATRUEDLINK
3N6C ... BRN TRUE2 [J INTO FPUT ROUTINE
3N76 ...)
3N8B #
3NN2 # COOR1, ENTRY USED WHEN AN ACTIVITY FINISHES.
3P7L LABFIX HSOOR1
3PM= SOOR1
3Q6W SQUMP [DUMP ACCUMULATORS
3QLG LABFIX HSOOR1Y
3R66 SOOR1Y
3RKQ SQOSS [PROCESS LINK
3S5B LABFIX HSOOR1X
3S*8 ... FIXTRA BPCOOR1X [BATCH PATCH LABEL
3SK2 SOOR1X
3T4L LABFIX FQOB
3T4S ...#UNS ICTON
3T52 ...(
3T58 ... FIXTRA K94COOR
3T5B ... BRN X95COOR [ICT ON:- LDCT 6 #400
3T5J ... LDX 1 FX2LAST
3T5Q ... LDN 7 K3
3T6= ... BXU 7 K3,SORT
3T6Q ... BZE 1 WAS0 [NO FIDDLING WITH MEL 0
3T7= ... LDX 2 ACTLIS(1)
3T7S ... BXU 2 FPTR(2),WAS0 [J IF LIST NOT EMPTY
3T82 ... SMO 1+GMELRTAB(1)
3T88 ... ORS 6 ASU [SUSPEND MEL
3T8B ...WAS0 LDN 0 K8
3T8J ... BXU 0 K8,ONE61 [J IF ACT ONGHOST LIST
3T96 ...XLOOK LDN 2 0
3T99 ... LDX 4 ASFNO1 [NOW LOOK AT ALL HIGHER GMELS
3T9# ... LDX 0 ASU+GMEL [CHECK MEM0
3T9C ... BNZ 0 ROUND [GO ON TO NEXT IF SUSP
3T9G ... LDX 3 ACTLIS
3T9K ... BXU 3 FPTR(3),PHOUND [GO TO RUN FIRST ON LIST0
3T9N ...ROUND ADN 2 1
3T9R ...ROUND1
3T9W ... LDX 1 1+GMELRTAB(2)
3T9^ ... LDX 0 ASU(1)
3T=4 ... BNZ 0 RD1 [J IF SUSP
3T=7 ... LDX 3 ACTLIS(2)
3T== ... BXU 3 FPTR(3),PH1 [GO TO RUN IF SOMETHING TO DO
3T=* ... ORS 6 ASU(1) [SUSP SPURIOUSLY DESUSP MEM
3T=D ...RD1 ADN 2 1
3T=H ... BCT 4 ROUND1 [GO ONTO NEXT
3T=L ...[..IF ALL SUSP DO 161
3T=Y ...ONE61
3T?4 ... GEOEVENTS
3T?7 ...TRY
3T?? ... BXE 7 K3,XLOOK [J IF K3 EMPTY
3T?* ...SORT STOZ ASU+GMEL
3T?J ...[ ...2960 DUALS TO STOP EXEC & G3 BOTH RECHAINING ON OR FROM K3
3T?K ... FIXTRA CURFIXASF1 [MENDED BY CONCURR MACRO
3T?L ... NULL [TO: LDX 0 FBIDMEM
3T?M ... NULL [TO: BPZ 0 CURFIXASF2
3T?Q ...TOUR LDX 3 K3
3T?Y ... BXE 3 7,XEND [J IF ALL DONE
3T#6 ... LDX 1 FPTR(3)
3T## ... STO 7 BPTR(1) [UPDATE NEXT ON K3
3T#G ... STO 1 K3
3T#N ... LDCH 2 ACRIT-CHAINADD(3) [ACTLIS NUMBER
3T#W ... SMO 1+GMELRTAB(2)
3T*4 ... STOZ ASU
3T*= ... LDX 2 ACTLIS(2) [ACTLIST BASE
3T*D ... STO 2 FPTR(3)
3T*L ... LDX 1 BPTR(2)
3T*S ... STO 3 BPTR(2)
3TB2 ... STO 1 BPTR(3)
3TB8 ... STO 3 FPTR(1)
3TBB ... BRN TOUR
3TBC ...[ WE COME HERE IF CONCURRENCY IS IN FORCE IN DUALS AND WE
3TBD ...[ ARE NOT "TRUSTED"
3TBF ... FIXTRA CURFIXASF2
3TBG ... ENTRUST TOUR,XLOOK [DECANT IF EXEC NOT RUNNING,
3TBH ... [ELSE TRY ACTIVITY LISTS
3TBJ ...[
3TBK ...[MEM0 MUST BE EMPTY IF WE GET HERE AND SINCE WE FOUND MEM
3TBL ...[OTHER THAN 0 DESUSP IT IS SAFE TO SUSP MEM0 EXPLICITLY RATHER
3TBM ...[THAN USE EXPENSIVE XCODE I.E 161
3TBN ...PH1 ORS 6 ASU+GMEL
3TBP ... FIXTRA CURFIXASF
3TBQ ... LDX 0 FX2LAST [OLD AP
3TBR ... BXGE 0 2,PHOUND [J IF GOING UP
3TBS ... '163 0 0 [IF GOING DOWN ENSURE PROGS HAVE A GO
3TBT ...NONEED
3TBW ... BRN PHOUND [GO AND RUN NEXT
3TBX ...XEND LDX 1 ACTLIS
3TBY ... BXE 1 FPTR(1),TRY [J IF GMEL0 LIST EMPTY
3TB^ ... LDN 2 0 [SET GMEL NO
3TC6 ...PHOUND
3TCG ... LDX 1 2
3TCW ...PHOUND1 STO 1 FX2LAST
3TD= ... LDX 3 ACTLIS(1) [ACT LIST BASE
3TDD ... LDX 2 FPTR(3)
3TDL ... LDX 1 FPTR(2) [BLOCK FOLLOWING
3TDS ... STO 3 BPTR(1)
3TF2 ... STO 1 FPTR(3) [UPDATE ACT LIST RING
3TF8 ... STOZ BPTR(2)
3TFB ... SBN 2 CHAINADD
3TFJ ... STO 2 FX2 [GOTCHER!
3TFQ ... TRANSFIX BRN,FZCO
3TFY ... FIXTRA K95COOR
3TG3 ...X95COOR
3TG6 ...)
3TG# ...[
3TGG ...[ ICT OFF CODE
3TGN ...[
3TJ= ... LDN 2 K8
3W3W ... LDN 3 K3
3WHG ... BXU 2 K8,SJH
3X36 ... BXU 3 K3,STOPE [CHECK IF GEOEVENTS NEEDED
3XGQ ...SJH
3Y2B ... GEOEVENTS
3YG2 ...STOPE
3Y^L ... LDX 2 K3 [GET NEW K3
3^F= #SKI K6COOR>49-49
3^YW (
42DG BPZ 2 XECOK
42Y6 GEOERR 0,RONG K3
43CQ XECOK
43XB )
444J ... LDN 0 BACT
449Q ... BXGE 2 0,NOTMPT
44C2 ... '142 0 2
44LS ...NOTMPT
44WL LDX 3 0(2) [OFF THE LIST
45B= LDN 0 K3 [UPDATE BACKWARD
45TW STO 0 1(3) [POINTER
46*G STOZ 1(2) [NOT DOUBLY CHAINED
46T6 SJK STO 3 K3 [UPDATE K3
47#Q SJM SBN 2 CHAINADD [RELATIVISE TO START OF ACTIVITY BLOK
47SB STO 2 FX2 [STORE CURRENT ACTIVITY
48#2 TRANSFIX BRN,FZCO
48RL #
49?= # COOR3, PUT WAITING IN SPECIFIED STYLE
49QW #
4==G LABFIX HSOOR3
4=Q6 SOOR3
4?9Q SQUMP [DUMP ACCUMULATORS
4?PB LABFIX HSOOR3Y
4#92 SOOR3Y
4#NL SQOSS [PROCESS LINK
4*8= LABFIX HSOOR3X
4*MW SOOR3X
4B7G LDX 2 FX2
4BM6 DSA 1 ATYPE(2)
4C6Q [WHERE NECESSARY
4CLB #SKI K6COOR>499-499
4D62 TRACE 2,CO3 ON Q
4DKL LDN 1 FLOWQ
4F5= STO 1 CHAINADD(2) [PUT ON
4FJW LDX 1 AQEND [END OF
4G4G STO 1 BACKCHAN(2) [QUEUE
4GJ6 ADN 2 CHAINADD
4H3Q STO 2 0(1)
4HHB STO 2 AQEND
4J32 TRANSFIX BRN,FQOB
4JGL #
4K2= #
4KFW # LONGWAIT TYPE COORDINATOR ROUTINES
4K^G #
4LF6 #
4LL# ...#SKI JWPHASE4<1$1
4LRG ...(
4LYQ [ROUTINE FOR CHECKING BREAKIN
4MDB LABFIX HSBCBIN1
4MY2 SBCBIN1
4NCL ... NGN 1 5
4NX= BRN PAST
4PBW LABFIX HSCHECKBIN
4PWG SCHECKBIN
4Q8X ... LDN 1 1
4QH# ... BRN PAST
4QTQ LABFIX HSBCBIN
4R*B SBCBIN
4RP5 ... NGN 1 1
4S4S ...PAST NGS 1 GEN6 [-VE IF TESTBRKIN
4SDH ...[ OTHERWISE AMOUNT TO STEBACK LINK
4SS= LDX 2 FX2
4SW8 ...#SKI IPL
4SY6 ...(
4T24 ... LDX 1 ATYPE(2)
4T42 ... SRL 1 12
4T5Y ... SBN 1 GENERAL+IPLINP
4T7W ... BZE 1 XIPL
4T9S ...)
4T?W LDCH 1 ATYPE(2)
4TRG SBN 1 CPAT/64 [IF NOT ISSUED IN A COMPRO ACTIVITY.
4W?6 BNZ 1 XITCH [CHECK JOBNO=0 AND EXIT.
4WD# ...#SKI IPL
4WKG ...XIPL
4WQQ LDCT 1 #100 [BREAK IN BIT.
4X=B ANDX 1 JOBEVENTS(2) [BREAK IN WORD.
4XQ2 BZE 1 XIT1
4Y9L ERS 1 JOBEVENTS(2) [UNSET B2
4YP= DEX 1 CLONG1(2) [CLEAR LONG EVENT WAIT FIELD AFTER BR
4^8W SBN 0 1 [THIS EXIT IF BROKEN IN
4^NG XIT LDX 1 FX1
5286 EXIT 0 1
52MQ #SKI K6COOR
537B (
53M2 XITCH
546L LDCH 1 ATYPE(2)
54L= SBN 1 AOLPT/64
555W BZE 1 XER [ERROR IF LW FROM OLPA
55KG LDCH 1 ATYPE(2)
5656 SBN 1 APET/64
56JQ BNZ 1 XIT [ERROR IF PCA
574B XER GEOERR 1,WRONGACT
57J2 )
583L #OPT XITCH=XIT
58H= XIT1 LDX 1 GEN6
592W BNG 1 XIT [J IF TESTBRKIN
59GG LDCT 1 #10
5=26 ANDX 1 CLONG1(2)
5=FQ BZE 1 XIT
5=^B SBX 0 GEN6 [ADJUST LINK
5?F2 ...[ SO REOBEY BREAK IN CHECK
5?YL SQUMP2
5#D= SQOSS2
5#XW LDN 1 ALWPAIR [X1 ->LINK PAIR FOR B/C
5*CG TRANSFIX BRN,CHCHSPEC
5*CJ ...)
5*CL ...#SKI JWPHASE4
5*CN ...(
5*CQ ...# THROUGHOUT THE FOLLOWING:-
5*CS ...# X1=FX1 IF AROUSAL ENTRY. ELSE=VALUE FOR LONGEVENT FIELD
5*CW ...# X2=FX2
5*CY ...# X5=1 IF LONGTARRY [DON'T CHECK FOR BROADCAST
5*D2 ...# =-1 IF LONGCOOR [DON'T CHECK FOR BREAK IN
5*D4 ...# =0 OTHERWISE
5*D6 ...# X6=0 IF TESTBRKIN
5*D8 ...# =1 IF LONGSTOP ETC.
5*D= ...# =-1 IF LONGWAIT ETC.
5*D# ...# X7=LINK - LOADED FROM X0 ON ENTRY
5*DB ...#
5*DD ... LABFIX HSCHECKBIN
5*DG ...SCHECKBIN [TESTBRKIN
5*DJ ... LDN 2 0
5*DL ... BRN SBIN
5*DN ... LABFIX HSOOR3LW2
5*DQ ...SOOR3LW2 [LONGWAIT ETC.
5*DS ... LDN 2 #100
5*DW ... BRN SBIN
5*DY ... LABFIX HSOOR3LW3
5*F2 ...SOOR3LW3 [LONGTARRY
5*F4 ... LDN 2 #202
5*F6 ... BRN SBIN
5*F8 ... LABFIX HSOOR3LW4
5*F= ...SOOR3LW4 [LONGCOOR
5*F# ... LDN 2 #201
5*FB ... BRN SBIN
5*FD ... LABFIX HSOOR3LW1
5*FG ...SOOR3LW1 [LONGSTOP
5*FJ ... LDN 2 #200
5*FL ...SBIN STO 2 GEN6
5*FN ... SQUMP
5*FQ ... LDCH 5 GEN6
5*FS ... SRC 5 1
5*FW ... LDX 6 GEN6
5*FY ... SRC 6 7
5*G2 ... LDX 7 0
5*G4 ...#SKI IPL
5*G6 ...(
5*G8 ... LDX 0 ATYPE(2)
5*G= ... SRL 0 12
5*G# ... SBN 0 GENERAL+IPLINP
5*GB ... BZE 0 XIPL
5*GD ...)
5*GG ... LDCH 0 ATYPE(2)
5*GJ ... SBN 0 CPAT/64
5*GL ... BNZ 0 XITCH [J IF NOT IN A CPAT
5*GN ...XIPL
5*GQ ... BNG 5 XIT1 [DON'T CHECK B-IN FOR LONGCOOR
5*GS ... LDCT 4 #100
5*GW ...#SKI
5*GY ...(
5*H2 ... BZE 6 TBKIN [J IF TESTBRKIN
5*H4 ... ORN 4 #20 [ADD BIT 19 TO CHECK FOR STOPJOB
5*H6 ...)
5*H8 ...TBKIN
5*H= ... ANDX 4 JOBEVENTS(2)
5*H# ... BZE 4 XIT1 [J IF NO B-IN
5*HB ... JBS XHLSOUT,2,EXLONGW [J IF WE MUST TELL HLS
5*HD ... ERS 4 JOBEVENTS(2) [CLEAR INFORM B-IN BIT...
5*HG ... LDN 0 0
5*HJ ... DEX 0 CLONG1(2) [AND LONG EVENT FIELD
5*HL ...XIT LDX 0 7
5*HN ... SUNDUMP
5*HQ ... LDX 1 FX1
5*HR ...
5*HS ... EXIT 0 0 [RETURN TO CALLING CHAPTER
5*HW ...#SKI K6COOR
5*HY ...(
5*J2 ...XITCH
5*J4 ... LDCH 0 ATYPE(2)
5*J6 ... SBN 0 AOLPT/64
5*J8 ... BZE 0 XER
5*J= ... LDCH 0 ATYPE(2)
5*J# ... SBN 0 APET/64
5*JB ... BNZ 0 XIT2
5*JD ...XER GEOERR 1,WRONGACT [OLPA OR PCA LONGWAITING!
5*JG ...)
5*JJ ...#OPT XITCH=XIT2
5*JL ...XITTB ADN 7 1
5*JN ... BRN XIT
5*JQ ...XIT1 BZE 6 XITTB [J TO EXIT IF TESTBRKIN
5*JS ... LDCT 0 #10
5*JW ... ANDX 0 CLONG1(2)
5*JY ... BZE 0 XIT2A [J IF NO BROADCAST
5*K2 ... BZE 5 NOTLT
5*K4 ... BPZ 5 XIT2A [IGNORE B/C IF LONGTARRY
5*K6 ...NOTLT LDN 1 ALWPAIR
5*K8 ...SPECDOWN
5*K= ... SBN 7 1
5*K# ... LDX 0 7
5*KB ... SQOSS2
5*KD ... TRANSFIX BRN,CHCHSPEC [GO DOWN TO MULTIPLX/HLSEVENT
5*KG ...XIT2A
5*KJ ... BXE 1 FX1,XHLSOUTQ [J IF THIS IS AROUSAL ENTRY
5*KK ...#UNS ISTDP
5*KL ...#SKI
5*KM ... JBC XIT2,,EVBWAITIN [J IF HLS NOT INTERESTED IN L/W'S
5*KN ... LDEX 3 1
5*KQ ... BNZ 3 XLW [J IF NOT LONGSTOP
5*KS ... LDEX 3 CLONG1(2)
5*KW ... BZE 3 XIT2 [J IF L/W WON'T BE ENTERED
5*KX ...#UNS ISTDP
5*KY ...(
5*K^ ...XLW LDX 4 1 [PRESERVE X1
5*L2 ... TRUEDORM [ANNOUNCE TRUE DORMANCY
5*L3 ... LDX 1 4
5*L4 ... JBC XIT2,,EVBWAITIN [J IF HLS NOT INTERESTED IN LW'S
5*L5 ... STO 3 ACOMMUNE4(2)
5*L6 ...)
5*L7 ...#UNS ISTDP
5*L8 ...#SKI
5*L9 ...XLW STO 3 ACOMMUNE4(2) [SUBSIDUARY INFO FOR HLS
5*L= ... LDX 4 3
5*L? ... SRL 4 4
5*L# ... ANDN 3 #17
5*L* ... SMO 4
5*LB ... LDX 0 HLSWAITS
5*LC ... SLL 0 0(3)
5*LD ... BPZ 0 XIT2 [J IF HLS NOT INTERESTED IN THIS L/W
5*LF ... LDX 3 JOBNO(2)
5*LG ... BZE 3 XIT2 [J IF NO-USER
5*LJ ... JBSS XIT2,2,EXLONGW [J IF HLS ALREADY KNOWS
5*LL ... LDN 0 EVWAITIN
5*LN ...XHLSINF
5*LQ ... STO 0 ACOMMUNE1(2) [EVENT NUMBER
5*LS ... STO 3 ACOMMUNE2(2) [JOB NUMBER
5*LW ... STOZ ACOMMUNE3(2)
5*LY ... LDN 1 AHLSPAIR
5*M2 ... SBN 7 1
5*M4 ... BRN SPECDOWN [GO DOWN TO INFORM HLS
5*M6 ...XHLSOUTQ
5*M8 ... LDN 4 0
5*M= ... BNG 6 XHLSOUT [J IF LONGWAIT ETC.
5*M# ... LDEX 3 CLONG1(2)
5*MB ... BNZ 3 XIT2 [J IF SPURIOUS LONGSTOP WAKE UP
5*MD ...XHLSOUT
5*MG ... LDX 3 1
5*MJ ... CALL 0 XLFSUB [INFORM HLS IF NECESSARY
5*ML ... LDX 1 3
5*MN ... BNZ 4 XIPL [RECHECK FOR B-IN
5*MQ ...XIT2
5*MS ... BPZ 6 XIT3 [J IF LONGSTOP ETC.
5*MW ... BXE 1 FX1,XITTB [J IF AROUSAL (EXIT +1 FOR NO B-IN)
5*MX ...WAIT3
5*MY ...#UNS FREEBUFF
5*M^ ...(
5*N2 ... DSA 1 ATYPE(2)
5*N3 ... LDX 4 FX2 [ POINTER TO ACTIVITY FOR FREEBUFF
5*N4 ... CALL 6 (FBACT) [ FREE FURBS OF ACTIVITY'S FILES
5*N5 ... BVCR XFREEBUFFV [ CLEAR OVERFLOW
5*N6 ...XFREEBUFFV
5*N8 ... LDX 2 FX2
5*N9 ... LDX 1 ATYPE(2)
5*N= ...)
5*N? ... LDX 0 7
5*N# ... SBN 0 1 [ADJUST LINK TO RESTART AT THE CALL
5*N* ... BRN SOOR3Y [ENTER COOR3 AT SQOSS
5*NB ...XIT3
5*NC ... BZE 6 XITTB [JUST IN CASE OF NON-CPAT TESTBRKIN
5*ND ... LDEX 3 CLONG1(2)
5*NF ... BZE 3 NOWATE [J IF WAIT TERMINATED NON-SPURIOUSLY
5*NG ... BXE 1 FX1,XITTB [J IF AROUSAL (EXIT +1 FOR SPURIOUS)
5*NH ... ORX 1 3
5*NJ ... BRN WAIT3 [ENTER THE WAIT
5*NK ...NOWATE
5*NL ... ADN 7 2
5*NN ... BRN XIT [EXIT +2 FOR GENUINE WAKE UP
5*NQ ...#
5*NS ... LABFIX HSLONGOFF
5*NW ...SLONGOFF [LONGOFF
5*NY ... LDN 1 0
5*P2 ... DEX 1 CLONG1(2) [CLEAR LONG EVENT FIELD
5*P4 ...XLFSUB [CALLED FROM XHLSOUT IN LONGWAIT SUB
5*P6 ... STO 0 GEN5
5*P8 ... LDCH 0 ATYPE(2)
5*P= ... SBN 0 CPAT/64
5*P# ... BNZ 0 XLFRT
5*PB ... JBCC XLFRT,2,EXLONGW [J IF HLS DOESN'T KNOW ABOUT THE LONG
5*PC ... FSHSKIP B,XLFRT
5*PD ...(
5*PF ... LDX 1 JOBNO(2)
5*PG ... SHLSQ 1,2,STEMPQ [THERE SHOULD BE AN HLSQ BLOCK FOR IT
5*PJ ... JBC XLFFREE,,EVBWAITOUT [J IF HLS NOT INTERESTED
5*PL ... LDX 1 HLSSTAT(2)
5*PN ... LDX 0 HLSEVLWOUT
5*PQ ... BNG 1 XLFBK [J IF BACKGROUND
5*PS ... SLL 0 1
5*PW ...XLFBK BPZ 0 XLFFREE [J IF HLS NOT INTERESTED
5*PY ... LDX 1 2
5*Q2 ... LDX 0 HLSYONQA(1)
5*Q4 ... ANDX 0 HALFTOP
5*Q6 ... ADN 0 EVWAITOUT [CHANGE EVENT NUMBER
5*Q8 ... STO 0 HLSYONQA(1)
5*Q= ... LDCT 0 #002
5*Q# ... ANDX 0 HLSYONQ(1)
5*QB ... ORX 0 HLSEVLWOUT+1
5*QD ... ORX 0 BIT10
5*QG ... STO 0 HLSYONQ(1)
5*QJ ... LDX 2 BHTEMP+1
5*QL ... CHAIN 1,2
5*QN ... LDX 0 HLSEVLWOUT+1
5*QQ ... ORX 0 BIT10
5*QS ... ORS 0 HLSWAIT
5*QW ... LDX 0 HLSEVLWOUT
5*QY ... SLL 0 2
5*R2 ... BPZ 0 XLFRT [J IF NOKICK
5*R4 ... FON #33
5*R6 ... BRN XLFRT
5*R8 ...STEMPQ
5*R= ... STEMPQ 1,2,XLFRT,STRE
5*R# ... LDX 0 HLSYONQA(2)
5*RB ... ANDN 0 #7777
5*RD ... SBN 0 EVWAITIN
5*RG ... BNZ 0 STRE
5*RJ ...XLFFREE
5*RL ... FREECORE 2
5*RM ...)
5*RN ... FSHCODE B,XLFRT
5*RP ... TRANSEND XLFRT
5*RQ ...XLFRT
5*RR ... LDX 1 FX1
5*RS ... LDX 2 FX2
5*RW ... BRN (GEN5)
5*RY ...#
5*S2 ...)
5*X6 #
5BBQ # THE LONGON ROUTINE SEARCHES THE CHAIN FOR ACT BLOCKS WITH SPEC L-S
5BWB # AND AUXILIARY INFORMATION, CLEARING THOSE WHICH AGREE IT THEN DOES
5CB2 LABFIX HSLONGON1
5CTL SLONGON1
5D*= STO 1 GEN6 [SET LONGON1 MARKER
5DSW BRN SLONGON2
5F#G LABFIX HSLONGON
5FS6 SLONGON
5G?Q STOZ GEN6
5GRB SLONGON2
5H?2 STO 1 FLINK [DUMP LINK
5HQL STO 2 FONSTYLE [DUMP WAITING STYLE
5J== LDN 2 BACT+ACTRING [BASE OF ACTIVITY RING
5JPW SNEXT LDX 2 0(2) [NEXT ACT BLOCK
5K9G BXE 2 BACTR,SOON [J IF BACK TO START
5KP6 LDEX 1 CLONG1-ACTRING(2) [LONGSTOP FIELD
5L8Q TXU 1 FONSTYLE [COMPARE WITH WAITING STYLE SPECIFIED
5LNB TXU 0 CLONG2-ACTRING(2)
5M82 BCS SNEXT [JUMP IF DIFFERENT AUXILIARY WORD
5MML #SKI K6COOR>399-399
5N7= (
5NLW TRACE 1,LONG FON
5P6G TRACE 0,LONG AUX
5PL6 )
5Q5Q ERS 1 CLONG1-ACTRING(2) [CLEAR LW FIELDS
5QKB BRN SNEXT [BACK FOR NEXT BLOCK
5QKP ... FIXTRA K96COOR
5QL4 ...#UNS ICT
5QLC ...(
5QLQ ... LABFIX APGA
5QM5 ... LDX 1 FX1 [ICT ON:- STO 1 HUNTED
5QMD ... LDX 2 FX2 [ICT ON:- STO 0 FLINK
5QMR ... EXIT 0 0 [ICT ON:- LDX 2 FX2
5QN6 ...)
5QNF ...#UNS ICTON
5QNS ...(
5QP7 ... SRL 1 6
5QPG ... SBN 1 #60
5QPT ... LDXC 0 APTYPETAB(1)
5QQ8 ... BCS USEST [USE SUBYPE
5QQH ... LDEX 1 0
5QQW ... ANDX 0 CACT
5QR9 ... BZE 0 TABUSE
5QRJ ... LDCH 1 ACRIT(2) [PICK FROM CALLING ACT
5QRX ...TABUSE
5QS= ... LDX 2 BPTR(2)
5QS# ... BXL 1 ASFNO,SMALL
5QSB ... LDX 1 ASFNO1 [TAKE MIN PRI IF TAB TOO BIG
5QSD ...SMALL
5QSK ... DCH 1 ACRIT(2)
5QSY ... LDX 1 FX1
5QT? ... LDX 2 FX2
5QTL ... BRN (FLINK)
5QT^ ...USEST LDEX 1 0
5QW# ... SRL 0 15 [GET TAB LENGTH
5QWM ... LDCH 2 HUNTED
5QX2 ... BXL 0 2,(GEOERR)
5QX* ... SRC 2 3 [CONVERT TO PTR
5QXN ... LDCT 0 #100
5QY3 ... ANDX 0 2
5QYB ... ERX 2 0 [CLEAR OCTAL DIGIT INDICATOR
5QYP ... ADX 2 1
5Q^4 ... LDCH 1 APSUBTYPE(2)
5Q^C ... BNZ 0 RIGHTDIG
5Q^Q ... SRL 1 3
5R25 ...RIGHTDIG
5R2D ... ANDN 1 3
5R2R ... LDX 2 FX2
5R36 ... BRN TABUSE
5R3F ...)
5R52 #END
^^^^ ...73167407007800000000