{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: IPBLISTD867)}}
====== IPBLISTD867 ======
(George Source)
**Macros used:** [[george:macro:ACROSS|ACROSS]], [[george:macro:ALTLEN|ALTLEN]], [[george:macro:AND|AND]], [[george:macro:BS|BS]], [[george:macro:CHAIN|CHAIN]], [[george:macro:COOR1|COOR1]], [[george:macro:DEMANDX|DEMANDX]], [[george:macro:DO|DO]], [[george:macro:DOWN|DOWN]], [[george:macro:ELSE|ELSE]], [[george:macro:FI|FI]], [[george:macro:FILEMOVE|FILEMOVE]], [[george:macro:FPUT|FPUT]], [[george:macro:FREECORE|FREECORE]], [[george:macro:FREEPER|FREEPER]], [[george:macro:FSHENTRY|FSHENTRY]], [[george:macro:IF|IF]], [[george:macro:INFORM|INFORM]], [[george:macro:JBS|JBS]], [[george:macro:LFEND|LFEND]], [[george:macro:LONGSET|LONGSET]], [[george:macro:MHUNT|MHUNT]], [[george:macro:MHUNTW|MHUNTW]], [[george:macro:OR|OR]], [[george:macro:OUTPER|OUTPER]], [[george:macro:REPEAT|REPEAT]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SETUPCORE|SETUPCORE]], [[george:macro:SUICIDE|SUICIDE]], [[george:macro:THEN|THEN]], [[george:macro:VFREEW|VFREEW]], [[george:macro:WHILE|WHILE]]
22*P ... SEG IPBLISTD,,R.WEYAND,,G170,G269
22PD # (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982.
22^= #OPT K0IPBLISTD=0
233F ...#OPT G170 = 0
235N ...#SKI G170&1
237X ...# WITH UGUG EDIT M170 (VARIABLE REMOTE *LP WIDTHS)
23=6 ...#OPT G269 = 0
23#* ...#SKI G269&1
23BJ ...# WITH UGUG EDIT M269 (REMOTE *LP LISTFILE DEBATCHERS)
23DW #LIS K0IPBLISTD>K0IPB>K0ALLGEO
23YG SEGENTRY K1IPBLISTD,SK1IPBLISTD
248# SEGENTRY K2IPBLISTD,SK2IPBLISTD
249C SEGENTRY K3IPBLISTD,SK3IPBLISTD
24=G SEGENTRY K4IPBLISTD,SK4IPBLISTD
24?K #
24#N FSHENTRY K5IPBLISTD,SK5IPBLISTD,,SK5IPBLISTD
24*R #
24BW SEGENTRY K7IPBLISTD,SK7IPBLISTD
24D6 [
24XQ [
26BL [
26W= [
26W? [
26W# [************************************************************
26W* [
26WB [ PRESET DATA
26WC [
26WD [************************************************************
26WF [
26WG [
26WH PJMARY +JMARY
26WJ STARSOLF #76347666,#32323232
26WK NEWLINES
26WM ...#SKI G269&1
26WP ...STAREOLF #76207632,#76663232,#32323232
26WR ...#SKI G269&1$1
26WT ...STAREOLF #76327632,#76663232,#32323232
26WX ...STAREND #32327666
26W^ ... SEGENTRY K70IPBLISTD [ LFTHROW MACRO
26X3 ... #76340000
26X5 ...PDC2 #76357602 [CR + DC2
26X8 TAPE #76327620,#76207620
26X9 [
26X= [
26X? [************************************************************
26X# [
26X* RINGO
26XB [
26XC [************************************************************
26XD [
26XF #
26XG # RING AMXOR/IOUT BLOCK(S) BEHIND IPBOUT ACTIVITY , WHICH IS THEN
26XH # PUT ON LIST
26XJ #
26XK SBX 7 FX1
26XL MHUNTW 3,AMXOR,ADCB
26XM LDX 0 GSIGN
26XN ORS 0 IWAIT(3) [MARK 'ACTIVITY ASLEEP'
26XP LDX 3 IADIN(3) [ADDRESS OF IPBIN ACTIVITY
26XQ LDX 3 IPBRING(3)
26XR SBN 3 IPBRING
26XS LDX 2 ACTRING(3)
26XT SBN 2 ACTRING [ADDRESS OF ACTIVITY AFTER IPBOUT
26XW LDX 4 BPTR(2)
26XX LDX 2 FX2
26XY LDEX 5 AWORK1(2) [NO OF BLOCKS TO BE RINGED
26X^ MHUNTW 1,AMXOR,IOUT [THIS WILL BE THE LAST OUTPUT
26Y2 LDN 0 1
26Y3 ORS 0 IMOPTY(1) [INDICATE ACTIVITY TO BE WOKEN UP
26Y4 SMO FX2
26Y5 LDX 0 AWORK1
26Y6 BPZ 0 NOWCH [LP : NOT END OF RESTART SECTION
26Y7 LDCT 0 4
26Y8 ORS 0 IPBIDE+1(1) [INDICATE END OF RESTART SECTION
26Y9 ORS 0 IWORK9(2) [SET "FIRST REC OF SECTION" BIT
26Y= BRN NOWCH
26Y? NEBO
26Y# MHUNTW 1,AMXOR,IOUT [FIND NEXT OUTPUT BLOCK
26Y* NOWCH
26YB CHAIN 1,4
26YC BCT 5 NEBO
26YD NGN 0 #1000 [#77777000
26YF ANDS 0 AWORK1(2) [CLEAR COUNT OF BLOCKS TO BE OUTPUT
26YG LDCT 0 #100
26YH ANDX 0 IPBSW(3) [B2 SET IF IPBOUT ASLEEP
26YJ BZE 0 WAKE [ALREADY ON LIST
26YK ERS 0 IPBSW(3) [INDICATE ON LIST
26YL LDX 2 3
26YM FPUT
26YN WAKE
26YP COOR1
26YQ ADX 7 FX1
26YR EXIT 7 0
26YS [
26YT [
26YW SETU
26^4 [
26^H [
2722 [ GET AMXOR/IOUT BLOCK FOR OUTPUT
272F [
272Y SMO FX2
273C LDX 4 AWORK3 [NPU SIZE IN CHARS
273D [
273F [
273G [************************************************************
273H [
273J PCOR
273K [
273L [************************************************************
273M [
273W SBX 7 FX1
274* LDX 5 4
274S ADN 5 IDATA-A1*4+3 [ROUND UP
275? SRL 5 2 [NO. OF WORDS IN OUTPUT
275Q SETUPCORE 5,2,AMXOR,IOUT,1
2769 STOZ IMOPTY(2) [DONT WAKE UNLESS LAST BLOCK
276N LDN 0 1
2777 SMO FX2
277L ADS 0 AWORK1 [COUNT OF BLOCKS FOR OUTPUT
2785 MHUNTW 1,AMXOR,ADCB
278J LDX 5 IDENTNO(1)
2793 STO 5 IPBIDE(2) [IDENTIFIER NUMBER
279G LDX 1 FX1
279^ ORX 4 GSIGN
27=D STO 4 IPBIDE+1(2) [OUTPUT CHAR COUNT
27=X LDN 5 IDATA(2) [START ADDRESS OF OUTPUT
27?B ADX 7 FX1
27?T STOZ IBSW(2) [BLOCK STATUS WORD
27## EXIT 7 0
27#R [
27*= [
27*? [
27*# [
27** [************************************************************
27*B [
27*C TESTIPBSTAT
27*D [
27*F [************************************************************
27*G [
27*H MHUNTW 3,AMXOR,ADCB
27*J SMO A1+FPTR(3)
27*K LDX 0 FOURTHWD
27*L SLL 0 2
27*M BNG 0 (6)
27*N EXIT 6 1
27*P [
27*Q [************************************************************
27*R [
27*S SENGAGE
27*T [
27*W [************************************************************
27*X [
27*Y SBX 7 FX1
27*^ CALL 6 TESTIPBSTAT
27B2 BRN SCANTDO
27B3 WHILE TRUE
27B4 MHUNT 3,AMXOR,ADCB
27B5 AND BS,3,ADCBINOP [ DEVICE INOPERABLE
27B6 DO
27B7 IF BS,3,ADCBTUNATT [ UNATTENDED SPOOLING
27B8 THEN
27B9 LDN 4 2 [ OUTPUT TO BOTH CONSOLES
27B= ELSE
27B? LDN 4 0 [ TO CLUSTER CONSOLE ONLY
27B# FI
27B* LONGSET #36,(GEOERR),IDENTNO(3)
27BB OUTPER
27BC DEMANDX 4,PJMARY(1),SCANTDO,STERM,,2
27BD VFREEW GMON,AOUT
27BF VFREEW ADATA,ADEMAND
27BG REPEAT
27BH ADX 7 FX1
27BJ LDN 0 0
27BK EXIT 7 0
27BL [
27BM SCANTDO [ CANTDO TO PLEASE ENGAGE
27BN [
27BP MHUNTW 3,AMXOR,ADCB
27BQ BS 3,ADCBWAITWR [ WAITING TO BE WRONGED
27BR [
27BS STERM [ TERMINATE TO PLEASE ENGAGE
27BT [
27BW ADX 7 FX1
27BX LDN 0 1
27BY EXIT 7 0
27B^ [
27C2 [************************************************************
27C3 [
27C4 SCHANMODE
27C5 [
27C6 [************************************************************
27C7 [
27C8 [ CHANGE MODE FOR BINARY OUTPUT
27C9 [
27C= SBX 7 FX1
27CX LDN 0 1
27CY ADX 7 FX1
27C^ EXIT 7 0
27D2 [
27D3 [************************************************************
27D4 [
27D5 SRUNOUT
27D6 [
27D7 [************************************************************
27D8 [
27D9 [ RUNOUT FOR TAPE PUNCH
27D= [
27D? [ X6 = NO OF RUNOUT CHARS
27D# [
27D* SBX 3 FX1
27DB WHILE TRUE
27DC SMO FX2
27DD LDX 4 AWORK3 [ NPU SIZE IN CHARS
27DF SBX 6 4
27DG AND EITHER,6,PZ [ MUCH MORE RUNOUT REQUIRED
27DH ADX 4 6
27DJ OR 4,PZ [ LITTLE MORE RUNOUT REQUIRED
27DK DO
27DL CALL 7 PCOR [ SETUP AMXOR/IOUT
27DM LDX 0 TAPE+1(1)
27DN STO 0 IDATA(2)
27DP LDX 1 ALOGLEN(2)
27DQ SBN 1 IDATA-A1+1
27DR LDX 4 5
27DS ADN 5 1
27DT MOVE 4 0(1) [ MOVE IN NULL CHARS
27DW REPEAT
27DX ADX 3 FX1
27DY EXIT 3 0
27D^ [
27F2 [************************************************************
27F3 [
27F4 SSTARS
27F5 [
27F6 [************************************************************
27F7 [
27F8 [ FORMAT TERMINATING LINE OF ASTERISKS
27F9 [
27F= [
27F? SBX 6 FX1
27F# ...#SKI G269&1
27F* ...(
27FB ... DOWN IPDBATCH,2
27FC ... LDX 0 ACOMMUNE1(2)
27FD ... STO 0 AWORK1(2) [ RESET AMXOR/IOUT BLOCK COUNT
27FF ...)
27FG ...#SKI G170&1$1
27FH ...(
27FJ ... SEGENTRY K57IPBLISTD
27FK ... LDN 4 A7021WIDTH+8
27FL ...)
27FM ...#SKI G170&1
27FN ...(
27FP ...#ALT K57IPBLISTD = 1022
27FQ ... LDN 4 8
27FR ... ADX 4 IWIDTH(2)
27FS ...)
27FT ...[ SEGENTRY FOR RESTORE TIME MACRO - LISTDC2
27FW ... SEGENTRY K60IPBLISTD
27FX ... NULL
27FY ... NULL
27F^ ... NULL
27G2 ... NULL
27G3 ... ADN 4 4
27G4 ... SEGENTRY K61IPBLISTD
27G5 ... NULL
27G6 ... CALL 7 PCOR
27G7 ... LDN 4 STAREOLF(1)
27G8 ... MVCH 4 12 [NEWLINE NEWLINE ^******
27G9 ... LDX 4 5
27G= ... SBN 4 1
27G? ...#SKI G170&1$1
27G# ...(
27G* ... SEGENTRY K58IPBLISTD
27GB ... MVCH 4 A7021WIDTH-10 [ **....**
27GC ...)
27GD ...#SKI G170&1
27GF ...(
27GG ...#ALT K58IPBLISTD = 1022
27GH ... SMO FX2
27GJ ... LDX 3 IWIDTH
27GK ... MVCH 4 -10(3)
27GL ...)
27GM ... LDN 4 STAREND(1)
27GN ... MVCH 4 6 [ **^ FORM FEED - SEE LFTHROW MACRO
27GP ... MHUNTW 3,AMXOR,ADCB
27GQ ...[ SEGENTRY FOR RESTORE TIME MACRO - LISTDC2
27GR ... SEGENTRY K62IPBLISTD
27GS ... NULL
27GT ... NULL
27GW ... NULL
27GX ... NULL
27GY ... LDN 4 PDC2(1)
27G^ ... MVCH 4 4 [ CR DC2
27H2 ... SEGENTRY K63IPBLISTD
27H3 ... NULL
27H4 ... LDX 3 A1+FPTR(3) [ X3 - AMXOR/ADEVS ENTRY
27H5 ... IF BS,3,ADEVS1901A [ 1901A RJE
27H6 ... THEN
27H7 ... BS 2,IOUTEODATA [ END OF DATA STREAM
27H8 ... FI
27H9 ... BS 2,IOUTEORESTR [ END OF RESTART SECTION
27H= ... ADX 6 FX1
27H? ... EXIT 6 0
27H# ...[
27H* ...[
27HB ...[
27HC ...[
27HD ...ZLINE
27HF ...[
27HG ...[
27HH ...[ END OF LINE IN HEADINGS : NL+RUNOUT FOR TP, NL+NL FOR LP
27HJ ...[
27HK ... LDN 4 ACES
27HL ... MVCH 4 3
27HM ... ANDX 5 BITS22LS
27HN ... SMO FX2
27HP ... LDX 6 AWORK1
27HQ ... BNG 6 TLINE
27HS LDN 4 NEWLINES(1)
27J? LDN 2 1
27JQ BRN ZMOVE
27K9 TLINE
27KN LDN 4 TAPE(1)
27L7 LDN 2 2
27LL ZMOVE
27M5 MOVE 4 0(2)
27MJ ADX 5 2
27N3 EXIT 7 0
27NG [
27N^ [
27PD [
27PX [
27QB SINITIAL
27QT [
27R# [
27RR SBX 6 FX1
27S= STO 6 ACOMMUNE1(2)
27TG MHUNTW 3,GOUT,INFO
9J82 LDX 6 AWORK1(2) [>0 IF PRINT ; <0 IF TAPE
9JML LDX 0 GFLI(3) [INITIAL LINE NUMBER
9JXD BNG 0 XFRER
9K7= STO 0 IWORK10(2) [RECORD NUMBER FOR STEP
9KLW STO 0 IWORK1(2) [TO DETECT FAIL DURING HEADINGS
9KPF BRN XFROK
9KS4 XFRER
9KWM STOZ IWORK10(2)
9K^= STOZ IWORK1(2)
9L3T XFROK
9L6G STOZ IWORK9(2) [INITIAL RESTART SECTION NUMBER
9LL6 LDX 0 GFTY(3)
9M5Q STO 0 IWORK16(2) [TYPE OF FILE
9MKB LDX 0 GNLI(3) [NO. OF LINES TO BE OUTPUT
9N52 BNZ 0 NEND
9NJL NGN 0 1 [INDICATE ALL LINES REQUIRED
9P4= NEND STO 0 IWORK12(2)
9PHW LDCT 0 3
9Q3G ANDX 0 GMODE(3) [TYPE OF RESTART REQUIRED
9QH6 SLL 0 7
9QSP ADS 0 IWORK11(2)
9R6# MHUNTW 3,AMXOR,ADCB
9R7G LDX 0 IWAIT(3)
9R8N ANDN 0 4
9R9W SRC 0 6 [B3 IN AWORK4 SET IF
9R?4 STO 0 AWORK4(2) [...SPOOLING
9R#= BNZ 0 XSPL [J IF SPOOLING
9R*D BNG 6 XNLP [J IF TP
9RBL XSPL
9S22 LDX 4 IPAGE [INSTALLATION PARAMETER
9S77 LDN 0 32
9S8W TXL 4 0 [AT LEAST 32 PAGES
9S=K BCC XSX
9S## LDX 4 0
9SB3 XSX ADN 4 1 [EXTRA WORD FOR TOTAL NO OF PAGES
9SFL ADN 4 10
9S^= SETUPCORE 4,3,ADATA,IPTEMP [WILL HOLD FIRST REC NO PER PAGE
9TDW STOZ A1(3) [INITIALISE PAGE COUNT
9TYG LDX 0 IWORK10(2)
9W77 STOZ A1+1(3)
9W9B STO 0 A1+2(3)
9WQG XNLP
9X4Y MHUNTW 3,GOUT,INFO
9XCB NOPRE LDX 7 GMODE(3)
9XX2 STO 7 AWORK2(2) [B2 INDICATES THERE IS A SETUP FILE
9YBL SLL 7 2
9YW= ANDX 7 GSIGN
9^64 ORS 7 AWORK4(2)
9^TG LDN 0 0
=2*6 LDX 4 GFTY(3)
=2SQ ANDN 4 1 [B23 : MAINFILE IS BASIC
=3#B BNG 6 NONM [J IF TAPE
=3S2 #
=4?L LDN 0 8 [INITIAL PAGE LINE COUNT = 8
=4R= STO 0 IWORK17(2)
=5=W LDX 0 GMFMSK(3) [CATEGORY MASK IF MONFILE
=5QG STO 0 IWORK14(2)
=6=6 LDX 0 GMODE(3) [SEQUENCING , MONFILE AND
=6PQ ANDN 0 7 [SPECIAL LISTING BITS
=79B BPZ 7 NOSU [NO SETUP FILE
=7P2 LDX 5 GFTY(3)
=88L ANDN 5 #20 [B19 : SETUP FILE IS BASIC
=8N= LDX 6 GFTY(3)
=97W ANDN 6 #360 [SETUP FILE TYPE
=9MG BNZ 5 SUFB [J IF SETUP FILE IS BASIC
==76 ORN 6 1 [AMORPHOUS SETUP FILE:SET SPECIAL BIT
==LQ BRN TNON
=?6B SUFB ORX 6 GSIGN [INDICATE BASIC FILE
=?L2 TNON STO 6 IWORK8(2) [STORE SETUP FILE TYPE
=#5L LDN 6 1
=#K= STOZ IWORK5(2) [START SETUP FILE AT BEGINNING
=*4W STOZ IWORK6(2) [LINE RESTART SETUP FILE
=*JG NGS 6 IWORK7(2) [LIST ALL THE SETUP FILE
=B46 NOSU LDN 5 4
=BHQ ANDX 5 0 [B21 SET IF MONFILE
=C3B BZE 5 NONM
=CH2 ANDN 0 6 [MONFILE : UNSET SPECIAL BIT
=D2L BRN SPE
=DG= NONM BNZ 4 SPE
=D^W ORN 0 1 [AMORPHOUS FILE : SET SPECIAL BIT
=FFG SPE LDEX 5 GFTY(3)
=F^6 SLL 5 4 [MAINFILE TYPE
=GDQ ORX 0 5
=GYB BZE 4 TAFF [NOT BASIC FILE
=HD2 ADX 0 GSIGN [PFCC PRESENT INDICATOR
=HXL TAFF STO 0 IWORK13(2)
=J3P LDX 6 ACOMMUNE1(2)
=J7S ADX 6 FX1
=J?X EXIT 6 0
=JD2 [
=JD* [
=JDN [
=JF3 [ WW WW W
=JFB [ WW WW WW
=JFP [ WW WW WWW
=JG4 [ WWWW WW
=JGC [ WWWWW WW
=JGQ [ WW WW WW
=JH5 [ WW WW WW
=JHD [ WW WW WW
=JJ5 [
=JN8 SK1IPBLISTD
=JP2 [
=JPS MHUNTW 3,GOUT,INFO
=JQL JBS Z1UIJPC,3,BLFFRTOER [ J IF ERROR DETECTED
=JRD CALL 7 RINGO
=JS? CALL 6 SINITIAL
=JYC LDX 0 AWORK1(2)
=J^Y BPZ 0 NOTP
=K3F ACROSS IPBLISTE,1
=K52 NOTP
=K5S BPZ 7 NOSPE [NO SPECIAL STATIONERY
=K6M MHUNTW 3,ADATA,IPTEMP
=K9= STOZ A1+2(3) [SETUP STARTS FROM ZERO
=KBG ACROSS IPBLISTB,2 [LIST TESTPATTERN FILE FIRST
=KW6 NOSPE ACROSS IPBLISTB,1
=KWN [
=KX= [
=KXS [
=KYB Z1UIJPC
=KYY LDX 7 GMODE(3)
=K^G ANDX 7 BIT11
=L24 BZE 7 NDRQ [J UNLESS READ ERROR WHEN LOOKING FOR ST
=L2L MHUNTW 3,AMXOR,ADCB
=L38 LDN 0 4
=L3Q ANDX 0 IWAIT(3)
=L4# BNZ 0 RESPL
=L4W LDXC 7 ISTATUS(3)
=L5D BCS RCREQ [J IF ALREADY INOP
=L62 RESPL
=L6J MHUNTW 1,AMXOR,IOUT
=L76 LDCT 0 #100
=L7N ORS 0 IPBIDE+1(1) [END OF DATA STREAM
=L8= CALL 7 RINGO [SEND HEADINGS
=L8S MHUNTW 3,AMXOR,ADCB
=L9B LDX 0 IWAIT(3)
=L9Y ANDN 0 4
=L=G BNZ 0 SPCO [J IF SPOOLING
=L?4 LDCT 7 #400
=L?L RCREQ
=L#8 LDX 6 IDENTNO(3)
=L#Q LONGSET #36,(GEOERR),6
=L*# ACROSS IPBLISTC,4
=L*W SPCO
=LBD OUTPER
=LC2 INFORM 0,JCORRUPT,1
=LCJ [
=LD6 [
=LDN [ WW WW WW
=LF= [ WW WW WW
=LFS [ WW WW WW
=LGB [ WWWW WW WW
=LGY [ WWWWW WWWWWWWW
=LHG [ WW WW WW
=LJ4 [ WW WW WW
=LJL [ WW WW WW
=LK8 [
=LKQ [
=LL# SK4IPBLISTD
=LLW [
=LMD [
=LN2 NDRQ
=LPJ CALL 7 SETU [GET BUFFER FOR ERROR MESSAGE
=M7? MHUNTW 1,ADATA,HEADING
=MK2 LDN 4 HEADPFCC(1) [MOVE IN MESSAGE
=N2P SMO HEADCNT(1)
=NDD MVCH 4 0
=NW7 FREECORE 1
=P?W CALL 7 ZLINE
=PPK MHUNTW 3,AMXOR,IOUT
=Q7# SBN 5 IDATA(3)
=QK3 SLC 5 2
=R2Q DSA 5 IPBIDE+1(3)
=RDF ADN 5 IDATA-A1*4+3
=RW8 SRL 5 2
=S?X ALTLEN 3,5
=SGQ CALL 6 SINITIAL
=SPL MHUNT 1,GOUT,INFO
=T7* IF BS,1,BLFSETUP [SETUP FILE
=TK4 THEN
=W2R FILEMOVE 0,1 [INTERCHANGE SO MAIN AT TOP
=W7* LDCT 0 #400
=W?X ERS 0 AWORK4(2) [INVERT FILE INDICATOR
=WDG FI
=X?Y MHUNTW 3,AMXOR,ADCB
=XPM IF BS,3,ADCBTSPOOL
=Y7B AND BS,3,ADCB7502LP
=YK5 THEN
=^2S BRN SK7IPBLISTD
=^DH ELSE
=^W= MHUNTW 3,AMXOR,IOUT
?2?^ LDCT 0 #40
?2PN ORS 0 IPBIDE+1(3) [REPORT OUTPUT SENT
?37C ACROSS IPBLISTC,1
?3K6 FI
?3K9 [
?3K# [
?3KC [
?3KG [ WW WW WWWWW
?3KK [ WW WW WW WW
?3KN [ WW WW WW
?3KR [ WWWW WW
?3KW [ WWWWW WWWWW
?3K^ [ WW WW WW
?3L4 [ WW WW WW
?3L7 [ WW WW WWWWWWWW
?3L= [
?3L* SK2IPBLISTD
?3LD [
?3LH [ ENGAGE BUTTON INTERUPT
?3LL [
?3LP STOZ AWORK1(2) [ COUNT OF AMXOR/IOUT BLOCKS
?3LS MHUNTW 3,AMXOR,ADCB
?3LT ...[ ######### RMTLFUNAV RESTORE TIME MACRO ############
?3LW ...[
?3LX ... SEGENTRY K20IPBLISTD
?3LY ... BRN XIFSP [IF ON, THIS REPLACED BY NULL
?3L^ ... JBS XSUI,3,ADCBINOP [IF INOP, JUMP TO SUICIDE
?3M2 ... SEGENTRY K21IPBLISTD
?3M3 ...XIFSP
?3M4 ... IF BC,3,ADCBTSPOOL [ NOT SPOOLING
?3M5 ... AND BC,3,ADCBINOP [ NOT INOPERABLE
?3M6 ... THEN
?3M8 LDCH 0 JSOURCE1(2)
?3M? SBN 0 2
?3MB IF 0,ZE [ LINE PRINTER
?3MF THEN
?3MG ...#SKI G170&1$1
?3MH ...(
?3MJ SEGENTRY K55IPBLISTD
?3MM LDN 4 A7021WIDTH+6
?3MN ...)
?3MP ...#SKI G170&1
?3MQ ...(
?3MR ...#ALT K55IPBLISTD = 1022
?3MS ... LDN 4 6
?3MT ... ADX 4 IWIDTH(2)
?3MW ...)
?3MX ...[ SEGENTRY FOR RESTORE TIME MACRO - LISTDC2
?3MY ... SEGENTRY K64IPBLISTD
?3M^ ... ADN 4 4
?3N3 CALL 7 PCOR
?3N6 LDN 4 STARSOLF(1)
?3N9 MVCH 4 8 [ FORM FEED ^****
?3N# LDX 4 5
?3NC SBN 4 1
?3ND ...#SKI G170&1$1
?3NF ...(
?3NG SEGENTRY K56IPBLISTD
?3NK MVCH 4 A7021WIDTH-8 [ ***....***
?3NL ...)
?3NM ...#SKI G170&1
?3NN ...(
?3NP ...#ALT K56IPBLISTD = 1022
?3NQ ... SMO FX2
?3NR ... LDX 3 IWIDTH
?3NS ... MVCH 4 -8(3)
?3NT ...)
?3NW ... LDN 4 STAREND(1)
?3NX ... MVCH 4 6 [ **^ FORM FEED - SEE LFTHROW MACR
?3NY ... LDN 4 PDC2(1)
?3N^ [ SEGENTRY FOR RESTORE TIME MACRO - LISTDC2
?3P4 SEGENTRY K65IPBLISTD
?3P7 MVCH 4 4 [ CR DC2
?3P= BS 2,IOUTEORESTR
?3P* ELSE [ TAPE PUNCH
?3PD LDX 0 IMDNPU(3)
?3PH ANDN 0 #7777
?3PL SLL 0 2
?3PP STO 0 AWORK3(2)
?3PS LDN 6 511
?3PX CALL 3 SRUNOUT
?3Q2 FI
?3Q5 CALL 7 RINGO
?3Q8 FI
?3RR #
?3RW LFEND EB
?3RX ...[
?3RY ...[ ########### RMTLFUNAV RESTORE TIME MACRO ###########
?3R^ ...[
?3S2 ...[ COME HERE IF MACRO ON AND DEVICE IS INOP
?3S3 ...[
?3S4 ...XSUI FREEPER [FREE DEVICE
?3S5 ... SUICIDE [AND SUICIDE
?3S6 ...[
?3S7 ...[
?3S8 ...[ WW WW WWWWWWWW
?3S= [ WW WW WW
?3S* [ WW WW WW
?3SD [ WWWW WWW
?3SH [ WWWWW WW
?3SL [ WW WW WW WW
?3SP [ WW WW WW WW
?3SS [ WW WW WWWWWW
?3SX [
?3T2 SK3IPBLISTD
?3T5 [
?3T8 [ END OF LISTING
?3T? [
?3TB STOZ AWORK1(2) [ COUNT OF AMXOR/IOUT BLOCKS
?3TF MHUNTW 1,AMXOR,ADCB
?3TJ IF BS,1,ADCBTSPOOL
?3TM AND BS,1,ADCB7502LP
?3TQ THEN
?3TT LFEND
?3TY FI
?3W3 MHUNT 1,GOUT,INFO
?3W6 IF BS,1,BLFBINARY
?3W9 THEN
?3W# MHUNT 1,AMXOR,ADCB
?3WC LDCT 0 #777
?3WG ANDX 0 IMDNPU(1)
?3WK CALL 7 SCHANMODE
?3WN ELSE
?3WR CALL 7 SENGAGE
?3WW IF 0,ZE [ DEVICE ENGAGED
?3W^ THEN
?3X4 MHUNTW 3,AMXOR,ADCB
?3X7 LDCH 0 JSOURCE1(2)
?3X= SBN 0 2
?3X* IF 0,ZE [ LINE PRINTER
?3XD THEN
?3XH CALL 6 SSTARS
?3XL ELSE [ TAPE PUNCH
?3XP MHUNTW 3,AMXOR,ADCB
?3XS LDX 0 IMDNPU(3)
?3XX ANDN 0 #7777
?3Y2 SLL 0 2
?3Y5 STO 0 AWORK3(2)
?3Y8 LDN 6 511
?3Y? CALL 3 SRUNOUT
?3YB FI
?3YF CALL 7 RINGO
?3YJ FI
?3YM FI
?3YQ LFEND
?3YT [
?3YY [
?3^3 [
?3^6 SK7IPBLISTD
?3^9 [
?3^# [ END OF LISTING - CLEAN COPY SPOOLING PRINTER ONLY
?3^C [
?3^G MHUNTW 3,AMXOR,ADCB
?3^K CALL 6 SSTARS [ FORMAT ASTERISK LINE
?3^N ACROSS IPBLISTC,1
?43= #END
^^^^ ...07672556000700000000