{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: IDFCLEAN867)}}
====== IDFCLEAN867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BXE|BXE]], [[george:macro:DOWN|DOWN]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HUNT2|HUNT2]], [[george:macro:HUNT2OPT|HUNT2OPT]], [[george:macro:MASK|MASK]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREECELL|MFREECELL]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:TEST|TEST]], [[george:macro:TRACE|TRACE]]
22FL #SEG IDFCLEAN8 [A C PUTMAN
22PD ...# COPYRIGHT INTERNATIONAL COMPUTERS 1982
22^= #OPT K0IDFCLEAN=0
23DW #LIS K0IDFCLEAN>K0ALLGEO>K0GREATGEO>K0COMMAND>K0IDF
23YG 8HIDFCLEAN
24D6 SEGENTRY K10IDFCLEAN,XIDF10
24XQ #
25CB # THIS SEGMENT CLEANS UP THE IDF
25X2 #
26BL MASK #77770000
26W= #73777777
27*W #17777
27TG RECZERO
28*6 LDN 6 0 [HUNT FIRST REC.
28SQ RECFD LDX 2 FX2
29#B REH HUNT2 2,FILE,FRRB
29S2 TXU 6 BRECNO+A1(2)
2=?L BCS REH
2=R= ADN 2 A1
2?=W EXIT 7 0
2?QG NEXCELL
2#=6 SMO FX2 [
2#PQ STO 3 AWORK1
2*9B NX1 LDX 6 3
2*P2 SRL 6 9
2B8L ANDN 6 #7777
2BN= CALL 7 RECFD
2C7W ANDN 3 #777
2CMG EXIT 5 0
2D63 ...#
2D76 SFREE
2DLQ LDX 1 FX2
2F6B SF1 HUNT2OPT 1,FILE,FRRB
2FL2 BNG 1 NOFREE [NO MORE FREE SPACES.
2G5L TXU 4 BRECNO+A1(1)
2GK= BCS SF1 [J.IF WRONG RECORD.
2H4W LDX 3 A1(1)
2HJG BZE 3 SF2 [J. IF NO SPACE IN THIS RECORD.
2J46 ADN 1 A1
2JHQ NOFREE
2K3B EXIT 6 0 [NORMAL EXIT
2KH2 SF2 ADN 4 1
2L2L BRN SFREE
2LG= TEST
2L^W SMO FX2
2MFG STO 7 ACOMMUNE7
2M^6 LDX 4 3
2NDQ SRL 4 9
2NYB ANDN 4 #7777 [FREE SPACE REC.NO IN X4
2PD2 LDX 6 2
2PXL SRL 6 9
2QC= ANDN 6 #7777 [REC.NO OF CELL TO BE MOVED IF NEC.
2QWW BZE 3 TS
2RBG TXL 4 6
2RW6 BCS TS1
2S*Q TS SMO FX2
2STB STO 6 AWORK4 [KEEP REC.NO.
2T*2 SMO FX2
2TSL STO 2 ACOMMUNE6 [FOR LATER RESCUE PERHAPS
2W#= LDN 5 #777
2WRW ANDX 5 2 [CELL PTR.
2X?G CALL 7 RECFD
2XR6 ADX 5 2 [X5 POINTS TO CELL FOR NEXT TEST ENT.
2Y=Q LDX 2 5
2YQB LDX 2 0(2) [CONTENTS OF FORWARD PTR.
2^=2 BRN TS6
2^PL TS1 SMO FX2
329= LDX 0 AWORK4 [RESCUE RECORD NO.
32NW TXU 0 4
338G BCC TS2
33N6 LDCT 0 #400
347Q ORX 3 0 [SET "ANOTHER RECORD" BIT
34MB TS2
3572 SMO 5
35LL STO 3 0 [STORE NEW RECORD PTR
366= SMO FX2
36KW STO 3 ACOMMUNE6 [FOR LATER RESCUE PERHAPS.
375G SMO FX2
37K6 STO 4 AWORK4 [FOR NEXT ENTRY INTO TEST
384Q ANDN 3 #777
38JB ADX 3 1 [ABSOLUTE PTR TO NEW CELL IN X3
3942 LDX 0 0(3)
39HL STO 0 0(1) [FREE SPACE CHAIN UPDATED
3=3= LDXC 5 2 [IDF POINTER TO CURRENT CELL
3=GW CALL 7 RECFD [GET PTR TO RECORD CONTAINING CELL
3?2G LDX 0 0(2) [X0=IDF PTR TO 1ST FREE CELL IN REC
3?G6 STO 5 0(2) [CHAIN CURRENT CELL INTO FREE LIST
3?^Q ANDN 5 #777
3#FB ADX 2 5 [X2=CORE PTR TO CURRENT CELL
3#^2 MOVE 2 8 [MOVE CONTENTS OF CURRENT TO NEW CELL
3*DL STO 0 0(2) [FINISH FREEING CELL
3*Y= LDX 2 FX2 [CELL HAS NOW BEEN MOVED : UPDATE ALL
3BCW LDX 5 AWORK3(2) [PTRS IN CELL : AWORK3=MARKER WD
3BXG LDN 7 8 [B1-B8= 1 BIT FOR EACH WD IN CELL
3CC6 SLL 4 9 [IF SET WD IS PTR & NEEDS UPDATING
3CWQ TS3 ADXC 5 5 [J IF NOT SET
3DBB BCC TS5
3DW2 LDXC 0 0(3) [GET POINTER
3F*L BZE 0 TS5 [J IF NOT NECESSARY TO ALTER IT
3FT= DEX 0 4 [SET UP EQUIV PTR WITH CURRENT REC
3G#W BXE 4 0,TS4 [TEST WHETHER PTRS ARE THE SAME
3GSG ORX 0 GSIGN [IF NOT SET B0,AS PTS TO ANOTHER BLK
3H#6 TS4 STO 0 0(3) [STORE CORRECTED PTR
3HRQ TS5 ADN 3 1 [J FOR NEXT WORD
3J?B BCT 7 TS3 [DROP OUT WHEN ALL 8 BITS TESTED
3JR2 LDEX 7 AWORK3(2) [THIRD CHARACTER OF MARKER WD SHOWS
3K=L SBN 3 8 [PRINCIPAL PTR IN CELL
3KQ= SRL 4 9 [TURN BACK INTO RECORD NUMBER
3L9W SMO 7 [GET CONTENTS OF PRINCIPAL PTR
3LPG LDX 2 0(3)
3M96 LDX 5 3 [REMEMBER CELL ADDRESS
3MNQ LDX 3 0(1) [IDF PTR TO 1ST AVAILABLE FREE CELL
3N8B SMO FX2 [STORE CONTENTS OF PRINCIPAL PTR
3NN2 STO 2 ACOMMUNE9 [FOR POSSIBLE LATER "RESCUE"
3P7L BNZ 3 TS6 [J UNLESS NO MORE FREE CELLS IN THIS
3PM= BUX 4 XWS [RECORD,OTHERWISE J TO STEP TO NEXT
3Q6W PT0B CALL 4 RESCUE [RESCUE PTR TO LAST MAIN PROPERTY
3QLG LDX 2 3 [CELL,GET PTR TO NEXT CELL
3R66 LDN 4 0 [X4 HAS BEEN OVERWRITTEN,SO USE
3RKQ CALL 6 SFREE [SFREE TO RELOCATE 1ST FREE CELL
3S5B BNZ 2 PART0 [J UNLESS NO MORE PROPERTIES
3SK2 NOPRP SMO FX2 [NOW DEAL WITH CONCEPTUALS
3T4L STOZ AWORK4
3TJ= BRN PART1
3TTL ...XWS CALL 6 SFREE [RELOCATE NEXT FREE CELL
3W72 ...TS6 SMO FX2
3WDB ... LDX 7 ACOMMUNE7 [GET LINK AND EXIT
3WPQ ... EXIT 7 0 [END OF SR TEST
3X36 RESCUE [CREATE X2 & X5 READY FOR TEST
3XGQ LDX 2 FX2
3Y2B LDX 5 AWORK1(2) [RESCUE IDF FORMATED POINTER
3YG2 RESQ LDX 6 5
3Y^L SRL 6 9
3^F= ANDN 6 #7777
3^YW STO 6 AWORK4(2)
42DG CALL 7 REH
42Y6 ANDN 5 #777
43CQ ADX 5 2
43XB LDX 2 5
44C2 LDX 3 0(2)
44WL EXIT 4 0 [X3 &X5 SET UP USING AWORK1.
4LF6 ZBATT [ROUTINE TO DEAL WITH BATT ROUTINE.
4LYQ SBX 7 FX1 [ON ENTRY ACOMMUNE7 =PTR.TO PREVIOUS
4MDB SMO FX2
4MY2 STO 7 ACOMMUNE8 [PRESERVE LINK
4NCL SMO 2
4NX= LDX 3 BATT(3)
4PBW BZE 3 XPACK [J. IF NO ATTRIBUTES
4PWG CALL 5 NX1 [HUNT ASS. BLOCK.
4QB6 ADX 3 2
4QTQ LDN 4 5
4R*B LDX 1 3
4RT2 LDX 6 BTYPE+1(3) [LD. PROPERTY
4S#L BZE 6 XPACK [MAYBE ONLY A CONSOLE PROP
4SS= ZBA SLL 6 1
4T?W BNG 6 XMOD [J. PERM.PROP.
4TRG STOZ BTYPE+1(3)
4W?6 LDN 0 1
4WQQ SBS 0 BNO(1) [DECREASE CT. IN BNO.
4X=B XMOD ADN 3 1
4XQ2 SBN 4 1
4Y9L BZE 4 XCTZ [J. END OF CELL
4YP= LDX 6 BTYPE+1(3) [LD. CONTENTS NEXT WD. IN CELL
4^8W BNZ 6 ZBA
4^NG BRN XMOD
5286 XCTZ LDX 6 BNO(1)
52MQ BZE 6 XFCE [J. IF COUNT ZERO.
537B LDX 3 1 [LD. OTHER PTR.
53M2 LDX 4 BTYPE(1)
546L BZE 4 XMOVA [J. IF NO CONSOLE PROP
54L= SBN 6 1
555W BZE 6 XPACK [J. IF ONLY CONSOLE PROP. LEFT
55KG XMOVA LDX 3 1
5656 XMOV LDX 4 BTYPE+1(1)
56JQ BZE 4 XUP
574B STOZ BTYPE+1(1)
57J2 STO 4 BTYPE+1(3)
583L ADN 3 1
58H= SBN 6 1
592W BZE 6 XPACK
59GG XUP ADN 1 1
5=26 BRN XMOV
5=FQ XFCE
5=^B SMO FX2
5?F2 LDX 3 ACOMMUNE7 [LD.PTR. TO CELL BEFORE
5?YL CALL 5 NX1
5#D= ADN 3 BATT [MAKE PTR. TO END OF CELL
5#XW ... MFREECELL 2,3
5*CG SBN 3 BATT
5*X6 XOUT
5BBQ SMO FX2
5BWB LDX 7 ACOMMUNE8 [LD. LINK.
5CB2 ADX 7 FX1
5CTL EXIT 7 0 [EXIT
5D*= XPACK
5DSW SMO FX2
5F#G LDX 3 ACOMMUNE7
5FS6 CALL 5 NX1
5G?Q BRN XOUT
5GRB XIDF10
5H?2 STOZ AWORK4(2) [START GARBAGE COLLECTING FROM REC 0
5H#* ...# FIRST DO PROPERTY CELLS
5H*N ...START LDN 4 0 [FIND 1ST AVAILABLE FREE CELL
5HC3 ... CALL 6 SFREE
5HDB ... CALL 7 RECZERO [AND BASE CELL
5HFP ... LDN 5 BEXOT(2) [FIND CONSOLE PROP CHAIN
5HH4 ... LDX 2 BEXOT(2)
5HJC ... BZE 2 NOPRP [JUMP IF NONE
5HKQ ...PART0 LDCT 0 #257 [PTRS IN CONSOLE CELL ARE
5HM5 ... SMO FX2 [WDS 0,2,4,5,6,7
5HND ... STO 0 AWORK3
5HPR ... CALL 7 TEST [MOVE MAIN CELL DOWN IDF IF POSS
5HR6 ... LDX 2 FX2
5HSF ... LDX 0 ACOMMUNE6(2) [SAVE PTR TO NEXT CONSOLE CELL
5HTS ... STO 0 AWORK1(2) [FOR LATER RESCUE
5HX7 ... LDCT 7 #377 [IN SUBSID CELLS, ALL WDS ARE
5HYG ... STO 7 AWORK3(2) [POINTERS - WD0 IS PRINCIPAL ONE
5H^T ... ADN 5 4
5J38 ... SMO 5
5J4H ... LDX 2 0 [POINTER TO 1ST SUBSID CELL
5J5W ...PT0A BZE 2 PT0B [JUMP IF FINISHED THIS PROP
5J79 ... CALL 7 TEST [OTHERWISE MOVE SUBSID CELL
5J8J ... BRN PT0A
5J== PART1 CALL 7 RECZERO [SFREE FINDS 1ST AVAILABLE FREE CELL
5JPW LDN 5 BCONT(2) [NOW PROCESS CONCEPTUAL CHAIN
5K9G LDX 2 BCONT(2) [J IF NO CONCEPTUALS
5KP6 BZE 2 PART2
5L8Q PT6 LDCT 0 #201 [PTRS IN MAIN CONCEPTUAL CELL ARE
5LNB SMO FX2 [IN WDS 0 (CONCEPTUAL CHAIN)
5M82 STO 0 AWORK3 [AND 7 (PTR TO USER NAME CELL)
5MML CALL 7 TEST [MOVE CELL DOWN IDF IF POSSIBLE
5N7= LDX 2 FX2
5NLW LDX 0 ACOMMUNE6(2) [SAVE PTR TO NEXT CONCEPTUAL FOR
5NWN ... STOC 0 AWORK1(2) [LATER RESCUE
5P6G ... [CLEAR BIT 0 AS AW1 USED FOR
5PB# ... [REC NO COMPARISON LATER
5PL6 LDCT 7 1 [NOW DEAL WITH USER NAME CELL - PTR
5Q5Q ORN 7 7 [PTR IN WD 7 ADDRESSES 1ST
5QKB STO 7 AWORK3(2) [SUBSIDIARY CELL - ONLY PTR IN CELL
5R52 LDX 2 5
5WGB ADN 5 7
5X22 NGNC 0 1
5X6D ... ANDS 0 4(2) [CLEAR ONLINE BIT
5X=W ... LDX 0 6(2)
5X?^ ... SMO FX2
5X*4 ... [ZERO COUNT OF IDES DETACHED
5XB7 ... STOZ ACOMMUNE5
5XC# ... BPZ 0 PTR5 [J TO CLEAR ALL AH'S IF NOT IPB CL
5XHQ ... SEGENTRY K91IDFCLEAN
5XN8 ... LDN 0 AHRETAIN [MENDED BY RETAINAH MACRO
5XSL ... BZE 0 PTR5 [J IF ATTACHES NOT TO BE RETAINED
5X^= LDX 2 7(2) [THEN DEAL WITH SUBSIDIARY CELLS
5YDW CALL 7 TEST [MOVE USER NAME UP THE IDF.
5YYG ...ZT5 ADN 5 7
5^D6 LDX 2 5
5^XQ LDX 2 0(2)
62CB BZE 2 PT4
62CP ... LDCT 7 #377
62D4 ... ORN 7 7
62DC ... SMO FX2
62DQ ... STO 7 AWORK3 [ALL WORDS IN CL CELLS ARE POINTERS
62F5 ... CALL 7 TEST
62FD ... LDX 2 FX2
62FR ... STO 3 ACOMMUNE6(2) [SAVE X3,X5
62G6 ... STO 5 ACOMMUNE7(2)
62GF ... LDN 0 6
62GS ... STO 0 AWORK3(2) [COUNT FOR NO OF POSSIBLE ATTACHES...
62H7 ...[ IN CELL
62HG ... LDX 4 5
62HT ...[ NOW UPDATE PTRS FROM ATTACHED IDS...
62J8 ...[ SO THEY STILL POINT AT CL CELL
62JH ...NEXWD SMO 4
62JW ... LDX 3 0
62K9 ... BZE 3 NLAH [J IF NO AH TO THIS CL IDENT
62KJ ... CALL 5 NX1 [FIND ID CELL OF ATTACHED ID
62KX ... SMO FX2
62L= ... LDX 0 AWORK1 [POINTER TO CL CELL
62LK ... SRL 0 9 [GET RECORD NUMBER
62LY ... ERX 0 BRECNO(2)
62M? ... ADX 3 2
62ML ... LDX 2 FX2
62M^ ... BZE 0 ZAMRE [J IF CL CEL IN SAME REC AS ID
62N# ... LDCT 0 #400 [ELSE SET BIT 0
62NM ...ZAMRE ORX 0 AWORK1(2)
62NP ... LDCT 7 #200 [LOOK IF B1 OF CONCEPT POINTER
62NR ... ANDX 7 CONTCEP(3) [IN IDE CELLSET
62NT ... BNZ 7 ZCCAH [IF SO, JUMP TO DETACH
62P2 ... STO 0 CONTCEP(3) [STORE CORRECT CL POINTER
62P* ...NLAH LDN 0 1
62PN ... SBSC 0 AWORK3(2)
62Q3 ... BCS ZNEXC [J IF TESTED WHOLE CELL
62QB ... ADN 4 1
62QP ... BRN NEXWD
62QQ ...ZCCAH STOZ CONTCEP(3) [ZERO CONCEP POINTER IN IDE CELL
62QR ... SMO 4
62QS ... STOZ 0 [ZERO IDE POINTER IN SUBSID CELL
62QT ... LDN 7 1
62QW ... ADS 7 ACOMMUNE5(2) [UPDATE COUNT OF IDES DETACHED
62QX ... BRN NLAH [DEAL WITH NEXT PTR IN SUBSID
62R4 ...ZNEXC LDX 3 ACOMMUNE6(2) [RESTORE X3,X5
62RC ... LDX 5 ACOMMUNE7(2)
62RQ ... BRN ZT5 [GO ON TO NEXT CELL
62S5 ...PTR5 STOZ 5(2) [CLEAR COUNT OF ATTACHES
62SD ... LDX 2 7(2) [THEN DEAL WITH SUBSIDIARY CELLS
62SR ... CALL 7 TEST [MOVE USER NAME UP THE IDF.
62T6 ...PT5 ADN 5 7
62TF ... LDX 2 5
62TS ... LDX 2 0(2)
62W7 ... BZE 2 PT4
62X2 CALL 7 TEST
63BL LDX 6 5 [NOW CLEAR OUT ALL ATTACHES.
63W= ADN 6 1
64*W SMO 5
64TG STOZ 0
65*6 MOVE 5 6 [ALL ATTACHES CLEARED FROM CONCEPT.
65SQ BRN PT5 [ANY MORE?
66#B PT4
66S2 CALL 4 RESCUE [RESCUE CONCEPTUAL CELL.
67?L SMO FX2
67R= STOZ AWORK3
67RM ... SMO FX2
67S4 ... LDX 0 ACOMMUNE5
67SF ... SBS 0 5(2) [DECREMENT COUNT OF SLOTS USED
67S^ ... LDX 0 5(2)
67WN ... BNZ 0 PT6A [J IF SOME IDS ATTACHED
67YC ... LDX 0 6(2)
6826 ... ANDN 0 #7777
683T ... BCT 0 PT6A
685J ... LDN 0 #7777
687? ... ANDS 0 6(2) [MASK OUT ONLY THE LOWEST SLOT NO.
6892 ...PT6A
68=W LDX 2 3
68QG LDN 4 0
69=6 CALL 6 SFREE
69PQ BNZ 2 PT6 [J. MORE CONCEPTUALS TO BE DEALT WITH
6=9B PART2 [DEALT WITH CONCEPTUALS
6=P2 CALL 7 RECZERO [HUNT ZERO RECORD.
6?8L LDX 3 BUNIT(2) [PTR. TO UNIT CHAIN (7007)
6?N= BZE 3 XCONP
6#7W PT4A CALL 5 NEXCELL [HUNT UNIT CELL
6#MG NGNC 0 1
6*76 SRC 0 2
6*LQ SMO 3
6B6B ANDS 0 BNUMB(2) [REMOVE ONLINE MARKER
6BL2 SMO 3
6C5L LDX 3 BLINE(2)
6CK= BZE 3 PT3 [J. NO LINES
6D4W PT2
6DJG CALL 5 NX1
6F46 SMO 3
6FHQ STOZ CONTCEP(2)
6G3B SMO 3
6GH2 LDX 3 0(2)
6H2L BNZ 3 PT2 [J. BACK TO FREE ATTACHED PTR.
6HG= PT3
6H^W CALL 4 RESCUE [RESCUE PTR. IN AWORK1
6JFG BNZ 3 PT4A
6J^6 XCONP
6KDQ CALL 7 RECZERO [HUNT FIRST RECORD.
6KYB LDX 3 BUNIT(2) [LD. BASE OF 7007 CHAIN
6LD2 BZE 3 ZNO7007 [J. NO 7007
6LXL ZUN CALL 5 NEXCELL [HUNT UNIT CELL.
6LYK ... ADX 3 2 [VALIDITY CHECKS FOR MXOR CELL
6L^J ... LDX 7 BNO(3)
6M2H ... BZE 7 ZZERR [UNIT NO CANNOT BE ZERO
6M3G ... LDCH 7 BTYPE(3)
6M4F ... SBN 7 #14
6M5D ... BPZ 7 ZZERR
6M6C ... LDX 7 BNUMB(3)
6M7B ... ANDN 7 #7777
6M8* ... SMO FX2
6M9# ... STO 7 ACOMMUNE4 [REMEBER HOW MANY LINES
6M=? ... SBX 3 2
6M?= ... SMO FX2
6M#9 ... STOZ ACOMMUNE5
6M*8 ... SMO FX2
6MB7 ... STOZ ACOMMUNE6
6MC= SMO FX2
6MWW LDX 0 AWORK1
6NBG SMO FX2
6NW6 STO 0 AWORK3 [PRESERVE PTR. TO UNIT CELL
6P*Q SMO FX2
6PTB STO 0 ACOMMUNE7
6Q*2 CALL 7 ZBATT [CALL ROUTINE TO REMOVE TEMP.ATTRIB.
6QSL SMO 2
6R#= LDX 3 BLINE(3)
6RRW BZE 3 ZNOLIN [J.NO LINES.
6S?G ZLIN
6SR6 CALL 5 NEXCELL [HUNT FOR A LINE
6SS7 ... ADX 3 2 [VALIDITY CHECKS FOR LINE CELL
6ST8 ... LDX 7 BNO(3) [GET LINE NO
6SW9 ... SMO FX2
6SX= ... LDX 6 ACOMMUNE6 [LOOK AT LAST LINE NO
6SY? ... SMO FX2
6S^# ... STO 7 ACOMMUNE6
6S^S ... BZE 7 ZL1
6T2* ... SBX 6 7 [CHECK INCREASING SEQUENCE
6T3B ... BPZ 6 ZZERR
6T3W ...ZL1
6T4C ... LDN 7 1
6T5D ... SMO FX2
6T6F ... ADS 7 ACOMMUNE5 [INCREMENT NOOF LINES SEEN
6T7G ... LDX 7 BTYPE(3)
6T8H ... BZE 7 ZZERR [CANNOT BE ZERO
6T9J ... SBX 3 2
6T=Q SMO FX2
6TQB LDX 0 AWORK1
6W=2 SMO FX2
6WPL STO 0 AWORK2 [PRESERVE LINE PTR.
6X9= SMO FX2
6XNW STO 0 ACOMMUNE7
6Y8G CALL 7 ZBATT [CALL ROUTINE TO REMOVE TEMP. ATTRIB.
6YN6 SMO 2
6^7Q LDX 3 BLINE(3)
6^MB BZE 3 ZNO7020 [J.NO 7020.
7272 Z7020 CALL 5 NEXCELL
728? ... ADX 3 2 [VALIDITY CHECKS FO RJE CELL
729J ... LDX 7 BNO(3)
72=T ... BZE 7 ZZERR [CANNOT BE ZERO
72#6 ... LDX 7 BTYPE(3)
72*C ... BZE 7 ZZERR [CANNOT BE ZERO
72BN ... LDX 7 BLINE(3)
72C^ ... ANDN 7 #77 [CHECK LINE NO CORRECT
72F= ... SMO FX2
72GH ... SBX 7 ACOMMUNE6
72HS ... BNZ 7 ZZERR
72K5 ... SBX 3 2
72LL SMO FX2
736= LDX 0 AWORK1
73KW SMO FX2
745G STO 0 ACOMMUNE7
74K6 CALL 7 ZBATT
754Q SMO 2
75JB LDX 3 0(3) [LD. PTR. TO NEXT 7020 IN CHAIN.
7642 BNZ 3 Z7020 [J.BACK MORE TO DEAL WITH.
76HL ZNO7020
773= LDX 2 FX2
77GW LDX 0 AWORK2(2)
782G STO 0 AWORK1(2)
78G6 CALL 4 RESCUE [RESCUE LINE PTR.
78^Q BNZ 3 ZLIN [J.BACK TO DEAL WITH NEXT LINE.
794W ... LDX 2 FX2
7982 ... LDX 7 ACOMMUNE4(2)
79?6 ... SBX 7 ACOMMUNE5(2) [CHECK RIGHT NO LINES SEEN
79B= ... BNZ 7 ZZERR
79FB ZNOLIN
79^2 LDX 2 FX2
7=DL LDX 0 AWORK3(2)
7=Y= STO 0 AWORK1(2)
7?CW CALL 4 RESCUE
7?XG BNZ 3 ZUN
7#C6 ZNO7007
7#WQ CALL 7 RECZERO
7*BB LDX 3 BIPB(2)
7*W2 BZE 3 PART4 [J.NO 7900 CHAIN
7B*L ZUNT CALL 5 NEXCELL
7BBK ... ADX 3 2 [VALIDITY CHECKS FOR IPB CELL
7BCJ ... LDX 7 BNO(3) [UNIT NO CANNOT BE ZERO
7BDH ... BZE 7 ZZERR [UNLESS V7900 FLAG SET
7BFG ... LDCH 7 BTYPE(3)
7BGF ... SBN 7 #30 [DEVICE TYPE MUST BE #30
7BHD ... BNZ 7 ZZERR
7BJC ... LDX 7 BNUMB(3)
7BKB ... ANDN 7 #7777
7BL* ... SMO FX2
7BM# ... STO 7 ACOMMUNE4 [REMEMBER HOW MANY IDES
7BN? ... SBX 3 2
7BP= ... SMO FX2
7BQ9 ... STOZ ACOMMUNE5
7BR8 ... SMO FX2
7BS7 ... STOZ ACOMMUNE6
7BT= SMO FX2
7C#W LDX 0 AWORK1
7CSG SMO FX2
7D#6 STO 0 AWORK2 [PRESERVE PTR. TO 7900.
7DRQ SMO FX2
7F?B STO 0 ACOMMUNE7
7FR2 CALL 7 ZBATT [CALL ROUTINE TO REMOVE CONS.PROP.
7G=L SMO 2
7GQ= LDX 3 BLINE(3)
7H9W BZE 3 ZNOID
7HPG ZID CALL 5 NEXCELL
7HQ* ... ADX 3 2 [VALIDITY CHECKS FOR IDE CELL
7HR8 ... LDX 7 BNO(3) [GET IDE NO
7HS3 ... SMO FX2
7HSW ... LDX 6 ACOMMUNE6 [LOOK AT LAST IDE NO
7HTP ... SMO FX2
7HWJ ... STO 7 ACOMMUNE6
7HXC ... SBX 6 7
7HY= ... BPZ 6 ZZERR [CHECK INCREASING SEQUENCE
7H^5 ... LDN 7 1
7H^Y ... SMO FX2
7J2R ... ADS 7 ACOMMUNE5 [INCREMENT NO IDES SEEN
7J3L ... LDX 7 BTYPE(3)
7J4F ... BZE 7 ZZERR [MUST BE NON ZERO
7J5# ... LDCT 7 #200
7J67 ... ANDX 7 BNUMB(3)
7J72 ... BZE 7 ZZERR [MUST HAVE B1 SET
7J7T ... SBX 3 2
7J96 SMO FX2
7JNQ LDX 0 AWORK1
7K8B SMO FX2
7KN2 STO 0 ACOMMUNE7
7L7L CALL 7 ZBATT
7LM= SMO 2
7M6W LDX 3 0(3)
7MLG BNZ 3 ZID
7MPL ... LDX 2 FX2
7MSQ ... LDX 7 ACOMMUNE4(2) [CHECK NO IDES SEEN
7MXW ... SBX 7 ACOMMUNE5(2) [IS RIGHT
7N32 ... BNZ 7 ZZERR
7N66 ZNOID LDX 2 FX2
7NKQ LDX 0 AWORK2(2)
7P5B STO 0 AWORK1(2)
7PK2 CALL 4 RESCUE
7Q4L BNZ 3 ZUNT [J.BACK MORE 7900
7QJ= ...PART4
7R3W ... ACROSS IDFCHK,1
7RHG ...
7S36 ...ZZERR TRACE 2,IDFCLEAN
7SGQ ... DOWN SETIDF,3 [SET ALARM BIT
7T2B ... GEOERR 1,IDFINVAL [BEFORE FALLING IN A HEAP
7TG2 ...#
*C9G MENDAREA 50,K99IDFCLEAN
*CP6 #END
^^^^ ...14352261000600000000