{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: HLSOCCUR865)}}
====== HLSOCCUR865 ======
(George Source)

**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BXE|BXE]], [[george:macro:BXL|BXL]], [[george:macro:BXU|BXU]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FPCACA|FPCACA]], [[george:macro:HUNT2|HUNT2]], [[george:macro:SEGENTRY|SEGENTRY]]

<code - HLSOCCUR865.txt>22FL ...#SEG  HLSOCCUR865         [CENT RJPORTER
22^= ...#OPT  K0HLSOCCUR=0  
23DW ...#OPT  K6HLSOCCUR=100
23YG ...#LIS  K0HLSOCCUR
24D6 ...      8HHLSOCCUR
24XQ ...[   
25CB ...[ THIS SEGMENT HANDLES HLSEVENT DEALING WITH ONLINE PERIPHERAL  
25X2 ...[ REQUESTS OVER NEEDS RESERVATIONS  
26BL ...[   
26W= ...      SEGENTRY K1HLSOCCUR,XK1   
27*W ...TOP9  #77700000 
27TG ...XK1 
7BC6 ...XONCHECK              [CHECK WHETHER THE EVENT HAS HAPPENED 
7BC7 ...      STO   5  ACOMMUNE5(2) 
7BC8 ...      STO   6  ACOMMUNE6(2) 
7BC9 ...      STO   7  ACOMMUNE7(2) 
7BC# ...      LDX   5  ACOMMUNE4(2) 
7BCG ...      SRL   5  15       [X5=T#  
7BCN ...      FJOCA    3,2  
7BCW ...      LDX   7  JNEEDSPTR(3) 
7BD4 ...      BZE   7  XONLREQ     [NO NEEDS FIELD=EVENT REQUIRED   
7BD= ...      SMO      7
7BDD ...      LDX   6  JOBNUM(3)
7BDL ...      BZE   6  XONLREQ     [NULL NEEDS FIELD
7BDS ...      BRN      XONLBCT  
7BF2 ...XONLOOP 
7BF8 ...      SMO      7
7BFB ...      LDCH  0  JOBNUM(3)
7BFJ ...      BXU   0  5,XONLBCT    [J IF TYPE FOUND NOT RIGHT  
7BFQ ...      SMO      7
7BFY ...      LDX   0  JOBNUM(3)
7BG6 ...      ANDN  0  #377          [ISOLATE COUNT REQUESTED   
7BG# ...      BZE   0  XONLREQ  
7BGG ...      STO   0  ACOMMUNE9(2) 
7BGN ...      BRN      XPRB         [NOW GO LOOK IN THE PRB 
7BGW ...XONLBCT 
7BH4 ...      ADN   7  1
7BH= ...      BCT   6  XONLOOP  
7BHD ...      BRN      XONLREQ      [NOT FOUND=NONE REQUESTED   
7BHL ...XPRB
7BHS ...      FPCACA   3,2  
7BJ2 ...      LDX   1  3          [REMEMBER PCA ADDR
7BJ8 ...      HUNT2    3,APERI,APERIRES 
7BJB ...      LDCT  7  #777 
7BJJ ...      ANDX  7  ACOMMUNE4(2)   [ISOLATE T#   
7BJQ ...      LDN   6  0          [INITIALISE COUNT OF THIS TYPE
7BJY ...      LDN   5  0          [INITIALISE OLPA COUNT
7BK6 ...XPRBLOOP
7BK# ...      LDX   0  A1(3)
7BKG ...      BNG   0  XPRBEND     [J IF AT END OF PRB  
7BKN ...      LDX   4  A1+1(3)  
7BKW ...      BPZ   4  XONL1      [J IF DEVICE LIST ADDR
7BL4 ...      ADN   5  1
7BL= ...XONL1   
7BLD ...      BXE   0  ACOMMUNE4(2),XONNEXT      [J IF IDENTICAL ENTRY FOUND
7BLL ...      SMO      FX1  
7BLS ...      ANDX  0  TOP9 
7BM2 ...      BXU   0  7,XONNEXT            [J IF DIFFERENT TYPE
7BM8 ...      BPZ   4  XONL2                [J IF DEVICE LIST ADDR  
7BMB ...      LDN   2  ACTRING(1)           [PCA ADDR   
7BMJ ...      LDX   4  5                    [OLPA COUNT 
7BMQ ...XOLPA   
7BMY ...      LDX   2  FPTR(2)  
7BN6 ...      BCT   4  XOLPA
7BN# ...      LDX   0  ATMARK-ACTRING(2)
7BNG ...      LDX   2  FX2  
7BNN ...      BZE   0  XONNEXT  
7BNW ...      SBN   0  3
7BP4 ...      BZE   0  XONNEXT             [J IF REALLY OFFLINE 
7BP= ...XONL2   
7BPD ...      ADN   6  1                    [ONE MORE ONLINE ENTRY  
7BPL ...XONNEXT 
7BPS ...      ADN   3  2
7BQ2 ...      BRN      XPRBLOOP 
7BQ8 ...XPRBEND 
7BQB ...      BXL   6  ACOMMUNE9(2),XIGNORE     [J IF NO EVENT  
7BQJ ...XONLREQ 
7BQQ ...      LDX   0  ACOMMUNE4(2) 
7BQY ...      SRL   0  15   
7BR6 ...      STO   0  ACOMMUNE4(2) 
7BR7 ...      LDX   5  ACOMMUNE5(2) 
7BR8 ...      LDX   6  ACOMMUNE6(2) 
7BR9 ...      LDX   7  ACOMMUNE7(2) 
7C=T ...      ACROSS  HLSEVENT,10   
7CQF ...XIGNORE 
7D=5 ...      ACROSS HLSEVENT,11
7DPP ...#END
^^^^ ...210306660004
</code>