{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: FLAW866)}}
====== FLAW866 ======
(George Source)
**Macros used:** [[george:macro:BACKTRAN|BACKTRAN]], [[george:macro:BADBLOCK|BADBLOCK]], [[george:macro:CHTRANX|CHTRANX]], [[george:macro:CONVERT|CONVERT]], [[george:macro:DECANTCT|DECANTCT]], [[george:macro:ERASEX|ERASEX]], [[george:macro:FREECORE|FREECORE]], [[george:macro:JPROP|JPROP]], [[george:macro:KEEPMESS|KEEPMESS]], [[george:macro:KEEPREP|KEEPREP]], [[george:macro:LFAILS|LFAILS]], [[george:macro:LOCKC|LOCKC]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFINDSU|MFINDSU]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:PLOGGING|PLOGGING]], [[george:macro:PUTREP|PUTREP]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:TPLOCKSU|TPLOCKSU]], [[george:macro:TRACE|TRACE]], [[george:macro:UNLOCKSU|UNLOCKSU]], [[george:macro:UP|UP]]
22FL ... SEG FLAW,84,FRANK BLUNDELL,FLAW
23YG #
24D6 SEGENTRY K1FLAW,QK1FLAW
24XQ #
25CB # THIS ROUTINE TAKES ACTION ON ALL FAILING TRANSFERS FROM PERION
25X2 # ENTRY POINT IS K1FLAW
26BL #
26W= TEWS +EWSCAF
27TG TEWI +EWINOP
28*6 TEDO +EWOWN
29#B TEWSC +EWSCFULL
29S2 ...TEWSN +EWSCNIL
2=?L TEWC +EWCHSUM
2?=W TEWL +EWLOST
2#=6 TEWF +EWFF
2*9B TEFL +EWFLAW
2B8L #SKI ENTWINE
2BN= TPRO +ENTIN41
2BQF ...#UNS ATRACK
2BSN ...(
2BWX ...TENO +EWNOALT [NO ALT TRACK
2B^6 ...TEALT +EWALT [ALT TRACK ALLOCATED
2C3* ...TEFAIL +EWALTFAIL [COULD NOT BE ALT TRACKED
2C5J ...)
2C7W Z
2CMG #TRA EDS+Z
2D76 +FLADDR
2DLQ #TRA EMDS+Z
2F6B +FLADDR
2FL2 #TRA EMCF+Z
2G5L +FLADDR
2GK= #TRA AFDS+Z
2H4W +FLADDR+64
2HJG #TRA BFDS+Z
2J46 +FLADDR+222
2JHQ #
2K3B #SKI AUTPAM
2KH2 #DEF TAC1=EWORK6
2L2L #SKI AUTPAM<1$1
2LG= #DEF TAC1=ACOMMUNE1
2L^W #DEF TAC2=TAC1+1
2MFG #DEF TAC3=TAC2+1
2M^6 #DEF TAC4=TAC3+1
2N6# ...RFIND MHUNTW 2,EWDAS,FLAWB [REFIND FLAWB FOR LOCKC
2N?G ... EXIT 1 0
2NDQ QK1FLAW
2NYB #SKIP K6FLAW
2PD2 TRACE EWORK3(2),FLAW?
2PMS ... STOZ AWORK3(2)
2PXL SMO 2
2QC= LDCH 0 EWORK4 [GET PERIPHERAL SUBTYPE
2QWW SMO 0
2RBG LDX 4 Z(1) [GET REQUIRED LENGTH OF EXFLAW BLOCK
2RW6 ... SETUPCORE 4,3,EWDAS,FLAWB,1 [SET UP FLAWB BLOCK
2S*Q ... LOCKC 3,RFIND [LOCK EXFLAW BLOCK
2SKJ ... MHUNTW 3,EWDAS,FLAWB
2STB MFINDSU 1,EWORK5(2) [FIND ASTUC
2SX# ... LDX 0 HUNIT(1) [PTR TO DEVICE LIST
2S^= ... STO 0 AWORK4(2)
2T38 ... LFAILS AWORK4(2),0 [IF COUNT = ZERO HEN
2T56 ... BZE 0 TNOFL [DONT DECREMENT
2T74 ... LDN 0 1
2T92 ... DECANTCT AWORK4(2),0,FAIL [SUBTRACT 1 FROM COUNT OF FAILS
2T=Y ...TNOFL
2T*2 LDX 0 HTYPE(1)
2TSL STO 0 FLTYPE(3) [TYPE/SUBTYPE TO EXFLAW
2W#= LDX 0 ASUBASE(1)
2WRW STO 0 FLBASE(3) [START CYLINDER OF SU
2X?G LDX 0 HBLOCK(1)
2XR6 STO 0 FLDEP(3) [SEGMENTS/CYLINDER
2Y=Q LDX 0 HFLAW(1)
2YQB STO 0 FLSTART(3) [POINTER TO FIRST FLAW INDEX
2^2L ...#UNSET JSKI34
2^3M ...(
2^4N ... LDX 5 TAC3(2) [ COUNT OF WORDS IN TRANSFER
2^5P ... STO 5 FLBS2(3)
2^6Q ... LDX 5 EWORK3(2) [ START BLK. ADDR. OF TRANSFER
2^7R ... CALL 7 XPLOG [ WAIT FOR TRANSFER TO BE LOGGED
2^8S ...)
2^98 ...#UNS ATRACK
2^9J ... JPROP AWORK4(2),X30BT,X30BT,X30BT,X20BT,X20BT
2^=2 LDN 0 128
2^PL STO 0 FLBS2(3) [LENGTH FOR BACKTRAN
329= LDN 0 FLBUFF(3)
32NW STO 0 FLBS3(3) [BUFFER ADDRESS FOR BACKTRAN
338G LDX 5 TAC3(2)
33N6 DVS 4 FLBS2(3) [CALCULATE NO.OF TRANSFERS
347Q LDX 6 EWORK3(2) [START BLOCK NUMBER
34MB LDX 0 TAC4(2)
3572 ADX 0 TAC3(2) [X0=FINISHING CORE ADDRESS
35LL SBN 6 1
366= BNZ 4 T1 [BRANCH IF ODD WORDS IN TRANSFER
36KW LDN 4 128
375G BRN T2
37K6 T1 ADN 5 1 [X5=NUMBER OF TRANSFERS
384Q T2 SBX 0 4 [START ADDRESS OF LAST BLOCK...
38JB STO 0 FLCORE(3) [...AS CURRENT CORE ADDRESS
3942 ADX 6 5 [X6=CURRENT BLOCK NUMBER
39HL T3 STO 6 FLBLOCK(3)
3=3= STO 6 FLBS4(3) [CURRENT BLOCK NO.
3=GW STO 5 FBLCNT(3) [COUNT OF NUMBER OF BLOCKS
3?2G STO 4 FLTRANCT(3) [LENGTH OF TRANSFER
3?G6 CALL 0 TRANSFER1
3?^Q BRN TOBER [ERROR IN TRANSFER
3#FB TD LDX 5 FBLCNT(3)
3#^2 SBN 5 1 [NUMBER OF BLOCKS LEFT IN TRANSFER
3*DL BZE 5 T4 [BRANCH IF NO MORE TRANSFERS
3*Y= LDN 4 128
3BCW SBS 4 FLCORE(3) [CURRENT CORE ADDRESS
3BXG LDX 6 FLBLOCK(3)
3CC6 SBN 6 1 [SUBTRACT ONE FROM BLOCK NUMBER
3CWQ BRN T3
3DBB T4 KEEPREP 5,OK [REPLY OK
3DW2 BRN TZB
3F*L TRANSFER3
3FT= LDN 5 FLBUFF(3)
3G#W SUM 4 128
3GSG SBS 4 FLBUFF+1(3) [CHECKSUM FLAW INDEX
3H#6 LDX 4 FLBUFF(3)
3HRQ STO 4 FLBS4(3) [INDEX HOME
3J?B NGNC 4 1
3JR2 TRANSFER2
3K=L LDN 4 0
3KQ= STO 4 FLBS1(3) [STORE MODE IN BACKTRAN C/A
3L9W NGNC 4 1
3LPG TRANSFER1
3M96 LDN 4 0 [X4 NON ZERO IF SYSTEM REQUEST
3MNQ SBX 0 FX1 [REMEMBER LINK AFTER DATUMISING
3N8B STO 0 7
3NN2 LDX 1 FLBS4(3)
3P7L STO 1 AWORK1(2) [REMEMBER BLOCK NO.
3PM= CONVERT FLBS4(3),FLTYPE(3),FLBASE(3),FLDEP(3)
3Q6W LDX 2 FX2
3QLG BZE 4 TSYST [BRANCH IF NON SYSTEM REQUEST
3R66 #DEF Q=TAC1
3RKQ #DEF R=TAC2
3S5B #DEF S=FLBS4
3SK2 #DEF T=APETADDR
3T4L #DEF V=FLTRANCT
3TJ= BACKTRAN FLBS1(3),BSET+BONL+FLAW,FLBS2(3),,R(2),S(3),FLBS3(3)
3W3W TCHEK ADX 7 FX1
3WHG CHTRANX FLTYPE(3),TFAIL,TSPFAL,TINOP
3X36 BNZ 4 TEX0
3XGQ ADN 7 1
3Y2B TEX0 EXIT 7 0
3YG2 TSYST BACKTRAN Q(2),BSET+BONL+BOBJ+FLAW,V(3),,R(2),S(3),FLCORE(3),T(2)
3Y^L BRN TCHEK
3^7W ...TFAIL
3^B6 ... LDCH 5 ACOMMUNE9(2) [TOPCHAR OF FAILED REPLY
3^JB ... STO 5 AWORK3(2) [AND PRESERVE IT
3^QL ... BZE 4 TEX0
3^YW KEEPMESS TEWS(1),EWORK5(2),AWORK1(2) [SCA FAIL
42DG BRN TC
42Y6 TINOP KEEPMESS TEWI(1),EWORK5(2) [SU INOP
43CQ BNZ 4 TC [J IF SYSTEM REQUEST
43XB KEEPREP 5,EXFAIL
44C2 BRN TZB
44WL BRN TC
45B= TSPFAL
45TW KEEPMESS TEDO(1),EWORK5(2),AWORK1(2) [SU FAIL
46*G TC KEEPREP 5,EXFAIL
46DL ...#UNS IPBD
46HQ ...TB UNLOCKSU EWORK5(2)
46LW ...#UNS IPBD
46Q2 ...#SKI
46T6 TB TPUNLOCKSU EWORK5(2)
47#Q TZB BADBLOCK TAC2(2)
47SB TK FREECORE 3 [FREE FLAWB BLOCK
48#2 PUTREP 5
48RL UP
48XH ...TE
493D ... SBX 7 AWORK2(2)
497* ... BZE 7 TEA [J IF FLAW INDEX IS EMPTY
49?= ... KEEPMESS TEWSC(1),EWORK5(2) [FLAW AREA FULL
49C7 ... BRN TEB
49H4 ...TEA KEEPMESS TEWSN(1),EWORK5(2),FLBLOCK(3) [BLOCK FAIL EMPTY F.I.
49L^ ...TEB
49QW KEEPREP 5,ACAFULL
4==G BRN TB
4=Q6 TOBER
4?9Q #SKI ENTWINE
4?PB TPLOCKSU EWORK5(2),TLINK
4?^8 ... LDX 6 FLSTART(3)
4#92 #SKIP K6FLAW>99-99
4#NL TRACE AWORK1(2),FLAW!
4*8= T5 DVS 5 FLBS2(3) [CALCULATE BLOCK ADDRESS OF...
4*MW STO 6 FLBS4(3) [...FIRST FLAW INDEX
4B7G STO 5 AWORK2(2) [REMEMBER WORD ADDRESS
4BM6 CALL 0 TRANSFER2 [READ FLAW INDEX
4C6Q TXU 6 FLBUFF(3)
4CLB BCC T8 [CHECK CORRECT BLOCK
4D62 T6 KEEPMESS TEWC(1),EWORK5(2),6 [CHECKSUM FAIL
4DKL BRN TC
4F5= T8 LDX 5 FLBUFF+1(3)
4FJW BZE 5 T9 [NO CHECKSUM
4G4G LDN 5 FLBUFF(3)
4GJ6 SUM 4 128 [CHECK CORRECT CHECKSUM
4H3Q BNZ 4 T6
4HHB T9 NGN 7 1
4J32 ADX 7 AWORK2(2)
4JGL TTRY ADN 7 1 [MODIFIER TO NEXT CELL
4K2= SMO 7
4KFW LDX 4 FLBUFF+2(3) [CONTENTS OF NEXT CELL
4K^G TXU 4 FLBLOCK(3)
4LF6 BCC THERE [BLOCK ALREADY IN FLAW AREA
4LYQ BZE 4 TNOUS [BRANCH IF CELL UNUSED
4MDB ADN 4 1
4MY2 BNZ 4 TTRY [LOOK AT NEXT CELL
4NCL SMO AWORK2(2)
4NX= LDX 6 FLBUFF(3)
4PBW BNZ 6 T5 [ANY MORE INDEX'S
4PWG LDX 6 TAC1(2)
4QB6 BNZ 6 TE [BRANCH IF WRITE TRANSFER
4QTQ T7 KEEPMESS TEWL(1),EWORK5(2),FLBLOCK(3)[FLAW ENTRY NOT FOUND
4R*B BRN TC
4RT2 TNOUS LDX 6 TAC1(2)
4S#L BZE 6 T7 [BRANCH IF READ TRANSFER
4SCQ ... LDX 0 AWORK3(2)
4SGW ... ANDN 0 #14 [BITS 2 & 3 OF FAILED REPLY
4SL2 ... SBN 0 #14 [ARE BOTH BITS SET
4SP6 ... BZE 0 T7 [J IF SO - SEEK ERROR
4SS= ERASEX TC [ERASE FAILING BLOCK
4T?W KEEPMESS TEFL(1),EWORK5(2),FLBLOCK(3)[BLOCK FLAWED
4TRG LDN 5 0 [REMEMBER TO WRITE AWAY FLAW INDEX
4W?6 LDX 6 FLBLOCK(3)
4WQQ SMO 7
4X=B STO 6 FLBUFF+2(3) [STORE BLOCK NUMBER IN CELL
4XB? ... BRN TFLAW
4XG8 ...THERE
4XL5 ... LFAILS AWORK4(2),0 [JUMP IF FAIL
4XQ2 ... BZE 0 TFLAW [COUNT= ZERO
4XTX ... LDN 0 1
4X^S ... DECANTCT AWORK4(2),0,FAIL [SUBTRACT 1 FROM COUNT OF FAILS
4Y5P ...TFLAW STO 7 FLPOINT(3) [REMEMBER CELL POINTER
4Y9L SBX 7 AWORK2(2)
4YP= SMO AWORK2(2)
4^8W ADX 7 FLBUFF+1(3)
4^NG STO 7 FLBS4(3) [STORE ADDRESS OF FLAW AREA
5286 #SKIP K6FLAW>99-99
52MQ TRACE TAC1(2),ININDEX
537B CALL 0 TRANSFER1 [REWRITE OBJ.TRANSFER TO FLAW AREA
53M2 BRN TAGAN [ERRED AGAIN
546L BNZ 5 TDA [BRANCH IF FLAW INDEX UNCHARGED
5483 ...#UNSET JSKI34
549D ...(
54=T ... LDX 5 6 [ BLK. NUM. OF FAILED TRANSFER
54#= ... CALL 7 XPLOG [ WAIT FOR INCIDENT TO GE LOGGED
54*M ...)
54L= CALL 0 TRANSFER3 [WRITE AWAY FLAW INDEX
54PB ...#UNS IPBD
54SG ...TDA UNLOCKSU EWORK5(2)
54XL ...#UNS IPBD
552Q ...#SKI
555W TDA TPUNLOCKSU EWORK5(2)
55KG BRN TD
5656 TLINK KEEPMESS TPRO(1),EWORK5(2) [PROCESSOR FAIL
56JQ KEEPREP 5,EXFAIL
574B BRN TK
57J2 ...TAGAN KEEPMESS TEWF(1),EWORK5(2),AWORK1(2) [FLAW BLOCK FAIL
583L LDX 7 AWORK1(2) [GET ADDRESS OF FLAW AREA
58H= SMO FLPOINT(3) [RESET CELL,POINTER TOH..
592W STO 7 FLBUFF+2(3) [...POINT TO FLAW BLOCK
598G ...#UNSET JSKI34
599X ...(
59?# ... LDX 5 7 [ BLK. NUM. OF FAILED FLAW AREA BLK
59#P ... CALL 7 XPLOG [ WAIT FOR INCIDENT TO BE LOGGED
59B6 ...)
59GG CALL 0 TRANSFER3 [WRITE AWAY FLAW INDEX
5=26 LDX 7 FLPOINT(3) [X7=MODIFIER TO LIST OF CELLS
5=FQ BRN TTRY
5=^B #
5=^F ...#UNS ATRACK
5=^J ...(
5=^M ...#
5=^Q ...# CODE TO DEAL WITH 2900 TYPE DISCS
5=^T ...# REPEATS BY TRACK RATHER THAN BLOCK TRANSFERS
5=^Y ...# X7 HOLDS NO OF BLKS/TRACK
5?23 ...#
5?26 ...X30BT LDN 7 30
5?29 ... BRN XD1
5?2# ...X20BT LDN 7 20
5?2C ...XD1 LDX 5 EWORK3(2) [START BLK OF OBJ PROG TRANSFER
5?2G ... STO 5 FLBS4(3)
5?2K ... STO 5 FLBLOCK(3)
5?2N ... DVS 4 FLDEP(3) [DIVIDED BY BLKS/CYL
5?2R ... STO 5 FLERB(3) [LEAVES CYL NO IN X5
5?2W ... STO 4 FLERASE(3) [AND BLK WITHIN CYL IN X4
5?2^ ... LDX 5 4
5?34 ... DVS 4 7 [DIVIDED BY BLKS/TRK LEAVES TRK NO
5?37 ... STO 4 FLSTART(3) [IN X5 AND BLK WITHIN TRK IN X4
5?3= ... LDN 0 128
5?3* ... LDX 5 TAC3(2) [NO OF WDS IN TRANSFER DIVIDED BY 128
5?3D ... DVS 4 0 [AND ROUNDED UP TO GIVE
5?3H ... BZE 4 XD2 [NO OF BLKS IN TRANSFER IN X5
5?3L ... ADN 5 1
5?3P ...XD2 STO 5 FLPOINT(3) [STORE FOR 1 TRACK CASE
5?3S ... ADX 5 FLSTART(3) [NO OF BLKS IN TRANSFER + BLK WITHIN
5?3X ... DVS 4 7 [TRK DIVIDED BY BLKS/TRK
5?42 ... BZE 5 XONE [^ IF ONLY 1 PART TRACK INVOLVED
5?45 ... BNZ 4 XD2A [CATER FOR CASE WHERE
5?48 ... SBN 5 1 [1 PART TRACK ENDING ON
5?4? ... BZE 5 XONE [TRACK BDY
5?4B ...#
5?4F ...# IF >1 TRACK INVOLVED THEN TRANSFER MUST BE REPEATED
5?4J ...# ON A TRACK (OR PART TRACK) BY TRACK BASIS
5?4M ...#
5?4Q ...# FIRST INITIALISE FBLCNT = NO OF BLKS TO BE TRANSFERRED
5?4T ...# FLCORE = TOP OF BUFFER ADDRESS
5?4Y ...#
5?53 ...XD2A LDX 6 TAC3(2) [NO OF WDS IN OBJ PROG TRANSFER
5?56 ... LDN 0 128
5?59 ... DVS 5 0
5?5# ... BZE 5 XD3 [^ IF INTEGRAL NO OF BLKS
5?5C ... ADN 6 1
5?5G ...XD3 STO 6 FBLCNT(3) [NO OF BLKS TO BE TRANSFERRED
5?5K ... LDX 6 5 [PRESERVE ODD NO OF WDS
5?5N ... LDX 0 TAC4(2) [START BUFFER ADDRESS
5?5R ... ADX 0 TAC3(2) [+ NO OF WDS TO BE TRANSFERRED
5?5W ... STO 0 FLCORE(3) [TOP OF BUFFER ADDRESS
5?5^ ...#
5?64 ...# LOOP FOR REPEAT TRANSFERS
5?67 ...#
5?6= ...# FIRST WORK OUT NO OF WDS TO BE TRANSFERRED
5?6* ...#
5?6D ...XLOOP LDX 5 FLERASE(3) [START BLK WITHIN CYL OF OBJ TFER
5?6H ... ADX 5 FBLCNT(3) [+ NO OF BLFS STILL TO BE TRANSFERRED
5?6L ... DVS 4 7 [DIVIDED BY BLKS/TRK
5?6P ... BNZ 4 XL2 [^ IF NOT ENDING ON TRK BDY
5?6S ... LDX 0 7
5?6X ... SBX 0 FBLCNT(3)
5?72 ... BNG 0 XL1 [^ IF >1 TRACK STILL TO TRANSFER
5?75 ... LDX 4 FBLCNT(3) [TRANSFER REMAINING BLKS
5?78 ... BRN XL2
5?7? ...XL1 LDX 4 7 [OR 1 COMPLETE TRACK
5?7B ...XL2 STO 4 FLPOINT(3) [NO OF BLKS IN THIS TRANSFER
5?7F ... LDN 0 128
5?7J ... MPY 4 0
5?7M ... BZE 6 XL3 [^ IF NOT ODD NO OF WDS IN TRANSFER
5?7Q ... SBN 5 128 [OTHERWISE REDUCE WD CT
5?7T ... ADX 5 6 [ACCORDINGLY
5?7Y ...XL3 STO 5 FLTRANCT(3) [CT OF WDS TO BE TRANSFERRED
5?83 ...#
5?86 ...# NOW STORE CORE ADDRESS
5?89 ...#
5?8# ... SBS 5 FLCORE(3)
5?8C ...#
5?8G ...# NOW WORK OUT START BLK NO AND UPDATE
5?8K ...# BLKS STILL TO BE TRANSFERRED AFTER THIS
5?8N ...#
5?8R ... LDX 4 FLPOINT(3) [NO OF BLKS IN THIS TRANSFER
5?8W ... SBS 4 FBLCNT(3)
5?8^ ... LDX 4 EWORK3(2)
5?94 ... ADX 4 FBLCNT(3)
5?97 ... STO 4 FLBS4(3)
5?9= ... STO 4 FLBLOCK(3) [START BLK OF THIS TRANSFER
5?9* ...#
5?9D ...# NOW DO THE TRANSFER
5?9H ...#
5?9L ...XL4 LDX 6 7 [PRESERVE BLKS/TRK
5?9P ... CALL 0 TRANSFER1
5?9S ... BRN XOBER [^ IF TRANSFER FAILED
5?9X ... LDX 7 6
5?=2 ...XL5 STOZ 6 [CANNOT BE ODD WDS AFTER 1ST TFER
5?=5 ... LDX 0 FBLCNT(3)
5?=8 ... BNZ 0 XLOOP [^ IF MORE BLKS TO TRANSFER
5?=? ... KEEPREP 5,OK [ALL REPEAT TRANSFERS OK
5?=B ... BRN TZB
5?=F ...#
5?=J ...# IF ORIGINAL TRANSFER TO BE REPEATED AS IT STOOD SET UP
5?=M ...# FLTRANCT AND FLCORE
5?=Q ...# FLBS4 AND FLBLOCK ALREADY SET UP
5?=T ...# ZEROISE FBLCNT TO INDICATE NO MORE BLKS TO TRANSFER
5?=Y ...#
5??3 ...XONE LDX 0 TAC3(2)
5??6 ... STO 0 FLTRANCT(3) [TRANSFER CT
5??9 ... LDX 0 TAC4(2)
5??# ... STO 0 FLCORE(3) [BUFFER ADDRESS
5??C ... STOZ FBLCNT(3)
5??G ... BRN XL4
5??K ...#
5??N ...# HERE IF TRANSFER FAILED
5??R ...#
5??W ...XOBER LDX 7 6 [RESTORE BLKS/TRK
5??X ... LDX 6 AWORK1(2)
5??Y ... STO 6 FLBS4(3) [RESTORE BLOCK NO
5??^ ... LDX 6 TAC1(2)
5?#4 ... BZE 6 XOB1 [^ IF READ
5?#7 ... LDX 0 AWORK3(2)
5?#= ... ANDN 0 #14
5?#* ... SBN 0 #14 [OR WRITE WITH SEEK ERROR AS NO
5?#D ... BZE 0 XOB1 [CORRECTIVE ACTION TO BE TAKEN
5?#H ... ERASEX XERF [OTHERWISE ERASE ALL BLKS IN TRANSFER
5?#L ...#
5?#P ...# IF ERASE SUCCESSFUL O/P MESSAGE AND DO NEXT REPEAT TRANSFER
5?#S ... KEEPMESS TEALT(1),EWORK5(2),FLBLOCK(3) [ALT TRACK ALLOCATED
5?#X ... BRN XL4
5?*2 ...#
5?*5 ...# IF ERASE FAILS O/P MESSAGE AND KEEP FAILED REPLY
5?*8 ...#
5?*? ...XERF KEEPMESS TEFAIL(1),EWORK5(2),FLBLOCK(3) [COULD NOT BE ALT TRKD
5?*B ... BRN XOB2
5?*F ...#
5?*J ...XOB1 KEEPMESS TENO(1),EWORK5(2),FLBLOCK(3) [NO ALT TRACK
5?*M ...XOB2 KEEPREP 5,EXFAIL
5?*Q ... BRN TZB
5?*T ...)
5?F2 #
5?NW ...#UNSET JSKI34
5?PD ...(
5?Q2 ...XPLOG SBX 7 FX1
5?QJ ... MFINDSU 1,EWORK5(2) [ PTR. TO ASTUC
5?R6 ... LDX 6 HUNIT(1) [%A FOR PLOGGING
5?RN ... DVS 4 FLDEP(3) [ X4=%C
5?S= ... SBX 5 ASUBASE(1) [X5=%B
5?SS ... PLOGGING 6,5,4,FLBS2(3) [ LOG INCIDENT
5?TB ... ADX 7 FX1
5?TY ... EXIT 7 0
5?WG ...#
5?X4 ...#
5?XL ...)
5?YL MENDAREA 20,K99FLAW
5#D= #END
^^^^ ...65775355000200000000