{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: HLSEMS864)}}
====== HLSEMS864 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:ALTLEN|ALTLEN]], [[george:macro:BS|BS]], [[george:macro:BSJ|BSJ]], [[george:macro:BSON|BSON]], [[george:macro:CHAIN|CHAIN]], [[george:macro:CLOSE|CLOSE]], [[george:macro:DICTJOB|DICTJOB]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHCODE|FSHCODE]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HUNTW|HUNTW]], [[george:macro:JBC|JBC]], [[george:macro:MFREE|MFREE]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUTX|MONOUTX]], [[george:macro:OPEN|OPEN]], [[george:macro:OUTPACK|OUTPACK]], [[george:macro:PHOTO|PHOTO]], [[george:macro:READ|READ]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:STEP|STEP]], [[george:macro:TESTMOVE|TESTMOVE]], [[george:macro:TESTREP|TESTREP]], [[george:macro:TRACE|TRACE]], [[george:macro:VFREEW|VFREEW]]
22FL #OPT K0HLSEMS=0
22^= #LIS K0HLSEMS>K0ALLGEO>K0GREATGEO>K0HLS
23DW #SEG HLSEMS [RUTH HEAP
23YG 8HHLSEMS
24D6 #
24XQ # THIS SEGMENT IS THE EMS ROUTINE WHICH PROCESSES :SYSTEM.JOBLIST
25CB # FOR THE HLS.IT IS ENTERED AFTER BACKMAP HAS DELETED ALL JOBS
25X2 # WITHOUT SAVING FILES.THIS ROUTINE MERELY LOOKS DOWN
26BL # :SYSTEM.JOBLIST SETTING UP A HLSQ BLOCK FOR EACH JOB AND ADJUSTING
26W= # COUNTS
27*W #
27TG #
28*6 # MARK 7-JNLSTART
28SQ # ALTHOUGH IT IS NO LONGER STRICTLY NECESSARY WE ARE STILL SETTING
29#B # UP THE ADATA/CSTORE BLOCK BECAUSE:
29S2 #
2=?L # 1) :SYSTEM JOBLIST IS NOT LEFT OPEN WHILE WE DO UMPTEEN MONOUTS
2=R= #
2?=W # 2) WE MAY NEED SUCH A BLOCK WHEN WE AGAIN OUTPUT TO THE CLUSTER
2?QG # CONSOLES
2#=6 #
2#PQ #
2*9B # ENTRY POINTS
2*P2 #
2B8L SEGENTRY K1HLSEMS,XK1
2BN= SEGENTRY K100HLSEMS
2C7W #GAP 20
2CMG ZNAMES +10
2D76 12HSYSTEM
2DLQ 12HJOBLIST
2F6B +1
2FL2 #20000000
2G5L 4HB1
2GK= #DEF STORSIZE=8
2H4W #DEF USER=0
2HJG #DEF SJOB=3
2J46 #DEF SPCT=6
2JHQ #DEF SJONO=7
2K3B PJCONT +JCONTINUE
2KH2 # THIS ENTRY POINT SETS UP AN ACTIVITY WHICH,AT THE END OF
2L2L # EARLY MORNING START, WILL OUTPUT MESSAGES TO THE CENTRAL
2LG= # CONSOLE AND TO THE RESPECTIVE CLUSTER CONSOLE.THIS CANNOT
2L^W # BE DONE AT EMS AS THE IDF IS NOT SET UP
2MFG #
2M^6 XK1
2NDQ #SKI K6HLSEMS>99-99
2NYB TRACE FX2,HLSEMS
2PD2 BSON HLSBIT,XNBLOK
2PXL SETNCORE 10,3,FILE,FABSNB
2QC= # OPEN SYSTEM.JOBLIST
2QWW LDN 4 ZNAMES(1)
2RBG LDN 5 A1(3)
2RW6 MOVE 4 10
2S*Q OPEN XBROK,READ
2STB TESTREP OK,XOK
2T*2 GEOERR 1,WRONGREP
2TSL XBROK GEOERR 1,BREAKIN
2W#= XOK READ [READ FIRST RECORD
2WRW # SET UP ADATA/CSTORE BLOCK
2X?G SETNCORE STORSIZE,3,ADATA,CSTORE
2XR6 LDN 7 A1 [SET UP POINTER WITHIN BLOCK
2Y=Q #
2YQB # LOOP OF JOBS
2^=2 XLOOP SETNCORE AHLS,2,ADATA,JSWAP
2^C8 ...#
2^JB ...XLOOPA
2^PL LDX 5 2
329= PHOTO 6
32NW STEP
338G BZE 3 XEND [J IF END OF FILE
33N6 LDX 2 5
347Q TESTMOVE 6,XNM
34MB MHUNTW 2,ADATA,JSWAP
3572 XNM MHUNTW 1,FILE,FRB
3599 ...#SKI JWPHASE3
35?D ...(
35*M ... ADX 3 JOBDATASIZE
35*^ ... JBC XLOOPA,3,JLBRUNNING
35B? ... FSHCODE AORB
35BK ...(
35BX ...# FOR SHARED FILESTORE, WE HAVE TO SET A BIT IN THE ADATA/JSWAP
35C9 ...# FOR ALL JOBS THAT WERE SAVED ON 'B'
35CH ...#
35CT ... STOZ HLSYONQA(2) [CLEAR SECOND MARKER WORD
35D7 ... JBC XNOTINB,3,JLBRUNB [JIF JOB WAS NOT RUNNING IN 'B'
35DF ... BS 2,BLASTRUNB [ELSE SET MARKER IN ADATA/JSWAP
35DR ...#
35F5 ...XNOTINB
35FC ...)
35G5 ... SBX 3 JOBDATASIZE
35J# ...)
35LL LDX 6 1(3)
366= STO 6 HLSJONO(2) [STORE JOB NUMBER
36KW LDN 6 HLSUNAM(2)
375G SMO JUSERELADD(1)
37K6 LDN 5 0(3)
384Q MOVE 5 3 [STORE USERNAME
38JB LDN 6 HLSJNAM(2)
3942 SMO JJOBRELADD(1)
39HL LDN 5 0(3)
3=3= MOVE 5 3 [STORE JOB NAME
3=GW LDX 5 GSIGN
3?2G STO 5 HLSSTAT(2) [SET JMISC FRIG
3?G6 STO 5 HLSYONQ(2)
3?^Q SMO JSOADDR(1)
3#FB LDX 0 0(3) [PICK UP CLUSTER
3#^2 STO 0 HLSPCT(2)
3*39 ...#SKI JWPHASE2
3*5D ...(
3*7M ... ADX 3 JOBDATASIZE
3*9W ... LDX 0 JLBUDGETS(3)
3*#5 ... STO 0 HLSPRIV(2)
3*B# ...)
3*DL MHUNTW 3,ADATA,CSTORE
3*Y= LDN 5 HLSUNAM(2)
3BCW SMO 7
3BXG LDN 6 USER(3)
3CC6 MOVE 5 3 [MOVE IN USER NAME
3CWQ LDN 5 HLSJNAM(2)
3DBB SMO 7
3DW2 LDN 6 SJOB(3)
3F*L MOVE 5 3 [MOVE IN JOB NAME
3FT= LDX 5 HLSPCT(2)
3G#W SMO 7
3GSG STO 5 SPCT(3) [SET PCT WORD
3H#6 LDX 5 HLSJONO(2)
3HRQ SMO 7
3J?B STO 5 SJONO(3)
3JDJ ...#SKI JWPHASE3<1$1
3JKQ ...(
3JR2 #SKI BILASJ
3K=L BSJ XADD [DO NOT INCREMENT COUNT IF BILA SJ
3KQ= SETNCORE 3,1,FILE,ADICT
3L9W MHUNTW 2,ADATA,JSWAP
3LPG LDN 5 HLSUNAM(2)
3M96 LDN 6 A1(1)
3MNQ MOVE 5 3 [SET UP FILE/ADICT BLOCK FOR DICTJOB
3N8B DICTJOB 4
3NN2 TESTREP OK,XOK2
3P7L GEOERR 1,DICTJOB
3PM= XOK2 CLOSE [CLOSE THE DICTIONARY
3Q6W MFREE FILE,ADICTENT
3QLG XADD
3R66 LDN 5 1
3RKQ ADS 5 JOBCOUNT
3RTJ ...)
3S5B MHUNTW 1,ADATA,JSWAP [RECHAIN HLSQ
3SK2 LDN 2 BHLSQ
3T4L XHNT LDX 2 FPTR(2)
3TJ= TXU 2 CXHL
3W3W BCC XFND
3WHG LDX 0 HLSJONO(2)
3X36 TXL 0 HLSJONO(1)
3XGQ BCS XHNT
3Y2B #SKI K6HLSEMS>5-5
3YG2 (
3Y^L TXU 0 HLSJONO(1)
3^F= BCS XCTU
3^YW GEOERR 1,HLSQRONG
42DG XCTU
42Y6 )
43CQ XFND LDX 2 BPTR(2)
43XB CHAIN 1,2 [RECHAIN HLSQ
44C2 MHUNTW 3,ADATA,CSTORE
44WL LDX 4 ALOGLEN(3)
45B= ADN 4 STORSIZE
45TW ALTLEN 3,4,ADATA,CSTORE
46*G ADN 7 STORSIZE
46T6 BRN XLOOP
47#Q # END OF SAVED JOBS
47SB XEND
48#2 CLOSE
48RL MFREEW ADATA,JSWAP
49?= MHUNTW 3,ADATA,CSTORE
49QW LDX 4 ALOGLEN(3)
4==G SBN 4 STORSIZE
4=Q6 BNZ 4 XBLOK [J IF SAVED JOBS FOUND
4?9Q FREECORE 3
4?PB BRN XNBLOK
4#92 XBLOK ALTLEN 3,4
4#NL XNBLOK
4#TS ...#SKI JWPHASE3<1$1
4*32 ...(
4*8= LDX 3 BHLSQ+1
4*MW TXU 3 CXHL
4B7G BCC XNJOB
4BM6 LDX 4 HLSJONO(3)
4C6Q TXL 4 JOBNUMBER [TEST AGAINST LARGEST NUMBER FOUND
4CLB BCS XNJOB [BY BACKMAP WHEN CHECKING WORKFILES
4D62 STO 4 JOBNUMBER
4DKL XNJOB
4DTD ...)
4F5= #SKI K6HLSEMS
4FJW TRACE FX2,HLOUTPUT
4G4G LDN 7 A1
4GJ6 XLOP
4H3Q HUNTW 3,ADATA,CSTORE
4HHB BNG 3 XNSAVE [J IF NO JOBS SAVED
4J32 ADN 7 USER
4JGL ADX 7 3
4K2= LDN 0 ACOMMUNE3(2)
4KFW MOVE 7 6
4K^G SBX 7 3
4LF6 SBN 7 USER
4LYQ SMO 7
4MDB LDX 6 SJONO(3)
4MY2 LDX 4 ALOGLEN(3)
4NCL RPT OUTPACK ACOMMUNE3(2),3,USERNAME,RPT
4NX= RPT1 OUTPACK ACOMMUNE6(2),3,JOBNAME,RPT1
4PBW LDX 5 PJCONT(1)
4PWG MONOUTX 5,6
4QB6 ADN 7 STORSIZE
4QTQ ADN 4 A1
4R*B TXU 7 4
4RT2 BCS XLOP
4S#L XNSAVE
4SS= VFREEW ADATA,CSTORE
4T?W ACROSS SETUP,4
4TRG #END
^^^^ ...26720640000100000000