{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: EMSENG864)}}
====== EMSENG864 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BS|BS]], [[george:macro:COOR1|COOR1]], [[george:macro:COOR3|COOR3]], [[george:macro:DCA|DCA]], [[george:macro:DOWN|DOWN]], [[george:macro:GPERI|GPERI]], [[george:macro:JBUSY|JBUSY]], [[george:macro:JENVNOT|JENVNOT]], [[george:macro:JMBS|JMBS]], [[george:macro:JUNBUSY|JUNBUSY]], [[george:macro:JWRONG|JWRONG]], [[george:macro:LOCK|LOCK]], [[george:macro:LTYPE|LTYPE]], [[george:macro:MONOUT|MONOUT]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:UNLOCK|UNLOCK]], [[george:macro:UP|UP]]
22FL #SEG EMSENG [COMM
22^= #OPT K0EMSENG=0
23DW #LIS K0EMSENG>K0EMS>K0ALLGEO
23YG 8HEMSENG
24D6 #
24XQ # THIS IS THE EARLY MORNING START ENGAGE BUTTON AND CONSOLE SEGMENT
25X2 #
26BL #
26W= SEGENTRY K1EMSENG,X1EMSENG [INITIALISE CONSOLE ACTIVITY
27*W SEGENTRY K2EMSENG,X2EMSENG [IMPLEMENT 'CONIN' MACRO
27TG SEGENTRY K3EMSENG,X3EMSENG [IMPLEMENT 'BUTTON' MACRO
28*6 #
28SQ #
29#B #
29S2 # DEVICE TYPE TABLE TO ALLOW ALL UDAS DEVICES TO BE REFERRED TO AS
2=?L # TYPE 6
2=R= #
2?=W TABLE +0
2?QG +1
2#=6 +2
2#PQ +3
2*9B +4
2*P2 +5
2B8L +6 [UDAS - EDS 8
2BN= +6 [UDAS - MCF
2C7W +8
2CMG +9
2D76 +10
2DLQ +11
2F6B +12
2FL2 +6 [UDAS - FDS
2G5L +14
2GK= +15
2H4W +16
2HJG +17
2J46 +18
2JHQ +19
2K3B +20
2KH2 +21
2L2L +22
2LG= +23
2L^W +24
2MFG +25
2M^6 +6 [UDAS - EDS(30)
2NDQ +27
2NYB +28
2PD2 +29
2PXL +30
2QC= +31
2QWW +32
2RBG +33
2RW6 +34
2S*Q +35
2STB +36
2T*2 +37
2TSL +38
2W#= +39
2WRW +40
2X?G +41
2XR6 +42
2Y=Q +43
2YQB +44
2^=2 +45
2^PL +46
329= +47
32NW +48
338G +49
33N6 +50
347Q +51
34MB +52
3572 +53
35LL +54
366= +55
36KW +56
375G +57
37K6 +58
384Q +59
38JB +60
3942 +61
39HL +62
3=3= +63
3=GW [
3?2G [
3?G6 [ WW WW W
3?^Q [ WW WW WW
3#FB [ WW WW WWW
3#^2 [ WWWW WW
3*DL [ WWWW WW
3*Y= [ WW WW WW
3BCW [ WW WW WW
3BXG [ WW WW WW
3CC6 [
3CWQ [
3DBB X1EMSENG [INITIALISE CONSOLE ACTIVITY
3FT= #DEF WIDTH=40
3G#W ...#DEF WILLBELOCKD=0
3GSG JENVNOT NORMAL1,DME [IF DME, ...
3H#6 SETNCORE ACTIVEINIT,3,CONBUFF,ACTIVE,+WILLBELOCKD
3HRQ STOZ ACHCT(3) [SET UP AND INITIALISE ...
3J?B STOZ ACLEN(3) [FIRST PAGE
3JR2 STOZ ACLNS(3)
3K=L STOZ ACDAT(3) [DATE&TIME NOT SET UP YET
3KQ= LDN 0 HEIGHTPAGE
3L9W STO 0 ACLFT(3)
3LPG LDN 0 WIDTH/4 + ACLOG
3M96 STO 0 ACLOG(3)
3MNQ STO 0 ACOUT(3)
3N8B LDN 0 1
3NN2 STO 0 AWORK1(2) [PAGEWAIT MECHANISM ON
3P7L LDN 0 #7474
3PM= DSA 0 FCANCEL+2 [TO AVOID U-CODE BUG
3Q6W LDX 3 CONSCNTRL
3QLG ADN 3 COVID+1
3R66 BS 3,COAUTO [SET MAIN MONITOR ON AUTO
3RKQ ACROSS OPER,1 [AND ENTER MAIN PATH
3S5B NORMAL1
3T4L LDN 0 72
3TJ= STO 0 AWORK1(2) [72 CHARACTERS PER LINE
3W3W LDX 0 GSIGN
3WHG STO 0 AWORK3(2) [TO SUPPRESS NORMAL INPUT
3X36 ACROSS CONSOLE,1
3XGQ [
3Y2B [
3YG2 [
3Y^L [ WW WW WWWWW
3^F= [ WW WW WW WW
3^YW [ WW WW WW
42DG [ WWWW WW
42Y6 [ WWWW WW
43CQ [ WW WW WW
43XB [ WW WW WW
44C2 [ WW WW WWWWWWW
44WL [
45B= [
45TW X2EMSENG
465N ... LDX 5 ACOMMUNE9(2)
46*G LDN 4 63 [OPERATORS CONSOLE TYPE
46T6 FINDPERE 3,APFOTY,4,WRONGED [FIND FIRST (PTR IN X3)
47#Q JWRONG 3,WRONGED [BR IF THIS ONE WRONGED
47SB # FOR MULTIPROCESSORS THE CONSOLE FROM WHICH EXEC IS LOADED IS MARKED
48#2 # RIGHT, AND THE OTHERS ARE MARKED WRONG. GEORGE MAY ONLY USE THE RIGHT
48RL # ONE.
49?= TESTBUSY
49QW JUNBUSY 3,UNBUSY [BR IF CONSOLE FREE
4==G COOR3 #53
4=Q6 BRN TESTBUSY
4?9Q UNBUSY
4?PB DCA 3,STO,4,COUNT [CHAR COUNT OF 63 (NO REASON)
4#92 LDN 7 0
4#NL DCA 3,STO,7,MODE [MODE 0 FOR INPUT
4*8= LDN 6 FCINBUF [START OF FIXED CORE I/P BUFFER
4*MW DCA 3,STO,6,CTSA
4B7G STOZ AWORK1(2)
4BM6 LDX 0 AFLAG(2) [ CHECK IF ACT. ALREADY LOCKED.
4C6Q ANDN 0 #10
4CLB BZE 0 NOTYETLOCK [ DONT RELOCK IF LOCKED ALREADY
4D62 NGS 2 AWORK1(2) [ INDICATE WAS LOCKED ON ENTRY
4DKL BRN NOFREEZE
4F5= NOTYETLOCK
4FJW LOCK 2 [LOCK ACTIVITY
4G4G NOFREEZE
4HHB JENVNOT NORMAL2,DME [IF DME,
4J32 DOWN OPERIN,2 [GET OPERIN BOTH TO DO THE READ
4JGL [ (IT REQUIRES DEV. LIST PTR IN X3)
4K2= BRN RED [AND RESPOND TO IT
4KFW NORMAL2
4LF6 GPERI 3,2 [INPUT
4LYQ COOR1
4NCL RED
4PBW LDX 0 AWORK1(2) [ CHECK IF LOCKED ON ENTRY
4PWG BNG 0 NOUNLOCK [ DONT UNLOCK IF IT WAS
4QB6 UNLOCK 2 [UNLOCK ACTIVITY
4QTQ NOUNLOCK
4S#L JENVNOT TERMNORM,DME [IF DME,
4SS= LDN 3 CPRW1(2)
4T6M ... JMBS P2,3,CONSINOP,CONSFAIL,CONSCANCEL,CONSCONTN
4TF4 ... STOZ ACOMMUNE9(2)
4TRG [REPEAT READ IF UNSUCCESSFUL
4W?6 UP [ELSE GO UP (/EMSIN LEFT BY OPERIN)
4WC3 ...P2 BZE 5 X2EMSENG
4WGY ... STO 5 ACOMMUNE9(2)
4WLT ... UP
4WQQ TERMNORM
4XQ2 LDCH 7 CPRW1(2) [REPLY CHARACTER
4Y9L ANDN 7 2
4YP= BNZ 7 P1 [JIF FAILED TO CANCEL & REPEAT
4^8W SBX 4 CPRW1(2) [CHARACTER TRANSFERRED
4^NG ... STO 4 3
5286 ADN 4 7 [ROUND UP TO
52MQ SRL 4 2 [BLOCK SIZE
537B SETUPCOR 4,7,CONBUFF,EMSIN
53M2 SMO 7
546L ... STO 3 A1
54L= ADN 7 A1+1 [START OF MESSAGE IN BLOCK
555W SBN 4 1
55KG BZE 4 P6 [BR IF MESSAGE OF ZERO LENGTH
5656 SMO 4
56JQ MOVE 6 0 [COPY TO BLOCK
574B P6 MONOUT ANEWLINE [OUTPUT NEWLINE
57#8 ... STOZ ACOMMUNE9(2)
57J2 UP
583L P1 MONOUT CANCELN [OUTPUT CANCEL NL
58?D ... BZE 5 X2EMSENG
58H= ... STO 5 ACOMMUNE9(2)
58R4 ... UP
592W [
59GG [
5=26 [ WW WW WWWWW
5=FQ [ WW WW WW WW
5=^B [ WW WW WW
5?F2 [ WWWW WWWW
5?YL [ WWWW WW
5#D= [ WW WW WW
5#XW [ WW WW WW WW
5*CG [ WW WW WWWWW
5*X6 [
5BBQ [
5BWB X3EMSENG
5CB2 LDN 3 0 [MODIFIER TO EBA
5CTL LDN 4 0 [COUNT OF INTERNAL NO.
5D*= N2 LDX 7 EBA(3)
5DSW BNZ 7 N1 [JIF ENGAGE BITS
5F#G N3 ADN 4 24 [NEXT WORD
5FS6 ADN 3 1 [DITTO
5G?Q TXL 3 EBAL [EBA LENGTH
5GRB BCS N2 [JIF NOT END OF EBA
5H?2 NGN 2 4095 [SET NEGATIVE
5HQL N7 SMO FX2
5J== STO 2 ACOMMUNE9 [STORE TO PASS UP
5JPW UP
5K9G N1 LDN 1 0 [BIT COUNT
5KP6 N5 LDCT 7 #400 [BIT MASK
5L8Q SRL 7 0(1) [POSITION
5LNB BZE 7 N3 [JIF FINISHED THIS WORD
5M82 ANDX 7 EBA(3) [MASK BIT
5MML BNZ 7 N4 [JIF ENGAGE BIT
5N7= N6 ADN 1 1 [INCREMENT COUNT
5NLW BRN N5
5P6G N4 LDX 6 4
5PL6 ADX 6 1 [TOTAL INTERNAL NO.
5PTY ... FINDPERE 2,APINT,6,,,,N9 [GET DEVICE LIST POINTER
5Q5Q ...N8
5Q*J ... JBUSY 2,N6
5QKB LTYPE 2,6 [GET TYPE
5R52 ADX 6 FX1
5RJL SMO 6
5S4= LDX 6 TABLE [LOAD EFFECTIVE DEVICE TYPE
5SHW SMO FX2
5T3G TXU 6 ACOMMUNE9
5TH6 BCS N6 [JIF NOT REQUIRED TYPE
5W2Q ERS 7 EBA(3) [CLEAR BIT
5WGB BRN N7 [RETURN UP WITH DEVICE LIST PTR.
5WJK ...N9
5WLS ... LTYPE 2,6
5WP3 ... LDN 0 63
5WR= ... TXU 6 0
5WTF ... BCS N6 [J IF NOT CONSOLE(OPER)
5WXN ... BRN N8
5X22 #END
^^^^ ...610723630006