{{htmlmetatags>metatag-description:(ICL George 3 and George 4 source: IPCONF865)}}
====== IPCONF865 ======
(George Source)
**Macros used:** [[george:macro:BXE|BXE]], [[george:macro:BXL|BXL]], [[george:macro:CCBB|CCBB]], [[george:macro:CLEAR|CLEAR]], [[george:macro:DECLINK|DECLINK]], [[george:macro:DESUSPEND|DESUSPEND]], [[george:macro:DOWN|DOWN]], [[george:macro:FINDACTFB|FINDACTFB]], [[george:macro:FINMOVE|FINMOVE]], [[george:macro:FREECORE|FREECORE]], [[george:macro:HUNT2|HUNT2]], [[george:macro:HUNTW|HUNTW]], [[george:macro:MENDAREA|MENDAREA]], [[george:macro:SEG|SEG]], [[george:macro:SEGENTRY|SEGENTRY]], [[george:macro:SREP|SREP]], [[george:macro:TICKLE|TICKLE]], [[george:macro:UP|UP]]
22FL ... SEG IPCONF,,JOHN BAILEY
22^= #
23DW ... SEGENTRY K1IPCONF,X1IPCONF
23YG ...#
24D6 ...# STORED WORDS
28*6 RNINE #02400000
29#B TBIT1 #20000000
2F6B # SUBROUTPNE TO LOCATE LINK ELEMENTS IN STACK
2FL2 # GIVEN THE LINK IDENTIFIER IN ACOMMUNE1(2) [X2 MUDT = FX2
2G5L # ADDRESS IS LEFT IN X3. LINK IS X7. ON EXIT X1=FX1
2GK= #
2H4W SREL
2HJG LDX 3 IPCPTR(2) [FIND IPC ACTIVITY
2J46 HUNT2 3,IPCD,IPSTACK [FIND STACK BLOCK
2JHQ LDX 1 ARINGNO(3)
2K3B ANDN 1 #7777
2KH2 BZE 1 SFR1 [STACK EMPTY
2L2L ADN 3 A1
2LG= SFR3 LDX 0 ALINUM(3)
2L^W BXE 0 ACOMMUNE1(2),SFR2
2MFG ADN 3 ARECLEN
2M^6 BCT 1 SFR3
2NDQ SFR1 NGN 3 1
2NYB SFR2 LDX 1 FX1
2PD2 EXIT 7 0
2PXL # SUBROUTINE USED TO SET OBJECT PROGRAM REPLIES
2QC= #
2QWW SREP
2RBG LDX 3 ACOMMUNE1(2)
2RW6 STO 4 ACC4(2)
2S*Q STO 5 ACC5(2)
2STB STO 7 ACC7(2)
2T*2 LDX 5 AREPPTR(3)
2TSL LDX 3 FPTR(3)
2W#= SBN 3 ARINGEL [ADDRESS OF AOLPT
2WRW #SKI G3
2X?G FINDACTFB 3,,APET,,,BPTR [ADDRESS OF AOLPTS PCA
2XR6 #SKI IPCG4
2Y=Q HUNT2 2,ADATA,HLOCKDOWN,3
2YQB SMO FX2
2^=2 LDN 4 ACOMMUNE2
2^PL LDN 7 1
329= FINMOVE 3,5,4,7,HLOCKB1,2,1
32NW LDX 2 FX2
338G LDX 4 ACC4(2)
33N6 LDX 5 ACC5(2)
347Q LDX 7 ACC7(2)
34MB LDX 3 ACOMMUNE1(2)
3572 NGNC 0 2
35LL ANDS 0 ASTATUS1(3)
366= STOZ ATIMCT(3)
36KW STOZ ASTR(3)
375G STOZ ALENTR(3)
37K6 STOZ AREPPTR(3)
384Q LDX 0 ASTMEL(3)
38JB STO 0 AWORK4(2)
3942 STOZ ASTMEL(3)
39HL LDX 3 FPTR(3)
3=3= SBN 3 ARINGEL
3=GW #SKI IPCG4
3?2G (
3?G6 HUNT2 2,ADATA,HLOCKDOWN,3
3?^Q CLEAR APETADDR(3),0,HLOCKB1,2,2
3#FB LDX 2 FX2
3#^2 )
3*DL CCBB 3
3*LW ... STO 5 ACC5(2)
3*T6 ... LDX 5 AWORK4(2)
3B3B ... TICKLE JOBNO(3),5
3B9L ... LDX 5 ACC5(2)
3BCW LDX 3 ARINGEL(3)
3BXG EXIT 6 0
3WHG # THIS SECTION CLEARS AWAY TASKS ASSOCIATED WITH AN
3X36 # IPB & DISESTABLISHES LINKS THROUGH THE IPB.
3XGQ # IT IS USED WHEN AN INITIALISE SEQUENCE IS INITIATED FROM
3Y2B # THE OTHER END,AND WHEN DIALOGUE IS SUSPENDED BY THIS END
3YG2 ...#
3Y^L ...X1IPCONF
3^F= ...SCLR
3^P4 ... LDX 2 FX2
3^YW SCL3 HUNTW 3,IPCD,ATASK
42DG BNG 3 SCL1
42Y6 LDX 0 A1+1(3)
43CQ SBN 0 1
43XB BZE 0 SCL2 [OPEN
44C2 SBN 0 2
44WL BNZ 0 SCL13
45B= LDX 0 A1(3)
45TW STO 0 IPWRB+1(2)
46*G DOWN IPCONC,20 [GET RID OF CLOSE TASK
46T6 BRN SCL3
47#Q SCL13 SBN 0 2
47SB BZE 0 SCL10 [OPEN OFR GEORGE
48#2 SCL5 FREECORE 3
48RL BRN SCL3
49?= SCL2 LDX 0 A1(3)
49QW STO 0 ACOMMUNE1(2)
4==G DOWN IPCONB,2
4=Q6 BRN SCL3
4?9Q SCL4 HUNTW 3,IPCD,ATASK
4?PB BRN SCL5
4#92 SCL10 LDX 0 A1(3) [OPEN TASK FOR GEORGE LINK
4#NL STO 0 ACOMMUNE1(2)
4*8= CALL 7 SREL
4*MW LDCT 0 #10
4B2? ... ERX 0 ASTATUS2(3) [REMOVE OPEN PROGRESS
4B#N ... ANDS 0 ASTATUS2(3)
4BM6 BRN SCL4
4C6Q # HAVING CLEARED THE TASK QUEUE,WE NOW DISESTABLISH ALL
4CLB # LINKS THROUGH THE IPB
4D62 SCL1 LDX 3 IPCPTR(2)
4DKL HUNT2 3,IPCD,IPSTACK
4F5= LDX 7 ARINGNO(3)
4FJW ANDN 7 #7777
4G4G BZE 7 SCLEX
4GJ6 ADN 3 A1
4H3Q SCL6 LDX 0 ASTATUS2(3)
4HHB SLL 0 1
4J32 BNG 0 SCL7 [NOT ESTABLISHED
4JGL LDX 0 APTRIPB(3)
4K2= TXU 0 FX2 [THROUGH THIS IPB,SO DISESTABLISH
4KFW BCS SCL7
4K^G LDX 0 BPTR(3)
4LF6 ... BNZ 0 SCL8A
4LYQ SCL7 ADN 3 ARECLEN
4MDB BCT 7 SCL6 [DO NEXT
4MY2 ...SCLEX UP [FINISHED, UP TO IPCONE
4NX= # LINK TO BE DISESTABLISHED
4P4D ...SCL8A LDX 0 BPTR(3)
4P9L ... BZE 0 SCL7
4PBW SCL8 LDX 0 ASTATUS1(3)
4PWG ANDN 0 1
4QB6 LDCT 6 #100
4QTQ BZE 0 SCL9 [NO TRANSFER STORED
4R*B LDCT 0 #200
4RT2 ANDX 0 ASTATUS1(3)
4S#L BNZ 0 SCL11 [GEORGE LINK
4SS= LDX 0 RNINE(1)
4T?W STO 0 ACOMMUNE2(2)
4TRG STO 3 ACOMMUNE1(2)
4W?6 CALL 6 SREP [SET DISESTABLISHED REPLY
4WQQ SCL12
4X=B LDCT 6 #40
4XQ2 SCL9 ORS 6 ASTATUS2(3)
4Y9L LDX 0 TBIT1(1)
4YP= ERS 0 ASTATUS2(3) [MARK DISESTABLISHED
4^8W LDN 0 #7777
4^NG ANDS 0 ALINUM(3)
5286 LDCT 0 #200
52MQ ANDX 0 ASTATUS1(3)
537B BNZ 0 SCJA
53M2 STOZ APTRIPB(3)
546L SCJA DECLINK
54L= BRN SCL7
555W SCL11 LDX 0 RNINE(1) [SET REPLY FOR GEORGE LINK
55KG SMO FPTR(3)
5656 STO 0 IPCGREP-IPCRNG
56JQ STO 7 6
574B CALL 7 SLACT
57J2 STO 6 7
583L DESUSPEND
58H= NGNC 0 2
592W ANDS 0 ASTATUS1(3)
59GG ANDS 0 ASTATUS2(3)
5=26 STOZ ATIMCT(3)
5=FQ STOZ ASTR(3)
5=^B STOZ ALENTR(3)
5?F2 STOZ AREPPTR(3)
5?YL STOZ ASTMEL(3)
5#D= BRN SCL12
5#XW # S/R TO LOCATE GEORGE ACTIVITY OWNING LINK WHOSE ENTRY
5*CG # IS POINTED TO BY X3.
5*X6 SLACT LDX 2 FPTR(3)
5BBQ SBN 2 IPCRNG [CONTROL BLOCK
5BWB SLACT1
5CB2 LDX 2 BPTR(2)
5CTL LDX 0 ATYPE(2)
5D*= BXL 0 CACT,SLACT1
5DSW EXIT 7 0
5F#G ... MENDAREA 1023-0?,K99IPCONF
96GG #END
^^^^ ...42657235000300000000