{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: DEWELL867)}}
====== DEWELL867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:ALTLENG|ALTLENG]], [[george:macro:BS|BS]], [[george:macro:CLOSE|CLOSE]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:COOR3|COOR3]], [[george:macro:CREATEB|CREATEB]], [[george:macro:DOWN|DOWN]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:ERASE|ERASE]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHCODE|FSHCODE]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GETDIR|GETDIR]], [[george:macro:GETFNAME|GETFNAME]], [[george:macro:GETJOB|GETJOB]], [[george:macro:HLSINFORM|HLSINFORM]], [[george:macro:HUNT|HUNT]], [[george:macro:ISSUCOMJ|ISSUCOMJ]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:JLADJUST|JLADJUST]], [[george:macro:JLASLOST|JLASLOST]], [[george:macro:JMBAC|JMBAC]], [[george:macro:LOBSFILE|LOBSFILE]], [[george:macro:MFREE|MFREE]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:NAME|NAME]], [[george:macro:OPENCREX|OPENCREX]], [[george:macro:OPEND|OPEND]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:ORIGIN|ORIGIN]], [[george:macro:OUTBLOCK|OUTBLOCK]], [[george:macro:OUTEXES|OUTEXES]], [[george:macro:OUTMESS|OUTMESS]], [[george:macro:OUTNULL|OUTNULL]], [[george:macro:OUTPACKX|OUTPACKX]], [[george:macro:OUTPAR|OUTPAR]], [[george:macro:PERMITBRK|PERMITBRK]], [[george:macro:READ|READ]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETMODE|SETMODE]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:SINM551|SINM551]], [[george:macro:SINMAC4|SINMAC4]], [[george:macro:SKIP|SKIP]], [[george:macro:TESTNAMX|TESTNAMX]], [[george:macro:TESTREP|TESTREP]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:TRACE|TRACE]], [[george:macro:USEROPEX|USEROPEX]], [[george:macro:VFREE|VFREE]]
22FL ...#OPT K0DEWELL=0
22^= #LIS K0DEWELL>K0ALLGEO>K0GREATGEO>K0COMMAND
233T ... SEG DEWELL,867,SECTION CENT,,G3UGSI,G400
236D ...[
2393 ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LIMITED 1982
23?L ...[ THIS EXCLUDES CODE UNDER #SKI G3UGSI
23B9 ...[
23C4 ...#UNS G400
23CX ...# THIS CHAPTER IS MODIFIED FOR G3PLUS-IH MK2
23DS ...#OPT G3UGSI=0
23HC ...#SKI G3UGSI
23L2 ...(
23NK ...# MACRO TO PREVENT M551 AND SECURITY INTERFACE CLASH
23R8 ... SINM551
23TR ...)
23YG #OPT WELLTEST=0
24XQ [
25CB [ THIS SEGMENT PERFORMS DEWELLMENT !
25X2 [ IE. SETS UP A JOB WHICH IS REMOVED FROM THE WELL
26BL [
26W= [
26^B ...#DEF XJWP4=0
27=Q ...#ALT XJWP4=1
27*W SEGENTRY K1DEWELL,START
27TG SEGENTRY K2DEWELL,WAYON
27^* ... SEGENTRY K3DEWELL,(GEOERR)
2858 ... SEGENTRY K4DEWELL,(GEOERR)
2893 ... SEGENTRY K5DEWELL,(GEOERR)
28#Y ... FSHENTRY K7DEWELL,,WMONF,WMONF
28*6 [
28SQ [
28X* ...#UNS G400
28^Y ...(
294H ... SEGENTRY K61DEWELL
2976 ...XTYPE +0 [B22 = MOP, B23 = BACK
299P ...)
29#B #DEF SIZEABS=10
29S2 #DEF SIZELIST=10
2=3S ...#DEF SIZEDIR=4
2=?L XMONE -1
2=R= ZERO 0
2?=W XONE 1
2?QG TWO 2
2#=6 THREE 3
2*9B SOCSLEN +ASSOCSLEN
2C7W MFLANG 4HB1B0
2C*4 ...ODLANG 4HC1
2CG= ...[
2CMG WTEMP #20000000
2D76 ...XJOBLIST 12H
2G5L 12HJOBLIST
2GK= 1
2H4W 1
2HJG 4H****
2J46 XTAB +IVTP
2JHQ ... +IVLP
2K3B +IVCP
2KH2 [
2L2L [
2LG= XTRACT
2L^W SBX 7 FX1
2MFG READ
2M^6 MHUNTW 3,FILE,FRB
2NDQ ADX 7 FX1
2NYB EXIT 7 0
2PD2 ...[
2PXL XOPEN SBX 7 FX1
2Q5D ... SETUPMOD ,5,FROZEN
2Q7B ... USEROPEX XBRK,6,5
2QWW ADX 7 FX1
2RBG TESTREP2 OK,YES
2RW6 EXIT 7 2 [ ANY OTHER
2S*Q XBRK ADX 7 FX1
2STB EXIT 7 1 [ BREAKIN
2T*2 YES EXIT 7 0 [ SUCCESS
2TSL [
2W#= [
2W#W ...[ PUT JOB SOURCE INTO ACOMMUNE2/3
2W*G ...[ & PREPARE TO O/P VOUTPACK
2WB6 ...MOPID
2WBQ ... SBX 7 FX1
2WCB ... LDX 0 ACES
2WD2 ... STO 0 ACOMMUNE3(2)
2WDL ... ADN 0 #2331 [CI
2WF= ... STO 0 ACOMMUNE2(2)
2WFW ... LDCH 0 JSOURCE1(2)
2WGG ... SBN 0 #74
2WH6 ... BZE 0 XENW4 [J IF CI
2WHQ ... LDX 0 ACES
2WJB ... STO 0 ACOMMUNE2(2)
2WK2 ... LDN 5 JSOURCE1(2)
2WKL ... LDN 6 ACOMMUNE7(2)
2WL= ... MOVE 5 3
2WLW ... ORIGIN
2WMG ...XENW4 LDN 4 2
2WN6 ... LDN 6 ACOMMUNE2(2)
2WNQ ... ADX 7 FX1
2WPB ... EXIT 7 0
2WQ2 ...[
2WQL ...[
2WRW VOUTPACK
2X?G LDN 5 JPDVARCHAR [ FOR VARCHAR OUTPUT
2XR6 XOUTPACK
2Y=Q SBX 7 FX1
2YQB OUTPACKX 6,4,5 [ OUTPUT NEXT PACKED PARAM
2^=2 ADX 7 FX1
2^PL EXIT 7 0
329= [
32NW [
32RF ...SJOB
32W4 ... FJOCA 3,2
32YM ... EXIT 7 0
333= ...[
335T ...[
33KF ...SFABSNB
3455 ... SBX 7 FX1
34JP ... SETUPCORE 4,3,FILE,FABSNB
354* ... STO 4 A1(3)
35H^ ... ADX 7 FX1
363K ... EXIT 7 0
36H9 ...[
3*^S ...OUTSKIP
3B3B ... OUTPAR SKIP
3B4Y ... EXIT 7 0
3B6G ...[
3B84 ...WELL3
3B9L ... STO 0 GEN0
3B?8 ... MHUNTW 3,JWELL,COPYSYS
3B#Q ... JLADJUST 3
3BB# ... BRN (GEN0)
3BCW [
3BXG ...[
3CC6 ...[
3CWQ ...START
3DBB ... LDN 4 SIZELIST
3DW2 ... CALL 7 SFABSNB [SET UP FABSNB TO OPEN USER JOB
7G29 ... LDN 4 XJOBLIST(1)
7G2= ... LDN 5 A1+1(3)
7G2? ... MOVE 4 SIZELIST-1 [ INITIALISE
7G2* ... MHUNTW 3,JWELL,COPYSYS
7G2B ... LDN 4 A1+FRH+JLUSER(3)
7G2G ... MOVE 4 3 [ USERNAME
7G2Q ... SETMODE 6,READ,NOERREP,UNTRAP
7G3G ... CALL 7 XOPEN [ OPEN JOBLIST(/****)
7G3Q ... BRN REDE
7G42 ... BRN XBR1 [ BREAKIN
7G4= ... GEOERR 1,JOBLIST?
7G4C ...REDE MFREE FILE,FABSNB
7G4J ... MHUNTW 3,JWELL,COPYSYS
7G4Q ... TRACE A1+FRH+JLJOBNO(3),DEWELL
7G52 ... LDN 6 A1+FRH+JLJOBNAME(3)
7G5= ... GETJOB 6,USER [ ENTRY FOR THIS JOB
7G5G ... TESTREP OK,X
7G5Q ... GEOERR 1,NO JOB
7G62 ...X CALL 7 XTRACT [ OBTAIN OTHER RECORDS
7G6= ... NAME 3,JWELL,JPARAMS
7G6G ... CALL 7 XTRACT
7G6Q ... NAME 3,JWELL,AJDF
7G72 ... CALL 7 XTRACT
7G7= ... NAME 3,JWELL,ACLB
7G7G ... CLOSETOP [ CLOSE JOBLIST
7G7Q ...[
7G82 ...[ HANDLE CREATION OF MONITORING FILE
7G8= ...[
7G8N ...WAYON
7G96 ...[ FIRST OPEN USER'S DIRECTORY
7G9J ... LDN 4 SIZEDIR
7G=2 ... CALL 7 SFABSNB
7G=G ... LDN 7 0
7G=Q ... MHUNTW 2,JWELL,COPYSYS
7G?2 ...[
7G?= ...[ SET AWORK2 FOR MOP/BACK JOB
7G?G ...[
7G?Q ... JLADJUST 2
7G#2 ... BS 2,JLBRUNNING
7G#= ... JBS SETMP,2,JLBMOP
7G#Q ... SMO FX2
7G*2 ... STO 7 AWORK2
7G*6 ...SETMP
7G*= ... SBN 2 A1+FRH
7G*G ... SBX 2 JOBDATASIZE
7G*Q ... LDN 4 JLUSER+A1+FRH(2)
7GB2 ... LDN 5 A1+1(3)
7GB= ... MOVE 4 3 [ USERNAME
7GC= ...[
7GC? ... SETMODE 6,GENERAL,QUERY
7GC# ... OPEND XBR1,6
7GC* ...[CHECK REPLY WORD FOR DIRECTORY OPEN
7GCB ... TESTREP2 OK,SFLOC
7GCC ... BRN WRONGSORT
7GCD ...[
7GCF ...[ CHECK WHETHER FILE OF THIS NAME
7GCG ...[ (IE JOBNAME) ALTREADY EXISTS
7GCH ...SFLOC
7GCJ ... SETNCORE 8,3,FILE,FLOCNB
7GCK ... MHUNTW 2,JWELL,COPYSYS
7GCL ... LDN 4 JLJOBNAME+A1+FRH(2)
7GCM ... LDN 5 A1(3)
7GCN ... MOVE 4 3
7GCP ...[
7GCQ ... STOZ A1+3(3)
7GCS ... STOZ A1+4(3) [TO FIND LATEST GENERATION
7GCW ... LDX 0 MFLANG(1) [LANG CODE B1B0
7GCX ... STO 0 A1+5(3)
7GCY ... STOZ A1+6(3)
7GC^ ... STOZ A1+7(3)
7GD2 ...[
7GD3 ...[ GET LATEST GEN OF THE FILE
7GD4 ... GETDIR 3
7GD5 ... MHUNTW 3,FILE,FLOCNB
7GD6 ... LDN 4 1
7GD7 ... TESTREP2 OK,OMF10 [FILE EXISTS
7GD8 ... TESTREP2 NOFILE,OMF,VRYWRONG,NAMEINUSE [FILE DOESN'T EXIST
7GD9 ... CALL 7 SEB [BREAK FOR OTHER REPLIES
7GD= ...[
7GD? ...[ NO MON FILE OF THIS NAME EXISTS
7GD# ...OMF
7GD* ... STO 4 A1+4(3) [SET FGN=1
7GDB ... BRN OMF20
7GDC ...[
7GDD ...[ A MON FILE OF THIS NAME EXISTS
7GDF ...OMF10
7GDG ... LDX 5 A1+4(3) [PICK UP FGN OF FILE
7GDH ... SLL 5 1 [CLEAR B0
7GDJ ... SRL 5 1
7GDK ... LDN 6 4095
7GDL ... TXL 5 6 [MAKE SURE FGN NOT TOO BIG
7GDM ... BCC NAMEINUSE [REPORT ERROR IF IT IS
7GDN ... ADX 5 4 [ADD 1 TO FGN
7GDP ... STO 5 A1+4(3)
7GDQ ...[
7GDR ...[ CREATE MONITORING FILE
7GDS ...OMF20
7GDT ... CREATEB 2
7GDW ... LDX 4 WTEMP(1)
7GDX ... STO 4 CEINF2(2) [TEMP FILE
7GDY ...[
7GD^ ... SETMODE 6,CREATE,APPEND,SYSTCOMM,REPLY
7GF2 ... OPENCREX XBR1,6
7GF3 ... TESTREP2 OK,OMF50
7GF4 ... CALL 7 SEB [BBEAK FOR REPLY NOT OK
7GF5 ...[
7GF6 ...[ MONITORING FILE HAS BEEN OPENED
7GF7 ...OMF50
7GF8 ... MFREE FILE,FLOCNB
7GF? ... MFREE FILE,FABSNB
7GFG ...[
7GFP ...[
7GG2 ...OJDFS
7GGQ ... SEGENTRY K90DEWELL
7GH2 ... BRN XK91DEWELL
7GH6 ...#SKI G3UGSI<1$1
7GH= ... INHIBITB XBR3
7GHB ...XK91DEWELL
7GHG ... SEGENTRY K91DEWELL
7GHK ...#SKI G3UGSI [USER GROUP SECURITY INTERFACE
7GHN ... INHIBITB XBR3
7GHS ... CALL 0 WELL3
7GJG ... STOZ EXT+3(2) [ FOR COMMAND PROCESSOR
7GJQ ... JBS NOJDF,3,JLBMOP [ J IF NO JDF
7GK2 ...[
7GK= ...[ OPEN JDF
7GKG ...[
7GKH ...OJDF
7GKJ ... LDN 4 SIZEABS
7GKK ... CALL 7 SFABSNB
7GKL ... MHUNTW 2,JWELL,AJDF
7GKM ... LDX 0 JDFGEN(2) [ GENERATION NO.
7GKN ... STO 0 A1+8(3)
7GKP ... LDX 0 JDFLANG(2) [ LANGUAGE CODE
7GKQ ... STO 0 A1+9(3)
7GKR ... LDN 4 JDFDIR(2) [ DIRECTORY
7GKS ... LDN 5 A1+1(3)
7GKT ... MOVE 4 3
7GKW ... LDN 4 JDFNAME(2) [ FILENAME
7GKX ... LDN 5 A1+4(3)
7GKY ... MOVE 4 3
7GK^ ... LDN 0 1
7GL2 ... STO 0 A1+7(3)
7GL3 ... SETMODE 6,READ,ERASING,REOPEN,LEAVE,REPLY
7GLQ ...XCORD OPEND XBR3,6
7GM2 ... TESTREP2 OK,SFINE,LOST,XLOST,CANT,XCOOR3,TEMPLOST,TLOST
7GM4 ...#UNS B7535
7GM6 ... TESTREP2 CLOSEAB,REMOVED
7GM= ... GEOERR 1,JDFOPEN?
7GMG ...XCOOR3
7GML ... MFREE FILE,ENT
7GMQ ... COOR3 6
7GN2 ... BRN XCORD
7GN= ...SFINE
7GNG ...[
7GNQ ...[
7GP2 ...[ SET BITS FOR COMMAND PROCESSOR
7GP= ...[
7GPG ... LDN 6 0
7GPQ ... MHUNT 3,FILE,ENT [ FROM JDF OPEN
7GQ2 ... LDX 0 ETM(3) [ TYPE/MODE
7GQ= ... ANDN 0 #77 [ MODE
7GQG ... ERN 0 #12
7GQQ ... BNZ 0 MEXT [ J IF SHIFT FILE
7GR2 ... ORX 6 GSIGN [ B0 FOR GRAPHIC
7GR= ...MEXT MFREE FILE,ENT [ NOT WANTED ANY MORE
7GR# ... CALL 0 WELL3
7GS2 ... JBC MRJ,3,JLBJB
7GS= ... LDCT 0 #200 [ BIT 1 FOR JB
7GSG ... ORX 6 0
7GSQ ...MRJ JBC MSTO,3,JLBRJ [ J IF NOT RJ
7GT2 ... LDCT 0 #100 [ BIT 2 FOR RJ
7GT= ... ORX 6 0
7GTG ...MSTO STO 6 EXT+3(2) [ STORE IN NEW CPAT
7GTQ ...[
7GTW ... STOZ AWORK3(2) [INITIALISE AWORK3
7GW2 ... LDN 0 0
7GW= ... TXU 0 JLASSOCS(3)
7GWG ... LDN 4 0 [ COUNT OF ASSOCIATIONS
7GWQ ... TXU 0 JLASSOCS+1(3)
7GX2 ... ADN 4 0
7GX= ... TXU 0 JLASSOCS+2(3)
7GXG ... ADN 4 0
7GXQ ... BZE 4 NOPROPS [ J IF NONE
7GY2 ... MPY 4 SOCSLEN(1)
7GY= ... ADN 5 1
7GYG ... OPENSYS ,PROPERTY,READ [ OPEN :SYSTEM.PROPERTY
7GYQ ... SETUPCOR 5,3,APERI,ASSOCS [ CREATE BLOCK
7G^2 ... STOZ A1(3)
7G^4 ... CALL 0 WELL3
7G^Q ... LDN 3 JLASSOCS(3)
7H22 ... LDN 4 AWORK2(2)
7H2= ... MOVE 3 3 [ SAVE PROP. NOS IN AWORK2-4
7H2G ... LDN 7 3
7H2Q ... LDN 6 0
7H32 ...[
7H3= ...XR SMO 6
7H3G ...[
7H3Q ...[ PROPERTY
7H42 ...[
7H4= ... LDX 5 AWORK2(2)
7H4G ... BZE 5 XNUN
7H4Q ... APROPNAM 5,0,PROPNOT
7H52 ... MHUNTW 3,APERI,ASSOCS
7H5= ...[
7H5G ...[ RETAIN START OF BLOCK ADDRESS
7H5Q ...[
7H62 ... LDN 1 A1+1(3)
7H6= ...[
7H6G ...[ FIRST ENTRY ADDRESS
7H6Q ...[
7H72 ... LDX 4 A1(3)
7H7= ...[
7H7G ...[ NO OF ENTRIES
7H7Q ...[
7H82 ... BZE 4 RNEW
7H8= ...RNDL TXU 5 1(1)
7H8G ... BCC RSAME
7H8Q ... ADN 1 ASSOCSLEN
7H92 ... BCT 4 RNDL
7H9= ...[
7H9G ...RNEW STO 5 1(1)
7H9Q ... LDN 4 ACOMMUNE1(2)
7H=2 ... LDN 5 2(1)
7H== ...[
7H=G ...[ COPY PROPERTY NAME
7H=Q ...[
7H?2 ... MOVE 4 3
7H?= ... LDN 0 1
7H?G ... ADS 0 A1(3)
7H?Q ... LDX 0 GSIGN
7H#2 ... STO 0 0(1)
7H#= ...[
7H#G ...[ HAVE SET LF BIT AD INCREASED NO OF ASSOCS IN BLOCK
7H#Q ...[
7H*2 ...RSAME LDX 5 FX1
7H*= ... ADX 5 6
7H*G ...[
7H*Q ...[ GET PERIPHERAL TYPE BIT FOR ASSOCS ENTRY
7HB2 ...[
7HB= ... SMO 5
7HBG ... LDX 0 XTAB
7HBQ ... ORS 0 0(1)
7HC2 ...XNUN ADN 6 1
7HC= ... LDX 2 FX2
7HCG ... BCT 7 XR
7HCQ ...[
7HCW ... STOZ AWORK3(2) [INDICATES PROPERTY FOUND OK
7HD2 ... CLOSETOP
7HD= ... MHUNTW 3,APERI,ASSOCS
7HDG ... LDX 4 A1(3)
7HDQ ... MPY 4 SOCSLEN(1)
7HF2 ... ADN 5 1
7HF= ... SLL 5 2
7HFG ... ADX 5 A1(3)
7HFQ ... BRN STENL
7HG2 ...[
7HG= ...RHUNT MHUNTW 2,APERI,ASSOCS
7HGG ... EXIT 1 0
7HGQ ...[
7HH2 ...[
7HH= ...STENL ALTLENG 3,5,RHUNT
7HH? ... BRN NOPROPS
7HH# ...[
7HH* ...PROPNOT
7HHB ...[ NOT FOUND IN :SYSTEM.PROPERTY, SO ASSUME
7HHC ...[ THAT ONLY "CENTRAL" EXISTS
7HHD ... CLOSETOP
7HHF ... MFREEW APERI,ASSOCS [CLOSE :SYSTEM.PROPERTY & FREE BLOCK
7HHG ... STOZ JSOURCE3(2) [ZEROISE JSOURCE3 IN CPAT
7HHH ... JLASLOST [ZEROISE JLASSOCS WORDS IN JOBLIST
7HHJ ... LDN 4 1
7HHK ... STO 4 AWORK3(2) [INDICATES PROPERTY NOT FOUND
7HHL ...[
7HHM ...[
7HHQ ...NOPROPS
7HJ2 ...NOJDF
7HJ= ...[
7HJG ...[ FREE FABSNB USED FOR OPENING FILES
7HJQ ...[ AND THEN SET ABOUT CREATING THE JOBBLOCK
7HK2 ...[
7HK7 ... VFREE FILE,FABSNB
7HK# ... CALL 0 WELL3
7HL2 ... JBS NCPR,3,JLBMOP
7HL= ... MHUNTW 1,JWELL,AJDF
7HLG ... LDN 4 JOBCURDIR(1)
7HLQ ... LDN 5 CPREFIX(2)
7HM2 ... MOVE 4 3 [ CURRENT DIRECTORY
7HM= ... LDX 1 FX1
7HMG ...NCPR
7HPG [
7J96 LDX 4 IMOPTRACE [ DEFAULT TRACE
7JNQ JBS SMIN,3,JLBMOP [ J IF MOP
7K8B LDX 4 JOBTRACE
7KN2 SMIN ORX 4 IMINTRACE
7L7L STO 4 AMFMSK(2) [ INITIAL MONFILE CATEGORIES
7LCD JBC SNOTM,3,JLBMOP
7LM= MHUNTW 3,CPB,CALAS
7M6W STO 4 CMFMSK(3) [ MASK FOR THI
7MLG [
7N66 SNOTM LDX 0 AWORK2(2)
7NKQ BNG 0 SMON
7P5B LOBSFILE XMONE(1)
7PK2 SMON LOBSFILE
7Q4L TESTREP2 LOBSALR,WMONF
7QJ= INCRECUB FORCED
7R3W [
7RHG [ CREATE OUPUT IN MONITORING FILE
7S36 [
7SGQ WMONF
7SGY ...#UNS G400
7SH6 ...(
7SH# ... SEGENTRY K60DEWELL [RESTORE TIME DODEWELLHOOK
7SHG ... BRN XDSK1 [BRN IF DEWELL HOOK NOT IN USE
7SHN ... LDX 7 XTYPE(1)
7SHW ... BZE 7 XDSK1 [NOTHING HOOKED
7SJ4 ... ERN 7 3
7SJ= ... BZE 7 XDSK5 [HOOK ON ALL JOBS
7SJD ... CALL 0 WELL3
7SJL ... JBS XDSK4,3,JLBMOP [J IF MOP
7SJS ... SRC 7 1
7SK2 ... BNG 7 XDSK1 [J IF BACK NOT HOOKED
7SK8 ... BRN XDSK5
7SKB ...XDSK4 SRC 7 2
7SKJ ... BNG 7 XDSK1 [J IF MOP NOT HOOKED
7SKQ ...XDSK5 LDX 4 EXT+3(2) [SAVE RUNJOB MARKER
7SKY ... DOWN DOMONOP,3
7SL6 ... BRN XDSK2 [BREAK-IN RETURN
7SL# ... BRN XDSK1A [DEWELL HOOK OK
7SLG ...# EXIT ABANDON
7SLN ... CALL 7 MONER [ERASE MONITORING FILE
7SLW ... CALL 7 XDSK3 [CLEAR MON MASK
7SM4 ... LDN 5 1
7SM= ... ACROSS ENWELLB,60 [GET ABANDON FINISHED BY ENDCOM
7SMD ...XDSK2 CALL 7 XDSK3
7SML ... BRN XBR3
7SMS ...XDSK1A
7SN2 ... STO 4 EXT+3(2)
7SN8 ...XDSK1
7SNB ...)
7SNJ ... CALL 0 WELL3
7SNK ... FSHCODE A,XENDA1
7SNL ...(
7SNM ...#
7SNN ...# FOR JOB'S THAT ARE TO RUN ON 'B', WE MUST GO TO 'B' AT THIS
7SNP ...# POINT IN THE PROCEEDINGS
7SNQ ...#
7SNR ... JBC XENDA1,3,JLBRUNB [JIF JOB WILL RUN IN 'A'
7SNS ... ACROSS JWELLTWO,3 [ELSE GO TO 'B' NOW!!
7SNT ...#
7SNW ...XENDA1
7SNX ...)
7SP# ... JMBAC WM1,3,JLBGENRES,JLBBREAK,JLBABANDON,JLBPARTRES
7SSD ... DOWN PNTLAST,8
7SWB ...WM1
7T2B MHUNTW 3,JWELL,JPARAMS
7TG2 LDEX 4 A1(3)
7T^L ... ADN 4 10
7WF= [
7WYW [ NOW CALCULATING GMON/ASET BLOCK SIZE
7XDG [
7XJC ... CALL 0 WELL3
7YXB LDX 0 JLRESTPTR(3)
7^C2 BZE 0 XOTB
7^LS ... SBX 0 JOBDATASIZE
7^WL SMO 0
823# ... LDX 0 0(3)
824W ... LDX 7 0
826D ... ANDX 0 HALFTOP
8282 ... BNZ 0 XOTB
829J ... ADX 4 7
82TW XOTB OUTBLOCK 4
83*G OUTPAR USERNAME,JOBNAME,DATENOW,TIMENOW
83FC ... CALL 0 WELL3
84SB LDN 4 1
85#2 LDN 5 JPDJOBTYPE
85RL LDN 6 ZERO(1)
86?= JBS ONL,3,JLBMOP [ J IF LN/DC
86QW ADN 6 1
87=G ONL JBC XCENTRAL,3,JLBCLUS [ J IF CENTRAL
87Q6 ADN 6 2
889Q CALL 7 XOUTPACK
88PB LDN 6 JSOURCE3(2)
8992 LDN 5 JPDPROPS
89DS ... LDN 4 1
89NL CALL 7 XOUTPACK
8=8= BRN PARAMOUT
8=D4 ...[
8=MW XCENTRAL
8?7G CALL 7 XOUTPACK
8?#N ... CALL 7 OUTSKIP
8#6Q PARAMOUT
8#LB MHUNTW 3,JWELL,JPARAMS
8*62 LDX 0 A1+1(3)
8*KL SLL 0 1
8*Y3 ... BNG 0 POUT
8B=D ... CALL 7 OUTSKIP
8BN# ... BRN POUT1
8C68 ...
8CJ6 POUT LDEX 4 A1(3)
8D3Q SBN 4 2
8DHB ... BZE 4 UNACS
8F32 LDN 6 A1+2(3) [ ADDRESS OF PARAMS
8FGL CALL 7 VOUTPACK [ OUTPUT PARAM OR PARAMS
8FMS ... BRN POUT1
8FT2 ...
8G28 ...UNACS
8G7B ...
8G#J ... CALL 7 OUTSKIP
8GFQ ...
8GLY ...POUT1
8GS6 ... CALL 0 WELL3
8G^G LDX 6 JLRESTPTR(3)
8HF6 BZE 6 MOUT [ SEE IF A REMAINDER FEILD
8HRG ... SBX 3 JOBDATASIZE
8HYQ SMO 6
8JDB LDX 4 0(3) [ COUNT
8JHM ... LDX 0 4
8JJQ ... ANDX 0 HALFTOP
8JKT ... BNZ 0 MOUT
8JN8 ... SBN 4 1
8JY2 ADX 6 3
8KCL ADN 6 1
8KX= CALL 7 VOUTPACK
8K^5 ... BRN MOUT2
8L2Y ...MOUT CALL 7 OUTSKIP
8L4R ...MOUT2 LDX 0 CONTEXT(2)
8L6L ... ANDN 0 #10
8L8F ... BZE 0 MOUT3 [J IF NOT MOP
8L=# ... CALL 7 MOPID
8L#7 ... CALL 7 VOUTPACK
8L#D ... BRN MOUT4
8L#J ...[
8L#P ...MOUT3 OUTNULL
8L*2 ...MOUT4 FJOCA 3,2
8L*? ... TESTNAMX 3,JUSER(3),CPREFIX(2),NOTID [J IF NO MATCH
8L*J ... CALL 7 OUTSKIP [OUTPUT NO PAR
8L*T ... BRN MOUT5
8L*^ ...[
8LB6 ...NOTID LDN 5 JPDUSERNAME
8LBC ... LDN 4 3
8LBN ... LDN 6 CPREFIX(2)
8LB^ ... CALL 7 XOUTPACK [OUTPUT CURR DIR
8LC= ...MOUT5 MONOUT ASTART
8LC? ...[
8LC# ...[ SEE WHETHER AN ASSOCIATED PROPERTY HAS BEEN LOST
8LC* ... CALL 0 WELL3
8LCB ... JBS TELLHLS,3,JLBMOP [J IF MOP
8LCC ... LDX 4 AWORK3(2)
8LCD ... BZE 4 TELLHLS [J IF AWORK3 IS CLEAR
8LCF ...[
8LCG ...[ AWORK3 SET MEANS USER MUST BE TOLD ABOUT LOST PROPERTY
8LCH ... MONOUT CENTONLY
8LCJ ... STOZ AWORK3(2)
8LCK ...[
8LCL ...TELLHLS
8LDS ... HLSINFORM XHLS,DEWELL,JOBNO(2)
8LFR ...XHLS
8LFX ... FSHCODE AORB
8LG3 ...(
8LG7 ...# FOR SHARED FILESTORE, WE SEND A MESSAGE TO THE MONITORING
8LG? ...# FILE TO SAY WHICH MACHINE THE JOB IS RUNNING IN!!
8LGC ...#
8LGH ... DOWN JWELLTWO,7 [CODE TO OUTPUT MESSAGE IS ELSEWHERE
8LGM ...)
8LGR ... CALL 0 WELL3
8MTQ JBS PCLB,3,JLBMOP [ NO ADATA/CREADL IF MOP
8N*B LDN 4 CPDATA-A1+3 [ BASIC SIZE - JDF ONLY
8NT2 MHUNTW 3,JWELL,JPARAMS
8P#L LDEX 5 A1(3)
8PS= SBN 5 2
8Q?W LDX 6 A1+1(3) [ ACTUAL CHAR SIZE
8QRG ANDN 6 #7777
8R?6 BZE 5 NP [ J IF NO PARAMS
8RQQ ADX 4 5 [ NEW SIZE
8S=B ADN 4 1
8SQ2 NP SETUPCOR 4,3,ADATA,CREADL [ CREATE BLOCK
8T9L SBX 4 5
8TP= SBN 4 CPDATA-A1
8W8W SLL 4 2
8WNG ADX 4 6 [ NEW CHAR SIZE
8X86 STO 4 A1(3) [ CHAR SIZE
8XMQ BZE 5 NOPS
8Y7B LDX 0 ACES
8YM2 STO 0 CPDATA+3(3) [ SPACES BETWEEN JDF AND PARAMS
8^6L MHUNTW 2,JWELL,JPARAMS
8^L= LDN 6 A1+2(2) [ INPUT PARAMS
925W LDN 7 CPDATA+4(3)
92KG SMO 5
9356 MOVE 6 0
93JQ NOPS MHUNTW 2,JWELL,AJDF [ JDF NAME
944B LDN 7 CPDATA(3)
94J2 LDN 6 JDFNAME(2)
953L MOVE 6 3 [ MOVE IN JDF NAME
95H= [
962W PCLB MHUNTW 3,JWELL,ACLB
96GG LDEX 5 A1(3) [ RECORD SIZE
9726 SBN 5 2 [ MINUS RED TAPE
97FQ SLL 5 2 [ INTO CHARS
97^B OUTEXES 5,A1+2,JWELL,ACLB [ OUTPUT A COPY OF COMMAND
98F2 OUTPAR TIMENOW
98YL LDN 4 0
994H ... CALL 0 WELL3
9=CG JBC MNOUT,3,JLBMOP [ SKIP IF NOT MOP
9=X6 LDN 4 #1000
9?BQ ANDX 4 AMXMSK(2)
9?WB ERS 4 AMXMSK(2) [ ENSURE CM BIT CLEAR
9#B2 MNOUT MONOUT ACOMJT [ O/P COPY OF COMMAND
9#FX ... CALL 0 WELL3
9*SW JBC NMP,3,JLBMOP
9B#G ORS 4 AMXMSK(2)
9BS6 NMP LDN 4 0
9C?Q JBC ZFREE,3,JLBMOP
9CRB LDN 4 1 [ X4=1 IF MOP
9D?2 ZFREE MFREE JWELL,COPYSYS [ JWELL BLOCKS NOW FINISHED WITH
9DQL MFREE JWELL,ACLB
9DYW ... MHUNT 1,JWELL,AJDF
9F76 ... LDX 0 JDFWFNAME(1)
9F*B ... STO 0 AWFNAME(2)
9FHL ... FREECORE 1
9FPW MFREE JWELL,JPARAMS
9G9G TRACE JOBNO(2),DEWELLED
9GBM ... SEGENTRY K92DEWELL
9GDB ... BRN XK93DEWELL
9GG5 ... DOWN PNTLAST,5
9GGY ...XK93DEWELL
9GHS ... SEGENTRY K93DEWELL
9GJM ...#SKI G3UGSI<1$1
9GKH ... PERMITBRK
9GMS ... LDX 0 CONTEXT(2)
9GN2 ... ANDN 0 #4000
9GN5 ... BNZ 0 TFS [J IF FULLY STARTED
9GN8 ... CALL 7 SJOB [X3->JOBBLOCK
9GN? ... LDEX 0 JURGE(3)
9GNB ... BZE 0 NOTFS1 [J IF NO URGENCY
9GNF ...TFS DOWN HLSEVENT,2
9GNG ...[
9GNJ ...NOTFS1
9GNK ...[ NEXT SECTION IS COMPILED IF G3 USER GROUP SECURITY
9GNL ...[ INTERFACE ENHANCEMENT IS SWITCHED ON
9GNM ...#SKI G3UGSI
9GNN ...(
9GNP ...[ SINMAC4 NEEDS B-IN INHIBITED
9GNQ ... SINMAC4
9GNR ... PERMITBRK
9GNS ... BZE 4 SUE [J IF NOT MOP
9GNT ...XENDC
9GNW ... ENDCOM
9GNX ...SUE
9GNY ... ISSUCOMJ
9GN^ ...)
9GP2 ...#SKI G3UGSI<1$1
9GP3 ...(
9GP6 BZE 4 SUE [ GO AND ISSUCOMJ IF NOT MOP
9GSF ... SINMAC4 MOP
9GXS ...XENDC ENDCOM [ MOP
9H37 ...[
9HQJ ...SUE SINMAC4 BACK
9H^= ... ISSUCOMJ [ BACKGROUND
9J4L ...)
9J82 [
9K?7 ...SEB
9KC4 ... GEOERR 1,MONFILE
9KG^ ...[
9KLW XBR3
9L6G [
9LL6 [ BREAKIN ON JDF OPEN
9M5Q [ SO ERASE MONFILE AND TAKE NORMAL BREAKIN PATH...
9MKB [
9N52 CALL 7 MONER
9NJL [
9P4= ...[
9PHW ...XBR1
9Q3G ... ACROSS ENWELLB,5
9QH6 ...[
9R2Q ...[
9R8# ...#UNS B7535
9R*W ...(
9RHD ...REMOVED
9RP2 ...[ JDF REMOVED, PROBABLY DUE TO QUITTED EDIT
9RWJ ... OUTMESS JWJDFGONE
9S46 ... CLOSE [CLOSE JDF
9S9N ... CALL 7 MONER
9SC= ...[ SET INDICATOR FOR ERROR ACTION IN ENWELLB
9SJS ... LDN 4 1
9SQB ... STO 4 ACOMMUNE1(2)
9SXY ... ACROSS ENWELLB,4
9T5G ...)
9T?4 ...[
9TDW WRONGSORT
9WD6 [
9WXQ OUTMESS JWMONF [ CANT OPEN MONITORING FILE
9XCB BRN XCOMMON
9XCY ...[
9XDG ...NAMEINUSE
9XF4 ...[ THERE IS A FILE IN USER S DIRECTORY WITH SAME NAME AS JOB,
9XFL ...[ BUT WRONG SORT FOR A MONITORING FILE
9XG8 ... OUTMESS JWNAMEUSED
9XGQ ... CLOSE [CLOSE DIRECTORY
9XH# ... BRN XCOMMON
9XHW ...[
9XJJ ...TLOST OUTMESS JWJDFTEMP
9XPQ ... BRN XLOST4
9XX2 XLOST OUTMESS JWJDF [ JDF LOST
9Y6S ...XLOST4
9YBL CALL 7 MONER [ ERASE MONITORING FILE
9YW= XCOMMON
9^3D ...[ SET INDICATOR FOR ENWELLB
9^8L ... STOZ ACOMMUNE1(2)
9^*W ... ACROSS ENWELLB,4
9^TG ...[
==LQ [
=?6B MONER SBX 7 FX1
=?L2 GETFNAME
=#5L CLOSETOP
=#K= ERASE [ ERASE MONFILE
=*4W ADX 7 FX1
=*JG EXIT 7 0
=B46 [
=B5H ...#UNS G400
=B6Y ...(
=B8* ...XDSK3 STOZ AMFMSK(2) [ZEROISE MONITORING MASK
=B9Q ... HUNT 2,CPB,CALAS [TO STOP OUTPUT TO NON-EXISTANT
=B?7 ... BNG 2 XDSKBJ [MONITORING FILE
=B#J ... STOZ CMFMSK(2) [HERE TO
=B*^ ...XDSKBJ
=BCB ... LDX 2 FX2
=BDR ... EXIT 7 0
=BG8 ...)
=BHQ #END
^^^^ ...05423554000500000000