{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: INCRCUBS860)}}
====== INCRCUBS860 ======
(George Source)
**Macros used:** [[george:macro:BBUS|BBUS]], [[george:macro:BC|BC]], [[george:macro:BFCBX|BFCBX]], [[george:macro:BITDEFS|BITDEFS]], [[george:macro:BSXD|BSXD]], [[george:macro:BXL|BXL]], [[george:macro:DOWN|DOWN]], [[george:macro:FCJOB|FCJOB]], [[george:macro:GEOERR|GEOERR]], [[george:macro:JBC|JBC]], [[george:macro:JBCS|JBCS]], [[george:macro:JBS|JBS]], [[george:macro:JMBAC|JMBAC]], [[george:macro:MBSXD|MBSXD]], [[george:macro:PSTAC|PSTAC]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETREP|SETREP]], [[george:macro:SETREP2|SETREP2]], [[george:macro:SFCA|SFCA]], [[george:macro:SFSTACK|SFSTACK]], [[george:macro:TESTREP2|TESTREP2]], [[george:macro:TRACEIF|TRACEIF]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]]
22FL ... SEG INCRCUBS,860,FILE,FILESTORE
22^= #
238P ... BITDEFS AWORK4,0,XBCOMM [UPDATE OTHER COMMUNAL USERS OF THIS
23D8 ... BITDEFS AWORK4,1,XBWHOLE ["WHOLE FILE" MAY BE SPECIFIED AS %C
23MM ... BITDEFS AWORK4,3,XBFORCED ["FORCED" SPECIFIED
23X6 ... BITDEFS AWORK4,4,XBANSWER ["ANSWER" SPECIFIED
246K ... BITDEFS AWORK4,5,XBSUBCUBS [SUBCUBS MACRO
24B4 ...#
24KH ...#
24T2 ... SEGENTRY K1INCRCUBS,X1INCRCUBS [APPCUBS MACRO (1 BLOCK INCREA
254F ... NULL [NEEDED TO MAINTAIN SEGENTRY POSITION
25?Y ... NULL
25HC ...#
25QW ... SEGENTRY K2INCRCUBS,X2INCRCUBS [INCREAMBS MACRO
262* ...#
269S ...#
26F? ... SEGENTRY K3INCRCUBS,X3INCRCUBS [INCRECUBS MACRO (%A BREAK-IN
26NQ ... [ACOMMUNE1 INCREASE REQUIRED
26Y9 ... SEGENTRY K31INCRCUBS,X31INCRCUBS [INCRECUBS MACRO (%A BREAK-IN
277N ... [ACOMMUNE1 CONTAINS INCREASE)
27C7 ... SEGENTRY K32INCRCUBS [INCRECUBS MACRO (%A FORCED, %
27LL ... [ INCREASE SPECIFIED, FILE OP
27W5 ... [ACOMMUNE1 INCREASE REQUIRED,
285J ... MBSXD 0,XBCOMM,XBFORCED [SET "FORCED" & "UPDATE COMMUNAL USER
28*6 BRN TFCA
28PL ... SEGENTRY K33INCRCUBS [INCRECUBS MACRO (%A ANSWER, %
2966 ... [ INCREASE SPECIFIED, FILE OP
29GL ... [ACOMMUNE1 INCREASE REQUIRED,
29X6 ... MBSXD 0,XBCOMM,XBANSWER ["ANSWER" & "UPDATE COMMUNAL USERS" B
2=?L BRN TFCA
2=R= #
2?5M ...#
2?D4 ... SEGENTRY K4INCRCUBS [LOBSFILE MACRO (ZERO DEPTH)
2?QG LDN 4 0 [DEPTH 0
2#=6 BRN MLOBSF
2#PQ ... SEGENTRY K41INCRCUBS,X41INCRCUBS [LOBSFILE MACRO (SPECIFIED DEP
2*9B ...#
2*P2 ... SEGENTRY K5INCRCUBS,X5INCRCUBS [SUBCUBS MACRO
2B8L ...#
2BN= ... SEGENTRY K7INCRCUBS,X7INCRCUBS [NOLOBSFILE MACRO
2DLQ #
2F6B ...[
2FL2 ...[
2G5L ...[ SUBROUTINES
2GK= ...[ -----------
2H4W ...[
2HJG ...[
2J46 ...[ THIS SUBROUTINE SEARCHES FOR A FILE'S FILE CONTROL AREA (FCA)
2JHQ ...[ ON ENTRY, X2=FX2, AWORK3= DEPTH OF FILE. X6 IS S/R LINK
2K3B ...[ ON EXIT , X1->FCA, X2=FX2. X0 DESTROYED.
2KH2 ...SFCA
2L2L ... SFSTACK AWORK3(2),1 [X1-> FCA
2LG= ... EXIT 6 0
6F46 [
6FHQ [ X2-> ACT. WHOSE JOB BLOCK IS TO BE SOUGHT (USUALLY CURRENT ACT.)
6G3B [
6GH2 SJOBLOCK
6H2L LDX 0 JOBNO(2)
6HG= BZE 0 NOLOBJOB [ERROR IF JOB NO. ZERO
6H^W FCJOB 1,2,,CPA,OLPA [X1-> JOB BLOCK
6MC= EXIT 6 0
6PTB [
6Q*2 [ ON ENTRY, X1-> JOB BLOCK, X2=FX2.
6QSL [
6R#= ...REQMORE
6RRW SBX 4 FX1
6S?G ... DOWN INCRCUBX,1 [ASK OPS FOR MORE ONLINE BS
6SR6 ... BRN UP [BREAK-IN -- GO STRAIGHT UP
6T=Q ... CALL 6 SJOBLOCK [X1-> JOB BLOCK
6TQB ... ADX 4 FX1
6W=2 ... EXIT 4 0
953L #
953R ...[
953Y ...[
9545 ...[ ENTRY FOR APPCUBS MACRO
954= ...[
954C ...[
954J ...X1INCRCUBS
954P ... LDN 3 1 [INCREASE IS 1 BLOCK
954W ... BSXD 0,XBCOMM [SET "UPDATE OTHER COMMUNAL USERS" MA
9553 ... STO 0 AWORK4(2)
9558 ... STO 6 AWORK3(2) [REMEMBER DEPTH
955* ... CALL 6 SFCA [X1-> FCA
955G ... JBC TESTCOMM,1,BACUBS [J IF PUBLIC (IF SO, MUST ALSO BE COM
955M ... LDX 6 ACOMMUNE1(2)
955S ... BZE 6 OTHERERR [GEOERR IF NO OPTIONAL PARAMETER GIVE
955^ ... SLL 6 1
9566 ... BPZ 6 NANS [J IF NO "ANSWER" PARAM. TO APPEND ET
956? ... BSXD 0,XBANSWER [SET "ANSWER" MARKER
956D ...NANS
956K ... SLL 6 1
956Q ... BPZ 6 NFORC [J IF NO "FORCED" PARAMETER
956X ... BSXD 0,XBFORCED [SET "FORCED" MARKER
9574 ...NFORC
9579 ... ORS 0 AWORK4(2)
957B ... JBS TPUB,1,BACOMM [J IF FILE OPEN COMMUNALLY (CUBS NOT
957H ... CALL 6 SJOBLOCK [X1-> JOB BLOCK
957N ... BRN XCD
957T ...[
9582 ...[ ENTRY FOR INCREAMBS MACRO (ANY USE OF THE MACRO)
9587 ...[
958# ...[
958F ...[
958L ...[
958R ...X2INCRCUBS
958Y ... CALL 6 SJOBLOCK [X1-> JOB BLOCK
9595 ... LDX 3 ACOMMUNE1(2) [REQUIRED INCREASE
959= ... ADS 3 CUBS(1)
959C ... TRACEIF K6INCRCUBS,199,399,JNAME(1),AMBS JBN [INCREAMBS MACRO :
959J ... TRACEIF K6INCRCUBS,199,399,CUBS(1),AMBSCUBS [INCREAMBS MACRO :
959P ... SETREP2 OK [OPTIONALLY SET OK REPLY
959W ... LDX 0 AMBS(1)
95=3 ... SBX 0 CUBS(1)
95=8 ... BPZ 0 QBIGR2 [J IF AMBS NOT EXCEEDED
95=* ... CALL 4 REQMORE [GO AND ASK OPS TO INCREASE JOB'S LIM
95=G ... TESTREP2 REFUSED,UP1 [EXIT IF REQUEST REFUSED
95=M ...QBIGR2
95=S ... SBS 3 CUBS(1) [RESET CUBS - TO USE THE AMOUNT GIVEN
95=^ ... [BY OPS THE APPEND (ETC.) MUST
95?6 ... [BE REISSUED
95?? ... BRN UP1
95?D ...[
95?K ...[ ENTRY FOR INCRECUBS MACRO
95?Q ...[ ACOMMUNE1 CONTAINS INCREASE IN BLOCKS
95?X ...[ ACOMMUNE2 DEPTH OF FILE
95#4 ...[
95#9 ...X3INCRCUBS
95#B ... MBSXD 0,XBCOMM,XBWHOLE [SET MARKER TO UPDATE CUBS FOR
95#H ... [OTHER USERS OF THIS FILE - ALSO "INC
95#N ... [ MAY HAVE B0 SET (WHOLE FILE)" BIT
95#T ...TFCA
95*2 ... LDX 3 ACOMMUNE1(2) [X3= INCREASE IN BLOCKS
95*7 ... STO 0 AWORK4(2) [SET RELEVANT BIT MARKERS
95*# ... LDX 0 ACOMMUNE2(2)
95*F ... STO 0 AWORK3(2) [REMEMBER DEPTH
95*L ... SETREP2 OK [OPTIONALLY SET OK REPLY
95*R ... CALL 6 SFCA [X1-> FCA
95*Y ...TPUB
95B5 ... JBC TESTCOMM,1,BACUBS [J IF PUBLIC
95B= ... JBC NOTWHOLE,2,XBWHOLE [J IF "WHOLE FILE" MAY NOT BE SPECIFI
95BC ... BPZ 3 NOTWHOLE [J IF "WHOLE FILE" NOT SPECIFIED
95BJ ... BC 2,XBCOMM [CLEAR "UPDATE OTHER COMMUNAL USERS"
95BP ... PSTAC 1,1
95BW ... BFCBX 1,1 [X1-> FCB
95C3 ... LDX 3 FBLMOD(1)
95C8 ... SBN 3 FBLKS-A1 [X3= NO. OF BLOCKS IN INCREASE (WHOLE
95C* ... TRACEIF K6INCRCUBS,199,399,3,INCRWHOL
95CG ...NOTWHOLE
95CM ... BNG 3 OTHERERR [J IF NO. OF BLOCKS -IVE
95CS ... CALL 6 SJOBLOCK [X1-> JOB BLOCK
95C^ ... ADS 3 CUBS(1) [UPDATE CUBS
95D6 ... TRACEIF K6INCRCUBS,199,399,JNAME(1),INCR JBN [INCRECUBS
95D? ... TRACEIF K6INCRCUBS,199,399,CUBS(1),INCRCUBS
95DD ... LDX 0 AMBS(1)
95DK ... SBX 0 CUBS(1)
95DQ ... BPZ 0 NOTXCD [J IF AMBS NOT EXCEEDED
95DX ...XCD
95F4 ... JBS NOTXCD,2,XBFORCED [J IF "FORCED"
95F9 ... JBS RGLUT,2,XBANSWER [J IF "ANSWER"
95FB ... CALL 4 REQMORE [ASK OPS FOR MORE ONLINE BS
95FH ... TESTREP2 REFUSED,UP1 [EXIT IF REQUEST REFUSED
95FN ...NOTXCD
95FT ... LDX 0 CUBS(1)
95G2 ... BXL 0 GUBS(1),TESTCOMM [J IF GUBS NOT EXCEEDED (OR EQUALLED)
95G7 ... STO 0 GUBS(1) [UPDATE GUBS
95G# ...TESTCOMM
95GB ... BNG 3 UP1 [J IF 'WHOLE FILE' (MUST ALSO BE 'PUBL
95GF ... JBS XCOMMUNE,2,XBCOMM [J IF TO UPDATE OTHER COMMUNAL USERS
95GL ...UP1
95GR ... UPPLUS 1
95GY ...[
95H5 ...X31INCRCUBS
95H= ... LDX 3 ACOMMUNE1(2) [X3= INCREASE
95HC ... SETREP2 OK
95HJ ... STOZ AWORK4(2) [CLEAR MARKER WORD
95HP ... BRN NOTWHOLE
95HW ...[
95J3 ...RGLUT
95J8 ...[
95J* ...[ 'ANSWER' PARAMETER
95JG ...[
95JM ... TRACEIF K6INCRCUBS,199,399,JNAME(1),APPG JBN [GLUTTON REPLY
95JS ... TRACEIF K6INCRCUBS,199,399,CUBS(1),APPGCUBS
95J^ ... SETREP2 GLUTTON
95K6 ... SBS 3 CUBS(1) [DECREASE CUBS AGAIN
95K? ... BRN UP1
95KD ...[
95KK ...[
95KQ ...[ ENTRY FOR LOBSFILE MACRO
95KX ...[
95L4 ...X41INCRCUBS
95L9 ... LDX 4 ACOMMUNE1(2) [X4= DEPTH OF FILE
95LB ...MLOBSF
95LH ... STO 4 AWORK3(2) [REMEMBER DEPTH
95LN ... SETREP2 OK
95LT ... BBUS 23,CONTEXT(2),UP [J IF NOUSER CONTEXT
95M2 ... CALL 6 SFCA [X1-> FCA
95M7 ... PSTAC 2,1
95M# ... BFCBX 2,2 [X2-> FCB OF REQUIRED FILE
95MF ... JBC UP,2,BFCUBS [J IF PUBLIC FILE
95ML ... TRACEIF K6INCRCUBS,199,399,4,LOBSFILE [
95MR ... JBCS UP,1,BACUBS [J IF "NON-PUBLIC FILE" BIT NOT ALREA
95MY ... TRACEIF K6INCRCUBS,199,399,4,LOBSALR [
95N5 ... SETREP LOBSALR
95N= ...UP
95NC ... UP
95NJ ...[
95NP ...[ FROM MACRO SUBCUBS IF %D IS "DEPTH". (%B CONTAINS DECREMENT,
95NW ...[ %A CONTAINS DEPTH & %C IS "JOB")
95P3 ...[ ACOMMUNE1 CONTAINS DECREMENT
95P8 ...[ ACOMMUNE2 CONTAINS DEPTH
95P* ...[
95PG ...X5INCRCUBS
95PM ... MBSXD 0,XBCOMM,XBSUBCUBS [SET "UPDATE OTHER COMMUNAL USERS" &
95PS ... STO 0 AWORK4(2)
95P^ ... LDX 0 ACOMMUNE2(2) [
95Q6 ... STO 0 AWORK3(2) [REMEMBER DEPTH
95Q? ... LDX 3 ACOMMUNE1(2) [X3= DECREMENT
95QD ... CALL 6 SFCA [X1-> FCA
95QK ... JBC TCOMM,1,BACUBS [J IF PUBLIC
95QQ ... CALL 6 SJOBLOCK [X1-> JOB BLOCK
95QX ... SBS 3 CUBS(1) [DECREMENT CUBS
95R4 ... TRACEIF K6INCRCUBS,199,399,JNAME(1),SUB JBN
95R9 ... TRACEIF K6INCRCUBS,199,399,CUBS(1),SUB CUBS
95RB ... BRN XCOMMUNE
95RH ...[
95RN ...[ NOLOBSFILE MACRO
95RT ...[
95S2 ...X7INCRCUBS
95S7 ... STOZ AWORK3(2) [DEPTH 0
95S# ... CALL 6 SFCA [X1-> FCA
95SF ... BC 1,BACUBS [CLEAR "NON-PUBLIC" BIT IF SET
95SL ... UP
95SR ...[
95SY ...[
95T5 ...[ FILE OPEN IN COMMUNE MODE-NO ERROR CASES TO REPORT,JUST ADD INCR.
95T= ...[ TO ALL JOBS USING THE FILE PUBLICLY
95TC ...[ X3- REQUIRED INCREASE
95TJ ...[ X2- FX2
95TP ...[
95TW ...XCOMMUNE
95W3 ... CALL 6 SFCA [X1-> FCA
95W8 ...TCOMM
95W* ... JMBAC NCOMMUNE,1,BACOMM,BACLEAN [J IF FILE NOT OPEN COMMUNALLY
95WG ... PSTAC 1,1 [X1-> FSTACK BLOCK
95WM ... LDEX 6 ARINGNO(1) [NO.OF ELEMENTS
95WS ... SBN 6 1
95W^ ... BZE 6 NCOMMUNE [J IF NO ONE ELSE HAS FILE OPEN
95X6 ... DOWN INCRCUBX,2 [UPDATE CUBS FOR OTHER JOBS WITH FILE
95X? ...NCOMMUNE
95XD ... JBS UP,2,XBSUBCUBS [J IF SUBCUBS
95XK ... BRN UP1
95XQ ...#
95XX ...NOLOBJOB
95Y4 ... GEOERR 1,NOLOBJOB [ JOB BLOCK MISSING
95Y9 ...OTHERERR
95YB ... GEOERR 1,INCRCUBS [ANY OTHER CLEAR MALFUNCTION
962W #
96GG #END
^^^^ ...04527143001000000000