{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: FORMLOOP865)}}
====== FORMLOOP865 ======
(George Source)
**Macros used:** [[george:macro:AND|AND]], [[george:macro:BLOCKTRACE|BLOCKTRACE]], [[george:macro:CLOSE|CLOSE]], [[george:macro:DEMANDX|DEMANDX]], [[george:macro:DO|DO]], [[george:macro:ELSE|ELSE]], [[george:macro:ELSF|ELSF]], [[george:macro:ERRORX|ERRORX]], [[george:macro:FI|FI]], [[george:macro:GEOPACK|GEOPACK]], [[george:macro:HUNT|HUNT]], [[george:macro:HUNTW|HUNTW]], [[george:macro:IF|IF]], [[george:macro:INFORMX|INFORMX]], [[george:macro:LONGSET|LONGSET]], [[george:macro:MFREE|MFREE]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:NAME|NAME]], [[george:macro:OPEN|OPEN]], [[george:macro:OR|OR]], [[george:macro:OUTMESSX|OUTMESSX]], [[george:macro:OUTPARAM|OUTPARAM]], [[george:macro:OUTPARAX|OUTPARAX]], [[george:macro:OUTPER|OUTPER]], [[george:macro:REPEAT|REPEAT]], [[george:macro:RV|RV]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETREP|SETREP]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:STEP|STEP]], [[george:macro:STEPAGAIN|STEPAGAIN]], [[george:macro:THEN|THEN]], [[george:macro:TRACEVER|TRACEVER]], [[george:macro:UNNORM|UNNORM]], [[george:macro:UP|UP]], [[george:macro:VFREEW|VFREEW]], [[george:macro:WHILE|WHILE]], [[george:macro:WRONG|WRONG]]
22FL #OPT K0FORMLOOP = 0
22^= #LIS K0FORMLOOP
23DW #SEG FORMLOOP
23YG 8HFORMLOOP
24D6 [
24XQ SEGENTRY K1FORMLOOP,ZFORMLOOP1 [ ATTRIBUTE COMMAND
25CB SEGENTRY K2FORMLOOP,ZFORMLOOP2 [ SETPROP MACRO
25JJ ...#UNS FLLP4B
25PQ ... SEGENTRY K3FORMLOOP,ZFORMLOOP3 [ATTRIBUTE COMMAND (CENTRAL CASE)
25R4 ...[
25SB ...[ SEGMENT ENTRY POINTS K40,K41 USED BY LFSOFTDEFLT MACRO
25TN ...[
25TY ...[
25W8 ...[ SEGMENT ENTRY POINTS K50 - K57 ARE USED BY
25WD ...[ RESTORE TIME MACRO - LFDBAID
25WN ...[
25X2 #UNS FL7502B
26BL ...#SKI
26W= (
27*W ZFORMLOOP1
27TG ZFORMLOOP2
28*6 SETREP OK
28SQ UP
29#B )
29S2 #UNS FL7502B
2=?L (
2=R= [
2?=W [
2?QG [************************************************************
2#=6 [
2#PQ [ PRESET DATA
2*9B [
2*P2 [************************************************************
2B8L [
2BN= PFABSNB
2C7W 10
2CMG 12HFORMATLOOPS
2D76 12H
2DLQ 1
2F6B 0 [ LATEST GEN.
2FL2 0 [ ANY LANG.
2G5L PGRAPHIC #40000012 [ TYPE / MODE FOR GRAPHIC FILE
2GK= PCORRUPT +JINCCORR [ "CORRUPT"
2H4W POFFLINE +JINCOFF [ "OFFLINE"
2HJG PJFLDATA +JFLDATA [ ERROR : FORMAT LOOP DATA FILE ...
2HPN ...PJFLOUTPUT +JFLOUTPUT [ OUTPUT TEMPORARILY ABANDONED ...
2HWW ...PFREEPROP3 +FREEPROP3 [ PLEASE FREE .. FORMAT LOOP DATA ...
2HY* ...PCENDEF 4H@000
2H^S ... SEGENTRY K40FORMLOOP
2J3? ... 4H8 40
2J4Q ... 4H003^
2J69 ... SEGENTRY K41FORMLOOP
2J7N ... 4H7B01
2J9# ...PSTART 4H^;PP [ START FORMAT LOOP RED TAPE
2JF6 ...PEND 4H^;^T [ END FORMAT LOOP RED TAPE
2JNY ...#UNS FLLP4B
2JW6 ...#DEF PCENLEN=16
2K3B ...#DEF PSTARTLEN = 4
2KH2 #DEF PENDLEN = 4
2L2L #DEF PDEFAULTLEN = PSTARTLEN + PENDLEN
2L59 ...#UNS FLLP4B
2L7S ...(
2L=C ...PACTLFC
2L*2 ...#HAL ACTLF+CENTRAL,0
2LCK ...)
2LG= [
2L^W [************************************************************
2MFG [
2M^6 SFABSNB
2NDQ [
2NYB [************************************************************
2PD2 [
2PXL [
2QC= [ SET UP FILE/FABSNB FOR OPENING FORMAT LOOP DATA FILE
2QWW [
2RBG [ X7 - LINK
2RW6 [ ON EXIT X2 -> FILE/FABSNB + A1
2S*Q [
2STB SBX 7 FX1
2T*2 SETNCORE 10,2,FILE,FABSNB
2TSL ADN 1 PFABSNB
2W#= ADN 2 A1
2WRW MOVE 1 10 [ PRESET CONTENTS
2X?G ADX 7 FX1
2XR6 EXIT 7 0
2Y=Q [
2YQB [************************************************************
2^=2 [
2^PL SDATACHECK
329= [
32NW [************************************************************
338G [
33N6 [
347Q [ CHECK FORMAT LOOP DATA
34MB [
3572 [ X6 - LINK
35LL [ ON EXIT X0 - ZERO - OK
366= [ NON-ZERO - ERROR
36KW [
36R4 ...#UNS FLLP4BC
36Y= ... TRACEVER 3,FLDATCH
375G LDN 0 0
37K6 EXIT 6 0
384Q [
38JB [************************************************************
3942 [
39HL SOPEN
3=3= [
3=GW [************************************************************
3?2G [
3?G6 [
3?^Q [ OPEN FORMAT LOOP DATA FILE
3#FB [ REQUIRES FILE/FABSNB
3#^2 [
3*DL [ X7 - LINK
3*Y= [ ON EXIT X6 - ZERO - OK
3BCW [ X3 - RECORD POINTER
3BXG [ POS - FILE DOES NOT EXIST
3CC6 [ NEG - NOT AVAILABLE
3CWQ [ X5 - MESSAGE IDENTIFIER
3DBB [
3DW2 SBX 7 FX1
3F*L [
3FT= SOPENAGAIN
3G#W [
3GSG OPEN (GEOERR),READ,QUERY,NOWAIT,LEAVE
3H#6 IF REP2,OK [ FILE OPENED
3HRQ MHUNT 2,FILE,ENT
3J?B AND +ETM(2),E,PGRAPHIC(1) [ GRAPHIC
3JR2 THEN
3K=L STEP
3KQ= IF EITHER,3,ZE [ FILE EMPTY OR CORRUPT
3KRH ...#UNS FLLP4B
3KSS ...(
3KW5 ... LDX 2 FX2
3KXB ... IF PZ,AWORK2(2)
3KYM ... THEN
3K^Y ...#UNS FLLP4BC
3L39 ... TRACEVER AWORK2(2),FLSTEP1
3L4G ... STEP
3L5R ... FI
3L74 ... OR EITHER,3,ZE [NO LP4B DATA
3L8* ...)
3L9W CALL 6 SDATACHECK
3LPG OR 0,NZ [ DATA ERROR
3M96 THEN
3MNQ CLOSE
3N8B LDX 5 PCORRUPT(1)
3NN2 NGN 6 1
3P7L ELSE
3PM= LDN 6 0
3Q6W FI
3QLG MFREE FILE,ENT
3R66 ELSF REP2,MAG
3R?# ... MHUNT 2,FILE,ENT
3RDG ... AND +ETM(2),E,PGRAPHIC(1) [ GRAPHIC
3RKQ THEN
3S5B RV
3SK2 IF REP2,ONLINE
3T4L THEN
3TJ= BRN SOPENAGAIN
3W3W [------------------
3WHG ELSE
3X36 LDX 5 POFFLINE(1)
3XGQ NGN 6 1
3Y2B FI
3YG2 MFREE FILE,ENT
3Y^L ELSE
3^F= IF REP2,OK
3^YW THEN
42DG CLOSE
42Y6 MFREE FILE,ENT
43CQ FI
43Q7 ... IF EITHER,REP2,WRONG
444J ... OR REP2,MAG
44C2 THEN
44WL MFREE FILE,ENT
45B= FI
45TW LDN 6 1
46*G FI
46T6 MFREE FILE,FABSNB
47#Q ADX 7 FX1
47SB EXIT 7 0
48#2 [
48RL [************************************************************
49?= [
49QW SPRSPLIT
4==G [
4=Q6 [************************************************************
4?9Q [
4?PB [
4#92 ...[ SPLIT PROPERTY NAMES IN & FORMAT INTO APERI/APROPS FORMAT
4#NL [
4*8= [
4*MW [ X7 - LINK
4B7G [
4BM6 SBX 7 FX1
4C6Q SETNCORE ATTMAX*4+2,1,APERI,APROPS
4CLB MHUNT 3,APERI,APROPNOS
4F5= ADN 1 A1+2 [ X1 - POSITION FOR NEXT CHAR OF PROPERT
4FJW STO 1 4 [ X4 - POSITION FOR LENGTH OF NAME
4G4G ADN 1 1
4G69 ... LDN 5 0
4G7Y ... SEGENTRY K50FORMLOOP
4G9M ... NULL
4G?B ... NULL
4G*5 ... LDX 2 CHTEMP(3)
4GBS ... ADX 3 ADTEMP(3)
4GDH ... SEGENTRY K55FORMLOOP
4GG= ...SPRPERM
4GJ6 LDN 5 0 [ X5 - LENGTH OF NAME
4H3Q WHILE 2,NZ [ CHARACTER LEFT IN NAMES
4HHB DO [ SPLIT AT &
4J32 LDCH 0 0(3)
4JGL SBN 0 #26
4K2= IF 0,ZE [ &
4KFW THEN
4K^G LDX 1 4
4LF6 STO 5 0(1) [ LENGTH OF NAME
4LYQ ADN 1 5 [ POSITION FOR NEXT NAME
4MDB ADN 4 4
4MY2 LDN 5 0
4NCL ELSE
4NX= ADN 0 #26
4PBW DCH 0 0(1) [ COPY CHAR
4PWG BCHX 1 £
4QB6 ADN 5 1
4QTQ FI
4R*B SBN 2 1
4RT2 BCHX 3 £
4S#L REPEAT
4SS= SMO 4
4T?W STO 5 0 [ LENGTH OF LAST NAME
4T#X ... SEGENTRY K51FORMLOOP
4T*Y ... NULL
4TB^ ... NULL
4TD2 ... NULL
4TF3 ... NULL
4TG4 ... NULL
4TH5 ... NULL
4TJ6 ... NULL
4TK7 ... SEGENTRY K54FORMLOOP
4TL8 ... NULL
4TM9 ... NULL
4TN= ... NULL
4TP? ... NULL
4TQ# ... NULL
4TRG ADX 7 FX1
4W?6 EXIT 7 0
4WQQ [
4X=B [************************************************************
4XQ2 [
4Y9L SSTARTBLOCK
4YP= [
4^8W [************************************************************
4^NG [
5286 [
52MQ [ SET UP ADATA/FORMLOOP BLOCK
537B [ ADD INITIAL RED TAPE
53M2 [
546L [ X7 - LINK
54L= [ ON EXIT X2 -> ADDRESS FOR REST OF DATA
555W [
55KG SBX 7 FX1
5656 VFREEW ADATA,FORMLOOP
56JQ SETUPCORE 6,2,ADATA,FORMLOOP
574B STOZ FORMPROP(2) [ CLEAR PROP NO. AS FOR DEFAULT LOOP
576^ ...#UNS FLLP4BC
579J ... TRACEVER 2,FLSTARTB
57#7 ...#UNS FLLP4B
57BQ ...#SKI
57F* ...(
57J2 ADN 1 PSTART
583L ADN 2 FORMDATA
58H= MVCH 1 PSTARTLEN [ START RED TAPE
58R4 ...)
592W ADX 7 FX1
59GG EXIT 7 0
5=26 [
5=FQ [************************************************************
5=^B [
5?F2 SENDBLOCK
5?YL [
5#D= [************************************************************
5#XW [
5*CG [
5*X6 [ PUT TRAILING RED TAPE AND DATA LENGTH
5BBQ [ IN ADATA/FORMLOOP BLOCK
5BWB [
5CB2 [ X2 -> ADDRESS FOR REST OF DATA
5CTL [ X7 - LINK
5D*= [ ON EXIT X1 -> ADATA/FORMLOOP
5DSW [
5DYR ...#UNS FLLP4B
5F4N ...#SKI
5F8K ...(
5F#G LDX 1 FX1
5FS6 ADN 1 PEND
5G?Q MVCH 1 PENDLEN [ TRAILING RED TAPE
5GHJ ...)
5GRB MHUNT 1,ADATA,FORMLOOP
5GYJ ...#UNS FLLP4BC
5H5Q ... TRACEVER 1,FLENDB
5H?2 SLC 1 2
5HQL SLC 2 2
5J== SBX 2 1
5JPW SBN 2 FORMDATA*4
5K9G SRC 1 2
5KP6 STO 2 FORMCHAR(1) [ DATA LENGTH IN CHARS
5KW# ...#UNS FLLP4BC
5L3G ... BLOCKTRACE 1,FORMLOOP
5L8Q EXIT 7 0
5L95 ...#UNS FLLP4B
5L9D ...(
5L9R ...[
5L=6 ...[*********************************************
5L=F ...[
5L=S ...SCENDEFBL
5L?7 ...[
5L?G ...[*********************************************
5L?T ...[
5L#8 ...[ SET UP A DEFAULT FORMAT LOOP BLOCK
5L#H ...[ FOR CENTRAL LP (I.E. LP4B)
5L#W ...
5L#^ ... SBX 5 FX1
5L*4 ... LDN 6 PCENLEN
5L*9 ... CALL 7 SSTARTBLOCK
5L*J ... ADN 1 PCENDEF
5L*X ... ADN 2 FORMDATA
5LB= ... MVCH 1 PCENLEN
5LBK ... CALL 7 SENDBLOCK
5LBY ...#UNS FLLP4BC
5LC? ... TRACEVER 2,FLCENDB
5LCD ... ADX 5 FX1
5LCL ... EXIT 5 0
5LC^ ...[
5LD# ...[*********************************************
5LDM ...[
5LF2 ...SREMDEFBL
5LF* ...[
5LFN ...[*********************************************
5LG3 ...[
5LGB ...[ SET UP DEFAULT FORMAT LOOP BLOCK
5LGP ...[ FOR REMOTE LP (I.E. 7502 LP)
5LH4 ...
5LH9 ... SBX 5 FX1
5LHC ... LDN 6 PDEFAULTLEN
5LHQ ... CALL 7 SSTARTBLOCK
5LJ5 ... ADN 1 PSTART
5LJD ... ADN 2 FORMDATA
5LJR ... MVCH 1 PSTARTLEN
5LK6 ... LDX 1 FX1
5LKF ... ADN 1 PEND
5LKS ... MVCH 1 PENDLEN
5LL7 ... CALL 7 SENDBLOCK
5LLG ...#UNS FLLP4BC
5LLT ... TRACEVER 2,FLREMDB
5LM2 ... ADX 5 FX1
5LM8 ... EXIT 5 0
5LMH ...[
5LNB [
5LY8 ...)
5M82 [
5MML [ WW WW W
5N7= [ WW WW WW
5NLW [ WW WW WWW
5P6G [ WWWW WW
5PL6 [ WWWWW WW
5Q5Q [ WW WW WW
5QKB [ WW WW WW
5R52 [ WW WW WW
5RJL [
5S4= [
5SHW [************************************************************
5T3G [
5TH6 ZFORMLOOP1
5W2Q [
5WGB [************************************************************
5X22 [
5XFL [
5XMW ...[ ENTRY FROM IDFASAT @ C. 572
5XW6 ...#UNS FLLP4B
5Y4B ...(
5Y=L ... NGN 0 1
5YDW [ AT ATTRIBUTE COMMAND TIME
5YYG [ ERROR IF NOT AVAILABLE
5^D6 [
5^G4 ...#UNS FLLP4BC
5^J2 ... TRACEVER 0,FLZ1
5^KY ... STO 0 AWORK2(2)
5^MW ...RCHECK
5^PS ...)
5^RQ ...#UNS FLLP4BC
5^TN ... TRACEVER AWORK2(2),FLZ13
5^XQ CALL 7 SFABSNB
62CB MHUNT 1,CPB,CUNI
62X2 LDEX 3 ANUM(1)
63BL ADN 1 APARA
63W= ADN 2 4
64*W MVCH 1 0(3)
64TG CALL 7 SOPEN
65*6 IF 6,NG [ FILE NOT AVAILABLE
65SQ THEN
66#B LDX 1 FX1
66S2 ERRORX PJFLDATA(1),5
67?L SETREP WRONG
67R= ELSE
68=W IF 6,ZE [ FILE OPENED
68QG THEN
69=6 CLOSE
69PQ FI
6=9B SETREP OK
6=P2 FI
6?8L UP
6?N= [
6#7W [
6#8B ...#UNS FLLP4B
6#8W ...(
6#9B ...[
6#9W ...[ WW WW WWWWWWWW
6#=B ...[ WW WW WWW WW
6#=W ...[ WW WW WW
6#?B ...[ WWWW WWWW
6#?W ...[ WWWWW WWW
6##B ...[ WW WW WW WW
6##W ...[ WW WW WW WW
6#*B ...[ WW WW WWWWWWWW
6#*W ...[
6#BB ...[
6#BW ...[
6#CB ...[*********************************************************
6#CW ...[
6#DB ...ZFORMLOOP3
6#DW ...[
6#FB ...[*********************************************************
6#FW ...[
6#GB ...[ ENTRY FROM ATTRIBUT
6#GW ...[
6#HB ... LDN 0 1
6#HW ...#UNS FLLP4BC
6#JB ... TRACEVER 0,FLZ3
6#JW ... STO 0 AWORK2(2) [CENTRAL IDENTIFIER
6#KB ... BRN RCHECK
6#KW ...[
6#LB ...)
6#MG [ WW WW WWWWW
6*76 [ WW WW WW WW
6*LQ [ WW WW WW
6B6B [ WWWW WW
6BL2 [ WWWWW WWWWW
6C5L [ WW WW WW
6CK= [ WW WW WW
6D4W [ WW WW WWWWWWWW
6DJG [
6F46 [
6FHQ [************************************************************
6G3B [
6GH2 ZFORMLOOP2
6H2L [
6HG= [************************************************************
6H^W [
6JFG [
6J^6 [ SET UP FORMAT LOOP DATA BLOCK FOR
6KDQ ...[ TRANSMISSION TO LP
6KYB [ IF NO SPECIAL LOOP SET UP " RESET TO DEFAULT " LOOP
6LD2 [ IF FILE NOT AVAILABLE REQUEST
6LXL [ " PLEASE FREE I. OF PROPERTY ....."
6MC= [ OR SEND OUTPUT TEMPORARILY ABANDONED
6MM4 ...[ IF SPOOLING AND PROPERTY NOT ATTRIBUTED
6MWW [
6MXR ...#UNS FLLP4B
6MYN ...(
6M^K ... SMO FX1
6N2G ... LDX 3 PACTLFC
6N3C ... IF 3,E,ATYPE(2)
6N4# ... THEN
6N59 ... LDN 0 1
6N66 ... ELSE
6N73 ... NGN 0 1
6N7Y ... FI
6N8T ...#UNS FLLP4BC
6N9Q ... TRACEVER 0,FLZ2
6N=M ... STO 0 AWORK2(2)
6N?J ...)
6N#F ...#UNS FLLP4B
6N*B ...#SKI
6NBG MHUNT 3,APERI,APROPNOS
6NDD ...#UNS FLLP4B
6NGB ... HUNT 3,APERI,APROPNOS
6NJ# ...#UNS FLLP4B
6NL= ...(
6NN8 ... IF 3,PZ
6NQ6 ... THEN
6NS4 ...)
6NW6 LDX 7 BPROPCNT(3)
6P23 ... SEGENTRY K52FORMLOOP
6P5Y ... NULL
6P9T ... NULL
6P*Q WHILE TRUE
6PTB SMO 7
6Q*2 LDX 0 BPROPS-1(3)
6QSL SLL 0 1
6R#= AND 0,NG [ NOT TEMPORARY
6RRW DO
6S?G REPEAT CT 7
6S*P ...#UNS FLLP4B
6SCY ...(
6SG7 ... ELSE
6SJB ... STOZ 7
6SLK ... FI
6SNS ...)
6ST? ... SEGENTRY K56FORMLOOP
6S^Q ...XCENTLP
6T69 ... IF 7,NZ [ TEMPORARY PROPS OR PERM IF LFDBAID
6T=Q THEN
6TQB HUNT 2,ADATA,FORMLOOP
6W=2 IF 2,PZ [ DATA BLOCK EXISTS
6WFS ... LDX 7 BPROPCNT(3)
6WPL WHILE TRUE
6X9= SMO 7
6XNW LDX 0 BPROPS-1(3)
6Y8G ANDX 0 BSP16
6YN6 AND 0,U,FORMPROP(2) [ NOT DATA FOR SAME PROPERTY
6^7Q DO
6^MB REPEAT CT 7
7272 AND 7,NZ [ DATA FOR ONE OF TEMP PROPS
72LL THEN
736= SETREP OK
73KW UP
745G [-
74K6 FI
754Q ... CALL 7 SPRSPLIT [ SPLIT UP TEMP- PERM(LFDBAID) PROP N
75JB MHUNT 3,APERI,APROPNOS
7642 LDN 4 0 [ COUNT OF TEMP PROPS
76HL LDX 5 BPROPCNT(3) [ COUNT OF PROPS
773= DO
77GW MHUNT 3,APERI,APROPNOS
782G SMO 5
78G6 LDX 0 BPROPS-1(3)
78M# ... SMO FX2
78SG ... STO 0 AWORK1 [ SAVE PROPERTY NO.
78TH ... SEGENTRY K53FORMLOOP
78WJ ... NULL
78XK ... NULL
78YL ... NULL
78^Q SLL 0 1
796Y ... SEGENTRY K57FORMLOOP
79#6 ...XCENTLP1
79FB IF 0,PZ [ TEMP
79^2 THEN
7=DL ADN 4 4 [ 4 WORDS PER NAME
7=Y= CALL 7 SFABSNB
7?CW MHUNT 1 ,APERI,APROPS
7?XG SMO 4
7#C6 LDX 3 A1+2-4(1) [ X3 = CHARS IN PROPERTY NAME
7#WQ ADX 1 4
7*BB ADN 1 A1+3-4 [ X1 -> PROPERTY NAME
7*W2 ADN 2 4
7B*L MVCH 1 0(3) [ MOVE PROPERTY NAME INTO FABSN
7BT= CALL 7 SOPEN
7C#W IF 6,ZE [ OPEN SUCCESSFUL
7CSG THEN
7D#6 LDEX 6 0(3)
7DRQ ADN 6 PDEFAULTLEN-2
7F?B VFREEW ADATA,FORMLOOP
7FR2 SETUPCORE 6,2,ADATA,FORMLOOP
7G=L STEPAGAIN
7GQ= MHUNTW 2,ADATA,FORMLOOP
7GTB ... ADN 2 FORMDATA
7GYG ...#UNS FLLP4B
7H3L ...#SKI
7H6Q ...(
7H9W ADN 1 PSTART
7J96 MVCH 1 PSTARTLEN [ START RED TAPE
7JDY ...)
7JNQ LDN 1 2(3)
7JSM ... LDX 0 1(3)
7JYJ ... SLC 0 2
7K4F ... ANDN 0 3 [ CHAR NOT USED IN LAST WORD
7K8B LDEX 3 0(3)
7KN2 SBN 3 2
7L7L SLL 3 2
7LCD ... SBX 3 0
7LG3 ... BZE 3 XNONE
7LJL ... BNG 3 XNONE
7LM= MVCH 1 0(3) [ MOVE IN DATA
7LX4 ...XNONE
7M6W CALL 7 SENDBLOCK
7MLG ... SMO FX2
7N66 ... LDX 0 AWORK1
7P5B ANDX 0 BSP16
7PK2 STO 0 FORMPROP(1) [ PROPERTY NO.
7Q4L CLOSE
7QJ= MFREE APERI,APROPS
7R3W SETREP OK
7RHG UP
7S36 [-
7SGQ ELSF 6,NG [ DATA FILE NOT AVAILABLE
7T2B THEN
7TG2 OUTMESSX 5 [ EXPLANATION
7T^L OUTPER [ PERIPHERAL IDENTIFIER
7WF= MHUNT 2,APERI,APROPS
7WYW SBN 4 4
7XDG ADX 2 4
7XY6 ADN 4 A1+3
7YCQ OUTPARAX A1+2(2),4,APERI,APROPS [ PROPERTY NAME
7YF2 ...#UNS FLLP4B
7YG= ... HUNTW 1,AMXOR,ADCB
7YHG ...#UNS FLLP4B
7YJQ ...#SKI
7YL2 ... MHUNTW 1,AMXOR,ADCB
7YM= ...#UNS FLLP4B
7YNG ...(
7YPQ ... IF 1,PZ [FOUND
7YR2 ... AND BS,1,ADCBTUNATT [ UNATTENDED SPOOLING
7YS= ...)
7YTG ...#UNS FLLP4B
7YWQ ...#SKI
7YY2 ... IF BS,1,ADCBTUNATT [ UNATTENDED SPOOLING
7Y^= ...#UNS FLLP4BC
7^2G ... TRACEVER 1,FL
7^3S ... THEN
7^63 ... LDN 4 2 [ OUTPUT TO BOTH CONSOLES
7^8= ... ELSE
7^=F ... LDN 4 0 [ TO CLUSTER CONSOLE ONLY
7^#N ... FI
7^*4 ...#UNS FLLP4B
7^*D ...(
7^*S ... IF 1,PZ
7^B8 ... AND BS,1,ADCBTSPOOL [ SPOOLING
7^BJ ...)
7^BY ...#UNS FLLP4B
7^C# ...#SKI
7^CN ... IF BS,1,ADCBTSPOOL [ SPOOLING
7^D8 ... LDX 5 AWORK1(2) [ LOOP PROPERTY NO.
7^FB ... ANDX 5 BSP16
7^GJ ... MHUNT 3,GOUT,GPROPNOS
7^HQ ... LDN 1 ATTMAX-1
7^JY ... WHILE TRUE
7^L6 ... LDX 0 GPROPNUM(3)
7^M# ... ANDX 0 BSP16
7^NG ... AND 0,U,5 [ PROPERTIES NOT SAME
7^PN ... DO
7^QW ... ADN 3 1
7^S4 ... REPEAT CT 1
7^T= ... AND 1,ZE [ PROPERTY NOT ATTRIBUTED
7^WL THEN
82B= SETNCORE 12,3,ADATA,CREADL
82TW STOZ A1(3)
83*G MHUNT 3,GOUT,INFO2
83T6 NAME 3,FILE,FABSNB
84#Q UNNORM FULL
84SB MHUNTW 3,ADATA,CREADL
85#2 OUTPARAM A1(3),A1+2,ADATA,CREADL
85RL MHUNT 3,FILE,FABSNB
86?= NAME 3,GOUT,INFO2
86QW MFREE ADATA,CREADL
87=G INFORMX 4,PJFLOUTPUT(1),1 [ OUTPUT TEMP. ABANDONED
889Q ELSE
88PB GEOPACK 6
8992 LONGSET ATTRIBUTE,(GEOERR),6
89NL DEMANDX 4,PFREEPROP3(1),XCANTDO,XBRKIN,,2
8=8= XCANTDO
8=MW XBRKIN
8?7G VFREEW GMON,AOUT
8?M6 VFREEW ADATA,ADEMAND
8#6Q FI
8#=9 ...#UNS FLLP4B
8#*N ...(
8#F7 ... LDX 2 FX2
8#JL ... IF PZ,AWORK2(2) [CENTRAL
8#N5 ... THEN
8#RJ ... CALL 5 SCENDEFBL
8#X3 ... ELSE
8*2G ... CALL 5 SREMDEFBL
8*5^ ... FI
8*9D ...)
8*#X ...#UNS FLLP4B
8*DB ...#SKI
8*HT ...(
8*M# ... LDN 6 PDEFAULTLEN [SET UP DEFAULT BLOCK
8*QR ... CALL 7 SSTARTBLOCK
8*W= ... CALL 7 SENDBLOCK
8*^P ...)
8B5= MFREE APERI,APROPS
8BJW SETREP LOOP
8C4G UP
8CJ6 [-
8D3Q FI
8DHB FI
8F32 REPEAT CT 5
8FGL MFREE APERI,APROPS
8G2= FI
8G5P ...#UNS FLLP4B
8G98 ...(
8G#M ... LDX 2 FX2
8GD6 ... IF PZ,AWORK2(2) [CENTRAL
8GHK ... THEN
8GM4 ... CALL 5 SCENDEFBL
8GQH ... ELSE
8GW2 ... CALL 5 SREMDEFBL
8G^F ... FI
8H4Y ...)
8H8C ...#UNS FLLP4B
8H?W ...#SKI
8HC* ...(
8HGS ... LDN 6 PDEFAULTLEN [SET UP DEFAULT BLOCK
8HL? ... CALL 7 SSTARTBLOCK
8HPQ ... CALL 7 SENDBLOCK
8HT9 ...)
8HYQ SETREP OK
8JDB UP
8JY2 [
8KCL )
8KX= #END
^^^^ ...040700000003