{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: DTREST860)}}
====== DTREST860 ======
(George Source)
**Macros used:** [[george:macro:ANSOK2|ANSOK2]], [[george:macro:BACKSPACE|BACKSPACE]], [[george:macro:BACKWAIT|BACKWAIT]], [[george:macro:BC|BC]], [[george:macro:BS|BS]], [[george:macro:BXE|BXE]], [[george:macro:BXL|BXL]], [[george:macro:BXU|BXU]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:COPYFILE|COPYFILE]], [[george:macro:FDTENT|FDTENT]], [[george:macro:FREEBAX|FREEBAX]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HUNT2|HUNT2]], [[george:macro:INSERT|INSERT]], [[george:macro:JBC|JBC]], [[george:macro:JBS|JBS]], [[george:macro:KEEPREP|KEEPREP]], [[george:macro:LF|LF]], [[george:macro:LFCLOSE|LFCLOSE]], [[george:macro:MBS|MBS]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:MTREAD|MTREAD]], [[george:macro:MTSKIP|MTSKIP]], [[george:macro:NAME|NAME]], [[george:macro:OPENDIR|OPENDIR]], [[george:macro:OPENRELN|OPENRELN]], [[george:macro:OUTPACKX|OUTPACKX]], [[george:macro:OUTPAR|OUTPAR]], [[george:macro:PICKREP|PICKREP]], [[george:macro:PUTREP2|PUTREP2]], [[george:macro:RESQUERY|RESQUERY]], [[george:macro:REWRITE|REWRITE]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETREP|SETREP]], [[george:macro:SETREP2|SETREP2]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:SFCB|SFCB]], [[george:macro:STARTACT|STARTACT]], [[george:macro:STEP|STEP]], [[george:macro:TESTREP|TESTREP]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:TESTREPNOT|TESTREPNOT]], [[george:macro:TESTRPN2|TESTRPN2]], [[george:macro:TOPFCB|TOPFCB]], [[george:macro:TOPFCB2|TOPFCB2]], [[george:macro:TRACE|TRACE]], [[george:macro:UP|UP]], [[george:macro:VFREEW|VFREEW]], [[george:macro:WAKEUP|WAKEUP]], [[george:macro:WHATBACK|WHATBACK]], [[george:macro:WRITEAUTO|WRITEAUTO]]
22#C ... SEG DTREST,860,C.R.JOHNSON,SCHEDULER
22LS ...[
22^= SEGENTRY K1DTREST,X1DTREST
23DW ...[
25CB SENTEOF #40000000 [TYPE IN EOF SENTINEL
25X2 YARCHM 8HARCH(M)
26BL YARCH 4HARCH
26LD ...[
26W= [ AWORK1 CONTAINS UNIT NUMBER
27*W [ AWORK2 CONTAINS AUXILIARY REPLY-PASSED BACK IN ACOMMUNE1
27TG [ AWORK3 PRESERVES MAIN REPLY THROUGH TAPEPOS S.R.
28SQ [
28XF ...[
28YB ...[ ******************************************************************
28^? ...[
2928 ...[ THIS SUBROUTINE SETS DUMPER'S SEARCHING BITS.
2935 ...[
2942 ...XNOTSEARCH [
294X ... LDX 2 FX2 [SET X2
295S ... TOPFCB2 1 [X1 -> DIRECTORTES FCB
296P ... JBS XNOTSET,1,BFDUMP [BFDUMP ALREADY SET
297L ... MBS 1,BFDUMP,BFDIRUPDATE [SET BITS
297R ...XNOTSET [
297Y ... EXIT 7 0 [
2985 ...[
298= ...[ ******************************************************************
298C ...[
298J ...[ SUBROUTINE TO FIND FDT ENTRY FOR TSN IN ADTSN(FX2)
298P ...[ X1 -> ENTRY ON EXIT
298W ...[ X6 IS LINK ACCUMULATOR
2993 ...[ IF ENTRY IS ABSENT , GEOERR
2998 ...[
299* ...POINTFDT [
299G ... SMO FX2 [
299M ... LDX 0 ADTSN [X0 => TSN
299S ... FDTENT 1,0 [X1 -> ENTRY
299^ ... EXIT 6 0 [
29=* ...[
29?* ...[ ******************************************************************
29#B [
29S2 [ TAPE READ SUBROUTINE-TRIES ITS HARDEST TO PUT TAPE AFTER CORRECT
2=?L [ EOF SENTINEL-X7 CONTAINS COUNT OF BLOCKS IN FILE
2=R= [
2?=W TAPEPOS
2?QG LDN 5 0
2#=6 BRN SETMARK
2#PQ TAPEREST
2*9B LDN 5 1
2*P2 SETMARK
2B8L MHUNTW 3,FILE,FRB
2BN= LDX 7 ESENCT(3) [BLOCK COUNT
2C7W LDX 4 7 [KEEP COUNT OF BLOCKS IN X4
2CMG SBX 6 FX1
2D76 MTREADWRITE
2DLQ ... SETNCORE GSBS,3,FILE,FWB,1
2F6B MTREADX
2FL2 MTREAD FILE,FWB [READ NEXT BLOCK
2G5L BZE 7 MTFILEND
2GK= SBN 7 1 [DECR BLOCK COUNT
2H4W TESTRPN2 OK,TROUBLE
2H#N ...[
2HJG [ TO STOP CORE FLOODING WITH WRITE BLOCKS
2HWX ...[
2J7J ... LDN 1 0 [ONLY ALLOW 4 BUFFERS
2JD9 ... LDX 0 4 [X0 => TOTAL NUMBER OF BLOCKS.
2JNW ... SBX 0 7 [X0 => NUMBER OF BLOCKS TRANSFERRED.
2J^H ... SRC 01 2 [
2K=8 ... BNZ 1 NOWAITING
2KH2 BACKWAIT [EVERY 4TH ONE
2LG= NOWAITING
2MFG BZE 5 MTREADX [READ NEXT BLOCK
2MH# ...[
2MK6 ...[ GET READY TO WRITE A BLOCK
2MLY ...[
2MNS ... MHUNTW 3,BSTB,FULLB
2MSF ... LDX 0 A1(3)
2MY6 ... SBN 0 2
2N3R ... SBX 0 7
2N7D ... SMO 0
2N?5 ... LDX 0 A1+1(3)
2NBQ ... STO 0 AWORK4(2) [CURRENT BLOCK NUMBER
2NGC ... LDX 0 A1+1(3)
2NL4 ... STO 0 AWORK3(2) [RESIDENCE NUM
2NPP ... MHUNTW 3,FILE,FWB
2NTB ... LDN 1 GSBS [TRANSFER LENGTH
2N^3 ... LDN 0 A1(3)
2P4N ... STO 0 AWORK2(2) [TRANSFER START ADDRESS
2P8* ... WRITEAUTO FREE+FAIL,1,,AWORK3(2),AWORK4(2),AWORK2(2)
2P#2 ... BRN MTREADWRITE
2PD2 [
2PXL [ CORRECT NO.OF BLOCKS HAVE BEEN READ FROM TAPE-WE SHOULD NOW HAVE
2QC= [ A SENTINEL
2QWW [
2RBG MTFILEND
2RW6 TESTRPN2 SENT,NOTSENT
2S*Q SCHK LDX 0 SENTEOF(1) [CHECK THAT IT IS END SENTINEL
2STB BXU 0 ESENTYP(3),XFORMAT [J IF NOT EOF
2T*2 BXU 4 ESENBP(3),XFORMAT [BLOCK COUNT INCORRECT
2TSL KEEPREP 7,OK
2W#= BRN OUT
2WRW [
2X?G [ BLK CT EXHAUSTED,BUT NO SENT. YET.IF NOT FAIL,TRY SKIP TO SENTINEL
2XR6 [
2Y=Q NOTSENT
2YQB TESTRPN2 FAIL,SKIPSENT
2^=2 MFAIL KEEPREP 7,FAIL
2^PL BRN OUT
329= [
32NW [ SOME SORT OF FORMAT ERROR
338G [
33N6 XFORMAT
347Q KEEPREP 7,FORMAT
34MB BRN OUT
3572 [
35LL [ NON OK REPLY WHILE READING
366= [
36KW TROUBLE
375G TESTRPN2 FAIL,XFORMAT
37K6 [ MUST HAVE BEEN A FAIL-TRY SKIPPING TO SENTINEL
384Q SKIPSENT
38JB MTSKIP FILE,FWB
3942 TESTREP2 FAIL,MFAIL,SENT,XFORMAT
39HL [
3=3= [ NOW A SENTINEL HAS BEEN FOUND-IF IT IS THE RIGHT ONE.THEN REPLY
3=GW [ OK FOR TAPEPOS BUT FORMAT FOR TAPEREST
3?2G [
3?G6 BZE 5 SCHK [J IF TAPE BEING POSITIONED-SENT CHEK
3?^Q BRN XFORMAT [ELSE FORMAT ERROR
3#FB OUT STO 7 AWORK2(2) [AUXILIARY RAEPLY
3#RR ... MFREEW FILE,FWB
3*68 ... ADX 6 FX1
3*DL EXIT 6 0
3*KS ...[
3*R2 ...[ ******************************************************************
3*Y= [
3BCW [ SEARCH FOR FREQ IN OFF-LINE CHAIN
3BXG [
3CC6 ...SFCB [
3CWQ ... CALL 6 POINTFDT [X1 -> FDT ENTRY
3DBB ... LDX 4 FDINC(1) [X4 => INCREMENT NUMBER
3DW2 ... LDX 5 FDFILE(1) [X5 => FILE NUMBER
3F*L ... LF 1,FDTFSNO,6 [X6 => FILESTORE NUMBER
3FT= ... LDX 2 BOLC [X2 -> START OF OFFLINE CHAIN
3G#W ... LDN 0 BOLC [
3GSG ...MISF LDX 2 FPTR(2) [
3H#6 BXE 2 0,XIT [J IF END OF CHAIN
3HRQ BXL 4 FDTINCNUM(2),XIT [ INC NOT THERE
3J?B BXU 4 FDTINCNUM(2),MISF [ INC NOT YET REACHED
3JDJ ... BXL 6 FDTFILSTR(2),XIT [ FILESTORE NOT THERE
3JKQ ... BXU 6 FDTFILSTR(2),MISF [ FILESTORE NOT YET REACHED
3JR2 BXL 5 FDTFILNUM(2),XIT [ FILE NOT THERE
3K=L BXU 5 FDTFILNUM(2),MISF [ FILE NOT YET REACHED
3KQ= ... EXIT 7 1 [FREQ BLOCK FOUND
3L9W ...XIT EXIT 7 0 [FREQ BLOCK NOT FOUND
3LPG ...[
3M96 ...[ ******************************************************************
3MNQ [
3N8B ...[ SUBROUTINE FOR SYSTEM JOURNAL MESSAGES
3NN2 [
3P7L [ OUTPACKX PUT IN SUBROUTINE TO LIMIT COMPILATION EXPANSION
3PM= [ X4=START OF MESSAGE PARAMETER
3Q6W [ X5=LENGTH OF MESSAGE
3QLG [ X6=NUMERICAL VALUE OF PDC
3QW# ...[
3R66 PACKIT
3RKQ SBX 7 FX1
3S5B OUTPACKX 4,5,6
3SK2 ADX 7 FX1 [EXIT MAY HAVE CO-ORD
3T4L EXIT 7 0
3TJ= ...[
3W3W ...[ ******************************************************************
3WHG ...[
3X36 ...[ DTREST IS ENTERED (DOWN) FROM DTSCAN WITH THE TAPE POSITIONED
3XGQ ...[ AFTER THE START OF FILE SENTINEL. A 10 WORD FABSNB HAS BEEN SET
3Y2B ...[ UP BY DTSCAN
3YG2 ...[ THE OCCASION OF A BACKING STORE JAM DOES NOT INHIBIT THE
3Y^L ...[ RESTORING OF FILES. IF THE JAM IS SUCH THAT NO BACKING STORE IS
3^F= ...[ AVAILABLE PROC TAPES AND NON-CURRENT DUMP TAPES WILL BE SET
3^YW ...[ WAITING FOR BACKING STORE; CURRENT DUMP TAPES WILL BE POSITIONED
42DG ...[ AT THE END OF THE FILE AND ALLOWED TO WIND ON IN CASE DUMPER
42Y6 ...[ SHOULD REQUIRE THEM.
43CQ ...[
43XB ...[
44C2 ...[
44WL ...X1DTREST
45B= ... MHUNTW 3,FILE,FRB [START OF SUBFILE SENTINEL.
45TW ... CALL 6 POINTFDT [X1 -> FDT ENTRY
46*G ... JBS WCDUMP,1,BIFDTCD [J IF CURRENT DUMP TAPE
47#Q ... WHATBACK 3,ESENCT(3) [MANDATORY BS REQUEST
47SB ... BRN XBACK
48#2 ...WCDUMP
48RL ... WHATBACK 3,ESENCT(3),NONAV [OPTIONAL BS REQUEST
49?= ...XBACK [BACKING STORE GOT. FILE IS NOW
49QW ... [BROUGHT ONLINE
8Y7B CALL 6 TAPEREST [RESTORE FILE FROM TAPE
8YM2 BNZ 7 MTFAIL [IF REPLY NON-OK,SET MAIN REPLY'FAIL'
8YWS ... STOZ AWORK2(2) [SET AUX REPLY OK
8^2P ...[
8^6L [ FILE RESTORED FROM TAPE
8^BD ...[
8^L= ... OPENDIR XBREAK,GENERAL,ERASING,QUERY
925W [
92KG [ ERASING BECAUSE IF LF,ERASE IS DONE,AND FILE HAS TO BE RESTORED,
9356 [ THEN UNLESS ERASING MODE SET,THE FILE WILL APPEAR TO HAVE BEEN
93JQ [ ERASED ALREADY
944B [
947P ...[ NOW CHECK REPLY
94?4 ...[
94BD ... TESTREP2 OK,TESTINC,NOUSER,PLOSS,NOFILE,PLOSS,VRYWRONG,PLOSS
94HF ... TESTREP2 NAME,PLOSS
94NG ... GEOERR 1,DIRSHUT
94W3 ... [DIRECTORY OPENED OK, CHECKS ARE
953J ... [NOW PERFORMED TO ENSURE THAT THIS
9595 ... [IS THE LATEST DUMP OF THE FILE.
95BL ...TESTINC [
95J7 ... MHUNTW 3,FILE,ENT [
95PN ... LDX 7 EINC(3) [X7 => INCREMENT NUMBER
95X9 ... BZE 7 OLDMP [J IF INC NO. ZERO - FILE RE-INPUT?
964Q ... CALL 6 POINTFDT [X1 -> FDT ENTRY
96=? ... LDX 6 FDINC(1) [INC NO. OF TAPES CURRENT POSITION
96CT ... BXU 7 6,OLDMP [OLD DUMP IF NOT EQUAL
96JW ... LDEX 0 ECOPS(3) [
96PX ... BNZ 0 ONL [JUMP IF FILE ALREADY ONLINE
96WY ... [IT HAS BEEN ESTABLISHED THAT THIS
973^ ... [IS THE LATEST DUMP OF THE FILE.
9792 ... [THE NAME RECORD IS UPDATED AND THE
97B3 ... [BLOCKS RECORD IS INSERTED.
97H4 ... MHUNTW 1,BSTB,FULLB
97N5 ... LDX 0 A1(1)
97T6 ... SBN 0 2 [NUMBER OF BLOCKS IN FILE
9827 ... SMO 0 [ARE LOADED INTO
9878 ... LDCT 0 0 [THE COUNT FIELD
98#9 ... ADN 0 1 [ONLINE INDICATOR
98F= ... STO 0 ECOPS(3)
98L? ... MHUNTW 1,FILE,FRB [SENTINEL
98R# ... LDX 0 ESEN10(1) [FENDBUCK
98Y* ... STO 0 EENDBUCK(3)
995B ... LDX 0 ESEN11(1) [FVERSION
99=C ... STO 0 EVERSION(3)
99CD ... LDX 0 ESEN17(1) [FSIZE
99JF ... DEX 0 EINF3(3)
99PG ...#UNSET JSKI28
99WH ...(
9=3J ...# *******************************************
9=8K ...# IP REDUMP CSS SPECIAL
9=?5 ... LDX 4 EINC(3) [X4 => INCREMENT NUMBER
9=*L ... SEGENTRY K98DTREST
9=MN ... NULL [WHEN SWITCHED ON THIS LINE
9=SP ... [IS 'TXL 4 INSTPARAM+1'
9=^Q ... BCC NTBRD
9?6R ... BS 3,BEDUMP
9?=5 ... CALL 7 XNOTSEARCH [SET DUMPER'S SEARCHING BITS
9??S ...NTBRD
9?DT ...# ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
9?KW ...)
9?M6 ... JBC PFCCOK1,3,BEPFCC [J IF NO NEED FOR PFCC'S
9?NB ... BS 3,BEDUMP [SET 'TO BE DUMPED' BIT
9?PL ...PFCCOK1 [
9?QX ... NAME 3,FILE,FWB [RENAME ENT BLOCK
9?XY ... REWRITE [NAME RECORD
9#4^ ... MHUNTW 3,FILE,FWB
9#=2 ... NAME 3,FILE,ENT [BACK TO ENT AGAIN
9#C3 ... MHUNTW 3,BSTB,FULLB
9#J4 ... NAME 3,FILE,FWB [RENAME FULLB
9#RK ... STEP [MOVE POINTER ON ONE
9*37 ... INSERT [BLOCKS RECORD INSERTED BEFORE TRAPS
9*5M ... TESTREP FILEFULL,XFULL
9*88 ... MHUNTW 3,FILE,FWB
9**9 ... NAME 3,BSTB,FULLB [BACK TO FULLB AGAIN
9*G= ... LDX 0 A1+1(3)
9*M? ... STO 0 AWORK4(2) [SAVE RES NUMBER
9*^# ...[
9B?* ...[ THIS CODING TESTS FOR THE POSSIBILITY THAT WHILE THE FILE IS BEING
9BKB ...[ RETRIEVED FROM TAPE AN ALLOCATE COMMAND MAY HAVE BEEN GIVEN FOR THIS
9BXC ...[ FILE
9C9D ...[
9CHJ ... MHUNTW 3,FILE,ENT
9CRB LDX 4 EINC(3) [PICK UP INC NO
9D?2 STO 4 AWORK1(2) [PRESERVE X4 FOR SJ MESSAGE
9DQL LDX 4 EINF2(3)
9F== STO 4 AWORK3(2) [PRESERVE FOR SJ MESSAGE
9FPW LDX 5 EALLOC(3) [VALUE OF FRN IN DIR. ENTRY
9G9G ANDN 5 #77
9GP6 LDX 4 AWORK4(2) [RECOVER FRN BEFORE THE TAPE RSSTORE
9H8Q SBX 4 5
9HNB BZE 4 XCONT [J IF FRN NOT ALTERED
9J82 SBN 5 1
9JML ... BZE 5 XCONT [J IF NEW VALUE CORRESPONDS
9K7= ... BNG 5 XCONT [TO CANCEL OR PUBLIC ALLOCATE
9KLW XDALL
9L6G ADN 5 1
9LH2 ... RESQUERY 5,XCONT
9LP= ... LDX 2 FX2 [RESQUERY CORRUPTS X2
9LXG ... STO 5 AWORK4(2) [SAVE NEW RES NUMBER
9L^4 ... MHUNTW 1,FILE,FABSNB [SET UP FABSNB FOR COPYFILE
9M2L ... LDX 3 A1(1) [FABSNB RECORD HEADER
9M48 ... SETUPCORE 3,2,FILE,FABSNB [SET UP NEW FABSNB
9M5Q ... HUNT2 1,FILE,FABSNB,2 [FIND ORIGONAL FABSNB
9M7# ... LDN 6 A1(1)
9M8W ... LDN 7 A1(2)
9M=D ... MOVE 6 0(3) [MOVE IN DATA
9MQ4 ... COPYFILE 5
9PHW XCONT
9PK? ...[
9PLN ...[ THIS CODING INSERTS PFCC'S IF THE
9PN5 ...[ FILE IS A MARK 6 BASIC FILE
9PPG ...[
9PQX ... MHUNTW 3,FILE,ENT [FIND ENT BLOCK
9PS# ... JBC PFCCOK,3,BEPFCC [BIT BEPFCC SET IF FILE NEEDS PFCC'S
9PTP ... BACKSPACE [SET UP DIRECTORY
9PX6 ... BACKSPACE [FOR OPENREL
9PYH ... SETNCORE 6,2,FILE,FLOCNB [SET UP FOR OPENREL
9P^Y ... MHUNTW 3,FILE,ENT [REHUNT ENT
9Q3* ... LDN 6 ELOC1(3) [POINT TO LOCAL NAME
9Q4Q ... LDN 7 A1(2) [POINTER IN FLOCNB
9Q67 ... MOVE 6 5 [MOVE 5 WORDS OF LOCAL NAME
9Q7J ... LDX 7 ELAN(3) [PICK UP LANGUAGE CODE
9Q8^ ... STO 7 A1+5(2) [STORE LANGUAGE CODE
9Q=B ... OPENRELN XBREAK,READ,LEAVE,DIROPEN,ERASING,QUERY
9Q?R ... TESTREP2 OK,XFILOPEN,NOUSER,PLOSS,NOFILE,PLOSS,VRYWRONG,PLOSS
9Q*8 ... GEOERR 1,FILSHUT
9QBK ...XFILOPEN
9QD2 ... LDN 6 #41 [USED TO SET UP PFCC'S
9QFC ...PLOOP
9QGS ... STEP [GET NEXT RECORD
9QJ9 ... BZE 3 PEND [J IF END OF FILE
9QKL ... LDX 0 1(3)
9QM3 ... ANDN 0 #77
9QND ... BNZ 0 PLOOP
9QPT ... ORS 6 1(3)
9QR= ... STEPREWR
9QSM ... BRN PLOOP
9QW4 ...PEND
9QXF ... CLOSETOP [CLOSE THE FILE....DIRECTORY STILL O
9QXY ...#UNS FNSAD
9QYC ... CALL 7 XNOTSEARCH [SET DUMPERS SEARCHING BITS
9QYW ...PFCCOK
9R=4 ...[
9RH= ...[ THIS PIECE OF BORING ONLINE CODING IS TO PREPARE THE PARAMETERS
9RSD ...[ FOR OUTPUTING THE SYSTEM JOURNAL MESSAGE-:
9S5L ...[ %A.%B(%C/%D)RETRIEVED ON %H AT %K(GEORGE MEAN TIME%G)
9SBS ...[ FROM TAPE %L INC %M TO RESIDENCE %E-SIZE%F BLOCKS,%J(OPT)
9SN2 ...[
9S^= ... TOPFCB 3 [X3 TOP FCB
9TDW ... LDN 4 FME1(3) [USER NAME
9TYG LDN 5 3
9WD6 LDN 6 JPDUSERNAME
9WXQ CALL 7 PACKIT
9XCB [ALWAYS ASSUME OUTPACKX CO-ORDINATES
9XX2 ... MHUNTW 3,FILE,ENT
9YBL ... LDN 4 ELOC1(3)
9YW= LDN 5 3
9^*W LDN 6 JPDLOCNAME [LOCAL NAME
9^TG CALL 7 PACKIT
=2*6 ... MHUNTW 3,FILE,ENT
=2SQ ... LDN 4 EGEN(3) [GENERATION NUMBER
=3#B LDN 5 1
=3S2 LDN 6 JPDGENNUM
=4?L CALL 7 PACKIT
=4R= ... MHUNTW 3,FILE,ENT
=5=W ... LDN 4 ELAN(3) [LANGUAGE
=5QG LDN 5 1
=6=6 LDN 6 JPDLANGUAGE
=6PQ CALL 7 PACKIT
=79B ... LDN 4 AWORK4(2) [RESIDENCE NUMBER
=88L LDN 5 1
=8N= LDN 6 JPDNUMA
=97W CALL 7 PACKIT
=9MG ... MHUNTW 3,BSTB,FULLB
==76 ... LDX 3 A1(3)
==LQ ... SBN 3 2 [SIZE OF FILE
=?6B LDN 4 3
=?L2 LDN 5 1
=#5L LDN 6 JPDBLOCKCT
=#K= CALL 7 PACKIT
=*JG LDN 4 GMTNOW [GEORGE MEAN TIME
=B46 LDN 5 1
=BHQ LDN 6 JPDNUMB
=C3B CALL 7 PACKIT
=D2L OUTPAR DATENOW,NULL [PRESENT DATE THEN NULL PARAM
=DG= SMO FX2
=D^W LDX 4 AWORK3 [PICK UP EINF2
=FFG SLL 4 9
=F^6 BNG 4 XARC [BIT 9 SET
=GDQ SLL 4 2
=GYB BPZ 4 XD9A [J IF NOT ARCHIVED
=HD2 SMO FX1 [BIT 11 SET
=HXL LDN 4 YARCHM [ MANAGER ARCHIVED
=JC= LDN 5 2
=JWW XP1
=KBG LDN 6 JPDVARCHAR
=KW6 CALL 7 PACKIT
=L*Q BRN XD9
=LTB XARC
=M*2 SMO FX1
=MSL LDN 4 YARCH
=N#= LDN 5 1
=NRW BRN XP1
=P?G XD9A OUTPAR NULL
=PR6 XD9
=Q=Q OUTPAR TIMENOW
=QQB SMO FX2
=R=2 LDN 4 ADTSN [TAPE SERIAL NUMBER
=RPL LDN 5 1
=S9= LDN 6 JPDTSN
=SNW CALL 7 PACKIT
=T8G SMO FX2
=TN6 LDN 4 AWORK1
=W7Q LDN 5 1
=WMB LDN 6 JPDINCNUM
=X72 CALL 7 PACKIT
=XLL MONOUT FILERET
=XS6 ... MHUNTW 3,FILE,ENT
=X^L ... LDX 4 EAUTOCOUNT(3)
=Y76 ... BZE 4 SKLF
=Y9K ... MHUNTW 1,FILE,FABSNB
=Y#4 ... LDX 6 A1(1) [X6 => FABSNB RECORD HEADER
=YBH ... SBN 6 10
=YF2 ... BZE 6 XLFCLOSE [J IF 10 WORD FABSNB
=YHF ... SETNCORE 10,3,FILE,FABSNB [SET UP 10 WORD FABSNB
=YKY ... HUNT2 1,FILE,FABSNB,3 [FIND ORIGONAL FABSNB AGAIN
=YNC ... LDN 7 10
=YQW ... STO 7 A1(3) [FABSNB RECORD HEADER
=YT* ... SMO 6
=YXS ... LDN 7 A1-1(1) [PICK UP USERNAME
=^2? ... LDN 0 A1+1(3)
=^4Q ... MOVE 7 3 [MOVE USERNAME INTO NEW FABSNB
=^79 ... ADN 7 5 [PICK UP LOCAL NAME
=^9N ... ADN 0 3
=^#7 ... MOVE 7 6 [MOVE IN LOCAL NAME
=^BL ... [DTSCAN FREES FABSNB IF IT EXISTS
=^L3 ...XLFCLOSE
=^NL ... LFCLOSE 4 [WAKE UP LISTFILE SCHEDULER
=^W6 ...SKLF
=^YW ... MFREEW BSTB,FULLB
?23L ... CLOSETOP [CLOSE DIRECTORY
?296 ... ANSOK2
?2BL ...RIDB VFREEW FILE,ENT
?2FG ... VFREEW BSTB,FULLB
?2JB #SKI K6DTREST>99-99
?342 (
?3HL TRACE EXEC3(2),DTRESREP
?43= TRACE AWORK2(2),DTAUXREP
?4GW )
?52G [
?5G6 [ WAKE UP ACTS WAITING FOR THIS FILE
?5^Q [
?6^2 CALL 7 SFCB [FIND FREQ IN OFF-LINE CHAIN
?7DL BRN RESUP [J IF NO FREQ
?7Y= ... BC 2,BFILBRES [CLEAR 'FILE BEING RESTORED' BIT
?8CW ... TESTREP OK,RESTORED,ONLINE,RESTORED,OLDDUMP,RESTORED
?9C6 TESTREP NAME,NOTRES,NOUSER,NOTRES,NOFILE,NOTRES
?9WQ TESTREPNOT VRYWRONG,RESUP
?=6J ...[
?=BB [ FILE NOT RESTORED
?=L8 ...[
?=W2 NOTRES
??*L ... BS 2,BFILNEXI [SET 'FILE NO LONGER EXISTS' BIT
?BR2 BRN WAKEUP
?C=L RESTORED
?CQ= ... BS 2,BFILERES [SET 'FILE RESTORED' BIT
?D9W WAKEUP
?DFN ... BS 2,BTERMST [SET 'TERMINAL STATE' BIT
?DPG STARTACT RET [WAKE UP DTS
?F96 RESUP LDX 2 FX2
?FNQ LDX 0 AWORK2(2)
?G8B STO 0 ACOMMUNE1(2) [PASS AUX IREP UP IN ACOM1
?GN2 UP
?H7L [
?HM= ...[
?J6W ...[
?JLG ...PLOSS [BAD REPLY FROM OPENDIR
?JW# ... PICKREP 7
?K66 ... FREEBAX [FREE BACKING STORE
?K*Y ... PUTREP2 7
?KKQ ... MFREEW BSTB,EMPTYB
?L5B ... BRN RIDB
?LK2 ...NONAV [NO BS AVAILABLE
?M4L ... CALL 6 TAPEPOS
?MJ= ... LDX 2 FX2
?N3W ... SETREP2 NOBAC
?NHG ... STOZ AWORK2(2) [SET AUX REPLY OK
?P36 ... BRN RIDB
?PGQ ...OLDMP [OLD DUMP
?Q2B ... SETREP OLDDUMP
?QG2 ... BRN PCLOSE
?Q^L ...ONL [ONLINE ALREADY
?RF= ... SETREP ONLINE
?RYW ...PCLOSE
?SDG ... CLOSETOP [CLOSE DIRECTORY
?SY6 ... BRN PLOSS
?TCQ ...MTFAIL [FAIL OR FORMAT ERROR
?TXB ... SETREP FAIL
?WC2 ... BRN PLOSS
?WWL ...XBREAK
?XB= ... GEOERR 1,SYSBRKIN
?XTW ...XFULL
?Y*G ... GEOERR 1,FILEFULL
#96Q #END
#9LB
^^^^ ...55272254000500000000