{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: EXMESS70)}}
====== EXMESS70 ======
(George Source)
**Macros used:** [[george:macro:ALTLEN|ALTLEN]], [[george:macro:FREECORE|FREECORE]], [[george:macro:HUNTW|HUNTW]], [[george:macro:INFORMX|INFORMX]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUTX|MONOUTX]], [[george:macro:OUTBLOCK|OUTBLOCK]], [[george:macro:OUTNULL|OUTNULL]], [[george:macro:OUTNUM|OUTNUM]], [[george:macro:OUTPARAM|OUTPARAM]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:UP|UP]]
22FL #SEG EXMESS70 [JOHN BAILEY
22^= #LIS K0EXMESS
23DW 8HEXMESS
23YG #
24D6 SEGENTRY K1EXMESS,QK1EXMESS
24XQ SEGENTRY K2EXMESS,QK2EXMESS
25CB SEGENTRY K3EXMESS,QK3EXMESS
25X2 #
26BL QK1EXMESS
26W= HUNTW 3,EWDAS,EWMESS
27*W BPZ 3 Z1 [JUMP IF ALREADY A EWMESS
27TG SETNCORE BMSTART-A1+12,3,EWDAS,EWMESS
28*6 LDN 4 BMSTART
28SQ STO 4 A1(3) [SET POINTER
29#B Z1 LDN 4 ACOMMUNE7(2)
29S2 LDX 5 A1(3)
2=?L ADX 5 3
2=R= MOVE 4 3 [MOVE MESSAGE TO EWMESS BLOCK
2?=W LDN 5 3
2?QG ADS 5 A1(3) [UPDATE POINTER
2#=6 LDX 5 A1(3)
2#PQ SBN 5 A1
2*9B TXU 5 ALOGLEN(3) [ROOM FOR ANOTHER MESSAGE?
2*P2 BCS Z2 [JUMP IF YES
2B8L ADN 5 12
2BN= ALTLEN 3,5,EWDAS,EWMESS [LENGTHEN BLOCK BY 12 WORDS
2C7W Z2 UP
2CMG QK2EXMESS
2D76 NGNC 4 1 [IGNORE OPTIONAL MESSAGES
2DLQ QK3EXMESS
2F6B LDN 4 0 [OUTPUT ALL MESSAGES
2FL2 MHUNTW 1,EWDAS,EWMESS
2G5L LDN 3 BMSTART
2GK= Z10 TXU 3 A1(1) [ANY MORE MESSAGES?
2H4W BCS Z3
2HJG FREECORE 1 [FREE EWMESS BLOCK
2J46 UP
2JHQ Z3 SMO 3
2K3B LDXC 5 0(1) [MESSAGE IDENTIFIER
2KH2 BCC Z4 [JUMP IF NOT OPTIONAL
2L2L BNZ 4 Z5 [IGNORE MESSAGE IF FROM K2EXMESS
2LG= Z4 SMO 3
2L^W LDX 6 1(1) [SERIAL NO
2MFG SMO 3
2M^6 LDX 7 2(1) [BLOCK NO
2NDQ BNG 6 Z9 [BRANCH IF NULL
2NYB BNZ 6 Z7 [BRANCH IF EXISTANT
2PD2 BNG 7 Z8 [BOTH NON-EXISTANT
2PXL BRN Z9 [ONLY ONE NON-EXISTANT
2QC= Z7 LDN 0 6
2QWW LDN 2 BSER(1) [CONVERT...
2RBG SLL 6 3 [...SERIAL...
2RW6 Z11 SLC 6 6 [...NUMBER...
2S*Q DCH 6 0(2) [...TO OCTAL
2STB BCHX 2 £
2T*2 SRL 6 3
2TSL BCT 0 Z11
2W#= LDN 6 1 [RESET X6 AS MARKER
2WRW Z9 LDN 0 5
2X?G OUTBLOCK [CREATE PARAMETER BLOCK
2XR6 BNG 6 Z20 [NULL
2Y=Q BZE 6 Z13 [NON EXISTANT
2YQB LDN 0 6
2^=2 OUTPARAM 0,BSER,EWDAS,EWMESS [SERIAL NO TO PARAMETER BLOCK
2^PL Z13 BNG 7 Z8 [NON-EXISTANT
329= OUTNUM 7,0 [BLOCK NO. TO PARAMETER BLOCK
32NW Z8 LDCT 0 128
338G ANDX 0 5 [ISOLATE BIT 1
33N6 ANDX 5 BITS22LS
347Q BZE 0 Z21 [BRANCH IF TO MONITORING FILE ONLY
34MB LDN 7 1
3572 INFORMX 7,5,1 [MESSAGE TO OPS CONSOLE
35LL BRN Z22
366= Z21 MONOUTX 5
36KW Z22 HUNTW 1,EWDAS,EWMESS [REFIND EWMESS BLOCK
375G Z5 ADN 3 3 [NEXT RECORD
37K6 BRN Z10
384Q Z20 OUTNULL [NULL PARAMETER
38JB BRN Z13
3942 #END
^^^^ ...15030261000100000000