{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: IPBINB867)}}
====== IPBINB867 ======
(George Source)
**Macros used:** [[george:macro:BXE|BXE]], [[george:macro:BXU|BXU]], [[george:macro:CCERROR|CCERROR]], [[george:macro:CHAIN|CHAIN]], [[george:macro:CLWTBSW|CLWTBSW]], [[george:macro:CLWTBWR|CLWTBWR]], [[george:macro:COOR1|COOR1]], [[george:macro:DISENGPER|DISENGPER]], [[george:macro:FON|FON]], [[george:macro:FPUT|FPUT]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FSHCODE|FSHCODE]], [[george:macro:FSHSKIP|FSHSKIP]], [[george:macro:GEOERR|GEOERR]], [[george:macro:GEOPACK|GEOPACK]], [[george:macro:GETACTX|GETACTX]], [[george:macro:HUNT2J|HUNT2J]], [[george:macro:HUNTACT|HUNTACT]], [[george:macro:HUNTW|HUNTW]], [[george:macro:IDFLINE|IDFLINE]], [[george:macro:INFORMX|INFORMX]], [[george:macro:IPBCOUNT|IPBCOUNT]], [[george:macro:JBUSY|JBUSY]], [[george:macro:JENVNOT|JENVNOT]], [[george:macro:JV7900|JV7900]], [[george:macro:JWTBSW|JWTBSW]], [[george:macro:JWTBWR|JWTBWR]], [[george:macro:LADDP|LADDP]], [[george:macro:LGEOG|LGEOG]], [[george:macro:LINKSET|LINKSET]], [[george:macro:LONGSET|LONGSET]], [[george:macro:LONGSTOX|LONGSTOX]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:MFREEW|MFREEW]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:MOVLONG|MOVLONG]], [[george:macro:NIP|NIP]], [[george:macro:OUTNULL|OUTNULL]], [[george:macro:OUTPACK|OUTPACK]], [[george:macro:OUTPACKC|OUTPACKC]], [[george:macro:PAIR|PAIR]], [[george:macro:REOPEN|REOPEN]], [[george:macro:RING2CHK|RING2CHK]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SUICIDE|SUICIDE]], [[george:macro:SWOUT|SWOUT]], [[george:macro:TRACEX|TRACEX]], [[george:macro:UNQUEUE|UNQUEUE]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]], [[george:macro:WRONG|WRONG]], [[george:macro:YWRONG|YWRONG]]
22FL #SEG IPBINB8 [R.WEYAND
22LS ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD. 1982
22S3 #OPT K0IPBINB=0
236D #LIS K0IPBINB>K0IPB>K0ALLGEO
23DW 8HIPBINB
23YG #
24D6 #
24XQ # THIS SEGMENT DEALS WITH EXCEPTIONAL IPB INPUT
25CB SEGENTRY K1IPBINB,SK1IPBINB
25X2 # K1 TRACES CC READ TRANSFERS
26BL SEGENTRY K2IPBINB,SK2IPBINB
26W= # K2 GETS A NEW ACTIVITY FOR INPUT ON IDLE OR NEWLY ENGAGED OUTPUT DEV.
27*W SEGENTRY K3IPBINB,SK3IPBINB
27TG SEGENTRY K4IPBINB,SK4IPBINB
28*6 # K3 (REDON) AND K4 (RIGHT) USE THE K2 ROUTINES FOR THEIR OWN PURPOSES
28SQ SEGENTRY K5IPBINB,SK5IPBINB
29#B # K5 SETS UP AMSCAN/IPBTYPE FOR "IDENTIFIER FREE" INPUT
29S2 SEGENTRY K6IPBINB,SK6IPBINB
2=?L # K6 DEALS WITH IPB INOPERABILITY AND RE-OPERABILITY
2=R= SEGENTRY K7IPBINB,SK7IPBINB
2?=W SEGENTRY K8IPBINB,SK8IPBINB
2?QG # K7 SETS UP CPA FOR "LINE CHANGED" INPUT WITH LINK TO K8
2#=6 SEGENTRY K10IPBINB,SK10IPBINB
2#PQ # K10 SETS UP ACTIVITY IF STILL-OPEN IDENTIFIER IS DETACHED OR FREED
2*9B #
2*D3 SEGENTRY K20IPBINB,SK20IPBINB
2*G= # K20IPBINB SETS UP AMSCAN:IPBTYPE WHEN ID IS RIGHTED
2*JF #
2*NL SEGENTRY K14IPBINB,SK14IPBINB
2*NN [ K14 ENTERED TO PASS DATA TO IPBCCA
2*NQ SEGENTRY K30IPBINB,SK30IPBINB
2*NS [ K30 SIMILIAR TO K10
2*X5 ... SEGENTRY K31IPBINB,SK31IPBINB
2B5B ...
2B?M ...SP1 PAIR IPBSCANB,14 [PREVIOUSLY WAS K2IPBSCAN
2BFY ...SP5 PAIR IPBSCANB,11 [PREVIOUSLY WAS K5IPBSCAN
2BN= SP8 PAIR IPBINB,8
2BNH #
2BNP [
2BNR ZJIPBINOP +JIPBINOP
2BNS ...ZJIPBINOPE +JIPBINOPE
2BNT ...REOPENBLK 0,#40000000,#01130000,#01120000
2BNX ...#UNS CCERROR
2BP2 ...XIN 4HIN
2BP5 #
2BPB # SUBROUTINE TO SEND THE SUPERVISORY SEGMENTS RESET & REOPEN IN A
2BPM # BATCH TO THE DCP.
2BPY # GOES UP IF SEGMENTS SENT SUCCESSFULLY, ELSE EXITS.
2BQ9 #
2BQG REOPEN
2BQR LDCT 0 #440
2BR4 ANDX 0 IPBSW(2)
2BR* BNZ 0 (7) [READ INHIBITED : MOPPING OFF : EXIT
2BRL [OR MARKED INOP : IPB ERROR : EXIT
2BRX SBX 7 FX1
2BS8 LONGSET CCREOPEN,SET
2BSF ... SETNCORE 4,1,AMXOR,IOUT
2BSQ SMO FX1
2BT3 LDN 3 REOPENBLK
2BT# LDN 4 IMOPTY(1)
2BTK MOVE 3 4
2BTW LDX 3 IPBRING(2) [PUT SUPER BLOCK ON FRONT OF IPBOUT Q
2BW7 SBN 3 IPBRING
2BWD CHAIN 1,3
2BWP LDCT 0 #101 [WAKE IPBOUT OF ASLEEP
2BX2 ANDX 0 IPBSW(3)
2BX? BZE 0 REOPENWAIT
2BXJ ERS 0 IPBSW(3)
2BXT LDX 2 3
2BY6 FPUT
2BYC REOPENWAIT [INFORM OPERATOR OF THE SITUATION AND
2BYN [WAIT FOR IPBOUT'S REPLY
2BY^ LDX 4 ACOMMUNE2(2) [PRESERVE CHAINADD'S VALUE ON COOR1
2B^= LDX 3 ACOMMUNE3(2) [PRESERVE MESSAGE IDENTIFIER
2B^H LGEOG ,6 [SET %A OF MESSAGE WITH GEOGRAPHIC NO
2B^S OUTPACKC 6,1,GEOPER
2C25 OUTNULL [SET %B NULL TO INCLUDE ALL OF MESSAG
2C2B LONGSTOX (GEOERR),,3 ["UNIT %A INOPERABLE %B; ATTEMPTING R
2C2M [ECOVERY"
2C2Y LDCT 0 #240 [J IF REOPEN FAILED OR
2C39 ANDX 0 IPBSW(2) [READ INHIBITED FLAGS ARE SET
2C3G BNZ 0 REOPENFAIL
2C3R UP [SUPER BLOCK SENT SUCCESSFULLY
2C44 REOPENFAIL [UNABLE TO SEND SUPER BLOCK : EXIT
2C4* LDCT 0 #200
2C4L ORS 0 IPBSW(2)
2C4X ERS 0 IPBSW(2) [LEAVE REOPEN FAILED FLAG UNSET
2C58 STO 3 ACOMMUNE3(2) [RESTORE MESSAGE IDENTIFIER
2C5F STO 4 ACOMMUNE2(2) [RESTORE CHAINADD'S VALUE ON COOR1
2C5Q ADX 7 FX1
2C63 EXIT 7 0
2C6# SET GEOERR 1,LONGSET [SHOULD NOT ALREADY BE IN A LONG WAIT
2C6K #
2C7W #
2CMG # SUBROUTINE TO PASS ICONIN TO IPBCCA AND UPDATE OVERLOAD COUNT ;
2D76 # ON ENTRY : CONDCB ADDRESS IN X3 , ICONIN ADDRESS IN X1
2DLQ #
2F6B SCHIC LDX 2 BPTR(3)
2FL2 HUNTACT AMOP,3 [POINT TO IPBCCA ACTIVITY
2G5L LDX 0 ALOGLEN(1)
2GK= ADS 0 INLOAD(3)
2H4W CHAIN 1,2
2HJG # WAKE IPBCCA ACT IF NECESSARY
2J46 LDEX 0 ATYPE(3)
2JHQ BZE 0 SCEX [NOT WAITING
2K3B LDX 2 3
2KH2 UNQUEUE
2L2L FPUT
2LG= #
2L^W SCEX EXIT 5 0
2MFG #
2M^6 # FIND THE ADDRESS IN X2 OF THE CONDCB ENTRY FOR IDENTIFIER IN X5
2NDQ #
2NYB SEEK LDX 2 FX2
2PD2 HUNT2J 2,AMXOR,ADEVS,AWORK1(2),SUIC
2PXL LDX 0 5
2QC= SBX 0 A1+FOURTHWD(2) [SUBTRACT LOWEST IDENTIFIER NO.
2QWW SLL 0 2
2RBG ADX 2 0
2RW6 LDCT 0 #10
2S*Q ANDX 0 A1+FOURTHWD(2)
2STB BZE 0 (6) [NOT ONLINED YET
2T*2 LDX 2 A1+BPTR(2)
2TSL BZE 2 (6) [NOT RINGED TO CONDCB YET
2W#= EXIT 6 1
2WRW #
2X?G # SUBROUTINE TO SET UP ACTIVITY OF TYPE IN X5 AND LENGTH IN X6
2XR6 #
2Y=Q SETAC SBX 0 FX1
2YQB SLL 5 12
2^=2 STO 0 AWORK3(2)
2^PL GETACTX 5,6
329= LDX 0 AWORK3(2)
32NW LDX 2 BPTR(2)
338G ADX 0 FX1
33N6 EXIT 0 0
347Q #
34MB # SEND SYSTEM SUPERVISORY SEGMENT TO AMOP/IPBCCA ACTIVITY
3572 # X6 CONTAINS MODIFIER DOWN CROUTE BLOCK TO POINT TO CSTATE BLOCK
35LL #
366= SSSS SBX 7 FX1
36KW SETNCORE IPBIDE-A1+2,1,AMXOR,ICONIN
375G LDX 5 AWORK1(2) [IPBIN COUNT ON IPBL LIST
37K6 HUNTW 2,AMXOR,CROUTE
384Q SMO 6
38JB LDX 3 A1+FPTR(2)
3942 ADX 3 BSTART(3) [ADDRESS OF AMXOR/CSTATE BLOCK
39HL STO 4 IPBIDE(1) [SUPERVISORY CODE
3=3= STO 5 IPBIDE+1(1)
3=GW LDCT 0 #400
3?2G STO 0 IBSW(1)
3?G6 ADX 7 FX1
3?^Q LDX 3 A1+FPTR(3)
3#FB SBN 3 A1 [ADDRESS OF CONDCB
3#^2 CALL 5 SCHIC [CHAIN ICONIN BEHIND IPBCCA
3*DL EXIT 7 0
3*Y= #
3BCW # SUBROUTINE TO GET ADDRESS IN X2 OF ACTIVITY OWNING ADCB IN X1
3BXG #
3CC6 SKACT LDX 2 1
3CWQ SFRED LDX 2 BPTR(2)
3DBB LDX 0 ATYPE(2)
3DW2 TXL 0 CACT
3F*L BCS SFRED
3FT= EXIT 7 0
3FWH ...#
3FXS ...#
3F^5 ...#
3G2B ...SINFO
3G3M ... SBX 7 FX1
3G4Y ... LGEOG ,6
3G69 ... GEOPACK 4,6,C
3G7G ... OUTPACK 4,1,GEOPER
3G8R ... INFORMX ,3,1
3G=4 ... ADX 7 FX1
3G?* ... EXIT 7 0
3G#W #
3GB* # ENTRY FROM IPBIN TO TRACE ONLINE A SUCCESSFUL CC READ
3GCS # TRANSFER IF "MOP TRACE" IS SWITCHED ON
3GF? SK1IPBINB
3GGQ LDX 0 ASWITCH1
3GJ9 SLL 0 7
3GKN BPZ 0 TRACEX ["MOP TRACE" SWITCHED OFF:EXIT
3GM7 LDCH 0 CPRW1(2)
3GNL SBN 0 1
3GQ5 BNZ 0 TRACEX [READ WAS NOT ENDED,OPERABLE:EXIT
3GRJ LDX 0 CPRW1(2)
3GT3 ANDN 0 #7777
3GWG NGX 0 0
3GX^ ADX 0 ALOGLEN(3)
3G^D LDX 1 3
3H2X TALL GEO 0 A1(1)
3H4B 8HIPBIN
3H5T ADN 1 1
3H7# BCT 0 TALL
3H8R TRACEX
3H== UP
3H#6 #
3HRQ # SET UP NEW ACTIVITY WITH LINK TO K2IPBSCAN ; TYPE IN X5 , LENGTH
3J?B # IN X6 , X4<0 IF ACTIVITY NOT TO BE PUT ON LIST (REDON ENTRY)
3JR2 # X4=0 IF OBEYED FROM IPBIN ACTIVITY
3K=L #
3KQ= # ENTRY FROM IPBIN AFTER INPUT ON IDLE DEVICE , OR LP OR TP ENGAGED
3L9W #
3LPG SK2IPBINB
3M96 LDX 7 0(3) [IDENTIFIER NUMBER
3MNQ LDN 4 0
3N8B SETDB ANDN 7 #7777
3NN2 LDX 2 FX2
3P7L CALL 0 SETAC [GET NEW ACTIVITY : ACTLF OR CPAT
3PCD FSHSKIP
3PM= LINKSET 2,SP1(1)
3PSD FSHCODE AORB
3P^L LINKSET 2,PAIR9(1)
3Q6W STO 7 ACC7(2)
3Q9F #
3Q#4 #
3QBM # CSDMOPTO MENDS HERE MAKES BLOCK 1 WORD LONGER
3QF= SEGENTRY K60IPBINB
3QHT #
3QLG SETNCORE ADCBLEN,1,AMXOR,ADCB,,1,2
3R66 STO 7 IDENTNO(1)
3RKQ BZE 4 SINT
3S5B LDX 2 AWORK1(2) [AMOP /IPBIN ADDRESS
3SK2 SINT STO 2 IADIN(1)
3T4L HUNT2J 2,AMXOR,ADEVS,,SFDCB
3TJ= SBX 7 A1+FOURTHWD(2)
3W3W SLL 7 2
3WHG ADX 2 7
3WJF LDN 0 1
3WKD BXU 4 0,SINTA [J. IF NOT K4 OR K10 ENTRY
3WLC LDCT 0 #24
3WMB ANDX 0 A1+FOURTHWD(2) [TEST IF BITS 4 AND 6 SET
3WN* BNZ 0 SFDCB
3WP# [J IF SOMEBODY ELSE SETTING UP ACTI
3WQ? SINTA
3WR# LDX 0 A1+BPTR(2)
3X36 BNZ 0 SFDCB [ALREADY RINGED : CLEAR UP
3X4N LDX 0 A1+FOURTHWD(2)
3X6= ANDN 0 #17
3X73 ... BZE 0 SINTB
3X7S SBN 0 #12 [DEVICE TYPE = MOP DISPLAY
3X9B BZE 0 SINTB
3X=Y LDCT 0 #241 [J. IF SCANNING OR ATTACHIG CLOSING
3X#G BRN SINTC
3XB4 SINTB
3XCL LDCT 0 #41 [ONLINCL WILL ALLOW MOP VDUS TO BE RINGED
3XF8 SINTC
3XGQ ANDX 0 A1+FOURTHWD(2) [FOR ONLINE - TO CLEAR UP
3XQJ BNZ 0 SFDCB
3Y2B LDCT 0 2 [NOW CHECK IF WRONGED
3Y=8 ANDX 0 A1+FOURTHWD(2)
3YG2 BZE 0 STILL [NOT WRONGED + OK ENRING
3YPS LDCT 0 #20 [UNSET INITIALISING FLAG(B4) IF SET
3Y^L ORS 0 A1+FOURTHWD(2)
3^9D ERS 0 A1+FOURTHWD(2)
3^F= SFDCB FREECORE 1 [ADCB
3^YW FREECORE BPTR(2) [NEW ACTIVITY
42DG BPZ 4 SACT
42Y6 UPPLUS 1 [REDON ENTRY : INDICATE ERROR
43CQ #
43XB STILL RING2CHK A1+FPTR(1),A1+FPTR(2) [ADEVS ENTRY AND ADCB
44C2 STOZ IWAIT(1)
44WL LDCT 0 #24
45B= ORS 0 A1+FOURTHWD(2) [SET B4 & B6 TO SHOW ACT BEING SET UP
45TW LDCT 0 #400
46*G STOZ IBIL(1)
46T6 ANDX 0 A1+FOURTHWD(2)
47#Q STO 0 ISTATUS(1) [COPY AVAILABILITY
47SB SMO FX2
48#2 LDX 2 BPTR
48RL STO 7 ACC6(2) [POINTER TO ADEVS ENTRY
49?= BNG 4 SNOFP [REDON WILL FPUT ITS OWN CPAT
49QW FPUT
4==G SNOFP LDX 2 FX2
4=Q6 CHAIN FPTR(2),BPTR(2) [CHAIN ADCB AFTER ACTIVITY
4?9Q SACT UP
4?PB #
4#92 # ENTRY FROM REDON COMMAND : SET UP CPAT TO READ BULK DATA STREAM
4#NL #
4*8= SK3IPBINB
4*MW LDN 5 CPAT
4B7G LDN 6 CPATLEN
4BM6 NGN 4 1 [INDICATE K3 ENTRY
4D62 STOG MHUNTW 2,CPAR,JSCE
4DKL LDX 7 JSCEA(2) [IDENTIFIER NUMBER
4F5= LADDP JSCEP(2),2 [GET APIA ADDRESS FROM DEVICE LIST
4FJW LDX 0 1(2)
4KFW SMO FX2
4K^G STO 0 AWORK1 [AMOP/IPBIN ADDRESS
4LF6 BRN SETDB
4LYQ #
4MDB # ENTRY FROM RIGHT COMMAND AFTER REMOTE LP OR TP RIGHTED
4MY2 #
4NCL SK4IPBINB
4NX= LDN 4 1 [INDICATE K4 ENTRY
4PBW LDN 5 ACTLF+GREMOTE
4PWG LDN 6 ACTLFLEN+GREMOTELEN [SET UP ACTLF FOR ASTERISKS OR RUNOUT
4QB6 BRN STOG
4QTQ #
4R*B # ENTRY FROM IPBIN WHEN "IDENTIFIER FREE" RECEIVED FROM DCP
4RT2 #
4S#L SK5IPBINB
4SJC LDX 4 2 [IPBIN PTR
4SM2 SK20IPBINB
4SS= LDN 5 AMSCAN+IPBTYPE
4T?W LDN 6 AMSCANLEN+IPBTYPELEN
4TRG CALL 0 SETAC [SET UP AMSCAN ACTIVITY
4W?6 LDX 0 0(3) [IDENTIFIER NUMBER
4X=B ANDN 0 #7777
4XQ2 STO 4 ACC5(2) [AMOP/IPBIN ADDRESS
4Y9L STO 0 ACC6(2) [IDENTIFIER NUMBER
4YP= LINKSET 2,SP5(1)
4^8W FPUT
4^NG UP
5286 #
52MQ # ENTRY FROM IPBIN WHEN IPB INOPERABLE OR DCP ERROR
52RM # IF INOPERABLE & "REOPEN" MACRO IS NOT "OFF",INFORM OPERATOR
52XJ # AND ATTEMPT TO SEND RESET & REOPEN SUPERVISOR SEGMENTS TO THE DCP
533F # AND GO UP IF SUCCESSFUL : OTHERWISE -
537B # INHIBIT CONCEPTUAL OUTPUT BY SENDING "SYSTEM OVERLOAD" TO IPBCCA'S
53M2 # WHICH WILL BE INTERPRETED AS 'IPB INOPERABLE'
546L # INFORM OPERATORS OF INOPERABILITY OR ERROR.
54L= # NUDGE ALL SYSTEM ACTIVITIES TO NOTICE INOPERABILITY
555W # WHEN OPERABLE AGAIN , SEND "SYSTEM CONTINUE" TO IPBCCA'S , WHICH
55KG # WILL BE INTERPRETED AS 'GENERATE AVAILABLE FOR IDENTS ON THIS IPB'
5656 #
56JQ SK6IPBINB
56L^ LDX 0 ACOMMUNE2(2)
56P8 BPZ 0 TELL [IPB ERROR
56Q? ... J7900E 2,TELL
56RC SEGENTRY K50IPBINB
56TL NULL [FOR "REOPEN" RESTORE TIME MACRO
56XT CALL 7 REOPEN [ATTEMPT TO "REOPEN" THE DCP
5724 TELL
574B HUNTW 3,AMXOR,CROUTE
57J2 BNG 3 NOC [NO CONCEPTUALS AROUND
583L LDX 6 ALOGLEN(3)
58H= BZE 6 NOC [CROUTE BLOCK EMPTY
592W LDCT 4 #252
59GG IPBCOUNT 5,2,1 [GET AMOP/IPBIN COUNT IN X5
5=26 SRL 4 3 [SYSTEM OVERLOAD CODE
5=FQ STO 5 AWORK1(2)
5=^B NXIP SBN 6 CROUTELEN
5?F2 CALL 7 SSSS [SEND SYSTEM SUP. SEG.
5?YL BNZ 6 NXIP
5#D= NOC LDCT 0 #40
5#XW ANDX 0 IPBSW(2) [J IF READ NOT INHIBITED
5*CG BZE 0 NORI
5*X6 UP
5BBQ NORI LDX 3 IPBRING(2)
5BHY #UNS CCERROR
5BP6 #SKI
5BWB LDCT 0 #400
5CB2 SBN 3 IPBRING
5CJ= LDX 5 ACOMMUNE2(2)
5CQG #UNS CCERROR
5CYQ #SKI
5D72 (
5D*= ORS 0 IPBSW(3) [MARK AMOP/IPBOUT INOPERABLE
5DSW ANDX 0 IPBSW(2)
5F#G BNZ 0 NOPAL [ALREADY MARKED INOPERABLE
5FJ# )
5FS6 LDCT 0 1
5G?Q ANDX 0 IPBSW(3) [SET IF WRITE REJECTED OPERABLE
5GRB BZE 0 NREJ
5H?2 ERS 0 IPBSW(3)
5HQL LDX 2 3
5J== FPUT [MAKE IPBOUT NOTICE INOPERABILITY
5JB7 #UNS CCERROR
5JG4 #SKI
5JK^ (
5JPW NREJ LGEOG ,6
5K9G LDX 3 ACOMMUNE3(2) [OUTPACKC OVERWRITES ACOMMUNE3
5K=X )
5K## #UNS CCERROR
5K*P (
5KC6 NREJ
5KDH LDCT 0 #400 [SET IPBOUT'S INOPERABLE/ERROR FLAG
5KFY ORS 0 IPBSW(3)
5KG3 BNG 5 REPORTINOP [REPORT IPB INOPERABLE
5KG4 BNZ 5 NOPAL [NO INOPERABILITY TO REPORT
5KG5 # X5 (ACOMMUNE2) IS ZERO IF A DCP ERROR HAS ALREADY BEEN
5KG6 # REPORTED OR IF THE VIRTUAL 7900 HAS BECOME INOPERABLE
5KG7 # (IE ALL READ COMMS CHANNELS RELEASED)
5KG8 # WHICH CASE IS DETERMINED HERE RATHER THAN IN IPBIN WHERE
5KG9 # NO ROOM EXISTS
5KG= LDCT 0 2
5KG? ANDX 0 IPBSW(3)
5KG# BNZ 0 NOPAL [DCP ERROR REPORTED: NO INOPERABILITY
5KG* [(OR DCP ERROR) TO REPORT
5KGB # VIRTUAL 7900 HAS BECOME INOPERABLE
5KGC # SET ACOMMUNE3 AS FOR IPB INOPERABILITY
5KGD # NOTE THE "REOPEN" MACRO IS NOT RELEVANT TO VIRTUAL 7900'S
5KGF LDX 0 ZJIPBINOP(1)
5KGG STO 0 ACOMMUNE3(2)
5KGH #
5KGJ REPORTINOP
5KH? ... JN7900E 2,XAC3
5KJ2 ... LDX 3 ZJIPBINOPE(1)
5KJP ... BRN XINF
5KKD ...XAC3
5KL7 LDX 3 ACOMMUNE3(2) [OUTPACKC OVERWRITES ACOMMUNE3
5KLT ...XINF
5KMJ )
5L25 ... CALL 7 SINFO
5L#M #UNS CCERROR
5LDJ (
5LJF LDX 0 IPBSW(2)
5LNB BPZ 0 NOPAL [DCP ERROR NOT REPORTED
5LS? STOZ 5 [DCP ERROR REPORTED :SET CHAINADD +VE
5LY8 )
5M45 NOPAL
5M82 #
5MML MHUNTW 3,AMXOR,ADEVS
5N7= LDX 4 ALOGLEN(3)
5NLW SRL 4 2 [NO. OF DEVICES
5NNK ... SBN 4 1
5NQ# ... ADN 3 4
5NS4 ...UTOP
5N^= ... LDN 1 #200
5P6D ... ANDX 1 A1+FOURTHWD(3)
5P?L ... BZE 1 NOT16
5PDS ... ERS 1 A1+FOURTHWD(3)
5PL2 ... FON IPBRELWS
5PR8 ...NOT16
5PYB ... LDX 1 A1+BPTR(3)
5Q5Q BZE 1 UNEX [DEVICE IDLE
5QKB LDCT 0 #10
5R52 ANDX 0 A1+FOURTHWD(3)
5RJL BNZ 0 UNEX [ONLINED : IGNORE
5S4= SBN 1 A1+FPTR
5SHW LDXC 0 IWAIT(1)
5T3G BCC UNEX [NOT WAITING
5TH6 STO 0 IWAIT(1)
5W2Q CALL 7 SKACT
5WGB FPUT [KICK ACTIVITY
5X22 UNEX ADN 3 4
5XFL BCT 4 UTOP
5X^= #
5Y38 #UNS CCERROR
5Y56 (
5Y74 BNG 5 SUS [NO DCP ERROR TO REPORT
5Y92 BZE 5 SUS [NO DCP ERROR TO REPORT
5Y=Y CCERROR 5,ACOMMUNE3(2) [REPORT DCP ERROR AND SUSPEND TIL MOP OFF
5Y?# ... LDCT 0 #004
5Y?N ... LDX 3 IPBRING(2)
5Y#4 ... ANDX 0 IPBSW-IPBRING(3)
5Y#D ... BNZ 0 WAKEOUT [J. BIT 6 SET IE RECOVERED OK
5Y#W SUS
5YBS )
5YDW LDCT 6 #500
5YYG ORS 6 IPBSW(2) [INDICATE INOP AND ASLEEP.
5^4C LDCT 0 #40
5^8# ANDX 0 IPBSW(2)
5^#9 BNZ 0 RUN [READ INHIBITED:MOPPING OFF:SKIP WAIT
5^*8 ... J7900E 2,WAITMP
5^B7 STO 5 CHAINADD(2)
5^C6 ...WAITMP
5^D6 COOR1 [WAIT UNTIL OPERABLE AGAIN
5^MY RUN
5^XQ LDX 3 IPBRING(2)
5^YY #UNS CCERROR
6226 (
623# [IF NOT MOPPING OFF AND A LINK LEVEL ERROR HAS OCCURRED,
624G [GO BACK TO SLEEP
625N LDCT 0 #40 [(TEST FOR READ INHIBIT FLAG)
626W ANDX 0 IPBSW(2)
6284 BNZ 0 WAKEOUT
629= LDCT 0 4 [(TEST FOR LINK LEVEL ERROR FLAG)
62=D ANDX 0 IPBSW-IPBRING(3)
62?L BNZ 0 SUS
62#S WAKEOUT
62B2 )
62X2 ORS 6 IPBSW(2)
63W= ERS 6 IPBSW(2)
643D ... LDCT 0 #100
648L ... SBN 3 IPBRING
64*W ANDX 0 IPBSW(3)
64TG BZE 0 SWA
65*6 LDX 2 3
65SQ FPUT [WAKE AMOP/IPBOUT ACTIVITY
65WN #UNS CCERROR
65YL (
662J ...SWA LDCT 6 #504 [UNSET IPBOUT'S INOP-ERROR/ASLEEP/
664G ORS 6 IPBSW(3) [DCP ERROR FLAGS
666D )
668B #UNS CCERROR
66=# #SKI
66#B SWA ORS 6 IPBSW(3)
66S2 ERS 6 IPBSW(3)
67?L LDCT 4 #253
67R= SRL 4 3 [SYSTEM CONTINUE CODE
68=W HUNTW 3,AMXOR,CROUTE
68QG BNG 3 NCR [NO CONCEPTUALS
69=6 LDX 6 ALOGLEN(3)
69PQ BZE 6 NCR [NULL CROUTE BLOCK
6=9B NIP SBN 6 CROUTELEN
6=P2 CALL 7 SSSS [SEND 'SYSTEM CONTINUE' TO IPBCCA
6?8L BNZ 6 NIP
6?N= NCR UP
6#7W #
6#MG # ENTRY FROM IPBIN WHEN "LINE CHANGED" RECEIVED FROM DCP
6*76 # SET UP CPAT TO CHANGE IDF AND PASS COPY TO EACH IPBCCA AFFECTED
6*LQ #
6B6B SK7IPBINB
6BL2 LDX 7 CPPTR(2)
6C5L LDN 6 CPATLEN
6CK= LDN 5 CPAT
6D4W CALL 0 SETAC [SET UP CPA
6DJG LINKSET 2,SP8(1) [SET LINK TO K8IPBINB
6F46 LDX 0 FX2
6FHQ LDX 4 1(3)
6G3B STO 0 AWORK1(2)
6GH2 STO 4 ACC7(2) [B0-11 : OLD LINE NO ; B12-23 : NEW
6H2L LDX 5 0(3)
6HG= STO 7 ACC6(2) [POINTER TO DEVICE LIST
6H^W STO 5 AWORK2(2) [LINE CHANGED : #01550000
6JFG FPUT
6J^6 UP
6KDQ #
6KYB SK8IPBINB
6LD2 IDFLINE
6LXL LDN 4 AI [FIRST ENTRY IN INLINE BLOCK
6MC= STA MHUNTW 2,IDF,INLINE [IDF'S LIST OF IDENTS ON THIS LINE
6MWW ADX 2 4
6NBG LDX 5 0(2)
6NW6 BNG 5 SUIC [LAST ENTRY DEALT WITH
6P*Q LDX 1 4
6PTB SBN 1 AI
6Q*2 BZE 1 SFIR [THIS IS FIRST ENTRY
6QSL LDX 0 1(2) [INTERNAL IDF CONCEPTUAL PTR
6R#= SRL 1 1 [NO. OF ENTRIES DEALT WITH
6RRW SON SBN 2 2
6S?G TXU 0 1(2) [EQUAL IF BOTH IDENTS ON SAME CONCEP
6SR6 BCC SBDX [ALREADY SENT COPY TO THIS IPBCCA
6T=Q BCT 1 SON
6TQB SFIR CALL 6 SEEK [POINT TO CONDCB ENTRY
6W=2 BRN SZE [NOT ONLINED YET
6WPL HUNTW 1,AMXOR,ICONIN
6X9= BPZ 1 SUCH [ALREADY ICONIN : PREV IDENT DETACHED
6XNW SETNCORE IPBIDE-A1+2,1,AMXOR,ICONIN
6Y8G LDX 0 AWORK2(2)
6YN6 STO 7 IPBIDE+1(1) [B0-11 OLD LINE NO ; B12-23 NEW NO
6^7Q LDCT 2 #400
6^MB STO 0 IPBIDE(1)
7272 STO 2 IBSW(1)
72LL CALL 6 SEEK
736= BRN SZE [DETACHED OR NOT YET RINGED
73KW SUCH LDX 3 2
745G ADX 3 BSTART(2) [ADDRESS OF CONDCB
74K6 CALL 5 SCHIC [CHAIN ICONIN BEHIND IPBCCA ACTIVITY
754Q BDX 4 STA
758M SUIC
75Y5 SUICIDE
7642 SZE MHUNTW 2,IDF,INLINE
76HL ADX 2 4
773= STOZ 1(2)
77GW SBDX BDX 4 STA [GO ON TO NEXT INLINE ENTRY
782G #
7855 [ALTERNATIVE TO K10 - BITS 4 & 6 WILL NOT BE TESTED IN SETDB
787N [
78=? SK30IPBINB
78#W LDN 4 30 [SET FLAG WORD
78CF BRN ZK30 [J. TO DO NECESSARY SET UP
78G6 # ENTRY FROM DETACH FOR CANCEL ATTACH/CONCEPTUAL COMMAND
78^Q # ON ENTRY : IDENTIFIER NUMBER IN X7 , AMOP/IPBIN ADDRESS IN AWORK1
79FB #
79^2 SK10IPBINB
7=DL LDN 4 1
7=JH ZK30
7=ND
7=S*
7=Y= LDX 5 7
7?CW CALL 6 SEEK [POINT TO ADEVS ENTRY
7?XG BNZ 2 NOTOL [NOT ONLINE
7#C6 GEOERR 1,ONLINE? [MARKED ONLINE TO CONCEPTUAL
7#WQ NOTOL LDEX 0 A1+FOURTHWD(2)
7*5C ERN 0 #32
7*7L BZE 0 SACT [STRAIGHT UP IF PVDU
7*9T ERN 0 #32 [RESTORE TYPE
7*BB ANDN 0 3
7*W2 SBN 0 3
7B*L BZE 0 OUTP [ACTLF FOR TYPE 3 OR 7
7BT= LDN 5 CPAT
7C#W LDN 6 CPATLEN
7CSG BRN SETDB [SET UP NEW ACTIVITY AND DCB
7D#6 OUTP LDN 6 ACTLFLEN+GREMOTELEN
7DRQ LDN 5 ACTLF+GREMOTE
7F?B BRN SETDB
7F#J [
7F*Q [ SK14IPBINB
7FBY [
7FD6 SK14IPBINB
7FF# [
7FGG [ SUBROUTINE TO PASS DATA TO IPBCCA
7FHN [
7FJW SCDAT
7FL4 LDX 4 3
7FM= LDX 3 7
7FNF SETNCORE IPBIDE-A1(3),1,AMXOR,ICONIN
7FNG STO 2 IMOPTY(1) [IPBIN ADDRESS
7FNH STO 5 IBSW(1) [BLOCK STATUS WORD
7FNJ LDN 5 IPBIDE(1)
7FNK MOVLONG 4,5,7 [DATA OR SUPERVISORY SEGMENT
7FNL LDX 4 1
7FNM LDN 3 IPBIDE(1)
7FNN CALL 7 SKADB
7FNP BZE 1 SGO [ADEVS RING ZERO : OLPA RELEASING
7FNQ LDN 3 A1(1)
7FNR ADX 3 BSTART(3) [ADDRESS OF CONDCB
7FNS LDX 0 ATYPE(3)
7FNT SRC 0 12
7FNW SBN 0 AMXOR+CONDCB
7FNX BZE 0 SCD
7FNY GEOERR 1,WRONGBLK [ADEV'S PTR WRONG
7FN^ SCD
7FP2 LDX 1 4 [ADDRESS OF ICONIN
7FP3 # CHAIN ICONIN BEHIND IPBCCA
7FP4 LDX 2 BPTR(3)
7FP5 HUNTACT AMOP,3 [FIND IPBCCA ACT
7FP6 LDX 0 ALOGLEN(1)
7FP7 ADS 0 INLOAD(3)
7FP8 CHAIN 1,2
7FP9 # WAKE IPBCCA ACT IF NECESSARY
7FP= LDEX 0 ATYPE(3)
7FP? BZE 0 SCEX1 [NOT WAITING
7FP# LDX 2 3
7FP* UNQUEUE
7FPB FPUT
7FPC #
7FPD SCEX1
7FPF UPPLUS 2
7FPG SGO FREECORE 4 [FREE ICONIN
7FPH BRN SCEX1[
7FPJ [ SUBROUTINE TO FIND ADDRESS IN X1 OF ADCB FOR GIVEN IDENTIFIER
7FPK [ IN ((X3)) AND ADDRESS IN X2 OF ADEVS ENTRY FOR THE IDEN
7FPL [
7FPM SKADB MHUNTW 2,AMXOR,ADEVS
7FPN LDX 0 0(3) [IDENTIFIER NUMBER
7FPP ANDN 0 #7777
7FPQ BZE 0 TDCB [ZERO : SYSTEM SUPERVISOR'S NUMBER
7FPR SBX 0 A1+FOURTHWD(2) [SUBTRACT LOWEST IDENTIFIER NO.
7FPS SLC 0 2
7FPT TXL 0 ALOGLEN(2)
7FPW #UNS CCERROR
7FPX BCC SERR1 [DCP ERROR : IDENTIFIER TOO LARGE
7FPY #UNS CCERROR
7FP^ #SKI
7FQ2 BCC SERR [DCP ERROR : IDENTIFIER TOO LARGE
7FQ3 ADX 2 0
7FQ4 TDCB LDX 1 A1+BPTR(2)
7FQ5 BZE 1 (7) [X1 ZERO IF NO RING POINTER
7FQ6 SBN 1 A1+FPTR
7FQ7 EXIT 7 0
7FQ8 SERR1
7FQ9 UPPLUS 1
7FQ= SERR
7FQ? UP
7FQM ...[
7FR3 ...[ K31 IPBINB
7FRC ...[
7FRR ...SK31IPBINB
7FS7 ...[
7FS# ...
7FSF ...SWT LDCT 0 #040
7FSL ... ERS 0 IPBSW(2)
7FSR ... MHUNTW 3,AMXOR,ADEVS
7FSY ... LDX 2 A1+BPTR(3)
7FT5 ... BZE 2 SFPA
7FT= ... STOZ A1+BPTR(3)
7FTC ... STOZ BPTR(2)
7FTJ ... SBN 2 A1+FPTR
7FTP ... CALL 7 SFRED
7FTW ... FPUT
7FW3 ...SFPA
7FW8 ... LDX 2 3
7FW* ... LDX 4 ALOGLEN(3)
7FWG ... SRL 4 2
7FWM ... SBN 4 1
7FWS ...SFPALOOP
7FW^ ... LDX 1 A1+BPTR+4(3)
7FX6 ... BZE 1 SFALPA
7FX? ... GEOERR 1,ADEVSRIN
7FXD ...SFALPA
7FXK ... ADN 3 4
7FXQ ... BCT 4 SFPALOOP
7FXX ... LDX 3 2
7FY4 ... FREECORE 3
7FY9 ... MFREEW AMXOR,INBF
7FYB ...XTESTWR
7FYH ... LDX 1 IPBRING(2)
7FYN ... SBN 1 IPBRING
7FYT ... BXE 1 2,XNOUT
7F^2 ... JBUSY CPPTR(1),XBUSY
7F^7 ...XNOUT
7F^# ... JWTBWR ,XWRG
7F^F ...XWAIT
7F^L ...
7F^R ... JENVNOT YWAIT,CME
7F^Y ... JWTBSW ,XSWOUT
7G25 ...YWAIT
7G2= ... UP
7G2C ...XBUSY LDX 0 BIT11
7G2J ... ORS 0 IPBSW(2)
7G2P ... COOR1
7G2W ... BRN XTESTWR
7G33 ...XJWRONG +JWRONG
7G38 ...XJUNIT +JUNITSWO
7G3* ...XJREJ +JSWOREJ
7G3G ...XWRG
7G3M ... JV7900 ,XW7900
7G3S ... YWRONG XGEO1,YWAIT
7G3^ ... DISENGPER
7G46 ...XWR
7G4? ... WRONG
7G4D ...XCLWR
7G4K ... CLWTBWR
7G4Q ... LDX 1 FX1
7G4X ... LDX 7 XJWRONG(1)
7G54 ...XINFO
7G59 ... LGEOG ,6
7G5B ... GEOPACK 4,6,C
7G5H ... OUTPACK 4,1,GEOPER
7G5N ...XMES
7G5T ... LDN 5 0
7G62 ... INFORMX 5,7,1
7G67 ... BRN XWAIT
7G6# ...XW7900
7G6F ... LDCT 0 #400
7G6L ... SMO CPPTR(2)
7G6R ... ERS 0 JK52B
7G6Y ... BRN XCLWR
7G75 ...XSWOUT
7G7= ... CLWTBSW
7G7C ... SWOUT ,XGEO,XRE
7G7J ... LDX 7 XJUNIT(1)
7G7P ... BRN XINFO
7G7W ...XRE
7G83 ... LDX 7 XJREJ(1)
7G88 ... BRN XINFO
7G8* ...XGEO
7G8G ... GEOERR 1,HLSBRKIN
7G8M ...XGEO1
7G8S ... GEOERR 1,IDFERR
7G8^ ...
7G9? ... MENDAREA 50,K100IPBINB
7G=L #END
^^^^ ...15147404000500000000