{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: INCOM864)}}
====== INCOM864 ======
(George Source)
**Macros used:** [[george:macro:ABANDCOM|ABANDCOM]], [[george:macro:ACROSS|ACROSS]], [[george:macro:ALTLEN|ALTLEN]], [[george:macro:BCONTEXT|BCONTEXT]], [[george:macro:BXE|BXE]], [[george:macro:BXU|BXU]], [[george:macro:CHNUMCON|CHNUMCON]], [[george:macro:COMBRKIN|COMBRKIN]], [[george:macro:COMERRX|COMERRX]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:ERROR|ERROR]], [[george:macro:FJOCA|FJOCA]], [[george:macro:FNORM|FNORM]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHCODE|FSHCODE]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:FSHSKIP|FSHSKIP]], [[george:macro:JBSS|JBSS]], [[george:macro:MBC|MBC]], [[george:macro:MFREE|MFREE]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:NAMETOP|NAMETOP]], [[george:macro:OUTPACK|OUTPACK]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SPARAPAS|SPARAPAS]], [[george:macro:TEST|TEST]], [[george:macro:TESTNAMX|TESTNAMX]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:TRANSBEG|TRANSBEG]], [[george:macro:TRANSFIN|TRANSFIN]]
22FL SEG INCOM,3,MIKE PUTNAM,INCDUMP
22^= #
23DW SEGENTRY K1INCOM,X1INCOM
23NN ... FSHENTRY K2INCOM,X2INCOM,,X2INCOM
23YG #
24D6 # THIS SEGMENT ANALYSES THE "INCDUMP" COMMAND & GIVES COMMAND ERRORS IF
24XQ # 1) NOT ISSUED FROM JOB RUNNING UNDER =DUMPER
25CB # 2) 1ST PARAMETER MISSING OR NULL
25X2 # 3) 1ST PARAMETER NOT RECOGNISED
26BL # THE SEGMENT THEN TAKES ACTION ACCORDING TO THE 1ST PARAMETER AS FOLL
26W= # DUMP SEGMENT GOES ACROSS TO INCWAIT WITH X7=0
27*W # NOW AS FOR DUMP, EXCEPT B0 OF X7 SET
27TG # RETURN MAY HAVE A 2ND PARAMETER. TAKE ACTION AS FOLLOWS:-
28*6 # A) IF ABSENT OR NULL, ASSUME ALL OBSOLETE TAPES TO BE RET
28SQ # (X6 SET -IVE).
29#B # B) IF A +IVE NUMBER, MAX. NO. OF OBSOLETE TAPES TO RETURN
29S2 # TO THE POOL (SET IN X6).
2=?L # C)IF MT ENTRANT DESCRIPTION, TAPE TO BE RETURNED IF OBSOL
2=R= # IF 2ND PARAM. IS MT ENTRANT, 3RD AND SUBSEQUENT PARAMETER
2?=W # MAY BE SPECIFIED BUT THEY MUST BE MT ENTRANTS
2?QG # (TSNS PUT IN FINTER1 BLOCK)
2#=6 # IF 2ND & SUBSEQUENT PARAMETERS ARE INCORRECT,
2#PQ # ERROR MESSAGES ARE GENERATED AND THEN THE FOLLOWING PARAM
2*9B # ARE EXAMINED & DEALT WITH.
2*P2 # GOES ACROSS TO INCOBS WITH X7=0.
2B8L # REUSE SAME AS RETURN EXCEPT TAPES TO-BE-REUSED (INDICATED BY X7
2BN= # INSTEAD OF RETURNED.
2C7W # QUEST GOES ACROSS TO DTQUEST TO ASK OPERATORS ABOUT INCREMENTS
2CMG # WITH ALL TAPES WRONGED.
2D76 # COMPRESS GOES ACROSS TO COMPRESS(ENTRY 2,FOR ODDREASONS)
2DLQ # RETRIEVE COUNTS ALL FREQ BLOCKS IN THE OFFLINE CHAUN.
2F6B # IT THEN OUTPUTS THE MESSAGE %A FILES BEING RETRIEVED
2FL2 #
2G5L # GIVES COMERR IF 1ST PARAM. IS DUMP OR QUEST AND THE JOB IS NOT
2GK= # SYSTEM-ISSUED.
2H4W #
2HJG # CONSTANTS
2J46 #
2J=B ...START
2JDL ... FSHSKIP B
2JLW ...(
2JT6 ... 8HDUMP
2K3B +XINCWT [LABEL TO BRANCH TO IF PARAM. IS DUMP
2KH2 8HNOW
2L2L +XNOW
2L=D ...)
2LG= 8HRETURN
2L^W +XRET
2MFG 8HREUSE
2M^6 +XREU
2N6# ... FSHSKIP B
2N?G ...(
2NDQ 8HQUEST
2NYB +XQ
2P88 ...)
2PD2 8HCOMPRESS
2PXL +XCOMPRESS
2QC= 8HRETRIEVE
2QWW +XRV
2RBG +0,0,0 [SPARE FOR MENDING IN EXTRA PARAMETER
2RW6 +0,0,0 [1ST ZERO INDICATES END OF LIST
2S*Q +0
2STB #
2T*2 ZDUMP 12HDUMPER
2TSL ZPAR +JPARMIS [PARAMETER MISSING
2T^S ... FSHSKIP B
2W72 ...(
2W#= ZNEG +JNEGNO [NEGATIVE NUMBER NOT ALLOWED IN %C
2WRW ZUSE +ERINUSE [COMMAND BEING USED BY ANOTHER JOB
2X3N ...)
2X?G ZINC +INCDUMP [THIS COMMAND NOT FOR GENERAL USE
2XR6 ZERM +ERMCH [PARAMETER NOT RECOGNISED
2Y=Q #
2YQB # SUBROUTINE
2^=2 #
2^PL # CHECKS IF CURRENT JOB IS SYSTEM-ISSUED. GIVES A COMERR IF IT ISN'T.
329= # ON ENTRY,X2=FX2. X4 IS S/R LINK.
32NW # ON EXIT, X2=FX2. USES X0.
338G XCHSYSIS
33N6 BCONTEXT (4),2,SYSISS [EXIT IF SYSTEM ISSUED
347Q NOSYS
34MB LDX 0 ZINC(1) [COMMAND NOT FOR GENERAL USE
3572 BRN XCOM
35LL #
366= #
36KW X1INCOM
375G FJOCA 3,2 [X3-> CURRENT JOB BLOCK
37K6 TESTNAMX 3,JUSER(3),ZDUMP(1),NOSYS,2 [J IF JOB NOT RUN UNDER =DUM
384Q SPARAPAS [1ST PARAMETER
389Y ... FSHCODE A,X2INCOM
38C6 ...X2INCOM [REENTRY POINT IN A MACHINE
38JB MHUNT 2,CPB,CUNI
3942 LDX 3 ANUM(2)
39HL BNG 3 NONE [J IF PARAMETER MISSING
3=3= BZE 3 NONE [J IF PARAMETER NULL
3=GW ANDN 3 #7777 [X3= NO. OF CHARS. IN PARAMETER
3?2G SBN 3 9
3?G6 BPZ 3 XER [J IF >8 CHARS.
3?^Q ADN 3 12
3#FB SRL 3 2 [X3= NO. OF WORDS IN PARAMETER
3#^2 LDX 4 3 [PRESERVE NO. OF WORDS
3*DL SBN 1 3
3*Y= TEST
3BCW LDX 3 4 [X3= NO. OF WORDS IN PARAMETER
3BXG ADN 1 3 [X1-> NTH PARAMETER IN LIST
3CC6 LDX 0 START(1) [X0= 1ST WORD OF PARAMETER IN LIST
3CWQ BZE 0 XER [J IF PARAMETER NOT IN LIST
3DBB NEXT
3DW2 SMO 3
3F*L LDX 0 -1+APARA(2) [X0= NEXT WORD OF PARAM.
3FT= SMO 3
3G#W BXU 0 -1+START(1),TEST [J IF NOT THIS PARAMETER
3GSG BCT 3 NEXT [J IF MORE WORDS TO TEST
3GTN ... FSHCODE B,XFSHBTRAN
3GWW ...(
3GY4 ...# INCDUMP CODE MUST ONLY BE OBEYED ON MACHINE A
3G^= ...# PARAMETERS 'DUMP','NOW' AND 'QUEST' FORBIDDEN ON MACHINE B
3H2D ... TRANSBEG FSHINCDUMP,INCOM,2,CLB,,ACOMMUNE1
3H3L ... BRN XFSHBEND ['ENDCOM' RETURN
3H4S ... BRN XABANDCOM ['ABANDCOM' RETURN
3H62 ... BRN XCOMBRKIN ['COMBRKIN' RETURN
3H78 ...XFSHBTRAN
3H8B ...)
3H9J ... FSHSKIP B
3H=Q ...(
3H#6 LDX 3 START+2(1) [X3-> LABEL IN LIST TO BRANCH TO
3HRQ FREECORE 2 [FREE CPB/CUNI BLOCK
3J?B ADX 3 FX1
3JR2 LDN 7 0 [CLEAR MARKER WORD
3K=L EXIT 3 0 [BRANCH TO APPROPRIATE CODE TO DEAL W
3KQ= [ PARTICULAR PARAMETER
3L9W #
3LPG #
3M96 XNOW
3MNQ LDCT 7 #400 [SET "GO TO DUMP IMMEDIATELY" MARKER
3N8B XINCWT
3NN2 CALL 4 XCHSYSIS [CHECK SYSTEM-ISSUED JOB
3P7L JBSS XINUSE,,BIDCOM [SET 'DUMP OPERATING' BIT
3PM= [UNLESS ALREDY SET WHEN ERROR
3Q6W [ENSURE NEVER 2 DUMPERS SIMULTANEOUSL
3Q#4 ...#UNS FNSAD2
3QF= ... MBC ,BATCHSTART,BATCHFIN [ NEITHER STARTEDNOR FINI
3QLG ACROSS INCWAIT,1 [GO TO WAIT (IF NECESSARY) AND DUMP
3R66 #
3R*Y ...)
3RKQ XREU
3RQY ... FSHSKIP B
3RY6 ...(
3S5B LDN 7 1 [SET "REUSE" MARKER
3S*8 ...)
3SK2 XRET
3SQ8 ... FSHSKIP B
3SXB ...(
3T4L SPARAPAS [GET 2ND (OR SUBSEQUENT) PARAMETER
3TJ= MHUNT 3,CPB,CUNI
3W3W LDX 0 JPARNUM(3)
3WHG SBN 0 3
3X36 BPZ 0 PNOTNUM [J IF >2ND PARAMETER
3XGQ NGN 6 1 [SET "ALL" MARKER OPTIONALLY
3Y2B NGX 0 ANUM(3)
3YG2 BPZ 0 XALL [J IF 2ND PARAMETER MISSING OR NULL
3Y^L [ THEN ALL OBSOLETE TAPES TO BE REL
3^F= SETNCORE 0,2,FILE,FINTER1 [BLOCK TO PUT TSNS (IF ANY)
3^JB ... MHUNT 3,CPB,CUNI
3^MG ... LDCH 0 APARA(3)
3^QL ... SBN 0 #30
3^TQ ... BZE 0 NOTNUM
3^YW CHNUMCON 1 [SEE IF 2ND PARAM IS A NUMBER (NO ERR
42DG MHUNT 3,CPB,CUNI
42Y6 TESTREP2 CHNUMERR,NOTNUM [J IF NOT VALID NUMBER FORMAT
43CQ MHUNTW 1,CPAR,GNUMCON
43XB LDX 6 A1+1(1) [X6= NO. OF TAPES TO RELEASE
44C2 FREECORE 1
44WL MFREEW FILE,FINTER1
45B= BNG 6 NEG [J IF NO. OF TAPES -IVE
45TW XALL
46*G FREECORE 3 [FREE CPB/CUNI
46T6 ACROSS INCOBS,1 [GO & RETURN OR MARK AS NOT USED NO.O
47#Q [ MTS SPECIFIED (OR LESS) OR LIST O
47SB [ MTS SPECIFIED
4848 ...)
48#2 XCOMPRESS
48F8 ... FSHSKIP B
48LB ...(
48RL ACROSS COMPRESS,2 [ENTRY 2 FOR HISTORICAL REASONS
49?= PNOTNUM
49QW LDX 0 ANUM(3)
4==G BZE 0 MFREE [J IF 3RD (OR SUBSEQUENT) PARAMETER N
4=Q6 BNG 0 XALL [J IF NO MORE PARAMS.
4?9Q NOTNUM
4?PB NAMETOP 3,FILE,FNAME [RENAME UNI BLOCK
4#92 FNORM [SEE IF PARAM. IS VALID ENTRANT DESCR
4#NL MHUNT 3,FILE,FNAME
4*8= NAMETOP 3,CPB,CUNI [RENAME PARAM BLOCK TO UNI
4*MW TESTREP2 NAMEFORM,MFREE [J IF NOT CORRECT ENTRANT DESCRIPTION
4B7G MHUNT 2,FILE,FABSNB
4BM6 LDX 3 ATYPE(2)
4C6Q ANDN 3 #2000
4CLB SMO HDREC(2)
4D62 LDX 4 A1+1(2) [X4= TSN SPECIFIED (IF ANY)
4DKL FREECORE 2 [FREE FABSNB
4F5= BZE 3 XFINT [J IF NOT MT ENTRANT
4FJW MHUNTW 3,FILE,FINTER1
4G4G LDX 5 ALOGLEN(3)
4GJ6 BZE 5 NOTSN [J IF NO PREVIOUS TSNS
4H3Q SLOOK
4HHB SMO 5
4J32 BXE 4 A1-1(3),MFREE [J IF TSN ALREADY KNOWN
4JGL BCT 5 SLOOK [J IF MORE TSNS TO SEARCH
4K2= LDX 5 ALOGLEN(3)
4KFW NOTSN
4K^G ADN 5 1
4LF6 ALTLEN 3,5,FILE,FINTER1 [LENGTHEN FINTER1 BLOCK BY 1 WORD
4LYQ MHUNTW 3,FILE,FINTER1
4MDB SMO 5
4MY2 STO 4 A1-1(3) [INSERT NEW TSN
4NCL MFREE
4NX= MFREE CPB,CUNI
4PBW BRN XRET
4PWG XFINT
4QB6 ERROR AMISS,ERNOP [OUTPUT ERROR MESSAGE "SERIAL NUMBER
4QTQ BRN MFREE
4R*B #
4RT2 XQ [SOME INCRS. HAVE ALL OF THEIR TAPES
4S#L [WRONGED. NEED TO ASK OPERATORS IF T
4SS= [WANT TO TAPERIGHT ANY.
4T?W ACROSS DTQUEST,1 [ENTER QUESTIONING SEGMENT
4TRG #
4W3# ...)
4W?6 XRV
4WD# ... FSHSKIP B
4WKG ...(
4WQQ LDX 3 BOLC [X3->IST BLOCK ON OLC
4X=B LDN 7 0 [COUNT OF FREQS
4XQ2 RVLOOP
4Y9L BXE 3 CXOL,RVEND [J IF END OF OLC
4YP= LDX 0 ATYPE(3) [TYPE OF BLOCK
4^8W SRL 0 12
4^NG SBN 0 FILE+FREQ
5286 BNZ 0 RVNEXT [J IF NOT A FREQ
52MQ ADN 7 1 [INCR. COUNT
537B RVNEXT
53M2 LDX 3 FPTR(3) [LINK DOWN CHAIN
546L BRN RVLOOP
54L= RVEND
555W OUTPACK 7,1,NUMA
55KG MONOUT INCDUMPRV [%A FILES BEING RETRIEVED
55LR ... FSHCODE A,XFSHAEND
55N4 ...(
55P* ... TRANSFIN ,,ALIEN
55QL ...XFSHAEND
55RX ...)
55T8 ...)
55WF ... FSHCODE B,XFSHBEND
55XQ ...(
55^3 ... BRN (GEOERR)
562# ...XFSHBEND
563K ...)
5656 ENDCOM
56JQ #
574B #
579J ... FSHSKIP B
57BQ ...(
57J2 XINUSE
583L LDX 0 ZUSE(1) [COMMAND BEING USED BY ANOTHER JOB
58H= BRN XCOM
58R4 ...)
592W XER SMO FX1
59GG LDX 0 ZERM [PARAMETER NOT RECOGNISED
5=26 BRN XCOM
5=7# ... FSHSKIP B
5=#G ...(
5=FQ NEG LDX 0 ZNEG(1) [PARAMETER -IVE
5=^B BRN XCOM
5?98 ...)
5?F2 NONE
5?YL LDX 0 ZPAR(1) [PARAMETER MISSING
5#D= XCOM
5#XW COMERRX 0 [GIVE APPROPRIATE COMMAND ERROR
5*CG #
5*G^ ... FSHCODE B,XFSHBCOM
5*LD ...(
5*PX ...XABANDCOM
5*TB ... ABANDCOM
5*YT ...XCOMBRKIN
5B4# ... COMBRKIN
5B7R ...XFSHBCOM
5B?= ...)
5BBQ #
5BWB #END
^^^^ ...32650060000200000000