{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: EVENTS864)}}
====== EVENTS864 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BBUS|BBUS]], [[george:macro:BSON|BSON]], [[george:macro:CAPCA|CAPCA]], [[george:macro:FINDJOBQ|FINDJOBQ]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FJOPCA|FJOPCA]], [[george:macro:FPCACA|FPCACA]], [[george:macro:FPCAJO|FPCAJO]], [[george:macro:FSHSKIP|FSHSKIP]], [[george:macro:GMTUPDATE|GMTUPDATE]], [[george:macro:HLSINFORM|HLSINFORM]], [[george:macro:HLSINFRT|HLSINFRT]], [[george:macro:HUNTW|HUNTW]], [[george:macro:ILLEGAL|ILLEGAL]], [[george:macro:INFORM|INFORM]], [[george:macro:JBC|JBC]], [[george:macro:JBCC|JBCC]], [[george:macro:JBS|JBS]], [[george:macro:JMBAC|JMBAC]], [[george:macro:LINK|LINK]], [[george:macro:MBC|MBC]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MONOUT|MONOUT]], [[george:macro:OUTBLOCK|OUTBLOCK]], [[george:macro:OUTNULL|OUTNULL]], [[george:macro:OUTPAR|OUTPAR]], [[george:macro:PERCOUNT|PERCOUNT]], [[george:macro:PROGBRKIN|PROGBRKIN]], [[george:macro:PROGEND|PROGEND]], [[george:macro:PROGRING|PROGRING]], [[george:macro:RUNPROG|RUNPROG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETBIT|SETBIT]], [[george:macro:SUICIDE|SUICIDE]], [[george:macro:UNPLUG|UNPLUG]], [[george:macro:UP|UP]]
22FL ...#SEG EVENTS [OWEN N JOHN :CENT
22^= #OPT K0EVENTS=0
23DW #LIS K0EVENTS>K0ALLGEO>K0LLS
23YG 8HEVENTS
24D6 #
24XQ # THIS SEGMENT DEALS WITH CERTAIN GEORGE INITIATED PROGRAM EVENTS
25CB # AND CERTAIN UPDATES AND MESSAGE OUTPUT FOR BLANKET
25X2 #
26BL # THE ENTRY POINTS ARE AS FOLLOWS:
26W= #
27*W # K1: THE TICKLER MACRO FOR A SPECIFIED MEMBER
27TG # K2: THE TICKLER MACRO FOR ALL MEMBERS
28*6 # K3: UPDATES AND MESSAGE OUTPUT FOR BLANKET
28SQ # K4: PCA ENTRY FOR GEORGE INITIATED EVENTS
29#B # K5: ENTRY AFTER UNPLUG FOR PROGRAM TIMEUP
29S2 #
2=?L SEGENTRY K1EVENTS,XX1E
2=R= SEGENTRY K2EVENTS,XX2E
2?=W SEGENTRY K3EVENTS,XX3E
2?QG SEGENTRY K4EVENTS,XX4E
2#=6 SEGENTRY K5EVENTS,XX5E
2#C# ... SEGENTRY K7EVENTS,XX7E
2#JG ...XLINK LINK EVENTS,7
2#PQ #
2*9B #
2*P2 THOU +1000
2B8L #
2BN= # PCA ENTERS HERE FOR GEORGE INITIATED EVENT
2C7W # I.E. ON-LINE PERI FAIL, PROGRAM TIMEUP, BREAKIN, JOBTIMEUP
2CMG #
2D76 XX4E
2DLQ UNPLUG 1 [NO WORDS ADJ IF PER FAIL OR PROGRAM
2F6B CAPCA [CHANGE TO CPA
2FL2 FPCACA 3,2
2G5L JBC QJ,3,ASTOPBIN
2GK= PROGBRKIN
2H4W QJ
2H#N ... JBCC QG,3,ASTOPJOB
2HJG ... HUNTW 3,COMDAT,CJTEX
2HS# ... BPZ 3 QG [J IF WE JTEX SET
2J46 FJOCA 3,2
2JHQ JBC QH,3,JBOFFL [J IF MOP
2K3B SPRIVJUM JSISSUE+JSSTART,3,QH [J IF SYS JOB
2KH2 [ISSUED/STARTED
2L2L QG PROGEND [RETURN TO COMMAND PROCESSOR
2LG= [WHICH WILL NOTICE JOBTIME UP,IF THAT
2L^W [WAS INDEED THE EVENT,WHEN
2MFG [CHARGING FOR THE ENTER COMMAND AND
2M^6 [DEAL WITH IT
2NDQ QH LDX 4 JOBTIME
2NYB MPY 4 THOU(1)
2PD2 ADSC 5 ATIMEJ+1(3)
2PXL ADS 4 ATIMEJ(3)
2QC= MONOUT JOBTEX
2QWW ... HLSINFORM QH1,JOBTIME,JOBNO(2)
2R2R ... JBS QH1,2,CXTFULSTART [J IF LEFT FS
2R32 ...
2R39 ... [THE NEXT FEW LINES CLEAR B9385, WHEREBY THERE WAS NO CHECK
2R3D ... [THAT THE HLS WAS INVOLVED IN FULLY STARTING JOBS
2R3M ...
2R3W ... JBC NOFFL,3,JBOFFL [J IF MOP
2R45 ... JBC QH1,,HLSBFS [J IF HLS NOT FSTARTING BACKGRND JOBS
2R4# ... BRN SHLS
2R4H ...NOFFL
2R4Q ... JBC QH1,,HLSMFS [J IF HLS NOT FSTARTING MOP JOBS
2R4^ ...SHLS
2R5B ... HLSINFORM SAVEABLE,FSTART,,,,,XLINK(1)
2R7^ ...XX7E
2R=K ... HLSINFRT QH1,FSTART
2RBG ...QH1
2RW6 RUNPROG [RESTART
2S*Q [FOR THE ENTER COMMAND AND DEAL WITH
2STB #
2T*2 # ENTERED HERE FROM UNPLUG IF PROGRAM TIMEUP
2TSL #
2W#= XX5E
2WRW ILLEGAL TIMEUP
2X?G #
2XR6 #
2Y=Q # THE ACTCDT ACTIVITY ENTERS HERE TO ASSEMBLE THE NECESSARY DA
2YQB # MESSAGE WHICH IS TO BE SENT TO THE OPERATORS CONSOLE. ON ENTRY, B0
2^=2 # OF X7 INDICATE RESPECTIVELY WHETHER DATE AND/OR TIME IS TO BE OUTP
2^PL # OBEYS CONSOUT MACRO TO SEND THE MESSAGE, THEN COMMITS SUICIDE.
329= #
32NW #
338G XX3E
33*N ... BBUS 23,4,TD11E
33GW ...[
33N4 ...[ THIS CURES B3208 WHEREBY IF EVENTS HAS TO WAIT CHARGESC MAY
33T= ...[ GET IT TO OP "SYS CAN NOW MEET ..." TWICE
342D ...[ DONE 11TH JULY 75 :CENT
347L ...[
34#S ... JMBAC TD11E,,ASWOQMISS,ASWREALBAD
34G2 ...[
34MB MBC ,ASWOQMISS,ASWREALBAD
3572 MONOUT CANQUOT [OUTPUT ALL CLEAR
35LL TD11E
35WD ... BSON EMSBIT,TD11D [CAN'T UPDATE GMT DURING BMAP
366= BBUS 22,4,TD11D
36KW GMTUPDATE
375G TD11D
37K6 BBUS 20,4,TD11C
37Q# ... FSHSKIP B,XFSHNB2400
37XG ...(
384Q OUTPAR DATENOW
38JB MONOUT JDCHAN
38PJ ...XFSHNB2400
38WQ ...)
3942 TD11C
39?S ... BSON EMSBIT,TD11A [OMIT PERCOUNT - IP'S NOT SETUP
39HL ... BBUS 21,4,TD11A
3=3= PERCOUNT ALL
3=GW TD11A
3?2G BNG 4 ND11
3?G6 BBUS 12,4,TD11B [JUMP IF NO DATE/TIME TO BE OUTPUT
3?^Q ND11
3#FB LDN 5 4
3#^2 BPZ 4 ND1 [J NO DATE TO O/P
3*DL LDN 5 7
3*Y= ND1 OUTBLOCK 5
3BCW BPZ 4 TD7
3BXG BBUS 12,4,TD8
3CC6 TD7 OUTPAR TIMENOW
3CWQ BNG 4 TD9
3DBB BRN TD10
3DW2 TD8 OUTNULL
3F*L TD9 OUTPAR DATENOW
3FT= BRN TD11
3G#W TD10 OUTNULL
3GSG TD11 INFORM 3,JTIMD,0
3H#6 BPZ 4 TD11B
3HHY ... BSON EMSBIT,TD11B [CAN'T O/P REMOTELY IN EMS
3HRQ ACROSS IPBOUT,5
3J?B TD11B
3JR2 SUICIDE
3K=L #
3KQ= # THE TWO FOLLOWING ENTRY POINTS ARE USED BY THE TICKLE MACRO. ENTRY IS
3L9W # AT K1EVENTS WHEN A SPECIFIC MEMBER IS TO BE TICKLED, K2EVENTS
3LPG # WHEN ALL MEMBERS ARE TO BE TICKLED.FOR ANY MEMBER TO BE TICKLED,
3M96 # IF IT IS ACTIVE,OR THE SMP BIT IS CLEAR,THEN THE P BIT WILL BE SET
3MNQ # OTHERWISE THE SMP BIT WILL BE CLEARED.
3N8B # ON ENTRY THE JOB NUMBER WILL BE IN ACOMMUNE2, AND WHEN ENTRY IS AT
3NN2 # K1EVENTS, THE MEMBER NUMBER IN ACOMMUNE1
3P7L #
3PM= XX2E
3Q6W LDN 4 4 [COUNT OF MEMBERS
3QLG LDN 3 AFW1
3R66 BRN XJOIN
3RKQ XX1E
3S5B LDN 3 AFW2-AFW1
3SK2 MPY 3 ACOMMUNE1(2) [MULTIPLY BY MEMBER NUMBER
3SXC ... LDX 3 4
3T9S ... ADN 3 AFW1 [X3=MEL (CORRECTS B2623)
3TJ= LDN 4 1 [NUMBER OF MEMBERS
3W3W XJOIN
3WHG FINDJOBQ 1,ACOMMUNE2(2),(GEOERR)
3WNN ... LDEX 0 JMISC(1) [J IF JOB HAS NO CORE IMAGE
3WTW ... BZE 0 UP [ AS TICKLER HAS NULL EFFECT
3X36 FPCAJO 2,1 [X2 ->PCA
3XGQ ADX 3 2 [X3 -> MEL
3Y2B TOUR LDXC 0 ASU(3)
3YG2 BCS PEND [J IF MEMBER NOT ESTABLISHED
3Y^L BZE 0 SETP [J IF MEMBER ACTIVE
3^F= BBUS 3,ASU(3),SETP
3^YW LDX 0 HSMPBIT
42DG ANDS 0 ASU(3) [MUST BE CLEARED LIKE THIS AS EXEC CA
42Y6 BRN PEND
433K ...SETP SETBIT 16,ARM(3) [SET REMEMBRANCE
4374 ...[
43=H ...[ THE FOLLOWING CURES B3241 - VIZ SMP MUST BE CLEARED
43B2 ...[ AFTER P-FLAG SET !
43FF ...[
43JY ... LDX 0 HSMPBIT
43NC ... ANDS 0 ASU(3)
43RW ...[
43XB PEND ADN 3 AFW2-AFW1 [INCREMENT PTR
44C2 BCT 4 TOUR [BACKAGAIN IF NECESSARY
44WL TFIN
45B= FJOPCA 2
45TW JBC UP,2,JBREPRI
46*G PROGRING LOCKOFF
46T6 UP UP
47#Q #SKI K6ALLGEO
47SB MENDAREA 50,K100EVENTS
48#2 #END
^^^^ ...225413100003