{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: INCFIN864)}}
====== INCFIN864 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BBS|BBS]], [[george:macro:BC|BC]], [[george:macro:BITDEFS|BITDEFS]], [[george:macro:BS|BS]], [[george:macro:BXE|BXE]], [[george:macro:BXGE|BXGE]], [[george:macro:CHAIN|CHAIN]], [[george:macro:DFCLEAR|DFCLEAR]], [[george:macro:DOWN|DOWN]], [[george:macro:DUMP|DUMP]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FREEFINC|FREEFINC]], [[george:macro:GEOERR|GEOERR]], [[george:macro:HUNTMISB|HUNTMISB]], [[george:macro:HUNTW|HUNTW]], [[george:macro:ISSUCOM|ISSUCOM]], [[george:macro:JBC|JBC]], [[george:macro:JBCC|JBCC]], [[george:macro:JBS|JBS]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:NAME|NAME]], [[george:macro:OUTPACK|OUTPACK]], [[george:macro:OUTPARN|OUTPARN]], [[george:macro:PERMITBRK|PERMITBRK]], [[george:macro:READ|READ]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SKIP|SKIP]], [[george:macro:UNSETBIT|UNSETBIT]], [[george:macro:UP|UP]], [[george:macro:VFREEW|VFREEW]]
22FL ... SEG INCFIN,864,FILESTORE ,INCDUMP
22^= #
23DW SEGENTRY K1INCFIN,X1INCFIN
23NN ... SEGENTRY K2INCFIN,X2INCFIN
23YG #
24D6 # THIS SEGMENT FINISHES CLEARING UP AFTER AN INCREMENT HAS BEEN DUMPED.
24XQ # IT OUTPUTS VARIOUS MESSAGES TO DUMPER'S MON. FILE & THEN GOES DOWN TO
254Y ...# INCRV IF FILES NEED RETRIEVING.
26W= #
273C ...#
2756 ...# AWORK1 SWITCH WORD DEFINITION
276T ...#
278J ...
27=? ... BITDEFS AWORK1,0,MBFINAL
27?F ...#UNS AMTGR
27#M ... BITDEFS AWORK1,2,MBPGENRES [ POTENTIALLY RESTORABLE INCREMENT
27*W #
27TG # MESSAGES
28*6 #
28SQ STAT 28HPOTENTIAL COMPRESSED SIZE
29#B 28HSIZE OF SYS. FILES READ
29J7 ... 28HDIRS SCANNED UNNECESSARILY
29LQ ... 28HDIRS SCANNED FOR TERM FILES
29S2 28HSIZE OF INCREMENT
2=?L STATSIZE
2=R= 28HNO. OF FILES IN INCREMENT
2=X7 28HTIME WAITING FOR DIRECTORIES
2?34 28HTIME WAITING FOR BS TRANSFRS
2?6^ 28HTIME WAITING FOR MT TRANSFRS
2?=W 28HTOTAL TIME TO DUMP
2?QG 28HTIME TO WRITE SENTINELS
2#=6 STATTIME
2#PQ 28HTIME TO WRITE FILES
2#WY XFIVE 1000/K9 [CLEANCTS/SEC
2*46 SIXTY +60
2*9B XBLOCKS 6HBLOCKS
2*F8 ...XENDINC 8HENDINC
2*P2 #
2B8L # THIS SUBROUTINE OUTPUTS A 24-CHAR. STRING FROM THE TABLE ABOVE AS THE
2BN= # 1ST PARAMETER OF A MESSAGE.
2C7W # ON ENTRY, X1=FX1,X2=FX2,X5=ADDRESS OF MESSAGE RELATIVE TO "STAT".
2CMG # X6 IS S/R LINK.
2D76 # ON EXIT, X1=FX1,X2=FX2, X3-> FINC BLOCK. USES X0. COORDINATES
2DLQ #
2F6B OUTBL
2FL2 SBX 6 FX1
2G5L MHUNTW 2,FILE,FINTER [FIND BUFFER BLOCK
2GK= SMO 5
2H4W ADN 1 STAT [X1 -> 28-CHAR. MESSAGE
2HJG ADN 2 A1
2J46 MOVE 1 7
2JHQ OUTPARN 28,A1,FILE,FINTER [OUTPUT CHAR.PART OF MESSAGE
2JQ2 ... MHUNTW 3,FILE,FGET
2KH2 ADX 6 FX1
2L2L EXIT 6 0
2LG= #
2L^W X1INCFIN
2MFG #
2M^6 SETNCORE 7,3,FILE,FINTER [SET UP MESSAGE BUFFER BLOCK
2NDQ #
2NYB # FIRST PUT OUT SIZE" MESSAGES - VALUES ARE ALL IN FINC BLOCK
2PD2 #
2PXL LDN 5 STATSIZE-STAT [INITIALISE MESSAGE MOD
2QC= LDN 7 STATSIZE-STAT/7+1 [INITIALISE COUNT
2QWW SLOOP1
2RBG CALL 6 OUTBL [MESSAGE AS 1ST PARAMETER
2RW6 SMO 7
2S*Q LDX 6 INCCMPSIZE-1(3) [PICK UP VALUE FROM FINC BLOCK
2STB OUTPACK 6,1,NUMA [ SIZE IN BLOCKS AS 2ND PARAMETER
2T*2 LDN 0 STATSIZE-STAT/7+1
2TSL BXE 7 0,SKIP [J IF 1ST MESSAGE
2W#= ADN 1 XBLOCKS
2WRW ADN 2 ACOMMUNE1
2X?G MOVE 1 2
2XR6 OUTPARN 6,ACOMMUNE1 ["BLOCKS" AS 3RD PARAMETER
2Y=Q SKIP
2YQB MONOUT EQUALS [ %A = %B %C
2^=2 SBN 5 7 [DECREASE MESSAGE MODIFIER
2^D= ... MHUNTW 2,FILE,FGET
329= JBS NEXTMESS,2,BINCGENRES [J IF GENERAL RSTABLE
32NW SBN 7 3 [OTHERWISE DON'T WANT LAST 2
338G BZE 7 SLOOP1OUT [MESSAGES (SYS FILES READ STUFF)
33N6 ADN 7 3
347Q NEXTMESS
34MB BCT 7 SLOOP1
3572 SLOOP1OUT
35LL #
366= # NOW PUT OUT "TIME" MESSAGES - AGAIN,VALUES IN FINC BLOCK.
36KW #
375G LDN 5 STATTIME-STAT [INITIALISE MESSAGE MOD
37K6 LDN 7 STATTIME-STATSIZE/7 [INITIALISE COUNT
384Q SLOOP2
38JB CALL 6 OUTBL [MESSAGE AS FIRST PARAMETER
3942 SMO 7
39HL LDX 4 INCDIRWAIT-1(3) [PICK UP NEXT TIME FROM FINC BLOCK
39X* LDX 1 FX1
3=?4 DVS 3 XFIVE(1) [X4=TIME IN SECS
3=LR DVS 3 SIXTY(1) [X4=MINS,X3=SECS
3?2G OUTPACK 4,1,NUMA
3?G6 OUTPACK 3,1,NUMB
3BXG MONOUT EQUTIME [ %A = %B MINS %C SECS
3CC6 SBN 5 7 [DECREASE MESSAGE MODIFIER
3CWQ BCT 7 SLOOP2
3DBB MFREEW FILE,FINTER [FREE BUFFER BLOCK
3DW2 #
3F*L # NOW GO TO RETRIEVE FILES,IF NECESSARY
3FT= #
3FXS ... MHUNTW 1,FILE,FINCPROC
3GSG LDX 5 INCRV(1) [NO OF FILES TO BE RVED
3H#6 BZE 5 NORVS [J IF NONE
3HRQ BBS 3,FINISH,YFIN [DON'T DO RVS IF FINISHED HAS
3J?B [OCCURRED
3JR2 JBS YFIN,,BDOGENRES [DON'T DO RVS IF FILESTORE CORRUPT
3K=L DOWN INCRV,1 [GO AND DO THEM
3KQ= NORVS
3KQL ...#
3KQQ ...# IF THE RESTORE TIME MACRO 'INCSTEND' IS INCLUDED AND WE ARE NOT
3KQW ...# PART-WAY THRU A PARALLEL DUMP THEN WE ISSUE THE J.D. MACRO ENDINC
3KR2 ...#
3KR6 ... MHUNTW 3,FILE,FINC
3KR= ... BPZ 3 NOCOM [J IF MIDWAY THRU PL DUMP
3KRB ... SEGENTRY K50INCFIN
3KRG ... BRN NOCOM [IF INCSTEND MACRO INCLUDED ISSUE
3KRH ...#UNS AMTGR
3KRJ ...(
3KRK ... JBC YESCOM,,BMTGR [ NO PROBLEM IF NOT USING MTGR
3KRL ... JBC NOCOM,2,MBFINAL [NOT FINAL GEN. REST. INCR.
3KRN ...YESCOM
3KRP ...)
3KRQ ... SETNCORE CPDATA+2-A1,2,ADATA,CREADL [COMMAND 'ENDINC'. THIS ALLOWS
3KRR ... LDN 0 6 [SITES TO TAKE SPECIAL ACTION IF NECE
3KRW ... STO 0 A1(2)
3KS2 ... ADN 1 XENDINC
3KS6 ... ADN 2 CPDATA
3KS= ... MOVE 1 2
3KSB ... ISSUCOM NOCOM
3KSG ...NOCOM
3KT6 ...# *****************************************************************
3KT9 ...# WE NOW DECIDE WHETHER WE MAY NEED THE FINC
3KT# ... MHUNTW 3,FILE,FGET
3KT* ...#UNS AMTGR
3KTB ... JBS NMTGREOT,,BMTGR
3KTC ... JBS ZFREEFINC,3,BINCEOT [ WE CAN'T USE IT IF HIT EOT OR FAIL
3KTD ...#UNS AMTGR
3KTF ...NMTGREOT
3KTG ... JBS NOFREE1,,BNOWD
3KTK ... JBS ZFREEFINC,2,MBFINAL [ FREE IT IF NO BSU REQUEST AND FINAL
3KTN ...NOFREE1
3KTR ... HUNTW 1,FILE,FINC
3KTW ... BNG 1 NOFREE3
3KT^ ... LDX 0 INCNO(1) [ MAY BE PARALLEL INC
3KW4 ... BXGE 0 INCNO(3),ZFREEFINC [ HIGHER FINC RETAINED
3KW7 ...NOFREE3
3KW= ... NAME 3,FILE,FINC
3KW* ... CHAIN 3,BMISC+1 [ CHAIN ON END OF MISC CHAIN
3KWD ... BRN NOFREE2
3KWH ...ZFREEFINC
3KWL ... FREEFINC 3 [ WE HAVE NO USE FOR TAPES
3KWP ...NOFREE2
3KWS ...# ******************************************************************
3KXD ...UP UP
3SK2 YFIN
3SQ8 ... STOZ INCRV(1) [CLEAR RV COUNT
3SXB ...YFIN2
3T4L MFREEW FILE,FABSNB [FREE ALL THE FABS, SINCE WONT USE
3TJ= [THEM
3W3W ... BCT 5 YFIN2
3WHG BRN NORVS
3X36 #
3X3B ...# ******************************************************************
3X3L ...#
3X3W ...# X2INCFIN
3X46 ...# ********
3X4B ...X2INCFIN
3X4L ...# THIS ENTRY POINT IS AN OVERFLOW FROM INCEND
3X4W ...#
3X56 ...# BEFORE CARRYING ON WE MUST CLEAR THE 'DUMP' BIT FOR ANY TAPE
3X5B ...# CLUSTERS WE USED.
3X5L ...#
3X5W ... LDX 2 JPTI+5
3X66 ... LDX 5 JPTI+6
3X6B ... SBX 5 2 [NO OF DECKS
3X6L ...UNSETBIT
3X6W ... LDX 3 0(2) [X3->DEVLIST FOR DECK
3X76 ... DFCLEAR 3,DUMP
3X7B ... ADN 2 1
3X7L ... BCT 5 UNSETBIT [J IF MORE TAPE DEX ON MC
3X7W ... MFREEW FILE,FQUAL
3X86 ...#
3X8B ...# IF WE ARE FINISHED WE ENDCOM OTHERWISE WE REENTER
3X8L ...# SEGMENT INCWAIT TO COMMENCE PREPARATIONS FOR ANOTHER INCREMENT
3X8W ...#
3X96 ... HUNTW 3,FILE,FINC [J IF STILL PRODUCING INC
3X9B ... BPZ 3 NFINAL
3X9L ... MFREEW FI,FDUMPFAB [FREE FABSNB
3X9W ... BC ,BPARALLEL [IF TWAS PARALLEL TAINT NOW
3X=6 ... JBC NFINAL,2,MBFINAL [J IF MORE INCS NEEDED
3X=B ... JBS XCORRPT,,BDOGENRES [J IF FILESTORE CORRUPT
3X=L ... PERMITBRK [ALLOW BREAKIN FOR JOB DESCRIPTS
3X=W ... [BENEFIT
3X?6 ... VFREEW FILE,FINCPROC [DISPOSE OF FINCPROC, IF ONE
3X?B ...#UNS JSKI33
3X?L ... BC 2,EXDUMPER [CLEAR 'DUMPER CPAT' BIT
3X?W ... BC ,BIDCOM [END OF INCDUMP DUMP OR NOW COMMAND
3X#6 ...#UNS IDC
3X#B ...(
3X#L ...#
3X#W ...#
3X*6 ... JBS ZIGNORE,,BNOWD [ JUMP IF NO UNJAMMER REQUEST
3X*B ... JBCC ZIGNORE,,BDCISS [ JUMP IF NO STORED DUMP COMMAND
3X*L ... HUNTMISB 1,FI,FDUCOM
3X*W ... FREECORE 1
3XB6 ... MONOUT INCIGNORED [ STORED DUMP COMMAND IGNORED[
3XBB ...# NO FURTHER INCREMENTS NEEDED
3XBL ...ZIGNORE
3XBN ... BITDEFS CLONG1,1,XBSPRIV [ BS PRIVILEGED MARKER
3XBQ ... BC 2,XBSPRIV [ CLEAR BS PRIVILEGE
3XBW ...#
3XC6 ...)
3XCB ... ENDCOM
3XCL ...XCORRPT
3XCW ... GEOERR BRIEFPM,BAD FS??
3XD6 ...NFINAL
3XDB ... LDCT 7 #400 ['DO NOT WAIT ' MARKER
3XDL ... ACROSS INCWAIT,1 [GO ACROS FOR ANOTHER INCR
3XDW ...#
3XF6 ...# ******************************************************************
3XFB ...#
3XGQ MENDAREA 20,K99INCFIN
3Y2B #
3YG2 #END
^^^^ ...71730415000300000000