{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: IPBINC865)}}
====== IPBINC865 ======
(George Source)
**Macros used:** [[george:macro:ALTLENG|ALTLENG]], [[george:macro:CCERROR|CCERROR]], [[george:macro:CHAIN|CHAIN]], [[george:macro:DOWN|DOWN]], [[george:macro:ENDCOM|ENDCOM]], [[george:macro:FON|FON]], [[george:macro:FPUT|FPUT]], [[george:macro:FREECORE|FREECORE]], [[george:macro:GETACTX|GETACTX]], [[george:macro:HUNT2|HUNT2]], [[george:macro:HUNT2J|HUNT2J]], [[george:macro:HUNTW|HUNTW]], [[george:macro:INFORMX|INFORMX]], [[george:macro:ISSUCOML|ISSUCOML]], [[george:macro:LGEOG|LGEOG]], [[george:macro:LINKSET|LINKSET]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:NBREAKIN|NBREAKIN]], [[george:macro:ORIGIN|ORIGIN]], [[george:macro:OUTBLOCK|OUTBLOCK]], [[george:macro:OUTNUM|OUTNUM]], [[george:macro:OUTPARAX|OUTPARAX]], [[george:macro:OUTPARN|OUTPARN]], [[george:macro:PAIR|PAIR]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETNCORE|SETNCORE]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:TELECOM|TELECOM]], [[george:macro:UP|UP]], [[george:macro:UPPLUS|UPPLUS]]
22FL ...#SEG IPBINC8 [COMM - IPB
22S3 ...#OPT K0IPBINC=0
236D ...#LIST K0IPBINC>K0IPB>K0ALLGEO>K0GREATGEO
23DW ... 8HIPBINC
23YG #
24D6 ... SEGENTRY K1IPBINC,SK1IPBINC
24XQ ... SEGENTRY K11IPBINC,SK11IPBINC
25CB ...[ K11 ENTERED BY AMOP-IPBIN WHEN TELELOAD REQUEST RECEIVED
25X2 ... SEGENTRY K12IPBINC,SK12IPBINC
26BL ...[ K12 ENTERED DBY CPA INITIATING TELELOAD
26W= ... SEGENTRY K13IPBINC,SK13IPBINC
27*W ...[ K13 ENTERED BY TELELOAD COMMAND
27TG ...#DEF VRUC=33 [COUNT OF CHARS IN RACK UP SEQUENCE
28*6 ...#DEF VBIC=8 [COUNT OF CHARS IN 'BREAK IN' MESSAGE
28SQ ...SBREAK 8HBREAK IN
29#B ...SHDR #40240000
29S2 ...SMSKR #77607777
2=?L ...VRACKUP #76130700
2=R= ...#
2?=W ...# SUBROUTINE TO SET UP ACTIVITY OF TYPE IN X5 AND LENGTH IN X6
2?QG ...#
2#=6 ...SETAC
2#PQ ... SBX 0 FX1
2*9B ... SLL 5 12
2*P2 ... STO 0 AWORK3(2)
2B8L ... GETACTX 5,6
2BN= ... LDX 0 AWORK3(2)
2C7W ... LDX 2 BPTR(2)
2CMG ... ADX 0 FX1
2D76 ... EXIT 0 0
2DLQ ...#
3F*L # SUBROUTINE TO GET ADDRESS IN X2 OF ACTIVITY OWNING ADCB IN X1
3FT= #
3G#W SKACT LDX 2 1
3GSG SFRED LDX 2 BPTR(2)
3H#6 LDX 0 ATYPE(2)
3HRQ TXL 0 CACT
3J?B BCS SFRED
3JR2 EXIT 7 0
3K=L #
3KQ= # SUBROUTINE TO FIND ADDRESS IN X1 OF ADCB FOR GIVEN IDENTIFIER
3L9W # IN ((X3)) AND ADDRESS IN X2 OF ADEVS ENTRY FOR THE IDEN
3LPG #
3M96 SKADB MHUNTW 2,AMXOR,ADEVS
3MNQ LDX 0 0(3) [IDENTIFIER NUMBER
3N8B ANDN 0 #7777
3ND8 ... BZE 0 TDCB [ZERO : SYSTEM SUPERVISOR'S NUMBER
3NN2 SBX 0 A1+FOURTHWD(2) [SUBTRACT LOWEST IDENTIFIER NO.
3P7L SLC 0 2
3Q6W TXL 0 ALOGLEN(2)
3Q=2 ...#UNS CCERROR
3Q*6 ... BCC SERR1 [DCP ERROR : IDENTIFIER TOO LARGE
3QD= ...#UNS CCERROR
3QHB ...#SKI
3QLG BCC SERR [DCP ERROR : IDENTIFIER TOO LARGE
3R66 ADX 2 0
3RKQ ...TDCB LDX 1 A1+BPTR(2)
3S5B BZE 1 (7) [X1 ZERO IF NO RING POINTER
3SK2 SBN 1 A1+FPTR
3T4L EXIT 7 0
3TJ= #
3W3W # SUBROUTINE TO WAKE ACTIVITY IF NECESSARY , WITH GIVEN DCB ADDRESS
3WHG #
3X36 STASH LDN 0 #2000
3XGQ ANDX 0 IWAIT(1) [B13 SET IF WARNING NOTICED BY ACT.
3Y2B BZE 0 (6)
3YG2 ERS 0 IWAIT(1)
3Y^L STAKE LDXC 0 IWAIT(1)
3^F= ... BCC VCK [ACTIVITY NOT ASLEEP
3^YW STO 0 IWAIT(1)
42DG CALL 7 SKACT
42Y6 ... LDX 7 1 [PRESERVE ADCB ADDRESS
43CQ FPUT [END OF WARNING CONDITION
43XB ...WOKEN LDX 1 7
44C2 EXIT 6 0
44WL ...VCK [WAKEUP MOP ACTIVITY IF IN WAITING STYLE: IVDUWAIT
45B= ...#UNS JSKI37
45TW ...(
46*G ... SMO A1+FPTR(1)
46T6 ... LDEX 0 FOURTHWD
47#Q ... SBN 0 10
47SB ... BNZ 0 NVDTW [J IF NOT A VDU
48#2 ... LDN 0 #1000
48RL ... ANDX 0 ICONTU(1)
49?= ... BZE 0 NVDTW [J IF NOT SUSP OUTPUT
49QW ... ERS 0 ICONTU(1) [UNSET "WAITING OUTPUT SUSPENDED"
4==G ... LDX 7 1
4=Q6 ... FON CONTVDUWT [WAKE CPA
4?9Q ... BRN WOKEN
4?PB ...NVDTW
4#92 ...)
4#NL ... CALL 7 SKACT [SET X2 -> CPAT
4*8= ... LDX 7 1 [PRESERVE ADCB ADDRESS
4*MW ... LONGCLEA 2,IVDUWAIT,(6)
4B7G ... BRN WOKEN
4BM6 ...#UNS AV7900S
4C6Q ...(
4CLB ...#
4D62 ...# SUBROUTINE TO CREATE AN AMXOR/IOUT BLOCK
4DKL ...# ON ENTRY X6 = THE REQUIRED LOGICAL LENGTH OF THE BLOCK
4F5= ...# ON EXIT X2 -> THE AMXOR/IOUT BLOCK CREATED
4FJW ...# LINK IN X7
4G4G ...#
4GJ6 ...SETUPIOUTBK
4H3Q ... SBX 7 FX1
4HHB ... SETUPCOR 6,2,AMXOR,IOUT
4J32 ... ADX 7 FX1
4JGL ... EXIT 7 0
4K2= ...)
4KFW ...#UNS ATELE
4K^G ...(
4LF6 ...SK12LINK
4LYQ ... PAIR IPBINC,12
4MDB ...ZJTELING +JTELING
4MN8 ...ZJELDU +JTELDU
4MY2 ...ZJTELNOT +JTELNOT
4NCL ...TLCOM 8HLOADTCP
4NX= ...TLIDW +0
4PBW ... 4H0 ,T
4PWG ...TLREF 4H00,_
4Q6# ... 4H
4QB6 ...[ FIRST 2 CHARS OF TLREF HAVE TCP REFE
4QTQ ...TLCME
4R42 ...TLREF3 4H000,
4R== ... 4H_
4RDG ...
4RLQ ...#DEF REFBL=ATELCOM+TLREF-TLCOM
4RT2 ...[ REFBL IS POSN OF TCP REF IN COMPASS
4S#L ...#DEF TIDBL=ATELCOM+TLIDW-TLCOM
4SS= ...[ TIDBL IS POSITION OF PERIDESC IN COM
4T?W ...#DEF TLLEN=TLCME-TLCOM [LTH IN WDS OF LOADTCP COMMAND
4TRG ...#DEF TLCHAR=TLLEN@L2 [NUMBER CHARS IN TLOADTCP COMMAND
4W?6 ...TELLCEN
4WQQ ... LDN 1 1 [SEND TO CENTRAL
4X=B ... SBX 7 FX1
4XQ2 ... INFORMX 1,6,1
4Y9L ... ADX 7 FX1
4YP= ... EXIT 7 0
4^8W ...[ SUB TO SEND MESSAGE TO TELE IDENT
4^NG ...[
5286 ...[ IDENTIFIERS TO FIND DATA AFTER TLOUT
52MQ ...#DEF TEXOK=0 [EXIT IF MOOUTPUT OK
537B ...#DEF TEXNREQ=TEXOK+1 [EXIT IF NOT OUTPUT
53M2 ...#DEF TLMASK=TEXNREQ+1 [BITS IN 4W UNSET IF SENDING MESSAGE
546L ...#DEF TMOVE=TLMASK+1 [NO. WDS IN MESSAGE
54L= ...#DEF TDAT=TMOVE+1 [START OF DATA
555W ...TLOUT
55KG ... LDX 7 TMOVE(3)
5656 ... ADN 7 IDATA-A1-1 [LTH. OF BLOCK
56JQ ... SBX 3 FX1
574B ... SETUPCORE 7,1,AMXOR,IOUT
57J2 ... ADX 3 FX1
583L ... HUNT2J 2,AMXOR,ADEVS,AWORK4(2),TLVRQ
58H= ... ADX 2 4 [POINT TO ADEVS ENTRY
592W ... LDX 6 2 [SAVE ADEVS ENTRY
59GG ... LDX 0 TLMASK(3) [MASK OF BITS TO FREE MESSAGE
5=26 ... ANDX 0 A1+FOURTHWD(2)
5=FQ ... BNZ 0 TLVRQ [GO TO FREE IF ANY SET
5=^B ... STOZ IBSW(1) [SHOW DATA ONLY
5?F2 ... STOZ IMOPTY(1) [SO IPBOUT WONT TRY TO WAKE ACT
5?YL ... STO 5 IPBIDE(1) [IDENT NUMBER
5#D= ... ADN 1 IDATA-1 [POINT TO SEG HEADER
5#XW ... LDN 0 TDAT(3)
5*CG ... SMO TMOVE(3)
5*X6 ... MOVE 0 0 [MOVE MESSAGE INTO BLOCK
5BBQ ... SBN 1 IDATA-1 [POINT AT START OF BLOCK
5BWB ... SMO FX2
5CB2 ... LDX 2 AWORK4 [IPBIN ADDRESS
5CTL ... LDX 7 IPBRING(2)
5D*= ... SBN 7 IPBRING [IPBOUT ADDRESS
5DSW ... SMO 7
5F#G ... LDX 2 ACTRING
5FS6 ... SBN 2 ACTRING
5G?Q ... LDX 2 BPTR(2)
5GRB ... CHAIN 1,2 [SEND MESSAGE
5H?2 ... LDX 2 7
5HQL ... LDCT 0 #100
5J== ... ANDX 0 IPBSW(2)
5JPW ... BZE 0 TLALWK [J IF IPBOUT ALREADY AWAKE
5K9G ... ERS 0 IPBSW(2)
5KP6 ... FPUT
5L8Q ...TLALWK
5LNB ... LDX 2 FX2
5M82 ... EXIT 3 TEXOK
5MML ...TLVRQ FREECORE 1 [FREE IOUT
5N7= ... EXIT 3 TEXNREQ
5NLW ...)
=SNW #
=T8G # BREAK-IN SEGMENT ; ACTIVITY NEWLY SET UP , TIMED OUT , ALREADY
=TN6 # BROKEN IN ON OR ACTIVE ; IF ACTIVE TRY TO BREAK IN ON JOB
=TS3 ...# FOR MOP DISPLAYS: NO "REVERSION" OCCURS; REPLY IS ALWAYS
=TXY ...# BINAK TO PREVENT ANY MESSAGES BEING DISCARDED GIVING RISE TO
=W3T ...# MIS-POSITIONING OF MESSAGES
=W7Q #
=W8R ...[
=W9S ...[ X X X
=W=T ...[ X X X
=W?W ...[ XX X
=W#X ...[ X X X
=W*Y ...[ X X X
=WB^ ...[
=WD2 ...SK1IPBINC
=WF3 ...[
=WG4 ...[
=WH5 ...[ NOTE X3 WILL CONTAIN PTR TO BUFFER BLOCK
=WJ6 ...[
=WK7 ... CALL 7 SKADB [RE-FIND ADEV'S ENTRY AND ADCB
=WKM ... BZE 1 SIDLE [ACTIVITY HAS TIDIED UP
=WL8 ... LDN 5 0 [RE-SET X5
=WMB LDCT 6 #10
=X72 LDCT 0 4
=XLL ADN 6 1
=Y6= ANDX 0 A1+FOURTHWD(2) [BIT 6 SET IF CPA JUST SET UP
=Y?D ... LDEX 4 A1+FOURTHWD(2)
=YDL ... BNZ 4 TNEW [MOP DISPLAY : NO ACTUAL "REVERSION"
=YKW ADS 6 IBIL(1)
=^5G ...TNEW BNZ 0 SOP [NB X5 = 0
=^K6 SMO FX1
?24Q LDX 0 SMSKR [#77607777
?342 ANDS 0 ISTATUS(1)
?3*B ... BNZ 4 VRDYC [MOP DISPLAY
?3LQ ... LDCT 5 #200 [INDICATE REVERSION EXPECTED
?3Y6 ... ORS 5 IWAIT(1)
?49G ... LDCT 0 #040
?4GW ANDX 0 IWAIT(1)
?52G BZE 0 SNOTO [NOT TIMED OUT
?5G6 ERS 0 IWAIT(1) [UNSET T/O
?5^Q CALL 6 STAKE [WAKE ACTIVITY IF ASLEEP
?6FB BRN SMK
?6G7 ...#
?6GY ...# MOP DISPLAY : DON'T PERMIT THE BREAK-IN WHEN A READY
?6HP ...# MESSAGE IS BEING SENT
?6JG ...# NOTE IWAIT'S READY FLAG(B7) IS NOT TESTED
?6K? ...# ESP AS IT CAN REMAIN SET SOME TIME AFTER INPUT
?6L4 ...VRDYC CALL 7 SKACT [LOCATE CPA
?6LT ... LDX 2 FPTR(2) [CHECK FOR GMON/AOUT BLK IMMEDIATELY
?6ML ... LDX 0 ATYPE(2) [AFTER CPA
?6NC ... SRL 0 12
?6P8 ... SBN 0 GMON+AOUT
?6P^ ... BNZ 0 SNOTO [NO OUTPUT MESSAGE BEING SENT
?6QQ ... LDX 5 A1+1(2)
?6XD ... SLC 5 1
?6Y9 ... BNG 5 SOP [READY MESSAGE BEING SENT
?6^2 #
?7DL SNOTO LDCT 0 4 [BROKEN IN ON OR ACTIVE
?7Y= ANDX 0 IWAIT(1)
?8CW BZE 0 SYBI [NEW BREAK IN : JOB ACTIVE
?8XG SMK LDX 0 BIT9
?9C6 ORS 0 ISTATUS(1) [UPDATE CONTROL MASK FOR DISCARDS
?9WQ SBIAC LDN 5 0
?=BB BRN SOP
?=W2 #
??*L SYBI CALL 7 SKACT [LOCATE ACTIVITY
??F5 ...#UNS ENBREAKIN
??JJ ...(
??N3 ... NBREAKIN 2,8,,SBIY [TRY TO BREAK IN ON JOB
??RG ... [IF BREAK IN ALLOWED,J TO SBIY
??W^ ...)
?#2D ...#UNS ENBREAKIN
?#5X ...#SKI
?#9B ...(
?##W NBREAKIN 2,8 [TRY TO BREAK IN ON JOB
?D9W BRN SBIY [BREAK IN ALLOWED
?DPG ...)
?F96 ... CALL 7 SKADB [BREAK IN REJECTED
?G8B BZE 1 SIDLE [J IF CPAT HAS SUICIDED
?GN2 LDEX 0 IBIL(1)
?H7L SBN 0 2
?HM= BPZ 0 SBIAC
?J6W LDCT 5 #404 [INDICATE BINAK & NL BUT NO DATA.
?JLG BRN SOP [O/P BI NOT ALLWD
?K66 #
?KKQ SBIY CALL 7 SKADB [BREAK IN ALLOWED
?KTJ ... BZE 1 SIDLE
?L5B LDCT 0 4
?LK2 ORS 0 IWAIT(1) [SET 7900 BI BIT(G3 BI BIT WAS SET BY PROCONTX)
?M4L LDN 5 8
?MJ= #
?N3W ...# OUTPUT BIACK OR BINAK WITH OR WITHOUT MESSAGE
?NHG #
?P36 SOP LDCT 0 1
?PGQ ORS 0 ISTATUS(1) [SET MASK TO DISCARD READIES
?Q2B LDN 2 0
?QG2 BZE 5 SBA [ZERO IF NO MESSAGE
?Q^L BNG 5 SNLON [NO DATA
?RF= LDCH 2 ICHARS(1) [LENGTH OF NEWLINE
?RYW ADX 2 5
?SDG SNLON ADN 2 3 [ROUNDING
?SY6 ADX 2 INOCHS(1) [NL+EOM
?TCQ SRL 2 2
?TXB SBA LDX 4 0(3)
?W3? ... SMO A1+FPTR(1)
?W78 ... LDEX 0 FOURTHWD
?W?5 ... BNZ 0 VBREAKIN [MOP DISPLAY
?WC2 LDN 6 IDATA-A1(2) [ACCOUNT FOR IMOPTY,IPBSW,IPBIDE,IPBIDE+1
?WG6 ...#UNS AV7900S
?WK= ... CALL 7 SETUPIOUTBK
?WNB ...#UNS AV7900S
?WRG ...#SKI
?X4W ... SETUPCORE 6,2,AMXOR,IOUT
?XB= LDX 0 SHDR(1) [#40240000
?XTW STO 4 IPBIDE(2) [IDENTIFIER NUMBER
?Y*G ORX 0 5 [B0 OF X5 MAY BE SET : ADD CHAR CT.
?YT6 STO 0 IPBIDE+1(2)
?^#Q BZE 5 SBB [J IF NO DATA : DOUBLE BI OR NEW CPA
?^SB LDX 6 2
#2#2 CALL 7 SKADB
#2RL BZE 1 SJUG [CPAT HAS JUST SUICIDED : TRY AGAIN
#3?= LDX 2 6
#3QW LDN 7 IDATA(2)
#4=G BNG 5 SNAL [J IF NL ONLY REQ : BI NOT ALLOWED
#4Q6 LDCH 0 ICHARS(1)
#59Q LDN 6 INLBUFF(1)
#5PB ADS 0 IPBIDE+1(2)
#692 SMO 0
#6NL MVCH 6 0 [NEWLINE
#78= LDN 6 SBREAK
#7MW ADX 6 FX1
#87G SMO 5
#8M6 MVCH 6 0 [BREAK IN
#96Q SNAL LDX 0 INOCHS(1)
#9LB ADS 0 IPBIDE+1(2)
#=62 LDN 6 INLBUFF(1)
#=KL SMO 0
#?5= MVCH 6 0 [NEWLINE + EOM
#?5C ... BRN SBB
#?5J ...#
#?5K ...[
#?5L ...[ MOP DISPLAY
#?5M ...[
#?5P ...VBREAKIN
#?5Y ...#UNS AV7900S
#?67 ...#SKI
#?6D ... LDCT 7 #404 [FOR BINAK SEG HEADER(EOM + BINAK)
#?77 ... LDN 6 IDATA-A1 [BLK LENGTH: IMOPTY,IBSW,BINAK SEG
#?7= ...#UNS AV7900S
#?7* ...(
#?7D ... CALL 7 SETUPIOUTBK
#?7H ... LDCT 7 #404 [FOR BINAK SEG HEADER(EOM + BINAK)
#?7L ...)
#?7P ...#UNS AV7900S
#?7S ...#SKI
#?7Y ... SETUPCOR 6,2,AMXOR,IOUT
#?84 ... STO 4 IPBIDE(2) [IDENTIFIER
#?89 ... STO 7 IPBIDE+1(2) [SEGMENT HEADER
#?8B ... BNG 5 SBB [BREAK-IN REJECTED : QUEUE BINAK SEG
#?8J ... BZE 5 SBB [ACTIVITY NEWLY SET UP OR ALREADY
#?8Q ... [BROKEN IN ON : QUEUE BINAK SEG
#?8Y ...# BREAK-IN ACCEPTED : SET UP "BREAK IN" MESSAGE
#?96 ...# THEN QUEUE BINAK SEG & MESSAGE
#?9# ... LDX 6 2 [IN CASE OF JUMP TO SJUG
#?9F ... CALL 7 SKADB [RE-FIND DCB
#?9L ... BZE 1 SJUG [CPAT HAS JUST SUICIDED : TRY AGAIN
#?9R ... LDEX 6 ICURSOR(1) [ACC FOR IMOPTY,IBSW,RACK UP,BI MESS,
#?9Y ... ADX 6 INOCHS(1)
#?=5 ... ADN 6 IDATA-A1+(VRUC+VBIC+3/4) [MESS TERM SEQ & CUR POS CODES
#?=6 ...#UNS AV7900S
#?=7 ... CALL 7 SETUPIOUTBK
#?=8 ...#UNS AV7900S
#?=9 ...#SKI
#?=# ... SETUPCOR 6,2,AMXOR,IOUT
#?=C ... LDX 5 2 [PRESERVE IOUT PTR
#?=J ... CALL 7 SKADB [RE-FIND DCB
#?=P ... BZE 1 SJUGA [CPAT HAS JUST SUICIDED : TRY AGAIN
#??4 ... LDCT 0 #200 [SET "REVERSION EXPECTED" FLAG(B1)
#??C ... ORS 0 IWAIT(1) [AND WAKE CPA IF NOT ALREADY TAKEN
#??Q ... CALL 6 STAKE [BREAK-IN EXIT
#?#6 ...VRIP LDX 2 5 [RESET IOUT PTR
#?#? ... LDN 6 IDATA(2) [PTR FOR START OF MESS IN IOUT BLOCK
#?#D ... LDCH 7 ICURPOS(1) [CURRENT LINE NO OF CURSOR
#?#K ... LDEX 0 ICURPOS(1) [CURRENT COLUMN NO OF CURSOR
#?#Q ... BZE 0 VRACK [CURSOR ON COLUMN 0:USE CURRENT LINE
#?#X ... ADN 7 1 [USE NEXT LINE NO
#?*4 ...VRACK BCHX 1 £ [-> CHAR 1
#?*9 ... LDCH 0 ICHARS(1) [DISPLAY LENGTH
#?*B ... ANDX 1 BITS22LS
#?*H ... TXL 7 0 [IF MESSAGE LINE NO DCB FOR SKACT
#?JB ... CALL 7 SKACT [SET X2 -> CPAT
#?JF ... CHAIN 5,2 [CHAIN BI MESSAGE AFTER CPAT'S OUTPUT MESSAGE
#?JM ...VBIR HUNT2 2,AMXOR,IOUT [SET X2 -> BINAK BLOCK
#?JW #
##4G SBB STOZ IMOPTY(2) [ACTIVITY NOT TO BE WOKEN
##J6 STOZ IBSW(2)
#*3Q SMO FX2
#*HB LDX 3 IPBRING
#B32 LDX 1 2
#BGL SBN 3 IPBRING [ADDRESS OF IPBOUT ACTIVITY
#C2= LDX 2 ACTRING(3)
#CFW SBN 2 ACTRING [ADDRESS OF ACTIVITY AFTER IPBOUT
#C^G CHAIN 1,BPTR(2) [CHAIN IOUT BEHIND IPBOUT
#D6N ... HUNTW 2,AMXOR,IOUT
#D?W ... BPZ 2 SBB [MUST BE "BREAK IN" MESS : CHAIN TOO
#DF6 LDCT 0 #100
#DYQ ANDX 0 IPBSW(3) [B2 SET IF IPBOUT ASLEEP
#FDB BZE 0 SNEW [ALREADY AWAKE
#FY2 ERS 0 IPBSW(3)
#GCL LDX 2 3
#GMD ... FPUT
#GX= ...SNEW
#HBW ... UP [RETURN TO IPBIN
#HWG ...[
#JB6 ...[ X X X X
#JTQ ...[ X X X X
#K*B ...[ XX X X
#KT2 ...[ X X X X
#L#L ...[ X X X X
#LS= ...[
#M?W ...SK11IPBINC [ENTRY FOR PVDU FROM IPBIN
#MRG ...#UNS ATELE
#N?6 ...(
#NQQ ... STO 2 AWORK4(2) [AMOP ADDR FOR TLOUT
#P=B ... LDXC 0 1(3)
#PQ2 ... BCC TLNREQ [J IF NOT WHOLE MESSAGE
#Q9L ... ANDN 0 #7777
#QP= ... ERN 0 2
#R8W ... BNZ 0 TLNREQ [J IF NOT 2 CHARS
#RG= ... LDX 6 2(3)
#RRL ... STO 6 AWORK1(2) [SAVE MESSAGE
#S52 ...[
#SBB ...[ 1ST CHAR SHOULD BE BETWEEN #50 (H) AND #61 (Q)
#SMQ ...[
#S^6 ...[ 2ND CHAR SHOULD BE BETWEEN #40 (@) AND #51 (I)
#T=G ...
#THW ...[
#TT= ... LDN 5 0
#W6L ... SLL 56 6
#WD2 ... SBN 5 #50 [EXTRACT 1ST CHAR
#WPB ... BNG 5 TLNREQ [LESS THAN #50
#WQC ... BNZ 5 TLLQ
#WRD ... SLL 56 6
#WSF ... ANDN 5 #77
#WTG ... SBN 5 #52
#WWH ... BZE 5 TLDU
#WXJ ... ADN 5 #52
#WYK ... BRN TLCH2
#W^L ...TLLQ
#X2Q ... SBN 5 #12
#X#6 ... BPZ 5 TLNREQ [J. GREATER THAN #61
#XKG ... SLL 56 6
#XWW ... ANDN 5 #77
#Y3J ...TLCH2
#Y8= ... ERN 5 #40
#YFL ... SBN 5 10
#YR2 ... BPZ 5 TLNREQ [J. 2ND CHAR NOT IN RANGE
#^4B ... LDX 5 0(3) [SAVE IDENT NO.
#^J2 ... STO 5 AWORK2(2)
*23L ... CALL 3 TLOUT [SEND PLEASE WAIT TO 7502
*2H= ... BRN TLSOK [J IF OK
*32W ... BRN TLNREQ [NO LONGER REQ TELELOAD
*3GG ... #77350040 [TL NOT REQ IF THESE SET IN 4W
*426 ... +TLWTEN-TLWTSTAR [LTH TO BE MOVED INTO IOUT
*4FQ ...TLWTSTAR
*4^B ... #40000015 [DAT SEG HEADER
*5F2 ... 16H PLEASE WAIT
*5YL ...TLWTEN
*6D= ...TLSOK
*6XW ... LDN 0 #2000
*7CG ... SMO 6
*7X6 ... ORS 0 A1+FOURTHWD [SET B13 SO AMOP IGNORES OTHER REQUE
*8BQ ... LDN 5 CPAT
*8WB ... LDN 6 CPATLEN
*9B2 ... CALL 0 SETAC [GET ACPA
*9TL ... STO 4 AWORK2(2)
*=*= ... LDX 3 FX2
*=SW ... LDX 0 AWORK1(3)
*?#G ... STO 0 AWORK1(2) [SAVE DATA CHARS
*?S6 ... LDX 0 AWORK2(3)
*#?Q ... STO 0 ACC5(2) [IDENT NUM
*#RB ... STO 3 ACC4(2) [AMOP ADDR
**?2 ... LINKSET 2,SK12LINK(1)
**QL ... FPUT
*B== ...TLNREQ
*BPW ... UP
*BS5 ...TLDU
*BW# ... LDX 5 0(3)
*BYH ... OUTNUM 5,0
*C2Q ... LDX 6 ZJELDU(1)
*C4^ ... CALL 7 TELLCEN
*C78 ... UP
*C9G ...)
*CP6 ...[
*D8Q ...[ X X X XXX
*DNB ...[ X X X X
*F82 ...[ XX X X
*FML ...[ X X X X
*G7= ...[ X X X XXX
*GLW ...SK12IPBINC
*H6G ...#UNS ATELE
*HL6 ...(
*J5Q ...[ SETUP JSOURCE WD TYPE FORMAT IN AC WD
*JKB ... STO 5 ACOMMUNE8(2)
*K52 ... SMO 4
*KJL ... LDX 0 CPPTR
*L4= ... LGEOG 0,6
*LHW ... LDCT 0 #300
*M3G ... ORX 0 6
*MH6 ... STO 0 ACOMMUNE7(2)
*N2Q ... STOZ ACOMMUNE9(2)
*NGB ... LDX 0 ACES [SPACEFILL AC2-3 TO RECEIVE PERIDESC
*P22 ... STO 0 ACOMMUNE2(2)
*PFL ... STO 0 ACOMMUNE3(2)
*P^= ... ORIGIN [GET DESC OF ORIGININATING IDENT
*QDW ... SETNCORE ATELCOMLEN,3,ADATA,COMPASS
*QYG ... LDX 0 AWORK2(2)
*RD6 ... STO 0 ATELDIS(3) [ADEVS DISPLACEMENT
*RXQ ... STO 4 ATELAM(3) [AMOP ADDR
*SCB ... LDN 7 ATELCOM(3)
*SX2 ... LDN 6 TLCOM(1)
*TBL ... MOVE 6 TLLEN
*TW= ... STO 5 ATELID(3)
*T^B ... LDN 6 0
*W4G ... LDX 7 AWORK1(2)
*W7L ... SLL 67 6
*W=Q ... SBN 6 #52
*W*W ... BNG 6 TL2C [J RANGE 80 - 99
*WF2 ... LDN 6 TLREF3(1)
*WJ6 ... LDN 7 REFBL(3)
*WM= ... MOVE 6 2 [ 3 CHARS RANGE 100 TO 179
*WQB ... LDN 6 2
*WTG ... LDX 7 AWORK1(2)
*WYL ... SLL 7 1
*X3Q ... SLL 67 5
*X6W ... SBN 6 #12 [TENS - RANGE 0-7
*X=2 ... LDCT 0 #170
*X*6 ... ANDX 7 0
*XD= ... SLL 67 6 [UNITS - RANGE 0 - 9
*XHB ... SLL 6 6
*XLG ... BRN TLSTRQ
*XPL ...TL2C
*XSQ ... LDN 6 #1717 [ORIGINAL RANGE 80-99
*XXW ... SLL 6 12
*Y32 ... ANDX 6 AWORK1(2)
*Y66 ...TLSTRQ
*Y9= ... ORS 6 REFBL(3)
*Y#B ... LDN 6 ACOMMUNE2(2)
*YS2 ... LDN 7 TIDBL(3)
*^?L ... MVCH 6 5 [MOVE IN PERI DESC
*^R= ... OUTPARN 5,TIDBL,ADATA,COMPASS
B2=W ...[ OUTPUT PERIDESC AS PARAM TO MESSAGE
B2QG ... LDX 6 ZJTELING(1)
B3=6 ... CALL 7 TELLCEN [TELL OPERATORS
B3PQ ... TELECOM [GO TO COMMAND
B49B ...)
B4P2 ...[
B58L ...[ X X X XXXX
B5N= ...[ X X X X
B67W ...[ XX X X
B6MG ...[ X X X X
B776 ...[ X X X XXXX
B7LQ ...SK13IPBINC
B86B ...#UNS ATELE
B8L2 ...(
B95L ... SYSCOMTE 3 [CHECK COMMAND ISSUED BY K12IPBINB
B9K= ... SETNCORE CPDATA+TLLEN-A1,3,ADATA,CREADL
B=4W ... MHUNTW 1,ADATA,COMPASS
B=JG ... LDN 0 TLCHAR [NUMBER CHARS IN COMMAND
B?46 ... STO 0 A1(3)
B?HQ ... LDN 7 ATELCOM(1)
B#3B ... LDN 0 CPDATA(3)
B#H2 ... MOVE 7 TLLEN [MOVE IN COMMAND
B*2L ...[
B*G= ...[ NOW GET DATA OUT OF COMPASS TO SAVE FINDING IT AGAIN AFTER COMMAND
B*^W ...[
BBFG ... LDX 4 ATELDIS(1) [ADEVS DISP
BB^6 ... LDX 5 ATELID(1) [IDENT NO.
BCDQ ... LDX 0 ATELAM(1)
BCYB ... STO 0 AWORK4(2) [AMOP ADDR
BDD2 ... ISSUCOML TLCE [ISSUE COMMAND - GO TLCE IF COM ERROR
BDXL ... HUNT2J 2,AMXOR,ADEVS,AWORK4(2),ZEC [GO TO ENDCOM IF NO ADEVS
BFC= ... NGN 0 #2001
BFWW ... SMO 4
BGBG ... ANDS 0 A1+FOURTHWD(2) [UNSET B13
BGW6 ... BRN ZEC [GO TO ENDCOM
BH*Q ...TLCE LDCT 6 #400 [PRESET TO CHECK IF MOPPED OFF
BHTB ... CALL 3 TLOUT
BJ*2 ... BRN TLSENT
BJSL ... BRN TLSENT
BK#= ... #57150040
BKRW ... +TLNOTEN-TLNOTSTAR [LTH TO BE MOVED INTO IOUT
BL?G ...TLNOTSTAR
BLR6 ... #40000041 [DATA SEG HEADER
BM=Q ... 36H AUTOMATIC TELELOAD UNSUCCESSFUL
BMQB ...TLNOTEN
BN=2 ...TLSENT
BNPL ... BNG 6 TLNADEV [IF -VE MUST BE NO ADEVS
BP9= ... NGN 0 #2001
BPNW ... SMO 6
BQ8G ... ANDS 0 A1+FOURTHWD [UNSET B13
BQN6 ...TLNADEV
BR7Q ... LDN 7 5
BRMB ... OUTBLOCK 7
BS72 ... OUTPARN 5,TIDBL,ADATA,COMPASS
BS9S ... MHUNTW 3,ADATA,COMPASS
BS#L ... LDN 6 3
BSCD ... LDN 0 #77
BSG= ... ANDX 0 REFBL(3)
BSK4 ... SBN 0 #34
BSMW ... BZE 0 TLNOUT3 [J = COMMA
BSQN ... LDN 6 2
BSTG ...TLNOUT3
BSY# ... LDN 7 REFBL
BT36 ... OUTPARAX 6,7,ADATA,COMPASS
BT6= ... LDX 6 ZJTELNOT(1)
BTKW ... CALL 7 TELLCEN [TELL OPERATORS LOADTCP DIDNT WORK
BW5G ...ZEC ENDCOM
BWK6 ...)
BX4Q ...SERR1
BXJB ... LDN 0 CCINVIDEN [REPORT INVALID IDEN + (SEG WD 0)
BY42 ... LDX 1 0(3)
BYHL ... LDX 2 FX2
B^3= ... STO 0 ACOMMUNE2(2) [FOR CCERROR MACRO%A AND CHAINADD
B^GW ... STO 1 ACOMMUNE3(2) [FOR CCERROR MACROS %B OR INFORM
C22G ... DOWN IPBINB,6
C2G6 ... UPPLUS 1
C2^Q ...
C3FB ...SJUGA
C3^2 ... FREECORE 5
C4DL ... MHUNTW 2,AMXOR,IOUT
C4Y= ... LDX 6 2
C5CW ...SJUG
C5XG ... FREECORE 6
C6C6 ...SIDLE
C6WQ ... UPPLUS 2 [GO UP TO LABEL SIDLE
C7BB ...#END
^^^^ ...022631600008