{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: EDITER867)}}
====== EDITER867 ======
(George Source)
**Macros used:** [[george:macro:AND|AND]], [[george:macro:BXGE|BXGE]], [[george:macro:BXL|BXL]], [[george:macro:CLOSE|CLOSE]], [[george:macro:EDERM|EDERM]], [[george:macro:EMPTY|EMPTY]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:NEW|NEW]], [[george:macro:OFF|OFF]], [[george:macro:OPEN|OPEN]], [[george:macro:OUTMON|OUTMON]], [[george:macro:PHOTO|PHOTO]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETCOMER|SETCOMER]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:TESTMOVE|TESTMOVE]], [[george:macro:UP|UP]], [[george:macro:VFREEW|VFREEW]], [[george:macro:WRONG|WRONG]]
22FL #LIS K0EDITER>K0ALLGEO>0
22^= #SEG EDITER [DICK RUSBRIDGE
2394 ...# (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982.
23DW 8HEDITER
23YG # THIS SEGMENT OUTPUTS ERROR MESSAGES AND COMMENTS FOR THE EDITOR.
24D6 ...# K1EDITER - OUTPUT FIXED MESSAGE IN COMERR OR COMMENT (EDERR MACRO)
24XQ # K2EDITER - OUTPUT FIXED MESSAGE IN COMMENT CATEGORY. (EDCOM MACRO)
25CB # K3EDITER - OUTPUT VARIABLE SYNTAX ERROR MESSAGE.
25JJ ...# K4EDITER - OUTPUT VARIABLE EXECUTION MESSAGE
25PQ ...# K5EDITER - OUTPUT FIXED MESSAGE IN COMERR CATEGORY. (EDCOMERR MACR
25X2 #
26BL # ENTRY POINT TABLE
26W= #
27*W SEGENTRY K1EDITER,N1EDITER [EDERR MESSAGE
27TG SEGENTRY K2EDITER,N2EDITER [EDC6M MESSAGE
28*6 SEGENTRY K3EDITER,N3EDITER [SYNTAX ERROR MESSAGE
28SQ SEGENTRY K4EDITER,N4EDITER [EXECUTION ERROR MESSAGE
28W^ ... SEGENTRY K5EDITER,N5EDITER [EDCOMERR MESSAGE
28^8 ... +0 [SPACE
293C ... +0 [HERE
295L ... +0 [FOR
297T ... +0 [EXTRA
29=4 ... +0 [SEGENTRYS
29#B #
29S2 SYNT 14HSYNTAX ERROR:
2=?L XECU 17HEXECUTION ERROR:
2=*3 ...#
2=BD ...# THE FOLLOWING MESSAGES ARE SET UP WITH UNIVERSALS
2=CT ...# WHICH ARE USED IN OTHER SEGMENTS, HENCE:-
2=F= ...# 1/ ANY NEW SEGENTRY MUST BE SET UP TO
2=GM ...# REPLACE ONE OF THE SPARE WORDS ABOVE
2=J4 ...# 2/ ANY NEW MESSAGES MUST BE ENTERED IN SUCH
2=KF ...# A WAY THAT THEY WILL NOT CHANGE ANY OF THE
2=LW ...# EXISTING UNIVERSAL VALUES. E.G. INSERTED
2=N? ...# AT THE END
2=PN ...#
2=R= EDERM LWIN,53,L/W WILL BE INEFFECTIVE SINCE TRACING INHIBITS OUTPUT
2?=W EDERM MODT,47,MERGING OLDFILES OF DIFFERENT TYPES NOT ALLOWED
2?QG EDERM YRTL,41,YOUR RECORD'S TOO LONG: I'VE TRUNCATED IT
2#=6 EDERM YROB,40,YOU'VE RUN OFF THE BEGINNING OF THE FILE
2#PQ EDERM ITON,40,INCOMPATIBLE TYPES FOR OLD AND NEW FILES
2*9B EDERM YBSL,39,YOU'VE REACHED YOUR BACKING STORE LIMIT
2*P2 EDERM FQUE,38,REPETITION OF THIS KIND IS NOT ALLOWED
2B8L EDERM TPEF,37,FILE IS OF THE WRONG TYPE FOR EDITING
2BN= EDERM BTNA,35,BACKWARDS TRANSCRIPTION NOT ALLOWED
2C7W EDERM YROE,34,YOU'VE RUN OFF THE END OF THE FILE
2CMG EDERM TWOF,33,F MAY NOT BE USED IN THIS CONTEXT
2D76 EDERM IEYE,32,I'VE EXHAUSTED YOUR EDITING FILE
2DLQ EDERM IEYJ,30,I'VE EXHAUSTED YOUR JOB SOURCE
2F6B EDERM AFNA,30,AMORPHOUS OLDFILE NOT ALLOWED
2FL2 EDERM YFYN,27,YOU'VE FILLED YOUR NEW FILE
2G5L EDERM YHNI,27,YOU HAVE NO INPUT FILE OPEN
2GK= EDERM TNFC,25,THERE IS NO FILE TO CLOSE
2H4W EDERM ITER,22,INSTRUCTION TERMINATED
2HJG EDERM EFSF,22,TOO MANY EDITING FILES
2J46 EDERM TMIF,20,TOO MANY INPUT FILES
2JHQ EDERM CHNF,19,CHARACTER NOT FOUND
2K3B EDERM NUTL,16,NUMBER TOO LARGE
2KH2 EDERM IPMT,16,INPUT FILE EMPTY
2L2L EDERM EDAB,14,EDIT ABANDONED
2L7S ...#UNS EDLOOP
2L*2 ... EDERM INCL,52,INSTRUCTION(S) NOT COMPLETED SINCE EDITOR WOULD LOOP
2LBQ ... EDERM YEDL,46,YOU'VE EXCEEDED THE INSTALLATION DEFAULT LIMIT
2LDG ... EDERM YESL,36,YOU'VE EXCEEDED YOUR SPECIFIED LIMIT
2LG= #
2L^W # SETS COMERR IF NOT FROM MOP CONSOLE
2MFG #
2M^6 SETCE LDN 0 #10 [MOP CONTEXT.
2NDQ LDN 4 #40 [IN COMMENT CATEGORY.
2NYB ANDX 0 CONTEXT(2) [IF CURRENTLY MOP
2PD2 BZE 0 SETS [J IF NOT MOP
2PK8 ... LDXC 0 IEFT(2)
2PQB ... BCS SETX [J IF NO EDITFILE
2PXL MHUNTW 3,CPB,CALAS
2QC= LDXC 0 CPBFSD(3)
2QWW BCS SETX [JM IF NOT MACRO
2RBG SETS LDN 4 #20 [RESET TO COMMERR CATEGORY
2RW6 SETCOMER [WHEN NOT MOP
2S*Q SETX STO 4 AWORK1(2) [SAVE MESSAGE CATEGORY
2STB EXIT 6 0
2T*2 #
2TSL N1EDITER [MESSAGE IS IN COMERR CATEGORY
2W#= #
2WRW CALL 6 SETCE [IF NOT MOP, SET COMERR
2X?G BRN X1
2XR6 #
2Y=Q N2EDITER [MESSAGE IS IN COMMENT CATEGORY
2YQB #
2^=2 LDN 4 #40
2^PL STO 4 AWORK1(2)
329= X1 SMO 7
32NW LDX 5 0(1)
338G ADN 5 3
33N6 SRL 5 2
347Q SETUPCORE 5,3,CPB,CUNI
34MB SMO 7
3572 LDN 2 0(1)
35LL LDX 7 0(2)
366= ADN 2 1
36KW LDX 1 5
375G ADN 3 A1
37K6 MOVE 2 0(1)
384Q X2 LDX 2 FX2
38JB LDX 6 ACOM6(2) [PRESERVE ACOM6
3942 LDX 4 AWORK1(2) [MESSAGE CATEGORY
39HL OUTMON 7,A1,4,CPB,CUNI
3=3= STO 6 ACOM6(2)
3=GW VFREEW CPB,CUNI
3?2G UP
3?G6 #
3?^Q RLIF [RELOCATE INSTRUCTION BLOCK
3#FB #
3#^2 LDX 5 IEIM(2)
3*8S LDX 3 IEIA(2)
3*DL TESTMOVE 5,X3
3*Y= MHUNTW 3,FILE,FRB [OTHERWISE FIND IT
3BCW PHOTO 5
3BXG STO 3 IEIA(2)
3CC6 STO 5 IEIM(2)
3CWQ X3 EXIT 4 0
3DBB #
3DW2 N3EDITER [ 'SYNTAX ERROR:'
3F*L #
3FT= CALL 6 SETCE [IF NOT MOP, SET COMERR
3G#W LDX 3 IEPS(2)
3GSG LDX 7 IEIP(2)
3H#6 SLC 3 2
3HRQ #SKI JDIAG1
3J?B (
3JR2 LDX 4 IEIG(2)
3K=L SLL 4 2 [J IF IEPS IS
3KQ= )
3L9W #SKI JDIAG1<1$1
3LPG LDN 4 A1+2*4 [J IF IEPS IS
3M96 BXL 3 4,X8 [RIDICULOUS
3MNQ SLC 7 2
3N8B SBS 3 7
3NN2 STO 7 3
3P7L SRL 3 2
3PM= LDN 4 #3763
3Q6W ADN 3 5
3QLG BXL 7 4,X4
3R66 X8 LDN 7 0
3RKQ X4 BNZ 7 X5
3S5B LDN 3 5
3SK2 X5 SETUPCORE 3,3,CPB,CUNI
3T4L LDN 6 A1(3)
3TJ= LDN 5 SYNT(1)
3W3W BZE 7 X6
3WHG MVCH 5 14
3X36 X7 CALL 4 RLIF
3XGQ LDX 5 IEPS(2)
3Y2B ADX 5 IEIA(2)
3YG2 LDX 3 7
3YPS X11 BZE 3 X9
3Y^L MVCH 5 0(3)
3^49 SBN 3 1
3^6S SRL 3 9
3^9C SLL 3 9
3^#2 BRN X11
3^BK X9
3^F= ADN 7 14
3^YW BRN X2
42DG X6 MVCH 5 12
42Y6 LDN 7 12
43CQ BRN X2
43XB #
44C2 N4EDITER [ 'EXECUTION ERROR:'
44WL #
45B= CALL 6 SETCE
45TW LDX 3 IEPS(2)
46*G LDX 7 IEIP(2)
46T6 SLC 3 2
47#Q #SKI JDIAG1
47SB (
48#2 LDX 4 IEIG(2)
48RL SLL 4 2 [ J IF IEPS
49?= )
49QW #SKI JDIAG1<1$1
4==G LDN 4 A1+2*4 [JUMP IF IEPS
4=Q6 BXL 3 4,X10 [IS RIDICULOUS
4?9Q SLC 7 2
4?PB SBS 3 7
4#92 STO 7 3
4#NL SRL 3 2
4*8= LDN 4 #3763
4*MW ADN 3 5
4B7G BXGE 7 4,X10
4BM6 BZE 7 X10
4C6Q SETUPCORE 3,3,CPB,CUNI
4CLB LDN 6 A1(3)
4D62 LDN 5 XECU(1)
4DKL MVCH 5 17
4F5= CALL 4 RLIF
4FJW LDX 5 IEPS(2)
4G4G ADX 5 IEIA(2)
4GJ6 LDX 3 7
4GRY X12 BZE 3 X13
4H3Q MVCH 5 0(3)
4H6* SBN 3 1
4H8Y SRL 3 9
4H?H SLL 3 9
4HB6 BRN X12
4HDP X13
4HHB ADN 7 17
4J32 BRN X2
4JGL X10 UP
4JK9 ...#
4JMS ...N5EDITER [MESSAGE IS IN COMERR CATEGORY
4JQC ...#
4JT2 ... LDN 6 X1(1)
4JXK ... BRN SETS
4K2= MENDAREA 200,K100EDITER
4KFW #END
^^^^ ...03732377000200000000