{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: IPBCCC867)}}
====== IPBCCC867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:BXGE|BXGE]], [[george:macro:BXL|BXL]], [[george:macro:CHAIN|CHAIN]], [[george:macro:DOWN|DOWN]], [[george:macro:FPUT|FPUT]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:HUNT2J|HUNT2J]], [[george:macro:IDFCONREQ|IDFCONREQ]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:TRACE|TRACE]], [[george:macro:UP|UP]]
22FL SEG IPBCCC,,PHILIP TURNER
22^= [ (C) COPYRIGHT INTERNATIONAL COMPUTERS LIMITED 1982
23DW #LIS K0IPBCCC>K0IPB>K0ALLGEO>K0GREATGEO
23YG 8HIPBCCC70
24D6 SEGENTRY K1IPBCCC,XK1
24XQ SEGENTRY K2IPBCCC,S37
25CB SEGENTRY K3IPBCCC,XK3
25X2 FSHENTRY K4IPBCCC,XK4,XK4,XK4
26BL FSHENTRY K5IPBCCC,XK5,XK5,XK5
26W= [
27*W ZTEMK #40000007
27TG XMSK1 #77000
28*6 XMSK7 #77000777
28SQ XMSK9 #777000
29#B XMSK33 #40000020
29S2 XMSK37 #44000002
2=?L XMSK46 #4000001
2=R= XMSK47 #70000001
2?=W XMSK48 #7770000
2?QG XMSK49 #30004312
2#=6 XMSK50 #40000040
2#PQ ZIN #2400000
2*9B ZOUT #4300000
2*P2 XIL1 LDN 4 #100
2B8L BRN XILL
2BN= XIL2 LDN 4 #200
2C7W BRN XILL
2CMG XIL7 LDN 4 #700
2D76 BRN XILL
2DLQ XIL17 LDN 4 #2100
2F6B BRN XILL
2FL2 XIL18 LDN 4 #2200
2G5L BRN XILL
2GK= XIL19 LDN 4 #2300
2H4W BRN XILL
2HJG XIL28 LDN 4 #3400
2J46 LDN 0 #200
2JHQ ORS 0 A1+IDSTATUS(2) [SET C-OSE IDENTIFIER
2K3B XILL LDN 5 0 [INPUT ILLEGAL
2KH2 BRN XCCA
2L2L [***** SUBROUTINES *****
2LG= ...OUTM
2MFG LDCT 4 #200
2M^6 LDN 3 4
2NDQ BRN OUTV
2NYB OUTY NGN 0 #101
2PD2 ANDS 0 A1+IDSTATUS(2) [UNSET ONE SHOT INPUT
2PXL BNZ 4 OUTW
2QC= OUTX LDCH 0 A1+IDADIN(3)
2QWW BNZ 0 (5) [J. IF INPUT OVERLOAD SITUATION
2RBG OUTW LDN 3 3
2RW6 OUTV SBX 5 FX1
2S*Q DOWN IPBCCC,1 [PASS BLOCK ON
2STB MHUNTW 2,AMXOR,CONDCB
2T*2 LDX 3 2 [CONDCB ADDR
2TSL ADX 2 7 [ADDR OF ENTRY FOR THIS IDENT
2W#= LDX 6 2
2WRW ADX 5 1
2X?G EXIT 5 0
2XR6 OCHZ ADN 7 CONDCBLEN
2Y=Q BXGE 7 ALOGLEN(3),(5) [J. IF END OF CONDCB SCAN
2YQB LDX 2 3
2^=2 ADX 2 7
2^PL LDX 0 A1+BPTR(2)
329= BZE 0 OCHZ [J. IF NULL IDENTIFIER
32NW SMO 0
338G LDEX 0 A1+FOURTHWD
33N6 LDX 6 ZOUT(1)
347Q BPZ 4 OCHZ1
34MB LDX 6 ZIN(1)
3572 OCHZ1 SMO 0
35LL SLL 6 0
366= BNG 6 OCHZ [J. IF WRONG TYPE
36KW LDN 0 #3000
375G ANDX 0 A1+IDSTATUS(2)
37K6 BNZ 0 OCHZ [J. IF FREE OR INOPERABLE SET
384Q LDX 0 A1+IDSTATUS(2)
38JB SRC 0 1
3942 EXIT 5 1
39HL SRI LDEX 0 A1+IDSTATUS+1(2)
3=3= ANDN 0 #17
3=GW LDX 6 ZOUT(1)
3?2G SMO 0
3?G6 SLL 6 0
3?^Q BNG 6 XIL2 [ILLEGAL 2 IF WRONG TYPE
3#FB SRIX LDX 0 A1+IDSTATUS(2)
3#^2 SRC 0 1
3*DL BNG 0 XIL2 [ILLEGAL 2 IF CLOSED SET
3*Y= LDCT 6 #200
3BCW ANDX 6 A1+IDSTATUS(3)
3BXG BNZ 6 XIL19 [ILLEGAL 19 IF STOP REMOTE INPUT SET
3CC6 SRC 0 4
3CWQ EXIT 5 0
3DBB SETR LDN 0 0
3DW2 LDN 6 #143 [INPUT END OF REMOTE OUTPUT
3F*L BRN SETW
3FT= VRCLO SMO A1+FPTR(2) [SET CLOSED AND IF NOT CLOSED SET CLOS
3G#W LDX 0 FOURTHWD
3GSG SRL 0 12
3H#6 ANDN 0 4
3HRQ ERN 0 5
3J?B ORS 0 A1+IDSTATUS(2)
3JR2 EXIT 5 0
3K=L WARN HUNT2J 1,AMXOR,IOUT,6,(5)
3KQ= SVAN LDX 6 1 [BY-PASS FIRST BLOCK
3L9W SVARN LDX 2 4 [CONDCB ENTRY
3LPG HUNT2J 1,AMXOR,IOUT,6,(5)
3M96 LDX 0 IPBIDE(1)
3MNQ ANDN 0 #7777 [IDENT NO.
3N8B TXU 0 A1+IDNUM(2)
3NN2 BCS SVAN [J IF NOT SAME IDENT.
3P7L LDX 6 BPTR(1)
3PM= BCHX 1 £
3Q6W LDCH 0 IPBIDE(1) [SUPERVISORY CODE
3QLG ANDX 1 BITS22LS
3R66 EXIT 5 1
3RKQ [***** END OF SUBROUTINES *****
3S5B TABLE
3SK2 NULL
3T4L NULL
3TJ= BRN S2 [STOP REMOTE INPUT
3W3W BRN S3 [ END IPB OUTPUT
3WHG NULL
3X36 NULL
3XGQ NULL
3Y2B NULL
3YG2 NULL
3Y^L NULL
3^F= BRN S10 [REOPEN
3^YW BRN S11 [RESET
42DG BRN S12 [CONFIG REQUEST
42Y6 NULL
43CQ NULL
43XB BRN XBACK [NULL
44C2 BRN S16 [OPEN
44WL BRN S17 [START INPUT
45B= BRN S18 [ONE SHOT INPUT
45TW BRN S19 [STOP INPUT
46*G BRN S20 [STOP INPUT AND CLEAR
46T6 NULL
47#Q BRN S22 [CLOSE
47SB BRN S23 [CRASH CLOSE
48#2 BRN S24 [CHANGE MODE
48RL BRN S25 [SET PRIORITY
49?= ... BRN XKEEP
49QW NULL
4==G NULL
4=Q6 NULL
4?9Q NULL
4?PB NULL
4#92 NULL
4#NL NULL
4*8= BRN S10D
4*MW BRN S11B
4B7G [***** K1 ENTRY POINT ******
4BM6 XK1
4C6Q SETUPCORE 3,3,AMXOR,IOUT
4CLB LDX 0 ALOGLEN(3)
4D62 ADS 0 IOUTLOAD(2)
4DKL SBN 0 4
4F5= BNG 0 OUT3 [J. IF COUNT=3
4FJW STO 6 IPBIDE+1(3)
4G4G BCT 0 OUT4 [J. IF COUNT=4
4GJ6 LDCT 6 #762 [OUTPUT NULL DATA SEGMENT
4H3Q STO 6 IDATA(3)
4HHB LDN 6 0
4J32 BRN OUT5
4JGL OUT4 LDN 6 #230 [OUTPUT CHANGE MODE
4K2= OUT3 LDX 0 GSIGN
4KFW SLL 6 12
4K^G OUT5 STO 0 IBSW(3)
4LF6 MHUNTW 2,AMXOR,CONDCB
4LYQ ADX 2 7
4MDB ADX 6 A1+IDNUM(2)
4MY2 STO 6 IPBIDE(3)
4NCL TRACE IPBIDE(3),CLOUTCCB
4NX= LDX 6 2
4PBW LDX 1 3
4PWG LDX 2 A1+IDADIN(2)
4QB6 LDN 0 1
4QTQ STO 0 IMOPTY(3)
4R*B BCHX 3 £
4RT2 LDCH 0 IPBIDE(3)
4S#L LDN 3 #40
4SS= SMO 6
4T?W ANDX 3 A1+IDSTATUS
4TRG BNZ 3 WVSET [J IF WARNING SET
4W?6 ORN 0 1 [TEST FOR CLOSE AS WELL AS CRASH CLOS
4WQQ WVSET ERN 0 23
4X=B BZE 0 OUNSV [J IF CRASH CLOSE
4XQ2 LDX 0 IPBIDE(1)
4Y9L SRL 0 12
4YP= ANDN 0 #77
4^8W SBN 0 19
4^NG BZE 0 OUNSV
5286 SBN 0 1
52MQ BZE 0 OUNSV
537B LDN 0 #46
53M2 SMO 6
546L ANDX 0 A1+IDSTATUS
54L= BZE 0 OUNSV [J IF NOT WARNING NOR CLOSING
555W SMO FX2
55KG LDX 3 ACTRING
5656 SBN 3 ACTRING
56JQ CHAIN 1,BPTR(3)
574B [ CHAIN BEYOND CONDCB
57J2 BRN OUT1
583L OUNSV
58H= LDX 3 IPBRING(2)
592W SBN 3 IPBRING
59GG LDX 2 ACTRING(3)
5=26 SBN 2 ACTRING
5=FQ CHAIN 1,BPTR(2) [CHAIN INTO IPBOUT ACTIVITY
5=^B LDCT 0 #100
5?F2 ANDX 0 IPBSW(3)
5?YL BZE 0 OUT1
5#D= ERS 0 IPBSW(3)
5#XW LDX 2 3
5*CG FPUT
5*X6 OUT1 UP
5BBQ XFREE MHUNTW 1,AMXOR,ICONIN
5BWB LDX 6 ALOGLEN(1)
5CB2 FREECORE 1
5CTL SBS 6 INLOAD(2) [DECREMENT INPUT OVERLOAD COUNT
5D*= EXIT 5 0
5DSW [***** K2 ENTRY POINT ******
5F#G S37
5FS6 MHUNTW 2,AMXOR,CONDCB
5G?Q LDX 3 2
5GRB ADX 2 7 [POINT TO CONDCB ENTRY
5H?2 SRL 4 12
5HQL LDCH 0 4
5J== SRL 4 6
5JPW SBN 0 24
5K9G BNZ 0 S37D
5K*C ... LDCT 0 #77
5KF# ... ANDX 0 A1+IDSTATUS+1(2)
5KK9 ... BZE 0 S37CM
5KP6 LDCT 0 1
5L8Q SBS 0 A1+IDSTATUS+1(2)
5LDJ ...S37CM
5LNB LDX 0 4
5M82 SBN 0 6
5MML BNZ 0 S37D [J UNLESS UNAVAILABLE MODE
5N7= SMO A1+BPTR(2)
5NLW LDX 0 FOURTHWD
5P6G ANDN 0 #17
5PL6 BZE 0 S37M
5Q5Q [ J IF MOP
5QKB SBN 0 10
5R52 BNZ 0 S37D [J IF NOT VDU
5RJL S37M NGN 0 #301
5S4= ANDS 0 A1+IDSTATUS+1(2) [UNSET M4 AND M4STATUS DETERMINED
5SHW S37D SBN 4 28
5T3G BNZ 4 S37A [J. UNLESS CODE 28
5TH6 NGNC 0 1
5W2Q ANDS 0 A1+IDSTATUS(2)
5WGB NULL
5X22 NULL
5XFL NULL
5X^= LDCT 0 #20
5YDW ANDX 0 A1+IDSTATUS(3)
5YYG BNZ 0 S54D [J. IC CLOSE DOWN SET
5^D6 LDN 4 #201 [CLOSE IDENTIFIER,CLOSED
5^XQ LDN 5 12
62CB BRN XCCA
62X2 S37A ADN 4 22
63BL BNZ 4 S37F
63W= ACROSS IPBCCD,2
64*W S37F BCT 4 NFREE
64TG LDN 0 #400
65*6 ANDX 0 A1+IDSTATUS(2)
65SQ BZE 0 XSET [J. UNLESS CANCEL ATTACH SET
66#B LDCT 0 #200
66S2 ANDX 0 A1+IDSTATUS+1(2)
67?L BRN S56Y
67R= XSET LDN 5 3
68=W BRN XCCA
68QG S56Y BZE 0 NFREE [J. UNLESS CHANGE MODE SET
69=6 S56X LDN 5 13
69PQ BRN XCCA
6=9B NFREE CALL 5 XFREE
6=P2 NXTBL LDN 5 17
6?8L XCCA
6?N= ACROSS IPBCCD,1
6#7W S54D LDX 0 A1+IDSTATUS(2)
6#MG SRC 0 1
6*76 BNG 0 S54A [J. IF CLOSED SET
6*LQ ANDN 0 3
6B6B BNZ 0 S54B [J. IF CLOSING OR CRASH CLOSING
6BL2 LDN 0 1
6C5L ORS 0 A1+IDSTATUS(2) [SET CLOSED
6CK= S54A CALL 5 XFREE
6D4W LDN 5 19
6DJG S54X LDN 0 1
6F46 SBS 0 A1+IDSTATUS(3) [DECREMENT CLOSE DOWN COUNT
6FHQ ZS54X LDCT 0 #40
6G3B ANDX 0 A1+IDSTATUS(3)
6GH2 BZE 0 XCCA [J. UNLESS INITIALISE SET
6H2L BRN SETV
6HG= S54B CALL 5 XFREE
6H^W LDN 5 24
6JFG BRN XCCA
6J^6 SETV LDCT 6 #200
6KDQ SMO A1+BPTR(3)
6KYB ANDX 6 IPSTATUS
6LD2 BNZ 6 XCCA [J. IF INTERNAL CLOSE DOWN
6LXL LDN 6 #140
6MC= LDCT 0 #20
6MWW SETW LDN 1 #777
6NBG SETS ANDX 1 A1+IDSTATUS(3)
6NW6 BNZ 1 XCCA [J. UNLESS RELEVANT COUNT ZERO
6P*Q SBN 5 1
6PTB SETP ERS 0 A1+IDSTATUS(3)
6Q*2 BRN XCCA
6QSL [
6R#= [***** K3 ENTRY POINT ******
6RRW XK3
6S?G MHUNTW 2,AMXOR,CONDCB
6SR6 LDX 3 2
6T=Q ADX 2 7
6TQB SMO 6
6W=2 BRN TABLE [J. ON SUPERVISORY CODE
6WPL S2 LDCT 4 #200
6X9= ORS 4 A1+IDSTATUS(3) [SET STOP REMOTE INPUT
6XNW LDX 0 XMSK7(1)
6Y8G ANDS 0 A1+IDSTATUS(3) [ZEROISE STOP REMOTE INPUT &OUNT
6YN6 S2B CALL 5 OCHZ
6^7Q BRN S2A
6^MB BPZ 0 S2F [J. UNLESS &LOSED SET
7272 ANDN 0 3
72LL BZE 0 S2B [J. UNLESS CLOSING OR CR. CLOSING SET
736= BRN S2D
73KW S2F SRC 0 8
745G BNG 0 S2D [J. IF CANCEL ATTACH SET
74K6 SLC 0 5
754Q BNG 0 S2G [J. IF NOT CLEARED SET
75JB SRC 0 1
7642 BNG 0 S2B [J. IF STOPPED SET
76HL LDN 0 #10
773= ORS 0 A1+IDSTATUS(2) [SET STOPPED
77GW BRN S2C
782G S2G SRC 0 1
78G6 BPZ 0 S2E [J. UNLESS STOPPED SET
78^Q NGN 0 #21
79FB ANDS 0 A1+IDSTATUS(2) [UNSET STOPPED
79^2 S2C LDN 6 #124 [OUTPUT STOP INPUT AND CLEAR
7=DL CALL 5 OUTX
7=Y= S2D LDCT 0 #200
7?CW ORS 0 A1+IDSTATUS(2) [SET SRI
7?XG S2E LDN 0 #1000
7#C6 ADS 0 A1+IDSTATUS(3) [INCREMENT SRI COUNT
7#WQ BRN S2B
7*BB S2A LDX 1 XMSK9(1)
7*W2 LDN 6 #142 [INPUT END OF REMOTE INPUT
7B*L LDCT 0 #200
7BT= LDN 5 15
7C#W BRN SETS
7CSG S3 NGN 4 #1000
7D#6 ANDS 4 A1+IDSTATUS(3) [ZEROISE EOIO COUNT
7DRQ S3A CALL 5 OCHZ
7F?B BRN S3C
7FR2 BPZ 0 S3D [J. UNLESS CLOSED SET
7G=L ANDN 0 3
7GQ= BZE 0 S3A [J. UNLESS CLOSING OR CR. CLOSING SET
7H9W BRN S3B
7HPG S3D SRC 0 8
7J96 ORX 0 A1+IDSTATUS+1(2)
7JNQ BNG 0 S3B [J. IF OUTPUT SENT SET
7K8B LDX 0 GSIGN
7KN2 ORS 0 A1+IDSTATUS+1(2) [SET OUTPUT SENT
7L7L LDX 6 XMSK37(1)
7LM= LDN 3 5
7M6W CALL 5 OUTV
7MLG S3B LDCT 0 #100
7N66 ORS 0 A1+IDSTATUS(2) [SET EOIO
7NKQ LDN 0 1
7P5B ADS 0 A1+IDSTATUS(3) [INCREMENT EOIO COUNT
7PK2 BRN S3A
7Q4L S3C LDN 5 15
7QJ= BRN SETR
7R3W S10 LDCT 0 #100
7RHG ANDX 0 A1+IDSTATUS(3)
7S36 LDN 4 0
7SGQ BZE 0 S10F [J. UNLESS RESET SET
7T2B S10D CALL 5 OCHZ
7TG2 BRN S10C
7T^L BNG 0 S10D [J. IF CLOSED SET
7WF= SRC 0 8
7WYW BNG 0 S10D [J. IF CANCEL ATTACH SET
7XDG SLC 0 2
7XY6 BZE 4 S10E
7YCQ LDN 6 #122 [ONE SHOT INPUT
7YXB BNG 0 S10B [J. IF ONE SHOT INPUT SET
7^C2 S10E SLC 0 2
7^WL BNG 0 S10D [J. IF STOPPED SET
82B= LDN 6 #121 [START INPUT
82TW SLC 0 1
83*G BPZ 0 S10B [J. UNLESS NOT CLEARED
83T6 LDN 6 #124 [STOP INPUT AND CLEAR
84#Q S10B CALL 5 OUTY [OUTPUT APPROPRIATE SUPERVISORY
84SB BRN S10D
85#2 S10C BNZ 4 S11D
85RL LDCT 0 #100 [UNSET RESET
86?= S10F LDN 6 #140 [INPUT READY
86QW LDN 5 14
87=G BRN SETP
87Q6 S11 LDCT 0 #100
889Q ORS 0 A1+IDSTATUS(3) [SET RESET
88PB LDN 4 0
8992 S11B CALL 5 OCHZ
89NL BRN S11C
8=8= BNG 0 S11B [J. IF CLOSED SET
8=MW ANDN 0 #210
8?7G BNZ 0 S11B [J. IF CANCEL ATTACH OR STOPPED SET
8?M6 LDN 6 #123 [OUTPUT STOP INPUT
8#6Q CALL 5 OUTY
8#LB BRN S11B
8*62 S11C BZE 4 XBACK
8*KL S11D
8B5= ACROSS IPBCCA,1
8BJW S17 CALL 5 SRI
8C4G NGN 5 #131 [ONE SHOT INPUT,STOPPED,NOT CLEARED
8CJ6 BNG 0 S17A [J. IF STOPPED SET
8D3Q S17X SLC 0 1
8DHB BPZ 0 XIL1 [J. UNLESS NOT CLEARED
8F32 S17A ANDS 5 A1+IDSTATUS(2) [UNSET APPROPRIATE BITS
8FGL S17Y LDCH 0 A1+IDADIN(3)
8G2= BNZ 0 XBACK [J. IF INPUT OVERLOAD CONDITION
8GFW LDN 0 #3400
8G^G ANDX 0 A1+IDSTATUS(2) [J. UNLESS INOPERABLE FREE
8HF6 BZE 0 XKEEP [OR CANCEL ATTACH SET
8HYQ BRN XBACK
8JDB S18 CALL 5 SRIX
8JY2 BPZ 0 XIL1 [ILLEGAL 1 UNLESS STOPPED SET
8KCL LDEX 0 A1+IDSTATUS+1(2)
8KX= LDX 6 ZIN(1)
8LBW SMO 0
8LWG SLL 6 0
8MB6 BPZ 6 XIL2 [ILLEGAL 2 IF WRONG TYPE
8MTQ LDN 0 #130 [ONE SHOT INPUT,STOPPED,NOT CLEARED
8N*B S18Y ORS 0 A1+IDSTATUS(2) [SET APPROPRIATE BITS
8NT2 BRN S17Y
8P#L S19 CALL 5 SRI
8PS= BNG 0 XIL1 [ILLEGAL 1 IF STOPPED SET
8Q?W LDN 0 #30 [STOPPED,NOT CLEARED
8QRG BRN S18Y
8R?6 S20 CALL 5 SRI
8RQQ BNG 0 S20A [J. IF STOPPED SET
8S=B SLC 0 1
8SQ2 BNG 0 XIL1 [ILLEGAL 1 IF NOT CLEARED SET
8T9L LDN 0 #10 [NOT CLEARED
8TP= BRN S18Y
8W8W S20A NGN 5 #121 [ONE SHOT INPUT,STOPPED
8WNG BRN S17X
8X86 XBACK LDN 5 15
8XMQ BRN XCCA
8Y7B XKEEP LDX 6 GSIGN
8YM2 LDN 5 4
8^6L ACROSS IPBCCA,2
8^L= S12A LDX 2 3
925W ADX 2 7
92KG LDX 0 A1+BPTR(2)
9356 BNZ 0 S12 [J. UNLESS NULL INDENTIFIER
93JQ LDN 0 #200
944B ORS 0 A1+IDSTATUS(2) [SET CLOSE IDENTIFIER
94J2 S12 ADN 7 CONDCBLEN
953L BXL 7 ALOGLEN(3),S12A [J. UNLESS END OF CONDCB SCAN
95H= IDFCONREQ [GENERATE CONFIGURATION REPORT
962W LDN 5 10
96GG BRN XCCA
9726 S16 LDX 0 A1+IDSTATUS(2)
97FQ SRC 0 1
97^B BPZ 0 XIL1 [ILLEGAL 1 UNLESS CLOSED SET
98F2 SLC 0 1
98YL BNG 0 XIL19 [ILLEGAL 19 IF OPENING SET
99D= ANDN 0 #3400 [ILLEGAL 28 IF INOPERABLE,FREE
99XW BNZ 0 XIL28 [OR CANCEL ATTACH SET
9=CG LDX 0 A1+BPTR(2)
9=X6 BZE 0 XIL28 [ILLEGAL 28 IF NULL INENTIFIER
9?BQ SMO 0
9?WB LDX 0 FOURTHWD
9#B2 ANDN 0 #17 [LEAVE BITS 18,19 UNSET
9#TL SMO 2
9**= DCH 0 A1+IDSTATUS+1
9*SW BZE 0 ZMM4 [J IF MOP TERMINAL
9B#G SBN 0 10
9BS6 BZE 0 ZMM4 [J IF NOT VDU
9C?Q LDN 0 #200
9CRB ORS 0 A1+IDSTATUS+1(2) [SET MODE4 STATE DETERMINED
9D?2 ZMM4
9DQL NGX 0 XMSK49(1) [UNSET SRI,EOIO,UNAVAILABLE,
9F== ANDS 0 A1+IDSTATUS(2) [ONE SHOT INPUT,CLOSE IDENTIFIER,
9FPW NGX 0 XMSK46(1) [NOT CLEARED,CLOSED
9G9G ANDS 0 A1+IDSTATUS(3) [INITIALISE,OUTPUT SENT,NPU AND
9GP6 NGX 0 XMSK47(1) [CHANGE MODE
9H8Q ANDS 0 A1+IDSTATUS+1(2)
9HNB LDX 5 XMSK33(1) [OPENING,STOPPED
9J82 S16X ORS 5 A1+IDSTATUS(2) [SET APPROPRIATE BITS
9JML BRN XKEEP
9K7= S22 LDX 0 A1+IDSTATUS(2)
9KLW SRC 0 1
9L6G BNG 0 XIL1 [ILLEGAL 1 IF CLOSED SET
9LL6 SRC 0 4
9M5Q BPZ 0 S22A [J. UNLESS STOPPED SET
9MKB SLC 0 1
9N52 BNG 0 XIL2 [ILLEGAL 2 IF NOT CLEARED SET
9NJL S22A LDCT 5 #100
9P4= ANDX 5 A1+IDSTATUS+1(2)
9PHW BNZ 5 XIL19 [ILLEGAL 19 IF NPU SET
9Q3G LDN 5 5 [CLOSING,CLOSED
9QH6 S22Y LDX 0 A1+IDSTATUS(2)
9R2Q SRC 0 3
9RGB BXGE 0 BITS22LS,XIL19 [ILLEGAL 19 IF CLOSING,CR.CLOSING SET
9S22 S22X SRC 0 6
9SFL BNG 0 S22B [J. IF CANCEL ATTACH SET
9S^= ANDN 0 3
9TDW BZE 0 S22CW [J UNLESS INOP OR FREE
9TYG CALL 5 VRCLO
9WD6 BRN S22C
9WXQ S22CW LDN 0 2
9XCB ANDX 0 5
9XX2 BZE 0 S16X [J UNLESS CR CL
9YBL LDX 6 3
9YW= LDX 4 2
9^*W ORX 7 GSIGN
9^TG LDN 5 S50CA(1)
=2*6 BRN SVARN [GO TO DEAL WITH SAVED BLOCKS
=2SQ S23W LDN 5 3
=3#B BRN S16X
=3S2 S22B
=4?L VFNCA
=4R= NGN 0 #401
=5=W ANDS 0 A1+IDSTATUS(2) [UNSET CANCEL ATTACH
=5QG LDN 0 #200
=6=6 ANDX 0 A1+IDSTATUS(2)
=6PQ BZE 0 S22C
=79B LDN 0 1
=7P2 ORS 0 A1+IDSTATUS(2)
=88L S22C LDN 5 5
=8N= BRN XCCA
=97W S23 LDX 0 A1+IDSTATUS(2)
=9MG SRC 0 1
==76 LDN 5 3 [CRASH CLOSING,CLOSED
==LQ BPZ 0 S22Y [J. UNLESS CLOSED SET
=?6B SRC 0 2
=?L2 BPZ 0 XIL1 [ILLEGAL 1 UNLESS CLOSING SET
=#5L NGN 6 5
=#K= ANDS 6 A1+IDSTATUS(2) [UNSET CLOSING
=*4W BRN S22X
=*JG S24 BZE 4 XBACK
=B46 LDX 0 A1+BPTR(2)
=BHQ BZE 0 XIL28 [J IF NULL DENT
=C3B LDX 0 4
=CH2 SRL 0 15
=D2L BZE 0 NNCM [J IF NOT MODE CHANGE
=DG= ANDN 0 7
=D^W SBN 0 4
=FFG BNZ 0 TNM4 [J IF NOT TO MODE 4
=F^6 SMO A1+BPTR(2)
=GDQ LDCH 0 FOURTHWD
=GYB ANDN 0 #17
=HD2 BZE 0 TM4 [J IF MOP
=HXL SBN 0 10
=JC= BNZ 0 TM4S
=JWW TM4
=KBG LDN 0 #100
=KW6 ORS 0 A1+IDSTATUS+1(2) [SET PROGRAM DEALING WITH WARNING
=L*Q NGN 0 #41 [UNSET WARNING MARKERS
=LTB ANDS 0 A1+IDSTATUS(2)
=M*2 ERN 0 #20 [INCLUDING REFLECTION MARKER
=MSL ANDS 0 A1+IDSTATUS+1(2)
=N#= BRN TM4S
=NRW TNM4 NGN 0 #101
=P?G ANDS 0 A1+IDSTATUS+1(2)
=PR6 [ UNSET "PROGRAM DEALING WITH WARNING"
=Q=Q TM4S LDCT 0 #400
=QQB ORN 0 1
=R=2 ANDX 0 A1+IDSTATUS(2)
=RPL BZE 0 NNCM [J IF ALREADY OPEN
=S9= LDN 0 #200
=SNW ORS 0 A1+IDSTATUS+1(2) [SET MODE4 STATUS DETERMINED
=T8G NNCM
=TN6 ANDX 4 BSP16
=W7Q BZE 4 S24A [J. IF NO NPUSIZE CHANGE REQUIRED
=WMB LDX 5 A1+IDMDNPU(3)
=X72 SRL 5 12
=XLL SBN 5 3
=Y6= BXL 5 4,XIL7 [ILLEGAL 7 IF NPUSIZE>I/P BUFF SIZE-3
=YKW LDCT 4 #200
=^5G S24A LDN 0 #3400
=^K6 ANDX 0 A1+IDSTATUS(2)
?24Q BNZ 0 XBACK [J. IF INOP.,FREE OR CL. ATTACH SET
?2JB LDX 0 A1+BPTR(2)
?342 BZE 0 XIL28 [ILLEGAL 28 IF NULL IDENTIFIER
?3HL LDCT 0 #100
?43= ANDX 0 A1+IDSTATUS+1(2)
?4GW BNZ 0 XIL19 [ILLEGAL 19 IF NPU SET
?52G BNG 4 XKEEP [J. IF SET PRIORITY
?5G6 LDCT 0 1
?5^Q ADS 0 A1+IDSTATUS+1(2) [INCREMENT CHANGE MODE COUNT
?6FB LDX 0 A1+IDSTATUS(2)
?6^2 BPZ 0 XKEEP [J. UNLESS OPENING SET
?7DL ORS 4 A1+IDSTATUS+1(2) [SET CHANGE MODE UNLESS NPUSIZE
?7Y= BRN XKEEP [CHANGE REQUIRED
?8CW S25 BZE 4 XIL5
?8XG SBN 4 19
?9C6 BNG 4 S24A [ILLEGAL 5 UNLESS 19>PRIORITY>0
?9WQ BRN XIL5
?=BB S50CA BRN S509 [J IF NO MORE FOR THIS IDENT
?=W2 SBN 0 23
??*L BZE 0 S509 [J IF CRASH CLOSE
??T= BNG 0 S50V [J IF NOT SET PRI NOR CM
?##W SBN 0 3
?#SG BNG 0 S50V
?*#6 LDX 6 1
?*RQ [ POINT PAST BLOCK
?B?B BRN SVARN
?BR2 S50V
?C=L LDX 0 ALOGLEN(1)
?CQ= LDXC 2 IMOPTY(1) [SET C IF CONTINUE SEG BEING REFLECT
?D9W LDX 2 FX2 [FX2 + 1 FOR CONTINUE SEG
?DPG SBS 0 IOUTLOAD(2) [INLOAD (= IOUTLOAD + 1) FOR CONTINUE
?F96 FREECORE 1
?FNQ BRN SVARN [LOOK FOR NEXT SEG
?G8B S509 BNG 7 S23W [J IF CAME FROM CRASH CLOSE
?GN2 LDN 0 #40
?H7L ORS 0 A1+IDSTATUS(2) [SET WARNING
?HM= S5092
?J6W LDN 0 #20
?JLG ANDX 0 A1+IDSTATUS+1(2)
?K66 BZE 0 XSET [J UNLESS STILL REFLECTING CONTINUE
?KKQ ERS 0 A1+IDSTATUS+1(2)
?L5B BRN NFREE [DO NOT PASS ON IF STILL REFLECTING C
?LK2 [
#2#2 [
#2RL XIL5 LDN 4 #500
#3?= BRN XILL
#3QW )
#4=G #END
^^^^ ...610755350009