{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: DTQUEST860)}}
====== DTQUEST860 ======
(George Source)
**Macros used:** [[george:macro:ALTLEN|ALTLEN]], [[george:macro:BC|BC]], [[george:macro:BS|BS]], [[george:macro:BXE|BXE]], [[george:macro:BXGE|BXGE]], [[george:macro:BXL|BXL]], [[george:macro:BXU|BXU]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:DOWN|DOWN]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:ISSUCOM|ISSUCOM]], [[george:macro:JMBAC|JMBAC]], [[george:macro:JMBS|JMBS]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:OPENINC|OPENINC]], [[george:macro:OUTPARAM|OUTPARAM]], [[george:macro:READAGAIN|READAGAIN]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:STARTACT|STARTACT]], [[george:macro:STEP|STEP]], [[george:macro:STEPREWRITE|STEPREWRITE]]
22FL ... SEG DTQUEST,860,C.R.JOHNSON,SCHEDULER
22^= [
23DW [ THIS SEGMENT IS ENTERED BY THE INCDUMP COMMAND WITH PARAM QUEST
23YG [ TO CHECK AVAILABILITY OF WRONGED INCREMENTS
24D6 [
25CB SEGENTRY K1DTQUEST,X1DTQUEST
25M8 ...[
25X2 QA 44HQN 1,CAN YOU TAPERIGHT ANY OF THESE TAPES?
26BL WAITCOM 8HWAIT 2
26W= [
27*W ...[ ******************************************************************
27TG ...[
28*6 ...[ THIS SUBROUTINE DOES A NON-COORDINATING SEARCH OF THE
28SQ ...[ OLC, CLEARING BIT 'BINCUNVERR' IN ALL RELEVENT HOST
29#B ...[ REQUEST BLOCKS.
29S2 ...[ X4 - LINK
2=?L ...[ X5 - INCREMENT NUMBER
2=R= ...[ X6,X7 - MUST NOT BE CORRUPTED
2?=W ...[
2?QG ...XSTATER [
2#=6 ... LDX 2 BOLC [X2 => BASE OF OLC
2#PQ ... LDN 3 0 [X3 => HOST FILESTORE
2*9B ...X1STATER [
2*P2 ... LDX 2 FPTR(2) [X2 -> NEXT BLOCK
2B8L ... BXE 2 CXOL,X2STATER [J IF END OF CHAIN
2BN= ... BXL 5 FDTINCNUM(2),X2STATER [J IF INCREMENT NOT THERE
2C7W ... BXU 5 FDTINCNUM(2),X1STATER [J IF INCREMENT NOT REACHED
2CMG ... BXL 3 FDTFILSTR(2),X2STATER [J IF HOST FILESTORE NOT THERE
2D76 ... BXU 3 FDTFILSTR(2),X1STATER [J IF FILESTORE NOT YET REACHED
2DLQ ... BC 2,BINCUNVERR [CLEAR 'UNVERIFIED INCREMENT' BIT
2F6B ... BRN X1STATER [NEXT BLOCK
2FL2 ...X2STATER [ALL DONE
2G5L ... EXIT 4 0 [
2NDQ [
2NKY ...[ ******************************************************************
2NR6 ...[
2NYB X1DTQUEST
2PD2 SETNCORE 20,3,FLIB,FLINC
2PXL LDN 1 1
2QC= STO 1 A1(3)
2QWW STOZ A1+1(3)
2RBG OPENII
2RW6 OPENINC ,GENERAL [INCINDEX
2S*Q LDN 7 0 [COUNT OF UNAVAILABLE INCS
2STB LDN 6 0 [MAX.NO.OF WRONGED TAPES
2T*2 STEP STEP
2TSL BZE 3 READEND
2W2W ... JMBS STEP,3,BIAVESTR,BIUNFINR [J IF NOT A REC FOR DTQUEST
2WRW LDX 4 AMTS-A1(3) [COUNT OF MTS
2X?G LDX 2 3
2XR6 LDX 5 AINCNO-A1(3) [INC.NO.
2Y=Q TESTWRONG
2YQB ... JMBAC NOTWRONG,2,BMUSWRR,BMOPWRR [J IF TAPE NOT WRONGED
2^=2 ADN 2 INCMAGLEN
2^PL BCT 4 TESTWRONG [LOOK AT NEXT MT
329= MHUNTW 2,FLIB,FLINC
32NW LDX 4 A1(2)
338G SBN 4 1
33N6 BZE 4 NOVERIFYET
347Q NEXTVERIF
34MB ADN 2 1
3572 BXE 5 A1+1(2),NOTWRONG [J IF INC VERIFIED AS UNAVAILABLE
35LL BCT 4 NEXTVERIF
366= NOVERIFYET
36KW READAGAIN [GET INCINDEX RECORD INTO FRB
375G ADN 7 1 [UPDATE COUNT OF INCREMENTS
37K6 MHUNTW 3,FILE,FRB
384Q ADX 6 AMTS(3) [UPDATE COUNT OF TAPES
38JB BRN STEP
3942 [
39HL [ INCREMENT NOW VERIFIED(MAY OR MAY NOT BE AVAILABLE)WAKE UP WAITERS
3=3= [
3=GW NOTWRONG
3?2G ... BS 3,BIAVESTR [SET 'INC VERIFIED' BIT
3?G6 LDX 2 FX2
3?^Q STEPREWRITE
3#FB ... CALL 4 XSTATER [CLEAR 'BINCUNVERR' BIT IN RELEVENT F
3CC6 BRN STEP
3CWQ READEND
3DBB CLOSETOP
3DW2 MHUNTW 3,FLIB,FLINC
3F*L LDN 1 1
3FT= STO 1 A1(3) [CLEAR LIST OF NEWLY VERIFIED INCS
3G#W BNZ 7 STATEMENT [J IF SOME STILL UNVERIFIED
3GSG FREECORE 3
3H#6 STARTACT RET [KICK SCHEDULER
3HRQ ENDCOM
3J?B [
3JR2 [ MAKE STATEMENT ABOUT WRONGED TAPES AND UNAVAILABLE INCS.
3K=L [
3KQ= [ MT%A %B %C WRONGED,MAKING INC%D %E UNAVAILABLE
3L9W [
3LPG STATEMENT
3M96 ADN 7 2
3MNQ MHUNTW 3,FLIB,FLINC
3N8B LDX 4 ALOGLEN(3)
3NN2 BXGE 4 7,RIGHTSIZE
3P7L ALTLEN 3,7,FLIB,FLINC
3PM= MHUNTW 3,FLIB,FLINC
3Q6W RIGHTSIZE
3QLG SBN 7 1 [ DPDATE RECORD HEADER
3R66 STO 7 A1(3)
3RKQ STOZ A1+1(3)
3S5B SBN 7 1 [ X7= NO OF INCREMENTS
3SK2 [
3T4L [ AND APROC TO CONTAIN UP TO X6 TAPES-INCMAGLEN WORDS PER TAPE
3TJ= [
3W3W LDX 5 6
3WHG LDN 0 INCMAGLEN
3X36 MPY 5 0
3XGQ ADN 6 AMTS-A1+1
3Y2B SETUPCORE 6,3,FILE,APROC
3YG2 STO 6 A1(3)
3Y^L STOZ AMTS(3)
3^F= [
3^YW [ INSERT INC.NOS INTO FLINC AND TAPE NOS INTO APROC
42DG [
42Y6 NEXTFRB
43CQ MHUNTW 3,FILE,FRB
43XB LDX 4 AINCNO(3) [NEXT INC NOT VERIFIED
44C2 MHUNTW 2,FLIB,FLINC
44WL SMO 7
45B= STO 4 A1+1(2) [INCS WILL BE IN DESCENDING ORDER
45TW LDX 6 AMTS(3) [COUNT OF MTS IN FRB
46*G MHUNTW 2,FILE,APROC
46T6 LDX 0 2
47#Q TSNGET
47SB LDX 5 AMTS(2)
48#2 LDX 4 AMAG(3)
48RL BZE 5 ZEROCT
49?= TRYNEXT
49QW BXE 4 AMAG(2),NOWIN
4==G ADN 2 INCMAGLEN
4=Q6 BCT 5 TRYNEXT
4?9Q ZEROCT
4?PB STO 4 AMAG(2) [NEW TSN IN LIST
4#92 LDN 1 1
4#NL LDX 2 0
4*8= ADS 1 AMTS(2) [INCREASE COUNT OF TSNS IN APROC
4*MW NOWIN ADN 3 INCMAGLEN
4B7G LDX 2 0 [RESET APROC POINTER AGAIN
4BM6 BCT 6 TSNGET
4C6Q MFREEW FILE,FRB
4CLB BCT 7 NEXTFRB
4D62 DOWN DTSUBS,4 [OUTPUT STATEMENT
4DKL MFREEW FILE,APROC
4F5= [
4FJW [ NOW ASK QUESTION-CAN YOU TAPERIGHT ANY OF THESE TAPES?
4G4G [
4GJ6 QUEST SETNCORE 20,2,ADATA,CREADL
4H3Q LDN 6 42
4HHB STO 6 A1(2) [CHAR COUNT
4J32 ADN 1 QA
4JGL ADN 2 CPDATA
4K2= MOVE 1 11
4KFW ISSUCOM QUESTERR
4K^G MHUNTW 2,APED,ADISPLAY
4LF6 LDCH 5 APEDDISM+1(2) [X5=FIRST CHAR OF REPLY
4LYQ SBN 5 #71
4MDB BZE 5 REPYES
4MY2 ADN 5 #71-#56
4NCL BZE 5 REPNO
4NX= [
4PBW [ INVALID ANSWER
4PWG [
4QB6 OUTPARAM APEDDISM(2),APEDDISM+1,APED,ADISPLAY
4QTQ MONOUT ANOTVAL
4R*B MFREEW APED,ADISPLAY
4RT2 BRN QUEST
4S#L [
4SS= [ SOME OF THE TAPES CAN BE MADE AVAILABLE-WAIT 2 MINS THEN TRY AGAIN
4T?W [
4TRG REPYES
4W?6 MONOUT HDOTR [DO TAPERIGHTS,PLEASE
4WQQ SETNCORE 10,2,ADATA,CREADL
4X=B LDN 6 6
4XQ2 STO 6 A1(2)
4Y9L ADN 1 WAITCOM
4YP= ADN 2 CPDATA
4^8W MOVE 1 2
4^NG ISSUCOM QUESTERR [WAIT 2MINS FOR OPS TO DO THIS
5286 MHUNTW 3,FLIB,FLINC
52MQ LDN 1 1
537B STO 1 A1(3)
53M2 STOZ A1+1(3)
546L [
54L= [ NONE OF INCS IN FLINC BLOCK CAN BE MADE AVAILABLE
555W [
55KG REPNO MFREEW APED,ADISPLAY
5656 BRN OPENII
56JQ QUESTERR
574B GEOERR 1,DTCHCOMM
57J2 MENDAREA 40,K99DTQUEST
583L #END
^^^^ ...25364750000100000000