{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: IPBIN867)}}
====== IPBIN867 ======
(George Source)
**Macros used:** [[george:macro:BXE|BXE]], [[george:macro:CCERROR|CCERROR]], [[george:macro:CCOUT|CCOUT]], [[george:macro:CHAIN|CHAIN]], [[george:macro:COOR1|COOR1]], [[george:macro:COOR3|COOR3]], [[george:macro:DOWN|DOWN]], [[george:macro:DSCA|DSCA]], [[george:macro:FINDACTFB|FINDACTFB]], [[george:macro:FON|FON]], [[george:macro:FPUT|FPUT]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GSCAN|GSCAN]], [[george:macro:GSPERI|GSPERI]], [[george:macro:HUNT2J|HUNT2J]], [[george:macro:HUNTW|HUNTW]], [[george:macro:JSBUSY|JSBUSY]], [[george:macro:LOCKC|LOCKC]], [[george:macro:LONGON1|LONGON1]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:NAME|NAME]], [[george:macro:NBREAKIN|NBREAKIN]], [[george:macro:PHOTO|PHOTO]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:TESTMOVE|TESTMOVE]], [[george:macro:TRACE|TRACE]], [[george:macro:UNLOCK|UNLOCK]]
22FL #SEG IPBIN8 [COMM - IPB
22^= [ (C) INTERNATIONAL COMPUTERS LTD. 1982
23DW #LIST K0IPBIN>K0IPB>K0ALLGEO>K0GREATGEO
23YG 8HIPBIN
24D6 #
24XQ SEGENTRY K1IPBIN,SK1IPBIN
25CB #
25X2 #DEF VRUC=33 [COUNT OF CHARS IN RACK UP SEQUENCE
26BL #DEF VBIC=8 [COUNT OF CHARS IN "BREAK IN" MESSAGE
26W= #
27*W VRACKUP #76130700
27TG SBREAK 8HBREAK IN
28*6 SMSKOP #63770077
28SQ SMSKR #77607777
29#B SMOP #77717777
29S2 SMSOR #57777777
2=?L SHDR #40240000 [EOM+BIACK+NORMAL DATA SIEVE BIT
2=R= XMASK #44040000 [B0,3,9
2=YD ...XIN 4HIN00
2?5L ...XNULL #01570000
2?=W SPSDMSK #77352040 [FOURTHWD MASK FOR PSEUDO VDUS
2?QG SSTYP
2#=6 #HAL AMXOR+IDATSG,0
2#PQ ZJIPBERR +JIPBERR
2*9B ZJIPBINOP +JIPBINOP
2*P2 #
2B8L #
2BN= [
2C7W [
2CMG #UNS CCERROR
2D76 (
2DLQ [
2F6B ...
2FL2 [
2G5L [ MADE A SUBROUTINE SO AS NOT TO INTERRUPT FLOW FOR MAINTENANCE
2GK= [
2H4W XSUBJOURN
2H6P ... LDX 4 AWORK2(2)
2H8J ... LDCH 6 0(3)
2H=C ... BNZ 6 XJRN1
2H#= ... LDN 6 2
2HB5 ... BRN XJRN2
2HCY ...XJRN1
2HFR ... LDX 0 0(3)
2HHL ... SMO FX1
2HKF ... TXU 0 XNULL
2HM# ... BCC XJRNE
2HP7 ...XJRN2
2HR2 ... HUNTW 2,AMXOR,AJOURN
2HST ... BNG 2 XJRN7
2HWN ...XJRN3
2HYH ... LDN 0 488
2J2B ... SBX 0 IPBCOUNT(2)
2J49 ... SBX 0 6
2J64 ... BNG 0 XJRN4
2J7X ... LDN 5 IPBDATA(2)
2J9Q ... ADX 5 IPBCOUNT(2)
2J?K ... SMO 5
2J*D ... STO 4 0
2JC? ... ADN 5 1
2JF6 ... LDN 4 0(3)
2JG^ ... SMO 6
2JJS ... MOVE 4 0
2JLM ... ADN 6 1
2JNG ... ADS 6 IPBCOUNT(2)
2JQ* ...XJRNE
2JS8 ... LDX 2 FX2
2JW3 ... EXIT 7 0
2JXW ...
2J^P ...XJRN4
2K3J ... LDX 0 IPBCOUNT(2)
2K5C ... BZE 0 XJRNE
2K7= ... LDX 0 IPBJRN
2K95 ... BNZ 0 XJRN5
2K=Y ... STOZ IPBCOUNT(2)
2K#R ... BRN XJRN3
2KBL ...XJRN5
2KDF ... SBX 7 FX1
2KG# ... NAME 2,AMXOR,AMISC
2KJ7 ... FINDACTFB 1,FX2,AMOP,AJOURN,,BPTR
2KL2 ... LDX 5 1
2KMT ... CHAIN 2,5
2KPN ... LDX 2 5
2KRH ... LDX 0 IPBSW(2)
2KTB ... BNG 0 XJRN6
2KX9 ... LDX 0 GSIGN
2K^4 ... STO 0 IPBSW(2)
2L2X ... FPUT
2L4Q ...XJRN6
2L6K ... SETNCORE 499,2,AMXOR,AJOURN
2L8D ... SMO FX2
2L=? ... LDX 0 CPPTR
2L#6 ... STO 0 IPBDATA+497(2)
2L*^ ... STOZ IPBCOUNT(2)
2LCS ... ADX 7 FX1
2LFM ... BRN XJRN3
2LHG ...
2LK* ...XJRN7
2LM8 ... SBX 7 FX1
2LP3 ... COOR3 #62
2LQW ... ADX 7 FX1
2LSP ... BRN XJRN2
2LWJ ...
2L^W )
2MFG #
2M^6 # SUBROUTINE TO COPY AVAILABILITY FROM X0 TO FOURTHWD AND ISTATUS
2NDQ #
2NYB SAVA NGNC 4 1 [#37777777
2PD2 ANDS 4 A1+FOURTHWD(2) [UNSET B0
2PXL ORS 0 A1+FOURTHWD(2) [COPY TO ADEVS
2QC= BZE 1 (6) [EXIT IF NOT RINGED : DEVICE IDLE
2QWW ORS 0 ISTATUS(1) [COPY TO ADCB
2RBG BNG 0 (6) [EXIT IF UNAVAILABLE
2RW6 LDCT 4 #420 [DEVICE AVAILABLE
2S*Q CALL 7 TBULKINPUT
2STB LDCT 4 #400 [NOT A BULK INPUT DEVICE
2T*2 [BULK INPUT DEVICE : DON'T UNSET LINE
2TSL [/TERMINAL FAIL EVENT FLAG(READBULK
2W#= [WILL,TO ENSURE EVENT ISN'T MISSED
2WRW LDCT 0 2
2X?G ANDX 4 ISTATUS(1)
2XR6 ANDX 0 A1+FOURTHWD(2)
2Y=Q BZE 4 (6) [EXIT IF ALREADY MARKED AVAILABLE
2YQB ERS 4 ISTATUS(1)
2^=2 BNZ 0 (6) [EXIT IF WRONGED
2^PL LONGON1 #36,IDENTNO(1) [WAKE ACTLF WAITING FOR THIS
329= CALL 7 SKADB [LONGON HAS CHANGED X1
32NW EXIT 6 0
338G #
33N6 # SUBROUTINE TO TEST IF IDENTIFIER IS A MOP TERMINAL
347Q # ON ENTRY X2 -> ADEVS ENTRY-(A1+FOURTHWD)
34MB # EXITS+0,WITH X0=DEVICE TYPE,IF FALSE; EXITS+1 IF TRUE
3572 #
35LL TESTIFMOP
366= LDEX 0 A1+FOURTHWD(2)
36B4 ... ANDN 0 #37
36KW BZE 0 YMOP [MOP CONSOLE
375G SBN 0 10
37K6 BZE 0 YMOP [MOP DISPLAY
384Q ADN 0 10 [LEAVE X0 = DEVICE TYPE
38JB EXIT 7 0
3942 YMOP EXIT 7 1
39HL #
3=3= # SUBROUTINE TO TEST IF IDENTIFIER IS A BULK INPUT DEVICE : ON ENTRY
3=GW # X2 -> ADEVS ENTRY-(A1+FOURTHWD); EXITS+0 IF FALSE,EXITS+1 IF TRUE
3?2G #
3?G6 TBULKINPUT
3?^Q LDEX 0 A1+FOURTHWD(2)
3#9J ... ANDN 0 #37
3#FB SBN 0 4
3#^2 BZE 0 YBIP [RJE CR
3*DL SBN 0 2
3*Y= BNZ 0 (7) [NOT RJE TR
3BCW YBIP EXIT 7 1
3BXG #
3CC6 # SUBROUTINE TO OUTPUT SUPERVISORY SEGMENT (IN X6) ; IDENT NO IN X5
3CWQ #
3DBB SCCO LDX 2 FX2
3DW2 STO 6 ACOMMUNE1(2) [COUNT + SUPERVISORY CODE
3F*L SBX 7 FX1
3FT= CCOUT 5,2
3G#W ADX 7 FX1
3GSG EXIT 7 0
3H#6 #
3HRQ # INPUT RECEIVED FROM IDLE IDENTIFIER : NEW ACTIVITY REQUIRED
3J?B #
3JR2 SETDB
3K=L LDCT 0 #163 [B2:MOP OFF B3:IDENTIFIER NOT YET SCA
3KQ= [B4:ACTIVITY BEING SETUP B7:WRONGED
3L9W ANDX 0 A1+FOURTHWD(2) [B8 : ATTACHING OR CLOSING FOR ONLINE
3LPG BNZ 0 SNEW [IGNORE INPUT
3M96 LDCT 0 #20
3MNQ ORS 0 A1+FOURTHWD(2) [SET 'ACTIVITY BEING SET UP' BIT
3N8B [BIT WILL BE CLEARED IN IPBINB
3NN2 SBX 7 FX1
3P7L DOWN IPBINB,2 [SET UP NEW ACTIVITY & DCB
3PM= ADX 7 FX1
3Q6W EXIT 7 0
3QLG #
3R66 # SUBROUTINE TO GET ADDRESS IN X2 OF ACTIVITY OWNING ADCB IN X1
3RKQ #
3S5B SKACT LDX 2 1
3SK2 SFRED LDX 2 BPTR(2)
3T4L LDX 0 ATYPE(2)
3TJ= TXL 0 CACT
3W3W BCS SFRED
3WHG EXIT 7 0
3X36 #
3XGQ # SUBROUTINE TO FIND ADDRESS IN X1 OF ADCB FOR GIVEN IDENTIFIER
3Y2B # IN ((X3)) AND ADDRESS IN X2 OF ADEVS ENTRY FOR THE IDEN
3YG2 #
3Y^L SKADB MHUNTW 2,AMXOR,ADEVS
3^F= LDX 0 0(3) [IDENTIFIER NUMBER
3^YW ANDN 0 #7777
42DG BZE 0 TDCB [ZERO : SYSTEM SUPERVISOR'S NUMBER
42Y6 SBX 0 A1+FOURTHWD(2) [SUBTRACT LOWEST IDENTIFIER NO.
43CQ SLC 0 2
43XB TXL 0 ALOGLEN(2)
44C2 #UNS CCERROR
44WL BCC SERR1 [DCP ERROR : IDENTIFIER TOO LARGE
45B= #UNS CCERROR
45TW #SKI
46*G BCC SERR [DCP ERROR : IDENTIFIER TOO LARGE
46T6 ADX 2 0
47#Q TDCB LDX 1 A1+BPTR(2)
47SB BZE 1 (7) [X1 ZERO IF NO RING POINTER
48#2 SBN 1 A1+FPTR
48RL EXIT 7 0
49?= #
49QW # SUBROUTINE TO WAKE ACTIVITY IF NECESSARY , WITH GIVEN DCB ADDRESS
4==G #
4=Q6 STASH LDN 0 #2000
4?9Q ANDX 0 IWAIT(1) [B13 SET IF WARNING NOTICED BY ACT.
4?PB BZE 0 (6)
4#92 ERS 0 IWAIT(1)
4#NL STAKE LDXC 0 IWAIT(1)
4*8= BCC VCK [ACTIVITY NOT ASLEEP
4*MW STO 0 IWAIT(1)
4B7G CALL 7 SKACT
4BM6 LDX 7 1 [PRESERVE ADCB ADDRESS
4C6Q FPUT [END OF WARNING CONDITION
4CLB WOKEN LDX 1 7
4D62 EXIT 6 0
4DKL VCK [WAKEUP MOP ACTIVITY IF IN WAITING STYLE: IVDUWAIT
4F5= SMO A1+FPTR(1)
4FJW LDEX 0 FOURTHWD
4G4G SBN 0 10
4GJ6 BNZ 0 NVDTW [J IF NOT A VDU
4H3Q LDN 0 #1000
4HHB ANDX 0 ICONTU(1)
4J32 BZE 0 NVDTW [J IF NOT SUSP OUTPUT
4JGL ERS 0 ICONTU(1) [UNSET "WAITING OUTPUT SUSPENDED"
4K2= LDX 7 1
4KFW FON CONTVDUWT [WAKE CPA
4K^G BRN WOKEN
4LF6 NVDTW
4LYQ CALL 7 SKACT [SET X2 -> CPAT
4MDB LDX 7 1 [PRESERVE ADCB ADDRESS
4MY2 LONGCLEA 2,IVDUWAIT,(6)
4NCL BRN WOKEN
4NX= #
4PBW # SUBROUTINE TO CREATE AN AMXOR/IOUT BLOCK
4PWG # ON ENTRY X6 = THE REQUIRED LOGICAL LENGTH OF THE BLOCK
4QB6 # ON EXIT X2 -> THE AMXOR/IOUT BLOCK CREATED
4QTQ # LINK IN X7
4R*B #
4RT2 SETUPIOUTBK
4S#L SBX 7 FX1
4SS= ... SETUPCOR 6,2,AMXOR,IOUT
4T?W ADX 7 FX1
4TRG EXIT 7 0
4W?6 #
4WQQ # REHUNT THE INBF BLOCK IF IT MOVES DURING A LOCKC
4X=B #
4XQ2 STIF MHUNTW 2,AMXOR,INBF
4Y9L EXIT 1 0
4YP= #
4^8W #
4^NG # ISSUE READ ORDERS TO THE IPB ; OBEYED FROM AMOP/IPBIN ACTIVITY
5286 #
52MQ SELECTFLAG [DEAL WITH EXCEPTION FLAGS IN
537B [STRICT ORDER
53M2 SLC 0 3
546L BNG 0 SWT [READ INHIBITED
54L= SRC 0 3
555W BNG 0 SERR0 [DCP ERROR REPORTED
55KG # THIS IS A MESSAGE BUFFERING COMMUNICATIONS SUBSYSTEM
5656 # INPUT ACTIVITY FOR A VIRTUAL 7900 .
56JQ # IF THE VIRTUAL 7900 HAS A WMC WRITE TRANSFER STORED,
574B # GO DOWN TO K5VIPBPERI TO PERFORM THE TRANSFER
57J2 # IF THE RETURN IS UP, IE WRITE TRANSFERS WERE NO LONGER
583L # STORED ,RECHECK FOR FLAGS & STORED WRITES BEFORE SLEEPING
58H= # IF THE RETURN IS UP +1, IE WRITE TRANSFER PERFORMED ,
592W # ENTER ROUTINE SNORJ TO PROCESS THE INPUT BUFFER
59GG # (NOTE K5VIPBPERI SETS THE INPUT ACTIVITY'S REPLY WORD
5=26 # WITH A SUCCESSFUL 7900 READ TRANSFER REPLY TO MINIMISE
5=FQ # CHANGES TO K1IPBIN)
5=^B # THEN RECHECK FOR FLAGS AND STORED WRITES BEFORE SLEEPING
5?F2 SMO CPPTR(2) [-> VIRTUAL 7900 DEVICE LIST
5?YL LDX 0 AVCWRITES
5#D= BZE 0 VSLEEP [NO WMC WRITE TRANSFER STORED : SLEEP
5#XW SMO CPPTR(2)
5*CG LDX 0 JK52H
5*X6 BZE 0 VSLEEP [J IF MOPPED OFF
5BBQ DOWN VIPBPERI,5
5BWB BRN SK1IPBIN [WMC WRITES WERE NO LONGER STORED
5CB2 [RECHECK FOR FLAGS AND STORED WRITES
5CTL MHUNTW 3,AMXOR,INBF [WMC WRITE TRANSFER PERFORMED
5D*= BRN SENDOFXFER [PROCESS INPUT BUFFER (INC MOPTRACE)
5DSW VSLEEP
5F#G LDCT 0 #100 [MARK AMOP/IPBIN ACTIVITY AS ASLEEP
5FS6 ORS 0 IPBSW(2)
5G?Q MHUNTW 3,AMXOR,INBF [UNLOCK MBS'S INPUT BUFFER
5GRB UNLOCK 3
5H?2 COOR1 [SLEEP
5HQL MHUNTW 3,AMXOR,INBF [LOCK MBS'S INPUT BUFFER
5J== LOCKC 3,STIF
5JPW MHUNTW 3,AMXOR,INBF
5K9G BRN SK1IPBIN [RECHECK FOR FLAGS AND STORED WRITES
5KP6 #
5L8Q ...SWT
5LNB ... DOWN IPBINB,31
68=W COOR1 [WAIT IF READ INHIBITED
6TQB [ A DUMMY LABEL IN CASE IPBIN ACT GETS FPUT IN ERROR
6W=2 [
6WPL XFIN
6X9= #
6XNW [* * *
6Y8G [* * *
6YN6 [** *
6^7Q [* * *
6^MB [* * *
7272 [
72LL [
736= SK1IPBIN
73KW LDX 1 FX1
745G LDX 2 FX2
74K6 [
754Q [ CODE TO CHECK FOR FINISH AND IF SO TO KICK OFF ANY CARD OR TAPE
75JB [ READER ACTIVITY THAT MAY BE WAITING FOR DATA, IE THE COS ERROR
7642 [ LOGGING FILE. SO THAT THEY CAN TAKE THEIR OWN FINISH ACTION
76HL [
773= LDX 0 FINISH
77GW BZE 0 SK1F [J. NOT FINISHING
782G HUNT2J 3,AMXOR,ADEVS,2,SK1E [HUNT ADEVS
78G6 LDX 6 ALOGLEN(3)
78^Q ADN 3 A1+FOURTHWD
79FB SK1A
79^2 SBN 6 4
7=DL BZE 6 SK1E [J END OF ADEVS
7=Y= LDX 0 FOURTHWD(3) [LD FOURTHWD
7?CW ANDN 0 #17 [MASK OUT DEVICE TYPE
7?XG SBN 0 4
7#C6 BZE 0 SK1B [J CARD READER
7#WQ SBN 0 2
7*BB BNZ 0 SK1D [J. NOT CARD OR TAPE
7*W2 SK1B
7B*L LDX 2 BPTR(3)
7BT= BZE 2 SK1D [J. NOT RINGED
7C#W LDX 0 IWAIT(2)
7CSG BPZ 0 SK1D [J. NOT ASLEEP
7D#6 SK1C
7DRQ LDX 2 BPTR(2)
7F?B LDX 0 ATYPE(2)
7FR2 SBN 0 CACT [FIND ACTIVITY BLK
7G=L BNZ 0 SK1C
7GQ= FPUT [RESTART ACTIVITY
7H9W SK1D
7HPG ADN 3 4
7J96 BRN SK1A [J. TO LOOK AT NEXT ENTRY
7JNQ SK1E
7K8B LDX 1 FX1
7KN2 LDX 2 FX2
7L7L SK1F
7LM= # DON'T ISSUE READ IF DCP ERROR REPORTED OR READ
7M6W # INHIBITED(BY IPBOUT) OR COMMUNICATING W/ A VIRTUAL 7900
7MLG LDX 0 XMASK(1) [B0/B3/B9
7N66 ANDX 0 IPBSW(2)
7NKQ BNZ 0 SELECTFLAG [EXCEPTION FLAG(S) SET
7P5B #
7PK2 # SET UP READ CONTROL AREA IF NOT ALREADY BUSY
7Q4L #
7QJ= JSBUSY ,(GEOERR)
7R3W LDN 0 2
7RHG DSCA ,STO,0,MODE
7S36 STOZ CPRW1(2)
7SGQ MHUNTW 3,AMXOR,INBF
7T2B PHOTO 4
7TG2 LOCKC 3,STIF
7T^L TESTMOVE 4,SNOBL
7WF= MHUNTW 3,AMXOR,INBF
7WYW SNOBL LDX 0 ALOGLEN(3)
7XDG DSCA ,STO,0,COUNT
7XY6 LDN 0 A1(3)
7YCQ DSCA ,STO,0,CTSA
7YXB #
7^C2 GSPERI ,2 [ISSUE READ.
7^WL LDX 0 CPRW1(2) [CHECK REPLY
82B= BPZ 0 SPOS [TERMINATED ALREADY
82TW SLC 0 5
83*G BNG 0 SINOP [BRANCH IF INOPERABLE
83T6 SRC 0 1
84#Q BNG 0 (GEOERR) [REJECTED
84SB SPOS COOR1
85#2 SENDOFXFER
85RL #SKI K6IPB>100-100
86?= (
86QW [TRACE THE TRANSFER ONLINE,IF SUCCESSFUL AND "MOP TRACE" IS SWITCHED ON
87=G DOWN IPBINB,1
87Q6 )
889Q LDX 0 CPRW1(2)
88PB SLC 0 5
8992 BPZ 0 SINOP [BRANCH IF INOPERABLE
89NL SRC 0 2
8=8= #UNS CCERROR
8=MW BNG 0 SERR2 [B3 SET : ERROR
8?7G #UNS CCERROR
8?M6 #SKI
8#6Q BNG 0 SERR [B3 SET : ERROR
8#LB SRC 0 1
8*62 #UNS CCERROR
8*KL BNG 0 SERR3 [B2 SET : UNTERMINATED READ
8B5= #UNS CCERROR
8BJW #SKI
8C4G BNG 0 SERR [B2 SET : UNTERMINATED READ
8CJ6 LDX 1 IPBRING(2)
8D3Q SBN 1 IPBRING
8D?J ... BXE 1 2,SNORJ
8DHB LDCT 0 1
8F32 ANDX 0 IPBSW(1)
8FGL BZE 0 SNORJ [SET IF OUTPUT REJECTED OPERABLE
8G2= ERS 0 IPBSW(1) [IF SO UNSET MARKER
8GFW LDX 2 1 [AND PUT ON LIST
8G^G FPUT
8HF6 #
8HYQ SNORJ LDCT 0 #220
8JDB ANDX 0 CPRW1(2) [ISSUE READ AGAIN
8JY2 BNZ 0 K1IPBIN
8KCL LDX 0 CPRW1(2)
8KX= ANDN 0 #7777
8LBW NGX 0 0
8LWG ADX 0 ALOGLEN(3)
8MB6 SBN 0 1 [SUB 1 FOR BLOCK STATUS WORD
8MTQ STO 0 AWORK3(2) [AWORK3 - COUNT OF WORDS IN BLOCK
8MY* ... SMO FX1
8N2Y ... LDX 0 XIN
8N5H ... STO 0 AWORK2(2)
8N86 ... LDX 0 A1(3)
8N=P ... DSA 0 AWORK2(2)
8N*B LDN 3 A1+1(3)
8NT2 STO 3 AWORK4(2) [AWORK4 - POINTER FOR BLOCK
8P#L #
8PS= # READ FINISHED SUCCESSFULLY : EXAMINE EACH SEGMENT OF DATA OR
8Q?W # SUPERVISORY INFORMATION IN AMXOR/INBF SEPARATELY ; CHAIN DATA AND
8QRG # SOME SUP. SEGS. BEHIND CONTROLLING ACTIVITY , OR AMOP/IPBCCA IF
8R?6 # IDENTIFIER ONLINED TO A CONCEPTUAL ; INBF ADDRESS IN X3 (LOCKED)
8RQQ #
8S=B SNEW LDX 2 FX2
8SQ2 NGX 0 AWORK3(2) [COUNT OF WORDS IN SEGMENT
8T9L BPZ 0 K1IPBIN [NONE LEFT : ISSUE NEXT READ
8TP= LDX 3 AWORK4(2)
8W8W #UNS CCERROR
8WNG CALL 7 XSUBJOURN
8X86 LDCH 0 0(3) [EXAMINE 1ST CHAR OF SEGMENT
8XMQ BZE 0 SDATSEG [BRANCH IF DATA SEGMENT
8Y7B # [OTHERWISE SUPERVISORY SEGMENT
8YM2 SBS 0 AWORK3(2) [UPDATE COUNT
8^6L ADS 0 AWORK4(2) [AND POINTER
8^L= #UNS CCERROR
925W (
92KG LDCH 2 0(3) [LENGTH OF SUPERVISORY SEGMENT
9356 GSCAN 0(3),SUPSEG,0(2) [SUPERVISORY SEGMENT
93JQ )
944B LDN 5 0 [CONCEPTUAL / SYSTEM SWITCH
94J2 BCHX 3 £
953L LDCH 4 0(3) [LD. SUPERVISORY
95H= ANDX 3 BITS22LS
962W LDX 6 0(3)
96GG ANDN 6 #7777
9726 SBN 4 32
97FQ BNG 4 SERR4 [DCP ERROR ILLEGAL SUPERVISORY CODE
97^B BZE 4 XSUP [J. SYSTEM SUP
98F2 LDX 0 4
98YL SBN 0 15
99D= BZE 0 XSUP [J. SYSTEM SUP
99XW CALL 7 SKADB [FIND ADCB BLOCK
9=CG [IF NO ADCB BLOCK THIS WILL BE DEALT WITTH
9=X6 BRN XOK
9?BQ XSUP [SYSTEM SUPERVISORY
9?WB BNZ 6 SERR1 [IDENT MUST THEREFORE EQUAL ZERO
9#B2 LDN 1 0 [DUMMY DCB BLOCK !
9#TL BRN SSUPSG
9**= XOK [IDENTIFIER SUPERVISORIES
9*SW LDCT 0 #10
9B#G ANDX 0 A1+FOURTHWD(2) [B5 SET IF ONLINE
9BS6 BZE 0 SSUPSG
9C?Q #
9CRB LDCH 7 0(3) [LENGTH OF SUPER SEG
9D?2 LDCT 5 #400 [FOR BLOCK STATUS WORD
9DQL DOWN IPBINB,14 [PASS INPUT TO IPBCCA ACTIVITY
9F== BRN SERR
9FPW BRN SERR1
9G9G [ CURRENT BLOCK - BLOCK WAS LOCKED BEFORE GOING DOWN
9GP6 CALL 7 SKADB [POINT TO ADEVS ENTRY
9H8Q LDCT 5 #400 [CONCEPTUAL SWITCH
9HNB LDN 1 0 [SIMULATE NO DCB
9J82 SSUPSG
9JML # WHEN SCOMMAND OBEYED X1 HOLDS ADDS ADCB
9K7= # X3 HOLDS ADDS OF SUPERVISORY SEGMENT
9KLW SMO 4
9L6G BRN SCOMMAND
9LL6 #
9M5Q SCOMMAND
9MKB BRN SREADY [READY
9N52 BRN SACKN [ACKNOWLEDGE
9NJL BRN SERIN [END OF REMOTE INPUT
9P4= BRN SEROP [END OF REMOTE OUTPUT
9PHW BRN SNEW
9Q3G BRN SILLG [ILLEGAL
9QH6 BRN SNEW
9R2Q BRN SNEW
9RGB BRN SUSOP [SUSPEND IPB OUTPUT
9S22 BRN SLOST [DATA LOST
9SFL BRN SYSOL [SYSTEM OVERLOAD
9S^= BRN SYSCU [SYSTEM CONTINUE
9TDW BRN SCORP [CONFIGURATION REPORT
9TYG BRN SLIC [LINE CHANGED
9WD6 BRN SNEW
9WXQ BRN SNEW
9XCB BRN SIDOP [IDENTIFIER OPENED
9XX2 BRN SCREQ [CLOSE IDENTIFIER
9YBL BRN SWARN [WARNING
9YW= BRN SCONT [CONTINUE
9^*W BRN SINCL [INPUT CLEARED
9^TG BRN SFAIL [FAIL
=2*6 BRN SCLIM [CLOSE IMPLEMENTED
=2SQ BRN SNEW
=3#B BRN SMDCH [MODE CHANGED
=3S2 BRN SDEVA [DEVICE AVAILABLE
=4?L BRN SDEVU [DEVICE UNAVAILABLE
=4R= BRN SIDFR [IDENTIFIER FREE
=5=W BRN SOPS [OUTPUT SENT
=5QG BRN SNEW
=6=6 BRN SNEW
=6PQ BRN SNEW
=79B #
=7P2 SREADY
=88L SACKN
=8N= BRN SNEW
=97W SILLG [**** ILLEGAL ****
=98R ... LDX 0 1(3)
=99N ... SRL 0 12
=9=K ... ANDN 0 #77
=9?G ... SBN 0 #33
=9#C ... BZE 0 SREL
=9*# ... SBN 0 1
=9B9 ... BNZ 0 SNREL
=9C6 ...SREL
=9D3 ... LDN 0 #200
=9DY ... ANDX 0 A1+FOURTHWD(2)
=9FT ... BZE 0 SRELA
=9GQ ... ERS 0 A1+FOURTHWD(2)
=9HM ... FON IPBRELWS
=9JJ ...SRELA
=9KF ... BRN SNEW
=9LB ...SNREL
=9MG #UNS CCERROR
==76 #SKI
==LQ TRACE 1(3),SUPSEGW2 [SECOND WORD OF ILLEGAL SUPER SEG
=?6B SERIN
=?L2 SEROP
=#5L BZE 1 SNEW
=#8Q ... LDX 0 1(3)
=#?W ... SRL 0 12
=#C2 ... SBN 0 #127
=#G6 ... BZE 0 SNEW
=#K= SEGENTRY K37IPBIN [USED BY THE CCILL RESTORE MACRO
=*4W BRN STOSS
=*JG LDEX 0 A1+FOURTHWD(2)
=*S# ... ANDN 0 #37
=B46 SBN 0 5
=BHQ BNZ 0 STOSS [NOT A 7023 IDENTIFIER
=C3B LDX 0 1(3)
=CH2 SRL 0 12
=D2L SBN 0 #0120
=DG= #UNS CCERROR
=D^W BZE 0 SERR4 [ILLEGAL "ALREADY OPENED":DCP ERROR
=FFG #UNS CCERROR
=F^6 #SKI
=GDQ BZE 0 SERR [ILLEGAL "ALREADY OPENED" : DCP ERROR
=GYB #
=HD2 STOSS LDCT 0 1
=HXL ANDX 0 IWAIT(1) [B8 SET IF SUP SEG REQUIRED
=JC= BZE 0 SNEW
=JWW LDX 6 3
=KBG LDCH 3 0(3) [LENGTH OF SUP SEG
=KW6 SETNCORE IPBIDE-A1(3),2,AMXOR,IDATSG
=L*Q LDN 7 IPBIDE(2)
=LTB NGN 0 1
=M*2 MOVE 6 0(3) [SUPERVISORY SEGMENT
=MSL STO 0 IBSW(2) [INDICATE NO DATA
=N#= LDN 3 IPBIDE(2) [-> IPBIDE OF AMXOR/IDATSG
=NRW CALL 7 SKADB
=P?G SBN 3 IPBIDE [-> AMXOR/IDATSG
=PR6 BZE 1 SGON [DCB JUST FREED
=Q=Q LDX 2 1
=QQB CHAIN 3,2 [AFTER DCB.
=R=2 ADN 3 IPBIDE [-> IPBIDE OF AMXOR/IDATSG
=RPL CALL 7 SKADB [RESET POINTER TO DCB
=S9= LDXC 0 IWAIT(1)
=SNW BCC SNEW [ACTIVITY ALREADY AWAKE
=T8G STO 0 IWAIT(1)
=TN6 CALL 7 SKACT
=W7Q FPUT
=WMB BRN SNEW
=X72 SGON FREECORE 3 [IDATSG REDUNDANT : NO DCB NOW.
=XLL BRN SNEW
=Y6= #
=YKW SUSOP LDX 4 1(3) [PRIORITY IN SECOND WORD
=^5G SRL 4 3
=^K6 ADN 4 1 [<8 :1 ; 715 : 3
?24Q SMO FX2
?2JB LDX 2 IPBRING
?342 SBN 2 IPBRING [POINTER TO AMOP/IPBOUT
?3HL BRN SOC
?43= #
?4GW SLOST BRN SERR4 [*** DATA LOST *** TREAT AS INVALID
?52G #
?5G6 SYSOL SMO FX2 [SYSTEM OVERLOAD
?5^Q LDX 2 IPBRING
?6FB LDN 4 1 [FOR IPBSW & IPSTATUS
?6^2 SBN 2 IPBRING
?7DL LDCT 0 #200
?7Y= ORS 0 IPBSW(2)
?8CW BRN SWAK
?8XG #
?9C6 SYSCU SMO FX2 [SYSTEM CONTINUE
?9WQ LDX 2 IPBRING
?=BB LDCT 0 #200
?=W2 SBN 2 IPBRING
??*L LDN 4 0 [FOR IPBSW & IPSTATUS
??T= ANDX 0 IPBSW(2)
?##W ERS 0 IPBSW(2)
?#SG SOC ORX 2 GSIGN [RECORD THE OVERLOAD CODE IN CHAR 2
?*#6 DCH 4 IPBSW(2) [OF IPBOUT'S IPBSW (CLEAR IF SYS CU)
?*RQ ANDX 2 BITS22LS
?B?B SWAK LDCT 0 #100
?BR2 ANDX 0 IPBSW(2) [B2 SET IF IPBOUT ASLEEP
?C=L BZE 0 STEL
?CQ= ERS 0 IPBSW(2)
?D9W FPUT
?DPG #
?F96 STEL HUNTW 2,AMXOR,CROUTE [ENTRY PER CONCEPTUAL USING THIS IPB
?FNQ BNG 2 SNEW
?G8B LDX 6 ALOGLEN(2)
?GN2 SLO LDX 1 A1+BPTR(2)
?H7L BZE 1 SNOCS
?HM= DEX 4 IPSTATUS(1) [RECORD OVERLOAD STATUS IN CSTATE BLK
?J6W SNOCS ADN 2 CROUTELEN
?JLG SBN 6 CROUTELEN
?K66 BNZ 6 SLO [NOT YET AT END OF CROUTE
?KKQ BRN SNEW
?L5B #
?LK2 SCORP BRN SNEW [*** CONFIGURATION REPORT ***
?M4L #
?MJ= SLIC DOWN IPBINB,7 [*** LINE CHANGED ***
?N3W BRN SNEW
?NHG #
?P36 SIDOP LDX 0 A1+BPTR(2) [*** IDENTIFIER OPENED ***
?PGQ BZE 0 SIOPZ [J IF NULL RING
?Q2B LDX 0 BIT10 [ELSE DONT UNSET B10
?QG2 SIOPZ SMO FX1
?Q^L ORX 0 SMOP
?RF= ANDS 0 A1+FOURTHWD(2) [UNSET BITS 9 & 10
?RYW LDX 0 2(3)
?SDG ANDX 0 GSIGN
?SY6 CALL 6 SAVA [COPY AVAILABILITY TO ADEVS & ADCB
?TCQ ... BZE 1 SID16
?TXB SMO FX1 [ZEROISE CHAR 2 : PRIORITY AND
?WC2 LDX 0 SMSKOP
?WWL ANDS 0 ISTATUS(1) [UNSET CLOSED & STOPPED BITS
?XB= LDX 0 1(3)
?XTW STO 0 IMDNPU(1) [MODE,NPU SIZE
?Y*G LDX 0 2(3)
?YT6 SRC 0 6
?^#Q ANDN 0 #7700
?^SB NGN 5 #7701 [LOADS #77770077
#2#2 ANDS 5 ISTATUS(1)
#2RL ORS 0 ISTATUS(1) [RECORD PRIORITY
#2T8 ...SID16
#2WQ ... SMO FX2
#2Y# ... LDX 0 IPBSW
#2^W ... ANDX 0 BIT9
#33D ... BNZ 0 SV16
#352 ...SNV16
#36J ... BZE 1 SNEW
#386 ... BRN STOSS
#39N ...SV16
#3?= LDEX 0 A1+FOURTHWD(2)
#3QW ANDN 0 #17
#4=G SBN 0 5
#4Q6 ... BZE 0 SNV16
#59Q LDN 0 #200
#5PB ANDX 0 A1+FOURTHWD(2)
#692 ... BZE 0 SNV16
#6NL ERS 0 A1+FOURTHWD(2)
#6SH ... LDX 0 BIT11
#6YD ... ORS 0 A1+FOURTHWD(2)
#74* ... BZE 1 SNEW
#78= LDCT 0 1
#7MW ANDX 0 IWAIT(1)
#87G BNZ 0 STOSS
#8M6 BRN SNOTIFY
#96Q #
#9LB SCREQ LDX 0 BIT11 [*** CLOSE IDENTIFIER ***
#=62 ORS 0 A1+FOURTHWD(2) [INHIBIT GEORGE USE (EG GETPER)
#=89 ... LDN 0 #200
#==D ... ANDX 0 A1+FOURTHWD(2)
#=#M ... BZE 0 SCNO16
#=BW ... ERS 0 A1+FOURTHWD(2)
#=CK ... LDX 6 1
#=D# ... LDX 7 2
#=F5 ... FON IPBRELWS
#=FS ... LDX 1 6
#=GH ... LDX 2 7
#=H# ...SCNO16
#=KL BNG 5 SNEW [ONLINE TO CONCEPTUAL
#?5= BZE 1 SCL [CRASH CLOSE IF IDLE
#?JW LDN 0 #2040 [SET B13 FOR STASH , AND
##4G ORS 0 IWAIT(1) [MARK 'CLOSE IDENTIFIER REQUESTED'
##J6 CALL 7 TESTIFMOP
#*3Q BRN SNMOP [NOT A MOP TERMINAL
#*HB LDCT 6 #40
#B32 CALL 7 SKACT
#BGL ANDX 6 IWAIT(1)
#C2= LDCH 0 JSOURCE1(2)
#CFW ERS 6 IWAIT(1) [UNSET TIMED-OUT MARKER , IF SET
#C^G SBN 0 7
#D2* ... BNZ 0 SCBRK
#D38 ... LDCT 0 #100
#D43 ... ANDX 0 ISTATUS(1)
#D4W ... BRN SCLE
#D5P ...SCBRK
#D6N ... LDCT 0 #400
#D9? ... ORS 0 ISTATUS(1)
#D?W ... BRN SNBRKIN16
#DBF ...SCL
#DF4 ... LDX 0 A1+FOURTHWD(2)
#DHM ... ANDN 0 3
#DL= ... SBN 0 3
#DNT ... BNZ 0 SCLD
#DRD ... LDN 0 #4000
#DW3 ... ORS 0 A1+FOURTHWD(2)
#DYL ... ERS 0 A1+FOURTHWD(2)
#F39 ...SCLD
#F5S ... LDX 0 BIT9
#F8C ... ANDX 0 A1+FOURTHWD(2)
#F9N ...SCLE
#F?2 ... BNZ 0 SNEW
#F*K ... LDX 5 0(3)
#FDB LDN 6 #127 [CRASH CLOSE
#FY2 ANDN 5 #7777 [IDENTIFIER NUMBER
#GCL CALL 7 SCCO
#GX= BRN SNEW
#HBW ...SNMOP
#JB6 SINM LDCT 0 #400
#JTQ ORS 0 ISTATUS(1) [MARK INOPERABLE
#K*B CALL 6 STASH [WAKE ACTIVITY IF NECESSARY
#KT2 BRN SNEW
#L#L #
#LS= SWARN BZE 1 SNEW [*** WARNING ***
#M?W LDCT 0 #200
#MRG ORS 0 ISTATUS(1)
#N?6 BRN SNEW
#NQQ SCONT BZE 1 SNEW [*** CONTINUE ***
#P=B SCONTA
#PQ2 LDCT 0 #200
#Q9L ANDX 0 ISTATUS(1)
#QP= BZE 0 SNEWCT [J. CONT. WITH NO WARNING
#R8W SMO FX1
#RNG LDX 0 SMSOR
#S86 ANDS 0 ISTATUS(1)
#SMQ CALL 6 STASH
#T7B SNEWCT
#TM2 LDN 0 19
#W6L BXE 0 4,SNEW [J. IF CONTINUE
#WL= BRN SCLAA1 [J. COMMAND WAS CLOSE IMPL.
#X5W #
#XKG SCLIM LDX 0 BIT9 [*** CLOSE IMPLEMENTED ***
#Y56 ORS 0 A1+FOURTHWD(2) [MARK CLOSED IN ADEVS
#YJQ LDX 0 A1+BPTR(2)
#^4B BNZ 0 SCLAA [J IF RING ELEMENT NOT NULL
#^J2 LDX 0 BIT10 [ELSE UNSET BIT 10
*23L ORS 0 A1+FOURTHWD(2)
*2H= ERS 0 A1+FOURTHWD(2)
*32W SCLAA
*3GG BZE 1 SNEW
*426 LDCT 0 #140 [SET B2,B3
*4FQ ORS 0 ISTATUS(1)
*4^B BRN SCONTA [J. TO SEE IF WAITING FOR CONT
*5F2 SCLAA1 [FINISH CLOSE IMPL.
*5YL LONGON1 #36,IDENTNO(1) [RESTART ACT(ESP. LF) IF ON A P.E.
*6D= CALL 7 SKADB [RESET X1
*6XW BRN STOSS
*7CG SOPS [OUTPUT SENT
*7X6 SINCL [*** INPUT CLEARED ***
*8BQ SMDCH [MODE CHANGED
*8WB BZE 1 SNEW
*9B2 BRN STOSS
*9TL #
*=*= SDEVA LDN 0 0 [*** DEVICE AVAILABLE ***
*=SW CALL 6 SAVA [MARK AVAILABLE IN ADEVS & ADCB
*?#G BNZ 1 SANI [DEVICE NOT IDLE
*?S6 BNG 5 SNEW [ONLINE TO CONCEPTUAL
*?Y3 ... LDX 0 BIT11
*#3Y ... ANDX 0 A1+FOURTHWD(2)
*#7T ... BNZ 0 SNEW
*#?Q LDEX 0 A1+FOURTHWD(2)
*#RB ANDN 0 3 [LP : TYPE 3 ; TP : TYPE 7
**?2 ERN 0 3
**QL BNZ 0 SVDC [J IF NOT LP OR TP
*B== SNBOF LDN 5 ACTLF+GREMOTE [LISTFILE ACTIVITY
*BPW LDN 6 ACTLFLEN+GREMOTELEN [LENGTH OF ACTIVITY
*C9G CALL 7 SETDB [SETS UP ACTY & DCB
*CP6 BRN SNEW
*D8Q SVDC LDEX 0 A1+FOURTHWD(2)
*DDJ ... ANDN 0 #37
*DNB SBN 0 10
*F82 BNZ 0 SNEW [J IF NOT VD
*FML LDN 5 CPAT [START UP MOP DISPLAY
*G7= LDN 6 CPATLEN
*GLW CALL 7 SETDB
*H6G BRN SNEW
*HL6 SANI LDEX 0 A1+FOURTHWD(2) [IF A RJE CONSOLE,ENSURE
*HTY ... ANDN 0 #37
*J5Q SBN 0 5 [CONSA/I7023 ACTIVITY IS NOTIFIED
*JKB [(ESPECIALLY AFTER A LINE/TERM FAIL)
*K52 BNZ 0 SNEW [NOT RJE CONSOLE
*KJL CALL 6 STAKE
*L4= BRN SNEW
*LHW #
*M3G SFAIL BNZ 1 SADF [*** FAIL ***
*MH6 BNG 5 SDEVU [ONLINE TO CONCEPTUAL
*N2Q CALL 7 TBULKINPUT
*NGB BRN XBIP [NOT A BULK INPUT DEVICE
*P22 LDN 5 CPAT [SET UP ACTIVITY TO DEAL WITH THE
*PFL LDN 6 CPATLEN [FAIL (NOTE DCP HAS STOPPED INPUT)
*P^= CALL 7 SETDB
*QDW CALL 7 SKADB [RESET X1 & X2
*QYG BNZ 1 SADF [UPDATE DCB IF ACTIVITY SET UP
*RD6 XBIP
*RXQ LDCT 0 #400 [MARK UNAVAILABLE IN ADEVS
*SCB LDEX 7 A1+FOURTHWD(2)
*SX2 ANDN 7 3
*TBL ERN 7 3
*TW= BNZ 7 SSS [NOT LP OR TP
*W*W ORN 0 #4000 [SET INITIAL BULK OUTPUT FAIL BIT
*WTG SSS
*X*6 ORS 0 A1+FOURTHWD(2)
*XSQ [ IF MOP OFF(A SYSTEM SUPERVISOR) IS CLOSING THE CC SYSTEM,
*Y#B [ CRASH CLOSE FAILED IDENTIFIERS TO AID COMPLETION
*YS2 ADX 2 A1+BSTART(2)
*^?L LDX 1 A1+FPTR+A1+BPTR(2) [(A1+BPTR OF ADEVS)
*^R= BZE 1 SFID [NO SYSTEM SUPERVISOR
B2=W LDX 0 IWAIT-A1+FPTR(1)
B2QG ANDN 0 #400
B3=6 BZE 0 SFID [NOT MOP OFF ACTIVITY CLOSING SYSTEM
B3PQ BRN SCL [SEND CRASH CLOSE
B49B SFID CALL 7 SKADB [RE-FIND FAILED IDEN'S ADEVS ENTRY
B4P2 BRN SDEVU
B58L SADF LDCT 0 #20 [SET B4 TO SHOW FAIL
B5N= LDXC 7 1(3)
B67W BCC SIN
B6MG LDCT 0 #30 [SET B5 ALSO IF LINE FAIL
B776 SIN ORS 0 ISTATUS(1)
B7LQ SMO 1
B86B DCH 7 ISTATUS [PUT RESTART SECTION NO INTO CHAR 3
B8L2 #
B95L SDEVU LDCT 0 #400 [*** DEVICE UNAVAILABLE ***
B9K= CALL 6 SAVA [MARK UNAVAILABLE IN ADEVS & ADCB
B=4W BNZ 1 SNI [J IF DEVICE NOT IDLE
B=JG BNG 5 SNEW [ONLINE TO CONCEPTUAL
B?46 [ WHEN "DEVICE UNAVAILABLE" IS RECEIVED FOR AN
B?HQ [ IDLE MOP IDENTIFIER,THE IDENTIFIER MUST BE
B#3B [ CRASH CLOSED TO "DISCONNECT" THE LINE (WHEN DIALED)
B#H2 LDEX 0 A1+FOURTHWD(2)
B#QS ... ANDN 0 #37
B*2L BNZ 0 SNEW [J IF NOT A MOP CONSOLE
B*G= LDN 5 CPAT
B*^W LDN 6 CPATLEN
BBFG CALL 7 SETDB[GET(EVENTUALLY)IPBMOP TO CRASH CLOSE THE IDENTIFIER
BB^6 BRN SNEW
BCDQ [
BCYB SNI
BDD2 [ MAJOR CHANGE-FAIL & UNAVAILABLE SUPERVISORY SEGMENTS ARE
BDXL [ CHAINED AFTER CONSA/I7023 ACTIVITIES
BFC= LDCT 0 #20
BFWW ORN 0 #777
BGBG ANDX 0 A1+FOURTHWD(2)
BGW6 SBN 0 5
BH*Q BZE 0 STOSS [7023 IDENTIFIER WITH ACTIVITY SET UP
BHTB [
BJ*2 [ IF A MOP TERMINAL IDENTIFIER, BREAK-IN ON MOP JOB,IN CASE
BJSL [ IT IS WAITING ABOVE ACCESS LEVEL(IPBMOP), EXCEPT IF
BK#= [ "INOPTIME" IS SET NON-ZERO AND THE IDENTIFIER IS ON A
BKRW [ NON-AUTO-ANSWER LINE.
BL?G CALL 7 TESTIFMOP
BLR6 BRN SNOTIFY [NOT A MOP TERMINAL
BM=Q #OPT IPBINOPTIME=0
BMQB SEGENTRY K51IPBIN [USED BY THE INOPTIME MACRO
BN=2 LDN 0 IPBINOPTIME<4095
BNPL BZE 0 SNBRKIN16 [INOPTIME = 0 : TAKE INOPERABILITY
BP9= [ACTION IMMEDIATELY
BPNW LDN 0 #1000
BQ8G ANDX 0 A1+FOURTHWD(2) [B14 = AUTO-ANSWER LINE
BQN6 BZE 0 SNOTIFY [NOT ON AN AUTO-ANSWER LINE : SKIP BI
BR7Q SNBRKIN16
BRMB LDCT 0 4 [SET "TAKE DEVICE INOPERABILITY
BS72 ORS 0 ISTATUS(1) [ACTION IMMEDIATELY" FLAG(B6)
BSLL [ENSURES 'DEVICE AVAILABLE' DOESN'T
BT6= [CANCEL INOPERABLE ACTION
BTKW CALL 7 SKACT [SET X2 -> CPAT
BW5G ... NBREAKIN 2,8
BWK6 CALL 7 SKADB [RE-FIND DCB
BX4Q BZE 1 SNEW [CPAT HAS JUST SUICIDED
BXJB [
BY42 SNOTIFY
BYHL CALL 6 STASH
B^3= BRN SNEW
B^GW #
B^N4 ...SIDFR
B^T= ... LDX 0 A1+FOURTHWD(2)
C22D ... ANDN 0 #400
C27L ... BNZ 0 SNEW
C2#S ... LDX 0 BIT11
C2G6 ADX 0 GSIGN [MASK OUT TEST AND UNAV BITS
C2^Q ORS 0 A1+FOURTHWD(2)
C3FB ERS 0 A1+FOURTHWD(2) [RELEASE FOR GEORGE USE
C3HK ... LDN 0 #200
C3KS ... ANDX 0 A1+FOURTHWD(2)
C3N3 ... BZE 0 SFNO16
C3Q= ... ERS 0 A1+FOURTHWD(2)
C3Q^ ... LDX 6 1
C3RN ... LDX 7 2
C3SF ... FON IPBRELWS
C3T8 ... LDX 1 6
C3TX ... LDX 2 7
C3WN ...SFNO16
C3^2 BNZ 1 STRI [STILL RINGED : 7023 CONSOLE
C4DL BNG 5 SNEW [ONLINE TO CONCEPTUAL
C4Y= DOWN IPBINB,5
C5CW BRN SNEW
C5SW ...STRI
C5Y6 ... LDN 0 #40
C63B ... ORS 0 IWAIT(1)
C66L ... ERS 0 IWAIT(1)
C69W ... LDX 0 BIT9
C6LW ... ANDX 0 A1+FOURTHWD(2)
C73W ... BZE 0 SNEW
C7W2 LDX 5 IDENTNO(1) [IDENTIFIER NUMBER
C8*L LDN 6 #120 [OPEN
C9#W CALL 7 SCCO
C9*J ... CALL 7 SKADB
C9B? ... LDX 0 A1+FOURTHWD(2)
C9CN ... ANDN 0 #17
C9F5 ... SBN 0 3
C9GG ... BZE 0 SNEW
C9HX ... SBN 0 1
C9K# ... BZE 0 SONES
C9LP ... SBN 0 2
C9N6 ... BZE 0 SONES
C9PH ... SBN 0 1
C9QY ... BZE 0 SNEW
C9SG LDN 6 #121 [START INPUT
C9XL ... BRN SCALL
C=2Q ...SONES
C=5W ... LDN 6 #122
C=92 ...SCALL
C=#6 CALL 7 SCCO
C=RQ BRN SNEW
C*9W #
C*PG # DATA SEGMENT : SET UP ACTIVITY IF NONE ALREADY
CB96 # IF ORDINARY DATA FROM MOP OR BULK , TRANSMISSION ERROR OR MOP
CBNQ # TIME-OUT SEGMENT : PASS COPY TO CONTROLLING ACTIVITY
CC8B # IF MOP BREAK-IN OR END OF REVERSION SEGMENT : ADJUST BREAK-IN
CCN2 # LEVEL IN ADCB AND SET MARKERS IF BREAK-IN ALLOWED
CD7L #
CDM= SDATSEG
CF6W LDX 0 1(3) [NO. CHARS OF DATA IN DATA
CFLG ANDN 0 #7777 [SEGMENT HEADER
CG66 ADN 0 11 [CALCULATE NO WORDS IN SEMENT
CGKQ SRL 0 2 [2+NO WDS OF DATA
CH5B SBS 0 AWORK3(2) [UPDATE COUNT
CHK2 ADS 0 AWORK4(2) [AND POINTER
CJ4L LDX 0 0(3)
CJJ= ANDN 0 #7777
CK3W #UNS CCERROR
CKHG BZE 0 SERR1 [DCP ERROR : IDENTIFIER ZERO
CL36 #UNS CCERROR
CLGQ #SKI
CM2B BZE 0 SERR [DCP ERROR : IDENTIFIER ZERO
CMG2 CALL 7 SKADB
CM^L BZE 1 SIDLE [ADEVS RING NULL
CNF= LDCT 0 #10
CNYW ANDX 0 A1+FOURTHWD(2) [B5 SET IF ONLINE
CPDG BZE 0 SNOOL
CPY6 LDX 7 1(3)
CQCQ ANDN 7 #7777
CQXB LDN 5 0 [FOR BLOCK STATUS WORD
CRC2 ADN 7 11 [HEADING + ROUNDING
CRWL SRL 7 2 [NO. OF WORDS IN SEGMENT
CSB= DOWN IPBINB,14 [PASS INPUT TO IPBCCA ACTIVITY
CSTW BRN SERR
CT*G BRN SERR1
CTT6 [ CURRENT BLOCK - BLOCK WAS LOCKED BEFORE GOING DOWN
CW#Q BRN SNEW
CWSB #
CX#2 SIDLE
CXRL LDX 4 0 [REL PTR TO ADEVS ENTRY
CY?= LDEX 0 A1+FOURTHWD(2)
CYQW ERN 0 #32
C^=G BNZ 0 NOTPSEUD [J IF NOT PSEUDO VDU
C^Q6 LDX 0 A1+FOURTHWD(2)
D29Q SMO FX1
D2PB ANDX 0 SPSDMSK [FOURTHWD MASK
D392 BNZ 0 SNEW [IGNORE DATA IF BIT MATCH
D3NL DOWN IPBINC,11 [TO INITIATE TELELOAD
D48= BRN SNEW
D4MW NOTPSEUD
D57G LDCT 0 2
D5M6 ANDX 0 1(3)
D66Q BNZ 0 SNEW [IGNORE IF 'END OF REVERSION'
D6LB LDN 4 0
D762 LDN 5 CPAT
D7KL LDN 6 CPATLEN
D85= CALL 7 SETDB [GET NEW ACTY IF NOT ATTACHING ,
D8JW CALL 7 SKADB [ONLINING , MOPPING OFF OR WRONGED
D94G SNOOL LDX 5 1(3) [USE X5 IN CASE J TO SOP
D9J6 SLL 5 4
D=3Q BPZ 5 SNOBI [NOT A BREAK-IN SEGMENT
D=HB SLL 5 5
D?32 BNZ 5 SNOBI [NON-ZERO CHARACTER COUNT : NOT BI
D?GL #
D#2= # BREAK-IN SEGMENT ; ACTIVITY NEWLY SET UP , TIMED OUT , ALREADY
D#FW # BROKEN IN ON OR ACTIVE ; IF ACTIVE TRY TO BREAK IN ON JOB
D#^G # FOR MOP DISPLAYS: NO "REVERSION" OCCURS; REPLY IS ALWAYS
D*F6 # BINAK TO PREVENT ANY MESSAGES BEING DISCARDED GIVING RISE TO
D*YQ # MIS-POSITIONING OF MESSAGES
DBDB #
DBY2 [
DCCL [ THIS IS NOW DEALT WITH IN SEGMENT IPBINC
DCX= [
DDBW DOWN IPBINC,1
DDWG BRN SNEW
DFB6 BRN SK1IPBIN [ERROR
DFTQ CALL 7 SKADB
DG*B BRN SIDLE [CPAT REMOVED
DGT2 #
DH#L # ORDINARY DATA AND/OR END OF REVERSION
DHS= #
DJ?W SNOBI LDCT 0 2
DJRG ANDX 0 1(3) [B7 SET IF END OF REVERSION
DK?6 BZE 0 SNER
DKD# ... LDEX 0 IBIL(1)
DKKG ... BZE 0 SZERO
DKQQ LDN 0 1
DL=B SBS 0 IBIL(1) [DECREASE BR IN LEVEL
DLG8 ...SZERO
DLQ2 CALL 7 SKACT [ADDS OF ACT TO X2
DM9L #
DMP= SNID LDX 2 FPTR(2)
DN8W BXE 2 1,SNODS [BR IF ADCB REACHED
DNNG SMO FX1
DP86 LDX 0 SSTYP
DPMQ TXU 0 ATYPE(2)
DQ7B BCS SNID [NOT YET REACHED IDATSG
DQM2 CHAIN 1,BPTR(2) [CHAIN DCB BEFORE 1ST IDATSG
DR6L SNODS LDX 6 1(3)
DRL= ANDN 6 #7777 [ISOLATE NO CHARS IN MESSAGE
DS5W CALL 7 SKADB [ADDS OF ADCB TO X1
DSKG BZE 6 SNIP [NO DATA & END OF REVERSION
DT56 #
DTJQ SNER LDX 6 1(3)
DW4B ANDN 6 #7777 [NO CHARS IN MESSAGE
DWJ2 ADN 6 11 [ALLOW 2 WORDS FOR IDE,HDDR
DX3L SRL 6 2
DXH= LDX 7 6 [NO WDS TO MOVE
DY2W SBN 7 2
DYGG LDCT 0 #200
D^26 LDN 5 CPDATA [START AT CPDATA UNLESS REVERTED
D^FQ ANDX 0 IWAIT(1) [UNLESS IT IS REVERTED
D^^B BZE 0 SORD
F2F2 ADN 6 IDATA-A1-2 [BLOCK LONGER IF REVERTED SEG
F2YL LDN 5 IDATA
F3D= LDCT 0 #200
F3XW ORS 0 0(3) [SET B1 TO INDICATE REVERTED SEG
F4CG ...SORD SETUPCORE 6,2,AMXOR,IDATSG
F4X6 LDN 4 2(3) [POINT TO START OF DATA
F5BQ ADX 5 2
F5WB BZE 7 SUGAR
F6B2 SMO 7
F6TL MOVE 4 0 [MOVE DATA SEG TO IDATSG BLOCK
F7*= SBN 7 513
F7SW BNG 7 SUGAR [DATA SEG < 513 CHARS
F8#G MOVE 4 0 [COMPLETE THE MOVE
F8S6 SUGAR LDX 0 1(3)
F9?Q STO 0 A1(2) [SET HDDR
F9RB LDX 0 0(3) [& IDE
F=?2 STO 0 A1+1(2)
F=QL LDX 6 2
F?== CALL 7 SKADB
F?PW BZE 1 SJUG [CPAT HAS JUST SUICIDED : TRY AGAIN
F#9G LDX 2 BPTR(1) [CHAIN IDATSG BEFORE ADCB
F#P6 CHAIN 6,2
F*8Q CALL 7 SKADB [RELOCATE ADCB
F*NB SNIP CALL 6 STAKE [WAKE CPA IF NECESSARY
FB82 BRN SNEW
FBML #
FC7= SJUGA FREECORE 5 ["BREAK IN" MESSAGE IOUT BLOCK
FCLW MHUNTW 2,AMXOR,IOUT [ALSO FREE BIACK+STOPSIEVING IOUT BLK
FD6G LDX 6 2
FDL6 SJUG FREECORE 6 [DATA IDATSG OR BIACK IOUT
FF5Q CALL 7 SKADB [RESET X1 & X2
FFKB BRN SIDLE [TRY THIS DATA SEGMENT AGAIN
FG52 #
FGJL #UNS CCERROR
FH4= (
FHHW SINOP SMO IPBRING(2) [IPB FOUND TO BE INOP
FJ3G LDX 6 IPBSW-IPBRING [HAVE A LOOK AT IPBSW IN OUTPUT ACT
FJH6 SLL 6 4 [IS UNIT BEING MOPPED OFF,PM
FJPB ... BPZ 6 XINOP
FJXL ... COOR3 #41
FK5W ... BRN SK1IPBIN
FK#6 ...XINOP
FKGB NGS 2 ACOMMUNE2(2) [FOR CHAINADD
FL22 LDX 1 ZJIPBINOP(1)
FLFL BRN SD
FL^= SERR0 LDN 0 0 [INDICATE DCP ERROR HAS BEEN REPORTED
FMDW SERR LDX 2 FX2
FMYG STO 0 ACOMMUNE2(2) [FOR CCERROR MACRO %A AND CHAINADD
FND6 SD STO 1 ACOMMUNE3(2) [FOR CCERROR MACRO %B OR INFORMX
FNXQ DOWN IPBINB,6
FPCB BRN K1IPBIN
FPX2 SERR1 LDN 0 CCINVIDEN [REPORT INVALID IDEN + (SEG WD0)
FQBL SERRZ LDX 1 0(3)
FQW= BRN SERR
FR*W SERR2 LDN 0 CCTRANSFER [REPORT TRANSFER ERROR + (REPLY WD)
FRTG SERRR LDX 1 CPRW1(2)
FS*6 BRN SERR
FSSQ SERR3 LDN 0 CCUNTERMRD [REPORT UNTERMINATED READ +(REPLY WD)
FT#B BRN SERRR
FTS2 SERR4 LDN 0 CCINVSUP [REPORT INVALID SUPER + (SEG WD0)
FW?L BRN SERRZ
FWR= )
FX=W #UNS CCERROR
FXQG #SKI
FY=6 (
FYPQ SINOP NGS 2 ACOMMUNE2(2) [FOR CHAINADD
F^9B LDX 0 ZJIPBINOP(1)
F^P2 BRN SD
G28L SERR LDX 2 FX2
G2N= LDX 1 FX1
G37W STOZ ACOMMUNE2(2) [FOR CHAINADD
G3MG LDX 0 ZJIPBERR(1)
G476 SD STO 0 ACOMMUNE3(2) [FOR INFORMX
G4LQ DOWN IPBINB,6
G56B BRN K1IPBIN
G5L2 )
G65L #
G6K= MENDAREA 10,K100IPBIN
G74W #END
^^^^ ...614521100026