{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: IDFLINE867)}}
====== IDFLINE867 ======
(George Source)
**Macros used:** [[george:macro:ALTLENG|ALTLENG]], [[george:macro:BXE|BXE]], [[george:macro:BXL|BXL]], [[george:macro:CLOSE|CLOSE]], [[george:macro:HUNT2J|HUNT2J]], [[george:macro:HUNTW|HUNTW]], [[george:macro:IDFOPEN|IDFOPEN]], [[george:macro:IDFWRITE|IDFWRITE]], [[george:macro:LGEOG|LGEOG]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MSEARCH|MSEARCH]], [[george:macro:MXB|MXB]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SUICIDE|SUICIDE]], [[george:macro:UP|UP]]
22FL #SEG IDFLINE8 [A C PUTMAN
22PD ...# COPYRIGHT INTERNATIONAL COMPUTERS 1982
22^= #OPT K0IDFLINE=0
23DW #LIS K0IDFLINE>K0ALLGEO>K0GREATGEO>K0COMMAND>K0IDF
23YG 8HIDFLINE
24D6 SEGENTRY K1IDFLINE,XIDF1
24XQ YREC [X3-CONTAINS FORWARD POINTER:X2 POINTS TO CURRENT RECORD
25CB [ON EXIT - X2 IS RECORD POINTER & X3 IS CELL POINTER.
25X2 BPZ 3 SAME
26BL YREC1
26W= SBX 6 FX1
27*W LDX 0 3
27TG SRL 0 9
28*6 ANDN 0 #7777
28SQ LDX 2 FX2
29#B STO 0 ACOMMUNE3(2)
29S2 MXB 2
2=?L ADX 6 FX1
2=R= SAME ANDN 3 #777
2?=W EXIT 6 0
2?QG WRITECLOSE
2#=6 SBX 6 FX1
2#PQ IDFWRITE
2CMG CLOSE
2D76 ADX 6 FX1
2DLQ EXIT 6 0
2DQM ...ZHUNT
2DWJ ... HUNTW 2,IDF,INLINE
2F2F ... EXIT 1 0
2F6B XIDF1
2FL2 IDFOPEN [OPEN THE IDF
2G5L LGEOG 6,4 [LD. INTO X4 GEO.NO.
2GK= LDN 6 0
2H4W SLL 67 12
2HJG SMO FX2
2J46 STO 6 AWORK3 [OLD LINE NO.
2JHQ SRL 7 12
2K3B SMO FX2
2KH2 STO 7 AWORK4 [NEW LINE NO.
2L2L LDN 3 BIPB
2LG= MSEARCH 2,3,4 [HUNT FOR THE IDENTIFIER CHAIN.
2L^W SMO 2
2MFG LDX 3 BLINE(3)
2M^6 ZA CALL 6 YREC [HUNT FOR THE IDENTIFIER CELL
2NDQ LDN 5 #7777
2NYB SMO 2
2PD2 ANDX 5 BNUMB(3) [MASK OUT LINE NO
2PXL SMO FX2
2QC= TXU 5 AWORK3 [BXU 5 , AWORK2 , J. ZD
2QWW BCS ZD
2RBG SMO 2
2RW6 LDX 5 BNUMB(3)
2S*Q ANDX 5 HALFTOP
2STB SMO FX2
2T*2 ADX 5 AWORK4 [REPLACE OLD LINE NO. BY NEW
2TSL SMO 2
2W#= STO 5 BNUMB(3) [ST. NEW LINE NO.
2WRW SMO 2
2X?G LDX 5 5(3) [LD. PTR. TO CONCEPTUAL.
2XR6 BZE 5 ZD [J. LINE IS NOT ATTACHED.
2Y=Q LDX 4 BRECNO(2)
2YQB SLL 4 9
2^=2 ADX 4 3
2^PL SMO FX2
329= STO 4 AWORK2 [PTR. TO IDENTIFIER CELL SAVED.
32NW HUNTW 1,IDF,INLINE
338G BPZ 1 ZC
33N6 ZB SETNCORE 11,1,IDF,INLINE [SET UP BLOCK 11 WORDS LONG.
347Q STOZ AWORK1(2) [PTR. DOWN BLOCK SET ZERO.
34MB LDX 3 AWORK2(2) [LD. PTR. TO IDENTIFIER.
3572 CALL 6 YREC1 [HUNT FOR IDENTIFIER CELL.
35LL HUNTW 1,IDF,INLINE [HUNT FOR BLOCK. J. IF DOES NOT EXIST
366= BNG 1 ZB
36KW ZC SMO FX2
375G LDX 7 AWORK1
37K6 ANDX 5 BITS22LS [MASK OUT ALL BUT B0
384Q SMO 7
38JB STO 5 AI+1(1) [ST. PTR. TO CONCEPTUAL.
3942 SMO 2
39HL LDX 5 BNO(3)
3=3= SMO 7
3=GW STO 5 AI(1) [ST. IDENTIFIER.
3?2G LDCT 5 #400
3?G6 SMO 7
3?^Q STO 5 AI+2(1) [ST. -VE TO INDICATE LAST ENTRY.
3#FB ADN 7 2 [INCREASE POSITION DOWN BLK
3#^2 SMO FX2
3*DL STO 7 AWORK1 [ST. AWORK1
3*Y= ... ADN 7 3
3BCW BXL 7 ALOGLEN(1),ZD [STILL ROOM IN BLOCK.
3BXG BXE 7 ALOGLEN(1),ZD [STILL JUST ENOUGH ROOM.
3C7# ... ADN 7 2 [NOT ENOUGH ROOM.
3CC6 ... ALTLENG 1,7,ZHUNT [ALTER THE LENGTH
3CLY ... CALL 1 ZHUNT
3CWQ ... LDX 1 2
3D6J ... LDX 2 FX2
3DBB LDX 3 AWORK2(2)
3DW2 CALL 6 YREC1 [RE-HUNT FOR IDENTIFIER CELL.
3F*L ZD SMO 2
3FT= LDX 3 0(3) [LD. PTR. TO NEXT IDENTIFIER.
3G#W BNZ 3 ZA [J. NOT ZERO THEREFORE MORE IDENT.
3GSG CALL 6 WRITECLOSE
3H#6 HUNT2J 1,IDF,INLINE,FX2,ZE [J. IF NO BLOCK
3HRQ UP [EXIT BY GOING UP
3HXM ...ZE
3JM5 ... SUICIDE [NO BLOCK FINISH
3JR2 MENDAREA 30,K100IDFLINE
3K=L #END
^^^^ ...52434107000100000000