{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: INCSET865)}}
====== INCSET865 ======
(George Source)
**Macros used:** [[george:macro:BBS|BBS]], [[george:macro:BC|BC]], [[george:macro:BS|BS]], [[george:macro:BWZ|BWZ]], [[george:macro:BXU|BXU]], [[george:macro:CHAIN|CHAIN]], [[george:macro:CLOSETOP|CLOSETOP]], [[george:macro:DEMAND|DEMAND]], [[george:macro:DOWN|DOWN]], [[george:macro:FON|FON]], [[george:macro:FREEFINC|FREEFINC]], [[george:macro:HUNTMISB|HUNTMISB]], [[george:macro:HUNTW|HUNTW]], [[george:macro:JBC|JBC]], [[george:macro:JBCC|JBCC]], [[george:macro:JBS|JBS]], [[george:macro:JMBS|JMBS]], [[george:macro:LONGOFF|LONGOFF]], [[george:macro:LONGSET|LONGSET]], [[george:macro:MBC|MBC]], [[george:macro:MBS|MBS]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MONOUT|MONOUT]], [[george:macro:NAME|NAME]], [[george:macro:OPENINC|OPENINC]], [[george:macro:OUTPACK|OUTPACK]], [[george:macro:OUTPARN|OUTPARN]], [[george:macro:PERMITBRK|PERMITBRK]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:STEPAGAIN|STEPAGAIN]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]], [[george:macro:VFREEW|VFREEW]], [[george:macro:WIND|WIND]]
22FL ... SEG INCSET,864,P.SMITH,INCDUMP
22^= #
23DW ... SEGENTRY K1INCSET,X1INCSET
28T8 ...#UNS IDC
28T9 ...(
28T= ...XFILES 12HFILES-ONLY
28T? ...XREST 12HRESTORABLE
28T# ...# ******************************************************************
28T* ...# ZDEMAND
28TB ...# *******
28TC ...#
28TD ...# THIS SUBROUTINE ISSUES A DEMAND FOR
28TF ...# "PLEASE ISSUE DUMP COMMAND FOR NEXT INCREMENT "
28TG ...# IF ONE HAS NOT ALREADY BEEN GIVEN
28TH ...# CANTDO CAUSES INCREMENT TO BE ABANDED
28TJ ...#
28TK ...ZDEMAND
28TL ... SBX 4 FX1
28TM ... JBS ZFDUCOM,,BDCISS [ JUMP IF COMMAND ALREADY ISSUED
28TN ...
28TP ... CLOSETOP [[ CLOSE INCINDEX ,DONT WAIT WITH IT OPEN
28TQ ... LONGSET ADUMPWAIT,SET [ SET WAITING STYLE
28TR ...SET
28TS ...# ISSUE DEMAND
28TT ... LDX 1 FX1
28TW ... LDN 1 XFILES(1) [ FILES ONLY
28TX ... BBS 1,6,XXFILES [ JUMP IF FILES ONLY
28TY ... LDX 1 FX1
28T^ ... LDN 1 XREST(1) [ OTHERWISE RESTOREABLE
28W2 ...XXFILES
28W3 ... LDN 2 ACOMMUNE2(2) [ MOVE PARAMETERS
28W4 ... MOVE 1 3 [ TO ACCOMMUNE WORDS
28W5 ... LDX 2 FX2 [ OUTPUT IT
28W6 ... OUTPARN 10,ACOMMUNE2
28W7 ... DEMAND 1,INCDEMAND,YINCABAND,(GEOERR),REENTER,1
28W8 ... JBC REENTER,,BDCISS [ JUMP IF SPURIOUS WAKE UP
28W9 ... DEMANDQUIT [ TIDY UP
28W= ... LONGOFF [ CLEAR FIELD
28W? ... OPENINC ,GENERAL [ OPEN IT AGAIN !
28W# ...ZFDUCOM
28W* ... ADX 4 FX1
28WB ... EXIT 4 0
28WC ...#
28WD ...# ******************************************************************
28WF ...)
28WG ...X1INCSET [ SET UP AND LOAD TAPES FOR A NEW INCR.
28WH ... [CALLED ON X4 AND COORDINATES.
28WJ ... [ON ENTRY B1 OF X6 SET IMPLIES A FILE ONLY INC IS
28WR ... [NEEDED. X7=LAST INCR NO
28X8 ... [THERE MAY BE A FINTER AND FINTER1 ABOUT TO HELP
28XK ... [WITH THE INITIAL TAPE SELECTION.
28Y2 ... [ON EXIT X7=X7+1 AND FINTERS FREED
28YT ...#UNS IDC
28YW ...(
28YX ...# ******************************************************************
28YY ...#
28Y^ ...# THE FOLLOWING CODE EFFECTS THE NEW IDC RTMS
28^2 ...# DTFILEINC DTRESTINC DTAFTERREST
28^3 ...# NEWDTASK NEWDTPOOL
28^4 ...#
28^5 ... MBC 2,IDCRTMOLD,IDCRTMASK,IDCRTMNEW
28^6 ... BBS 1,6,RTMDTFILE [ JUMP IF FILES ONLY
28^7 ... SEGENTRY K85INCSET [ FOR DTRESTINC RTM
28^8 ... BS 2,IDCRTMOLD [ TO BE CHANGED TO
28^9 ...# BS 2,IDCRTMASK [ OR
28^= ...# BS 2,IDCRTMNEW [ BY
28^? ...# DTRESTINC OLD ASK OR NEW
28^# ... BRN RTMDTREST
28^* ...#
28^B ...# ******************************************************************
28^C ...RTMDTFILE [ FOR FILE ONLY INCREMENTS
28^D ... SEGENTRY K86INCSET [ USED BY DTRESTINC
28^F ... BS 2,IDCRTMOLD [ TO BE CKANGED TO
28^G ...# BS 2,IDCRTMASK [ OR
28^H ...# BS 2,IDCRTMNEW [ BY
28^J ...# DTFILEINC OLD ASK OR NEW
28^K ...#
28^L ...RTMDTREST
28^M ...# ******************************************************************
28^N ...#
28^P ...# FOR INCREMENT FOLLOWING A RESTOREABLE INCREMENT
28^Q ...# DTAFTERREST CONTROLS THIS CHOICE
28^R ... HUNTW 1,FILE,FINTER1 [ CONTAINS LAST RESTOREABLE INC IF TH
28^S ... BNG 1 NOTAFTEREST [ IS ONE
28^T ... JBS NOTAFTEREST,1,BINEWDT [INC TERM BY EOT OR TAPEFAIL -NEW
28^W ... JBC NOTREST,1,BIGENRES [ JUMP IF NOT RESTBLE
28^X ... SEGENTRY K82INCSET
28^Y ... BS 2,IDCRTMOLD [ CHANGED TO
28^^ ...# BS 2,IDCRTMASK [ OR
2922 ...# BS 2,IDCRTMNEW [ BY
2923 ...# DTAFTERREST OLD ASK OR NEEW
2924 ... BRN NOTREST
2925 ...NOTAFTEREST
2926 ... BS 2,IDCRTMNEW [ NO FINTER1 SO NEW TAPES NEEDED
2927 ...NOTREST
2928 ... JBS RTMASK,2,IDCRTMNEW
2929 ... JBC RTMASK,2,IDCRTMASK
292= ...# DONT ASK IF NEW TAPES NEEDED OR ASK NOT SPECIFIED
292? ... CALL 4 ZDEMAND
292# ...RTMASK
292* ...# ******************************************************************
292B ...# IF NEW TAPES REQUIRED, FREE FINC AND OLD TAPES
292C ...#UNS AMTGR
292D ... JBS NOFINCLA,,BMTGR
292F ... JBC NOFINCLA,2,IDCRTMNEW
292G ... HUNTMISB 3,FILE,FINC
292H ... BNG 3 NOFINCLA
292J ... FREEFINC 3
292K ...NOFINCLA
292L ...#
292M ...#
292N ...#
292P ...#
292Q ...#
292R ...#
292S ...#
292T ...#
292W ... SEGENTRY K83INCSET
292X ... BRN NOTNDTASK
292Y ...#
292^ ... JBS NOTNDTASK,,BDCISS
2932 ... JBC NOTNDTASK,2,IDCRTMNEW
2933 ... CALL 4 ZDEMAND
2934 ...NOTNDTASK
2935 ... SEGENTRY K84INCSET
2936 ...
2937 ... JBCC NOFDUCOM,,BDCISS
2938 ...#
2939 ... HUNTMISB 3,FI,FDUCOM
293= ... CHAIN 3,FPTR(2)
293? ... BWZ FDUTSNCT(3),NOFDUCOM
293# ... DOWN DUMP,3
293* ...NOFDUCOM
293B ...)
293C ... LDX 5 AINCCOPIES
293D ... LDX 4 5
293F ... SLL 4 1
293G ... ADN 4 FGETSER-INCNO
293H ... SETUPCORE 4,3,FILE,FGET
293J ... ADN 7 1
293M ... STO 7 INCNO(3)
2944 ... STO 5 INCCOPIES(3)
294F ... STOZ INCREPLY(3) [ZERO REST OF BLOCK
294W ... LDN 0 INCREPLY(3)
295? ... LDN 1 INCREPLY+1(3)
295N ... SBN 4 3
2965 ... SMO 4
296G ... MOVE 0 0
296X ... LDN 1 FGETSER(3) [INITIALISE TSN WORDS
297# ... NGN 0 1 [-1 SHOWS TSN NEEDED
297P ...TSNINIT
2986 ... STO 0 0(1)
298H ... ADN 1 FGETLEN
298Y ... BCT 5 TSNINIT
299* ... BBS 1,6,NREST [J IF NOT TO BE RESTORABLE INCR
299Q ... BS 3,BINCGENRES [SET POTENTIALLY RESTORABLE BIT
299R ...NREST
299S ...#UNS AMTGR
299T ...(
299W ... JBC NOTFREE,,BMTGR
299X ... HUNTMISB 2,FILE,FINC
299Y ... BNG 2 NOTFREE
299^ ... ADN 2 INCCMPSIZE
29=2 ... ADN 3 INCCMPSIZE
29=3 ... MOVE 2 2
29=4 ... SBN 2 INCCMPSIZE
29=5 ... JBC NOTFREE,FX2,IDCRTMNEW
29=6 ... FREEFINC 2
29=7 ...NOTFREE
29=8 ...)
29=J ...#
29=^ ...# NOW THE BASIC FINC(FGET) BLOCK IS SET UP WE MUST DECIDE WHETHER
29?B ...# THIS IS TO BE A TOTAL DUMP OR NOT.
29?R ...# THIS IS SO IF EITHER 1) TOTAL BIT IS SET IN INCWORD IN FIXED AND
29#8 ...# START OF FILESTORE SCAN (FIRST FILE ONLY
29#K ...# INCR IF IN PLLL MODE OR EMPTY INCBATCH LIST
29*2 ...# IF NOT)
29*C ...# OR 2) LAST INCR WAS TOTAL AND WE ARE NOT AT THE STA
29*S ...# OF A FILESTORE SCAN
29B9 ...#
29B* ...#UNS AMTGR
29BF ...#SKI
29BL ... JBS PMODE,,BPARALLEL [J IF IN PLL MODE
29C3 ... MHUNTW 3,FILE,FINCPROC
29CD ... LDX 0 INCBATCH(3)
29CT ... BZE 0 SBATCH [J IF START OF BATCH
29CY ...#UNS AMTGR
29D3 ...#SKI [ NOT TRUE ANY MORE FOR MTGR
29D6 ...(
29D= ... BRN NSBATCH [J IF NOT
29DM ...PMODE
29F4 ... HUNTW 3,FILE,FINC [IN PMODE START OF BATCH IF FINC
29FF ... BNG 3 SBATCH [NOT ALREADY SET UP
29FW ...#
29G4 ...)
29G? ...# WE ARE NOT STARTING A BATCH SO THE LAST RECORD IN INCINDEX
29GN ...# SETTLES IT
29H5 ...#
29HG ...NSBATCH
29HX ... WIND [POSITION ON LAST RECORD
29J# ... STEPAGAIN
29JD ...#UNS AMTGR
29JJ ... JBS SBATCH,3,BIENDBATR [ JUMP IF LAST INC END OF BATCH
29JP ... JBC NTOT,3,BITOTDR [J IF LAST INC NOT TOTAL
29K6 ... MHUNTW 3,FILE,FGET
29KH ... BS 3,BINCTOTD [ITS TOTAL
29KY ... BRN NTOT
29L* ...#
29LQ ...# WE ARE AT THE START OF A BATCH SO THE TOTAL BIT DETERMINES IT
29M7 ...#
29MJ ...SBATCH
29MN ...#UNS FNSAD2
29MS ... BS ,BATCHSTART [ SHOW START BATCH FROM BEGINNING
29M^ ... BC ,BNOWD [TAKE OUT 'PLEASE DUMP' BIT
29N4 ... JBS YTOT,,BTOTD
29N7 ...#UNS IDC
29N= ...(
29N* ... HUNTW 1,FI,FDUCOM
29ND ... BNG 1 NTOT
29NH ... JBS YTOT,1,BFDTOTAL [ JUMP IF DU TOTAL
29NL ...)
29P8 ... BRN NTOT [NULLED BY NEWDUMP
29PK ...YTOT
29Q2 ... MHUNTW 3,FILE,FGET
29QC ... BS 3,BINCTOTD [SET BIT IN FINC
29QS ...NTOT
29R9 ...#
29RL ...# WE NOW SET UP A FILE FWB TO HOLD THE NEW INCREMENT RECORD
29S3 ...#
29SD ... MHUNTW 2,FILE,FGET
29ST ... LDX 3 INCCOPIES(2)
29T= ... LDN 0 INCMAGLEN
29TM ... MPY 3 0
29W4 ... ADN 4 AMAGR [X4= REQUIRED LENGTH OF NEW INCINDEX
29WF ... SETUPCORE 4,3,FILE,FWB [X3-> NEW RECORD
29WW ... STO 4 AINCRH(3) [SET REC. HEADER
29X? ... LDN 0 #41 [SET 2ND WORD OF RECORD HEADER
29XN ... STO 0 AINCHD(3) [ FOR BASIC PERIPH. FILE
29Y5 ... STOZ AINCRH+2(3)
29YG ... LDN 0 AINCRH+2(3)
29YX ... LDN 1 AINCRH+3(3)
29^# ... SMO 4
29^P ... MOVE 0 509 [ZEROISE ALL OF FWB EXCEPT REC. HEADE
2=26 ... STO 7 AINCNO(3) [SET UP INCR NO.
2=2H ... MHUNTW 2,FILE,FGET
2=2Y ... LDX 0 INCCOPIES(2)
2=3* ... STO 0 AMTS(3) [ AND NO OF MTS.
2=3Q ... JBC NOTTOT,2,BINCTOTD [J IF NO "DUMP TOTAL" COMMAND
2=47 ... BS 3,BITOTD [SET 'DUMP TOTAL' BIT IN NEW RECORD
2=4J ...NOTTOT
2=4^ ... MBS 3,BIREDUMP,BINSUITRV,BIUNFIN [INDICATE TO BE
2=5B ... [REDUMPED,NOT RETRIEVABLE,
2=5R ... [AND IN PROGRESS
2=68 ... LDN 0 5
2=6K ... ORS 0 AINCSTATE(3) [FORMAT VERSION NUMBER
2=72 ...#
2=7C ...# THIS IS THE INITIAL TAPE SELECTION CODE. TRANSFER AS MANY TAPES AS
2=7S ...# AVAILABLE OR REQUIRED ACROSS FROM LAST INCINDEX RECORD TO FILE.FGET
2=89 ...# BLOCK, UNLESS ALL NEW TAPES REQUIRED.
2=8= ...#UNS IDC
2=8? ...(
2=8# ...# IF ANY OF SPARE POOL OR TSNS HAVE BEEN GIVEN - WE IGNORE THE CURRE
2=8* ...# DUMP TAPES - UNLESS THEY HAVE BEEN EXPLICITLY GIVEN
2=8B ... HUNTW 1,FI,FDUCOM
2=8C ... BNG 1 OLDTAPES [ J IF NO FDUCOM
2=8D ...# ******************************************************************
2=8F ...# IF ANY TSNS HAVE BEEN GIVEN IN DUMP COMMAND
2=8G ...# AND THEY ARE IN FINC BLOCK IN MISC CHAIN , TRANSFER THEM TO FGET
2=8H ...#
2=8J ...#
2=8K ... HUNTMISB 3,FILE,FINC [
2=8L ... BNG 3 NOFINC2 [ JUMP IF NO FINC RETAINDED
2=8M ... BWZ FDUTSNCT(1),NOFINC2 [ OR IF NO TSNS GIVEN IN DU COMMAND
2=8N ... MHUNTW 2,FILE,FGET [
2=8P ...#
2=8Q ...# IN THE FOLLOWING LOOP , THE ACCUMULATORS ARE USED
2=8R ...# X1 = ENTRY IN FDUCOM X6 IS MODIFIER DOWN BLOCK
2=8S ...# X2 = ENTRY IN FGET X4 IS COUNT OF TAPES IN FGET
2=8T ...# X3 = ENTRY IN FINC X5 IS COUNT OF TAPES IN FINC
2=8W ...#
2=8X ... LDN 6 0
2=8Y ... LDX 5 INCCOPIES(3) [
2=8^ ...TAPEAGAIN
2=92 ... SMO 6 [
2=93 ... LDX 0 FDUTSN(1) [ PICK UP REQUESTED TSN
2=94 ... BXU 0 FGETSER(3),NOTTSN [ JUMP UNLESS FOUND ENTRY
2=95 ... STO 0 FGETSER(2) [ STORE TSN IN FGET
2=96 ... LDX 0 FGETSTATE(3) [ TRANSFER STATE WORD
2=97 ... STO 0 FGETSTATE(2) [
2=98 ... LDCT 0 #400 [ CLEAR TSN IN OLD FINC
2=99 ... STO 0 FGETSER(3) [
2=9= ... ADN 2 FGETLEN [ UPDATE POINTER IN NEW FGET
2=9? ...NOTTSN
2=9# ... ADN 3 FGETLEN [ TRY NEXT TAPE IN FINC
2=9* ... BCT 5 TAPEAGAIN [
2=9B ... HUNTMISB 3,FILE,FINC [ RESET POINTERS TO FINC
2=9C ... LDX 5 INCCOPIES(3) [ AND NUMBER OF TAPES
2=9D ... ADN 6 1
2=9F ... BXU 6 FDUTSNCT(1),TAPEAGAIN [ JUMP UNLESS FINISHED FDUCOM TAPE
2=9G ... FREEFINC 3 [ TRANSFERRED ALL TAPES NEEDED FREE R
2=9H ...
2=9J ...NOFINC2
2=9K ...#
2=9L ...# ******************************************************************
2=9M ...#
2=9N ... MHUNTW 1,FI,FDUCOM
2=9P ... JMBS TAPES,1,BFDPOOL,BFDSPARE,BFDTSN
2=9Q ...OLDTAPES
2=9R ... JBS TAPES,FX2,IDCRTMNEW
2=9S ...)
2=9T ...#
2=9W ... HUNTW 3,FILE,FINTER1 [X3-> FINTER1 BLOCK (LAST INCR.)
2=9X ... BNG 3 TAPES [J IF NOT GIVEN (NEW TAPES)
2=9Y ... LDX 6 INCCOPIES(2) [X6= NO. OF MTS REQUIRED
2=== ... LDX 5 AMTS(3) [X5= NO. OF MTS IN LAST INCR. REC.
2==M ... LDN 4 0 [INITIALISE MOD DOWN LAST INCR. LIST
2=?F ... JBS TAPES,3,BINEWDT [J IF LAST INCR HIT EOT OR WRITE FAIL
2=?W ... [ & SO INCR. HAD TO BE FORCIBLY TER
2=#? ... MHUNTW 2,FILE,FGET
2=#N ...MORESER
2=*5 ... SMO 4
2=*G ... LDX 0 AMAG(3) [INSERT NEXT TSN IN LAST INCR. INTO
2=*X ... STO 0 FGETSER(2) [ NEXT POSITION IN FGET BLOCK
2=B# ... ADN 4 INCMAGLEN [UPDATE MODIFIERS IN FINTER1
2=BP ... ADN 2 FGETLEN [ & FGET BLOCKS
2=C6 ... SBN 5 1 [REDUCE NO. OF TAPES AVAILABLE FROM L
2=CH ... BZE 5 TAPES2 [J IF NONE LEFT
2=CY ... BCT 6 MORESER [J IF MORE MTS REQUIRED
2=C^ ...TAPES2
2=D2 ...#UNS IDC
2=D3 ...(
2=D4 ...# ******************************************************************
2=D5 ...
2=D6 ...# TRANSFER ANY TAPES IN OLD FINC TO NEW FGET
2=D7 ... HUNTMISB 3,FILE,FINC
2=D8 ... BNG 3 NOFINC [ JUMP IF NO FINC
2=D9 ... CHAIN 3,FX2 [ OTHERWISE CHAIN IT
2=D= ... MHUNTW 2,FILE,FGET [
2=D? ... LDX 4 INCCOPIES(2) [ NO OF TAPES NEEDED
2=D# ... LDX 5 INCCOPIES(3) [ NO OF TAPES IN OLD FINC
2=D* ...NEXTFGETSN
2=DB ... LDX 0 FGETSER(2) [ TSN OF WANTED TAPE
2=DC ... BXU 0 FGETSER(3),NOTHIS1 [ JUMP UNLESS FOUNR
2=DD ...#
2=DF ...# TRANSFER STATE WORD AND OVERWRITE TSN
2=DG ...#
2=DH ... LDX 0 FGETSTATE(3) [
2=DJ ... STO 0 FGETSTATE(2) [
2=DK ...#
2=DL ... LDCT 0 #400 [
2=DM ... STO 0 FGETSER(3) [
2=DN ...#
2=DP ...NOTHIS1
2=DQ ... ADN 2 FGETLEN [ TRY NEXT TSN
2=DR ... BCT 4 NEXTFGETSN [
2=DS ...#
2=DT ... MHUNTW 2,FILE,FGET [ RESET POINTER TO FGET
2=DW ... LDX 4 INCCOPIES(2) [
2=DX ... ADN 3 FGETLEN [ POINTS TO NEXT TAPE
2=DY ... BCT 5 NEXTFGETSN
2=D^ ...# ANNY TAPES NEEDED HAVE MOVED TO FGET SO THE FINC IS FREED
2=F2 ... MHUNTW 3,FILE,FINC
2=F3 ... FREEFINC 3
2=F4 ...NOFINC
2=F5 ...# ******************************************************************
2=F6 ...)
2=F8 ...TAPES
2=F9 ...#UNS IDC
2=F= ...(
2=F? ... HUNTMISB 3,FILE,FINC
2=F# ... BNG 3 NOFINCTAPE
2=F* ... FREEFINC 3 [ FREE THE FINC IF ONE IN MISC CHAIN
2=FB ...NOFINCTAPE
2=FC ... BS ,BCANAB [ SHOW THERE IS A CANCELLABLE DUMP
2=FD ...)
2=FF ... LDX 2 FX2
2=FJ ... STOZ 3 [SET 'MTS OBTAINED' INDICATOR
2=F^ ... STOZ AWORK1(2) [CLEAR INCTAPES MARKER WORD
2=GB ... STOZ AWORK2(2) [CLEAR TSN MARKER FOR INCTAPES
2=GR ... VFREEW FILE,FINTER1 [NO FINTER1 IF INCINDEX EMPTY
2=H8 ... DOWN INCTAPES,1 [OBTAIN & POSITION FOR DUMPING MTS
2=HK ... [ MENTIONED IN FGET BLOCK
2=J2 ... [UP -'NO MTS OBTAINED' EXIT FROM INCT
2=JC ... [ ABANDON INCR.
2=JS ... ADN 3 1 [SET 'NO MTS' INDICATOR
2=K9 ... [UPPLUS 1 - NORMAL EXIT FROM INCTAP
2=K= ...#UNS IDC
2=K? ...(
2=K# ... BC ,BCANAB [ NO LONGER CANCELLABLE DUMP
2=K* ... VFREEW FI,FREJTAPES
2=KB ... VFREEW FI,FDUMPTAPES
2=KC ... VFREEW FI,FDUCOM
2=KD ...)
2=KL ... MFREEW FILE,FWB
2=L3 ... VFREEW FILE,FINTER
2=LD ... BNZ 3 YINCABAND [J IF ABANDONING INCR.
2=LT ... MHUNTW 3,FILE,FGET [FGET IS CALLED FINC FOR REST OF
2=M= ... NAME 3,FILE,FINC [ITS LIFE
2?6W ... UPPLUS 1
79FB #
79^2 # IF NO TAPES ARE AVAILABLE FOR DUMPING (I.E. THE OPS HAVE REPLIED NO T
7=DL # "DO YOU STILL WISH TO DUMP ON 1 MT?"), ABANDON THE INCREMENT, PUT OUT
7=Y= # A MESSAGE, FREE BLOCKS AND GO BACK ACROSS TO INCWAIT TO WAIT.
7?2T ...# BEFORE LETTING THE ABANDON TAKE PLACE WE CHECK THAT THE INCRMENT
7?5D ...# IS NOT THE THIRD OR LATER OF A PARALLEL DUMP. (IF IT IS BPARALLEL
7?83 ...# WILL BE SET AND THERE WIL BE A RESTORABLE FINC ABOUT.) IF THIS
7?=L ...# IS THE CASE WE OUTPUT AN ADMONITORY MESSAGE AND REPEAT THE OPERATION
7?*9 ...# OF INCSTART.
7?CW #
7?XG YINCABAND
7G?Q ... JBC NPL,,BPARALLEL [IS THIS A PLL DUMP. J IF NOT.
7G#3 ... HUNTW 3,FILE,FINC [IS THERE AN INCR SET UP ALREADY
7G## ... BNG 3 NPL [J IF NOT
7G#K ... JBC TWOINCS,3,BINCGENRES [J IF ITS NOT RESTORABLE
7G#W ... MONOUT ANOINCAB [NAUGHTY NAUGHTY!
7G*7 ... MHUNTW 3,FILE,FGET
7G*D ... BNG 3 NOFGETCD [ THERE WILL BE NO FGET IF CD ISSUE
7G*P ... FREEFINC 3,NODUMP [ RETURN DTA'S TO RETRIEVAL SYSTEM
7GB2 ...NOFGETCD
7GB? ... OPENINC ,GENERAL [REOPEN INCINDEX
7GBJ ... CALL 4 ZDEMAND [[ PLEASE ISSUE DUMP COMMAND
7GBT ... UP [AND TRY AGAIN
7GC6 ...#
7GCC ...TWOINCS [WE HAVE TWO INCRS TO ABANDON
7GCN ... OUTPACK INCNO(3),1,INCNUM [OUTPUT MESSAGE
7GC^ ... MONOUT INCABAND [FOR THE FILE ONLY INCR
7GD= ...#
7GDH ...# THE FIRST INCREMENT IS ALREADY SET UP SO WE HAVE TO RELEASE THE DTAS
7GDS ...# AND POSSIBLY UPDATE THE DIRENT IN :DUMPER FOR THE TAPES
7GF5 ...#
7GFB ... MHUNTW 3,FILE,FINC [
7GFM ... FREEFINC 3,NODUMP [ FREE THE FGET AND ANY TAPES
7GFY ...NPL
7GG9 ... FON BSUJWT [RELEASE BS UNJAMMER IF IT IS WAITING
7GGG ... [ FOR END OF THIS DUMP
7GGR ... BC ,BNOWD [REMOVE 'DUMP NOW BIT' IF SET
7GH4 ... MHUNTW 2,FILE,FGET
7GH* ... BPZ 2 YCD [ JUMP IF FGET THERE
7GHL ... VFREEW FILE,FINTER
7GHX ... VFREEW FILE,FINTER1
7GJ8 ... ADN 7 1 [ OTHERWISE OUTPUT
7GJF ... OUTPACK 7,1,INCNUM [ INCREMENT NUMBER
7GJQ ... MONOUT INCABAND [ ABANDONED
7GK3 ... HUNTMISB 3,FILE,FINC
7GK# ... BNG 3 NPL2
7GKK ... FREEFINC 3 [ FREE FINC IF THERE IS ONE
7GKW ... BRN NPL2
7GL7 ...YCD
7GLD ... OUTPACK INCNO(2),1,INCNUM [OUTPUT INCR NO. AS PARAMETER
7GLP ... MONOUT INCABAND [OUTPUT TO MON. FILE & OPS. CONSOLE
7GM2 ... ["INCREMENT %A ABANDONED AND OBLITERA
7GM? ... MHUNTW 3,FILE,FGET
7GMJ ... FREEFINC 3,NODUMP
7GMT ...NPL2
7GN6 ... MFREEW FILE,FQUAL
7GNC ... LDCT 7 #200 [SET 'GO WAITING' MARKER
7GNN ... PERMITBRK [ALLOW BREAK-IN SO CAN DEAL WITH "FIN
7GN^ ... BC ,BPARALLEL
7GPK ... UP [THIS INCR RECORD NOW OBLITERATED (AC
7GQ= [ DELETED FROM INCINDEX IN INCTAPES
7H9W #
7HPG #
7J96 ... MENDAREA 30,K99INCSET
7JNQ #
7K8B #END
^^^^ ...35214447000400000000