{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: DICTJOB82)}}
====== DICTJOB82 ======
(George Source)
**Macros used:** [[george:macro:BUDGSTART|BUDGSTART]], [[george:macro:BXE|BXE]], [[george:macro:BXU|BXU]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:KEEPREP|KEEPREP]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREE|MFREE]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:NAME|NAME]], [[george:macro:OPEN|OPEN]], [[george:macro:OPENSYS|OPENSYS]], [[george:macro:OUTPACK|OUTPACK]], [[george:macro:PHOTO|PHOTO]], [[george:macro:PICKREP|PICKREP]], [[george:macro:PUTREP2|PUTREP2]], [[george:macro:READDICT|READDICT]], [[george:macro:REWIND|REWIND]], [[george:macro:REWRITE|REWRITE]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETREP2|SETREP2]], [[george:macro:STEP|STEP]], [[george:macro:TESTMOVE|TESTMOVE]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:UP|UP]]
22FL [
22^= [THIS VERSION INCLUDES:
23DW [1. OPENSYS
23YG [2. DICTJOB 3 TO STORE CJOBCT IN ACOM1 IF NON-ZERO
24D6 [
24XQ SEG DICTJOB,,BACK SECTION,ALLGEO
25CB SEGENTRY K1DICTJOB,QK1DICTJOB
25X2 SEGENTRY K2DICTJOB,QK2DICTJOB
26BL SEGENTRY K3DICTJOB,QK3DICTJOB
26W= SEGENTRY K4DICTJOB,QK4DICTJOB
27*W SEGENTRY K5DICTJOB,QK5DICTJOB
27TG ZUP 8H*UPDATE
28*6 QK1DICTJOB
28SQ LDN 7 1 [REMEMBER ENTRY POINT
29#B BRN OPEN
29S2 QK2DICTJOB
2=?L LDN 7 2
2=R= BRN OPEN
2?=W QK3DICTJOB
2?QG LDN 7 3
2#=6 BRN OPEN
2#PQ QK4DICTJOB
2*9B LDN 7 4
2*P2 BRN OPEN
2B8L QK5DICTJOB
2BN= LDN 7 5
2C7W LDX 0 ACOMMUNE1(2) [NO. TO SUBTRACT FROM COUNT OF JOBS
2CMG STO 0 AWORK1(2)
2D76 BRN READD
2DLQ OPEN
2F6B OPENSYS XBR,DICTIONARY,GENERAL
2FL2 READD
2G5L READDICT
2GK= TESTREP2 OK,USER
2H4W SBN 7 3
2HJG BNZ 7 NOUSE
2J46 GEOERR 1,DICTNOUS [ERROR IF ENTRY WAS AT K3
2JHQ NOUSE
2K3B SBN 7 2
2KH2 BZE 7 UP
2L2L KEEPREP 7,NOUSER
2LG= UPCL
2L^W CLOSETOP
2MFG PUTREP2 7
2M^6 UP
2NDQ UP
2NYB USER
2PD2 MHUNTW 3,FILE,ADICTENT
2PXL SBN 7 2
2QC= BZE 7 PART2 [X7=2,DICTJOB 2 MACRO
2QWW SBN 7 1
2RBG BZE 7 PART3 [X7=3,DICTJOB 3 MACRO
2RW6 SBN 7 2
2S*Q BZE 7 PART5 [X7=5,DICTJOB 5 MACRO
2STB ADN 7 2
2T*2 [
2TSL [ X7 +VE -DICTJOB 4,-VE,DICTJOB 1
2W#= [
2WRW # ENTRY FOR JOB TO UPDATE CJOBCT
2X?G PART1
2XR6 LDCT 0 #500 [TO-BE-ERASED,PSEUDO USER BITS
2Y=Q ANDX 0 CERASE(3)
2YQB BNZ 0 NOKJOB
2^=2 OKJOB [USER NOT PSEUDO AND NOT TO-BE-ERASED
2^PL BPZ 7 OKK [IF DICTJOB 4,DONT DO BUDGSTART
329= PHOTO 6
32NW BUDGSTART [MACRO TO CHECK BUDGET NOT OVERDRAWN
338G TESTREP2 OK,OKJ
33N6 PICKREP 7 [SAVE REPLY FROM BUDGSTART
347Q BRN UPCL
34MB OKJ
3572 TESTMOVE 6,OKK
35LL MHUNTW 3,FILE,ADICTENT
366= OKK
36KW LDN 0 1
375G ADS 0 CJOBCT(3)
37K6 NAME 3,FILE,FWB
384Q REWRITE [REWRITE UPDATED DICTIONARY ENTRY
38JB MHUNTW 3,FILE,FWB
3942 NAME 3,FILE,ADICTENT [LEAVE ADICTENT BLOCK FOR 'JOB'
39HL BRN NOINF
3=3= NOKJOB
3=GW FREECORE 3 [ADICTENT BL NOT WANTED IN THIS CASE
3?2G KEEPREP 7,UNJOB
3?G6 BRN UPCL
3?^Q # ENTRY FOR ENDJOB TO UPDATE CJOBCT
3#FB PART2
3#^2 LDX 0 CJOBCT(3)
3*DL SBN 0 1
3*Y= BPZ 0 OKCT [JOB COUNT SHOULD NEVER GO NEG
3BCW OUTPACK CUSER(3),3,USERNAME
3BXG MONOUT JERUNAC
3CC6 MFREE FILE,ADICTENT
3CWQ CLOSETOP
3DBB BRN NOINF
3DW2 OKCT
3F*L STO 0 CJOBCT(3)
3FT= NAME 3,FILE,FWB
3G#W REWRITE
3GSG MFREEW FILE,FWB
3H#6 CLOSETOP
3HRQ BRN NOINF
3J?B [ ENTRY FOR DICTJOB 3 (USED BY ERASE)
3JR2 PART3
3K=L LDX 7 CJOBCT(3)
3KQ= BNZ 7 NINFJOB [J IF JOBS GOING IN THIS USER
3L9W LDX 0 CERASE(3)
3LPG BNG 0 NOINF [J IF THIS IS A PSEUDO USER
3M96 LDX 5 CUSER(3) [KEEP THIS USER'S NAME
3MNQ LDX 6 CUSER+1(3)
3N8B LDX 7 CUSER+2(3)
3NN2 FREECORE 3 [ADICTENT BL NOT WANTED BY 'ERASE'
3P7L REWIND [SEARCH DICT FOR INFERIOR NON-PSEUDO
3PM= NEXT
3Q6W STEP [READ NEXT DICT ENTRY
3QLG BZE 3 NOINF [J IF END OF DICT
3R66 LDX 0 ZUP(1)
3RKQ BXE 0 CUSER-A1(3),NEXT [IGNORE DUMMY UPDATE RECORDS
3S5B BXU 5 CSUPUSER-A1(3),NEXT [J IF NAMES NOT SAME
3SK2 BXU 6 CSUPUSER-A1+1(3),NEXT
3T4L BXU 7 CSUPUSER-A1+2(3),NEXT
3TJ= LDCT 0 #500 [SEE IF INFERIOR USER IS MARKED TO BE
3W3W ANDX 0 CPSEU-A1(3) [ERASED OR IS A PSEUDO USER
3WHG BNZ 0 NEXT [J IF SET
3X36 TOOHIGH
3XGQ KEEPREP 7,TOOHIGH
3Y2B BRN UPCL
3YG2 NOINF
3Y^L SETREP2 OK
3^F= UP
3^YW NINFJOB
42DG FREECORE 3
42Y6 CLOSETOP
43CQ STO 7 ACOMMUNE1(2) [NO. OF JOBS FOR ERROR MESSAGE
43XB SETREP2 INFJOB
44C2 UP
44WL PART5
45B= LDX 0 CPSEU(3)
45TW BNG 0 P5PSEUDO [J IF PSEUDO USER
46*G LDX 0 CJOBCT(3)
46T6 SBX 0 AWORK1(2)
47#Q BNG 0 P5A [BRANCH IF COUNT NEGATIVE
47SB STO 0 CJOBCT(3)
48#2 NAME 3,FILE,FWB
48RL REWRITE
49?= MFREE FILE,FWB
49QW BRN NOINF
4==G P5A
4=Q6 STOZ CJOBCT(3)
4?9Q NAME 3,FILE,FWB
4?PB REWRITE
4#92 MHUNTW 3,FILE,FWB
4#NL OUTPACK CUSER(3),3,USERNAME
4*8= MONOUT JERUNAC
4*MW MFREE FILE,FWB
4B7G SETREP2 NOTENUF
4BM6 UP
4C6Q P5PSEUDO
4CLB FREECORE 3
4D62 SETREP2 UNJOB
4DKL UP
4F5= XBR [BREAK-IN LABEL [GEOERR NEEDS REPLA
4FJW GEOERR 1,DICT XBR [CAN'T BREAK IN OPENING DICTIONARY
4G4G MENDAREA 20,K99DICTJOB
4GJ6 #END
^^^^ ...51657343000100000000