{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: GIVEA867)}}
====== GIVEA867 ======
(George Source)
**Macros used:** [[george:macro:DATECON|DATECON]], [[george:macro:DATUMA|DATUMA]], [[george:macro:DOWN|DOWN]], [[george:macro:EVENTFIN|EVENTFIN]], [[george:macro:FINDPUC|FINDPUC]], [[george:macro:FJOPCA|FJOPCA]], [[george:macro:MACCS|MACCS]], [[george:macro:MELPTR|MELPTR]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:TESTTP|TESTTP]], [[george:macro:TIMECON|TIMECON]], [[george:macro:TRACE|TRACE]]
22FL ...#OPT K0GIVEA=0
22^= ...#LIS K0GIVEA>K0OBJPROG>K0ALLGEO>K0GREATGEO
23DW ...#SEG GIVEA865
23JR ...[
23NN ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1983
23SK ...[
23YG ... 8HGIVEA
24D6 #
24XQ #
25CB [ THIS SEGMENT IS ENTERED FROM OPCA TO PROCESS THE
25NQ ...[ 165 (GIVE) ORDER WITH ALL VALUES OF OPERAND N(M) EXCEPT
2626 ...[ 4 AND 12 WHICH ARE DEALT WITH BY SEGMENT GIVE (WHICH USED TO
26?G ...[ DEAL WITH THEM ALL BUT BECAME TOO BIG).
26JW ...[ A ZERO REPLY IS GIVEN IF N(M) IS NEGATIVE
26W= [ OR GREATER THAN THE CURRENT VALUE OF TOPGIVE, OR IF
27*W [ N(M) = 6 OR 7.
27TG #
28*6 [ ENTRY POINT
28SQ ... SEGENTRY K1GIVEA,ZEP1
29#B #
29S2 #DEF TOPGIVE=13
2=?L PB11 #10000
2=R= XMONTH 44H0FEB0MAR0APR0MAY0JUN0JUL0AUG0SEP0OCT0NOV0DEC
2?=W THOU +1000
2?QG XK9 +K9
2#=6 XK +1024
2#PQ XMINK -1024
2D76 SL 4H/00/
2DLQ #
2F6B ZEP1 [ENTRY POINT FROM OPCA
2FL2 LDX 7 EVENT5(2) [ISOLATE X-FIELD OF EXTRACODE
2G5L SLC 7 3
2GK= ANDN 7 7
2H4W DATUMA 3
2HJG MACCS ,3
2J46 LDX 3 0
2JHQ ADX 3 7
2K3B LDXC 4 EVENT2(2) [(MODIFIED) OPERAND
2KH2 BCS XGIVE
2L2L BNZ 4 XG
2LG= #
2L^W [ GIVE(0) DATE IN BINARY
2MFG #
2M^6 LDX 4 EDATE [GET BINARY DATE
2NDQ STSLR STO 4 0(3) [STORE SINGLE-LENGTH REPLY
2NYB #SKI K6GIVE>99-99
2PD2 TRACE 4,GIVESLR
2PXL TC EVENTFIN
2QC= #
2QWW XG LDN 6 TOPGIVE
2RBG TXL 6 4
2RW6 BCS XGIVE
2S*Q SMO 4
2STB X BRN X
2T*2 BRN XG1
2TSL BRN XG2
2W#= BRN XG3
2WRW ... BRN (GEOERR) [SINCE NOW IN GIVE
2X?G BRN XG5
2XR6 BRN XG6
2Y=Q BRN XG7
2YQB BRN XG8
2^=2 BRN XG9
2^PL BRN XG10
329= BRN XG11
32NW ... BRN (GEOERR) [SINCE NOW IN GIVE
338G #
33N6 XG13
347Q [ GIVE(13) EXECUTIVE NAME AND SYSTEM IDENTIFIER
34MB LDX 4 EXECNAME
3572 LDX 5 EXECNAME+1
35LL BRN STDLR
366= #
4=Q6 XG1
4?9Q #
4?PB [ GIVE(1) DATE IN CHARACTER FORM
4#92 #
4#NL DATECON EDATE
4*8= LDX 5 ACOMMUNE1(2)
4*MW LDX 6 ACOMMUNE2(2) [X56= DDCCCYY
4B7G LDX 4 5
4BM6 ANDN 5 #7777
4C6Q SLL 56 6
4CLB LDN 0 11
4D62 XG1A SMO 0
4DKL TXU 5 XMONTH-1(1)
4F5= BCC XG1B
4FJW BCT 0 XG1A
4G4G XG1B LDX 5 0 [MONTH IN RANGE 0-11
4GJ6 SBN 5 9
4H3Q BNG 5 XG1C [BRN UNLESS OCT,NOV OR DEC
4HHB ADN 5 #100-10 [ALLOW FOR NEXT ADDITION
4J32 XG1C ADN 5 10 [NOW IN RANGE 1-9,#100-#102
4JGL SLL 5 6
4K2= ORX 5 SL(1) [/MM/
4KFW SRL 4 12 [--DD
4K^G ANDN 4 #1777 [CONVERT SPACE TO ZERO IF DAY<10
4LF6 SLL 45 12 [DD/MM/--
4LYQ SRL 6 12 [00YY
4MDB ORX 5 6
4MY2 STDLR STO 4 0(3) [STORE DOUBLE-LENGTH REPLY
4NCL SBNC 7 7
4NX= BCS ST [BRN UNLESS XX* = X7X0
4PBW SBN 3 8
4PWG ST STO 5 1(3)
4QB6 #SKI K6GIVE>99-99
4QTQ (
4R*B TRACE 4,GIVEREP1
4RT2 TRACE 5,GIVEREP2
4S#L )
4SS= BRN TC
4T?W XG2
4TRG #
4W?6 [ GIVE(2) TIME IN CHARACTER FORM
4WQQ #
4X=B TIMECON CLEANCT [CONVERT TIME
4XQ2 LDX 4 ACOMMUNE1(2) [GET CONVERSION
4Y9L LDX 5 ACOMMUNE2(2)
4YP= ADN 4 #100 [. TO /
4^8W ADX 5 PB11(1) [. TO /
4^NG BRN STDLR [J TO STORE DOUBLE LENGTH REPLY
5286 XG12A
52MQ LDX 2 FX2
537B XG3
53M2 #
546L [ GIVE(3) CORE STORE ALLOCATED TO PROGRAM
54L= #
5=26 LDX 4 ALIMIT(2) [GET SIZE
5=FQ BRN STSLR [J TO STORE SINGLE LENGTH REPLY
5=^B #
B*2L XG5
B*G= #
B*^W [ GIVE(5) DETAILS OF CENTRAL PROCESSOR AND EXECUTIVE
BBFG #
BB^6 LDCT 4 256
BCDQ ORN 4 GEORGE^#40 [ UDAS IMPLEMENTED
BCYB ORX 4 CPEXECINFO
BD3* ... SEGENTRY K50GIVE [FOR MACRO CSSGIVE5
BD6# ... NULL
BD9? LDEX 5 GVERSION [GEORGE ISSUE NO.
BDG8 SLL 5 6
BDR5 ORX 5 CPEXECINFO+1
BF42 LDX 0 GVERSION
BF#X SRL 0 12
BFKS DCH 0 5 [GEORGE MARK NO.
BFWW BRN STDLR
BGBG #
BGW6 [ UNASSIGNED MODES - GIVE ZERO REPLY
BH*Q #
BHTB XG6
BHTL ... SEGENTRY K60GIVEA
BHTW ...# FOR MACRO CSSGIVE6
BHW8 ... BRN XGIVE
BHWK ...#
BHX2 ...# A SPECIAL PRIVILEGED READ ACCESS TO GEORGE CODE.
BHXC ...# IP MANAGER3=0,OR -VE----NO FACILITY
BHXS ...# =1,GIVE 6 ONLY
BHYC ...# >1,GIVE 6 & GIVE 6/2
BH^3 ... BNG 7 XGIVE
BH^D ... BZE 7 XGIVE
BH^T ... LDX 6 0(3)
BJ2= ... BNG 6 XGIVE6MODE2
BJ2M ... BNZ 6 XMV1
BJ34 ... LDX 6 2
BJ3F ...XMV1 LDX 3 1(3)
BJ3W ... LDX 7 3
BJ4? ... ANDN 3 #777
BJ4N ... SRL 7 15
BJ55 ... BNZ 7 XMV2
BJ5G ... LDN 7 45
BJ5X ...XMV2 LDX 4 6
BJ6P ... ADX 4 3
BJ7H ... TXL 4 CORES
BJ7Y ... BCC STSLR+1
BJ7^ ...# NEXT CHEXK IS THAT TARGET ADDRESS IS NOT BEYOND END OF PROG (B9518)
BJ82 ... LDX 0 ALIMIT(2)
BJ83 ... SBX 0 7
BJ84 ... BZE 3 XGV6B [0 = MOVE OF 512 WORDS
BJ85 ... SBX 0 3
BJ86 ...XGV6A
BJ87 ... BNG 0 STSLR+1
BJ8* ... ADX 7 ADATUM(2)
BJ8Q ... MOVE 6 0(3)
BJ97 ... BRN STSLR+1
BJ9= ...XGV6B
BJ9* ... SBN 0 512
BJ9D ... BRN XGV6A
BJ9J ...XGIVE6MODE2
BJ9^ ... SBN 7 1
BJ=B ... BZE 7 XGIVE
BJ=R ... DOWN PNTLAST,7
BJ?8 ... BRN STSLR+1
BJ?K ...#
BJ*2 XG7
BJSL XGIVE LDN 4 0
BK#= BRN STSLR
BKRW #
BL?G XG8
BLR6 [ GIVE(8) MODE SETTING
BM=Q SMO 2
BMQB LDCH 4 ALMT [CURRENT MODES B18-23 OF ALMT
BN=2 SRL 4 3
BNPL BRN STSLR
BP9= #
BPNW XG9
BQ8G [ GIVE(9) MODE SETTING REQUESTED
BQN6 #
BR7Q LDX 4 0(3)
BRMB ANDN 4 5 [GET REQUIRED MODES
BS72 #SKI K6GIVE>99-99
BSLL TRACE 4,GIVE9REP
BT6= SLL 4 3
BTKW SMO 2
BW5G DCH 4 ALMT
BWK6 MELPTR 2 [POINT TO CURRENT MEMBER ELEMENT
BX4Q SMO 2
BXJB DCH 4 ARM
BY42 BRN TC
BYHL XG10
B^3= [ GIVE (10) TIME USED IN MICROSECONDS (APPROXIMATELY)
B^GW #
C22G LDX 5 ATM1(2)
C2G6 ADX 5 ATM2(2)
C2^Q ADX 5 ATM3(2)
C3FB ADX 5 ATM4(2)
C3^2 TESTTP ,XGTP
C4DL BRN XGORD
C4Y= XGTP FINDPUC ,2 [TRUSTED PROGRAM
C5CW ADX 5 ATM1(2)
C5XG ADX 5 ATM2(2)
C6C6 ADX 5 ATM3(2) [ADD PUC TIMERS TO SUMMED
C6WQ ADX 5 ATM4(2) [TP TIME.
C7BB LDX 2 FX2
C7W2 XGORD
C8*L FJOPCA 2
C8T= LDXC 5 5 [ALLOW FOR TIMER SUM GOING NEGATIVE
C9#W LDN 4 0 [TOTAL BEATS IN X4,X5
C9SG DVR 4 BEATTIME [DIVIDE BY BEATSAMSEC TO GET MSEC
C=#6 ADXC 5 HCLOCKTIME+1(2)
C=RQ LDX 4 HCLOCKTIME(2) [ADD IN MSEC CLOCKED SO FAR
C??B MPY 5 THOU(1)
C?R2 MPA 4 THOU(1) [CONVERT TO MICROSEC
C#=L LDX 4 5
C#Q= LDX 5 6 [RESULT TO X4,X5
C*9W BRN STDLR
C*PG #
CB96 XG11
CBNQ #
CC8B [ GIVE (11) TIME SINCE MIDNIGHT IN SECONDS
CCN2 LDX 4 CLEANCT [TIME IN K9S
CD7L MPY 4 XK9(1) [TIME IN MS
CDM= DVD 4 THOU(1)
CF6W LDX 0 5 [INTEGRAL PART
CFLG DVR 4 THOU(1) [X5=FRACTIONAL PART
CG66 LDX 4 0
CGKQ BRN STDLR
CH5B #
CHK2 MENDAREA 25
CJ4L #END
^^^^ ...61214277000200000000