{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: EVENTFN)}}
====== EVENTFN ======
(George Source)

**Macros used:** [[george:macro:CLEAR|CLEAR]], [[george:macro:COOR1X|COOR1X]], [[george:macro:FINDTP|FINDTP]], [[george:macro:FPUT|FPUT]], [[george:macro:GEOERR|GEOERR]], [[george:macro:LABFIX|LABFIX]], [[george:macro:LINKSET|LINKSET]], [[george:macro:MACCS|MACCS]], [[george:macro:MONEND|MONEND]], [[george:macro:RINGTP|RINGTP]], [[george:macro:TESTPUC|TESTPUC]], [[george:macro:TRANSFIX|TRANSFIX]]

<code - EVENTFN.txt>22FL    #OPT  K0EVENTFN=0   
22^=    #LIS  K0EVENTFN>K0KERNEL>K0ALLGEO   
23DW    #SEG  EVENTFN                      [RUTH PORTER 
23YG    #OPT  K6EVENTFN=K6KERNEL>K6ALLGEO   
24D6          LABFIX   HNEVFIN  
24XQ    NEVFIN  
25CB          LDX   2  FX2  
25X2          LDCH  0  ATYPE(2) 
26BL          SBN   0  APET/64  
26W=          BZE   0  PCA  
27*W          GEOERR   1,EVENTFIN   
27TG    PCA 
28*6          CLEAR    2,0                 [CLEAR LOCKDOWN COUNTS:NULL IN G3
28SQ          CALL  7  PUCTP               [CALL PUC S/R.   
29#B          LINKSET  2,GVFN              [SET PCA LINK TO K1OPCA  
29S2          MONEND                       [CLEAR UP IF MR ELSE CLEAR STOP BIT  
2=?L          COOR1X
2=R=    PUCTP                              [SUBROUTINE TO SWITCH FROM PUC TO TP 
2?=W          TESTPUC  2,PUC
2?QG    NPUC  EXIT  7  0                   [RETURN IF NON PUC OR TP WD31 Z. 
2#=6    PUC   FINDTP   2,3  
2#PQ          MACCS    ,3,1 
2*9B          LDX   0  31(1)               [TP WD 31.   
2*P2          BZE   0  NPUC 
2B8L          LDX   0  ANM(2)   
2BN=          ANDN  0  3
2C7W          SLL   0  6                   [SET BS 16/17 OF TP WD 31
2CMG          ORS   0  31(1)               [TO CURRENT PUC MEMBER NO.   
2D76          LDCT  1  #600 
2DLQ          ADX   1  2
2F6B          LDCH  5  ALMT(1)             [PICK UP PUC MODES   
2FL2          SRC   5  8
2G5L          MACCS    ,2,1 
2GK=          LDX   0  GMSK1
2H4W          ANDS  0  9(1) 
2HJG          ORS   5  9(1)                [SET PUC WD 9,BS 2/4,TO PUC MODES
2J46          LDX   0  ASTOP(2) 
2JHQ          ANDX  0  GMSK2
2K3B          ADN   0  #1000               [CLEAR B14 OF TP STOP WD.
2KH2          ERS   0  ASTOP(2) 
2L2L          SBN   0  #2000               [SET B14 OF PUC STOP WD.AND  
2LG=          ADS   0  ASTOP(3)            [TRANSFER TP STOP WD TO PUC STOP WD  
2L^W          RINGTP   FX2                 [ENRING TP,DERING PUC.   
2MFG          EXIT  7  0
2M^6    # THE NEXT SECTION SERVICES THE MONEND MACRO.ENTER WITH X2-> PCA
2NDQ    #   
2NYB          LABFIX   HNMON
2PD2    NMON  LDX   1  AMON(2)  
2PXL          BNG   1  NM1                 [J IF MONRESUME IN PROGRESS  
2QC=          NGNC  1  1
2QWW          ANDS  1  ASTOP(2)            [CLEAR STOP BIT  
2RBG          EXIT  0  0                   [ AND RETURN 
2RW6    NM1   STO   0  GEN0 
2S*Q          LINKSET  2,GMND   
2STB          TXU   2  FX2  
2T*2          TRANSFIX BCC,FZCO            [IF IN PCA -> CHCH   
2TSL          FPUT                         [ELSE SET PCA GOING  
2W#=          BRN      (GEN0)              [ AND EXIT TO CALL   
2WRW    #END
^^^^ ...76467475000100000000
</code>